lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11
  12 our $VERSION = '0.30';
  13
  14 __PACKAGE__->mk_accessors('template');
  15 __PACKAGE__->mk_accessors('include_path');
  16
  17 *paths = \&include_path;
  18
  19 =head1 NAME
  20
  21 Catalyst::View::TT - Template View Class
  22
  23 =head1 SYNOPSIS
  24
  25 # use the helper to create your View
  26     myapp_create.pl view TT TT
  27
  28 # configure in lib/MyApp.pm (Could be set from configfile instead)
  29
  30     MyApp->config(
  31         name     => 'MyApp',
  32         root     => MyApp->path_to('root'),
  33         'View::TT' => {
  34             # any TT configurations items go here
  35             INCLUDE_PATH => [
  36               MyApp->path_to( 'root', 'src' ),
  37               MyApp->path_to( 'root', 'lib' ),
  38             ],
  39             TEMPLATE_EXTENSION => '.tt',
  40             CATALYST_VAR => 'c',
  41             TIMER        => 0,
  42             # Not set by default
  43             PRE_PROCESS        => 'config/main',
  44             WRAPPER            => 'site/wrapper',
  45         },
  46     );
  47
  48 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  49
  50     sub message : Global {
  51         my ( $self, $c ) = @_;
  52         $c->stash->{template} = 'message.tt2';
  53         $c->stash->{message}  = 'Hello World!';
  54         $c->forward('MyApp::View::TT');
  55     }
  56
  57 # access variables from template
  58
  59     The message is: [% message %].
  60
  61     # example when CATALYST_VAR is set to 'Catalyst'
  62     Context is [% Catalyst %]
  63     The base is [% Catalyst.req.base %]
  64     The name is [% Catalyst.config.name %]
  65
  66     # example when CATALYST_VAR isn't set
  67     Context is [% c %]
  68     The base is [% base %]
  69     The name is [% name %]
  70
  71 =cut
  72
  73 sub _coerce_paths {
  74     my ( $paths, $dlim ) = shift;
  75     return () if ( !$paths );
  76     return @{$paths} if ( ref $paths eq 'ARRAY' );
  77
  78     # tweak delim to ignore C:/
  79     unless ( defined $dlim ) {
  80         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  81     }
  82     return split( /$dlim/, $paths );
  83 }
  84
  85 sub new {
  86     my ( $class, $c, $arguments ) = @_;
  87     my $config = {
  88         EVAL_PERL          => 0,
  89         TEMPLATE_EXTENSION => '',
  90         %{ $class->config },
  91         %{$arguments},
  92     };
  93     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  94         my $delim = $config->{DELIMITER};
  95         my @include_path
  96             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  97         if ( !@include_path ) {
  98             my $root = $c->config->{root};
  99             my $base = Path::Class::dir( $root, 'base' );
 100             @include_path = ( "$root", "$base" );
 101         }
 102         $config->{INCLUDE_PATH} = \@include_path;
 103     }
 104
 105     # if we're debugging and/or the TIMER option is set, then we install
 106     # Template::Timer as a custom CONTEXT object, but only if we haven't
 107     # already got a custom CONTEXT defined
 108
 109     if ( $config->{TIMER} ) {
 110         if ( $config->{CONTEXT} ) {
 111             $c->log->error(
 112                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 113             );
 114         }
 115         else {
 116             $config->{CONTEXT} = Template::Timer->new(%$config);
 117         }
 118     }
 119
 120     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 121         $c->log->debug( "TT Config: ", dump($config) );
 122     }
 123
 124     my $self = $class->next::method(
 125         $c, { %$config },
 126     );
 127
 128     # Set base include paths. Local'd in render if needed
 129     $self->include_path($config->{INCLUDE_PATH});
 130
 131     $self->config($config);
 132
 133     # Creation of template outside of call to new so that we can pass [ $self ]
 134     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 135     # of include paths to search for templates.
 136
 137     # Use a weakend copy of self so we dont have loops preventing GC from working
 138     my $copy = $self;
 139     Scalar::Util::weaken($copy);
 140     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 141
 142     if ( $config->{PROVIDERS} ) {
 143         my @providers = ();
 144         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 145             foreach my $p (@{$config->{PROVIDERS}}) {
 146                 my $pname = $p->{name};
 147                 my $prov = 'Template::Provider';
 148                 if($pname eq '_file_')
 149                 {
 150                     $p->{args} = { %$config };
 151                 }
 152                 else
 153                 {
 154                     if($pname =~ s/^\+//) {
 155                         $prov = $pname;
 156                     }
 157                     else
 158                     {
 159                         $prov .= "::$pname";
 160                     }
 161                     # We copy the args people want from the config
 162                     # to the args
 163                     $p->{args} ||= {};
 164                     if ($p->{copy_config}) {
 165                         map  { $p->{args}->{$_} = $config->{$_}  }
 166                                    grep { exists $config->{$_} }
 167                                    @{ $p->{copy_config} };
 168                     }
 169                 }
 170                 eval "require $prov";
 171                 if(!$@) {
 172                     push @providers, "$prov"->new($p->{args});
 173                 }
 174                 else
 175                 {
 176                     $c->log->warn("Can't load $prov, ($@)");
 177                 }
 178             }
 179         }
 180         delete $config->{PROVIDERS};
 181         if(@providers) {
 182             $config->{LOAD_TEMPLATES} = \@providers;
 183         }
 184     }
 185
 186     $self->{template} =
 187         Template->new($config) || do {
 188             my $error = Template->error();
 189             $c->log->error($error);
 190             $c->error($error);
 191             return undef;
 192         };
 193
 194
 195     return $self;
 196 }
 197
 198 sub process {
 199     my ( $self, $c ) = @_;
 200
 201     my $template = $c->stash->{template}
 202       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 203
 204     unless (defined $template) {
 205         $c->log->debug('No template specified for rendering') if $c->debug;
 206         return 0;
 207     }
 208
 209     my $output = $self->render($c, $template);
 210
 211     if (UNIVERSAL::isa($output, 'Template::Exception')) {
 212         my $error = qq/Couldn't render template "$output"/;
 213         $c->log->error($error);
 214         $c->error($error);
 215         return 0;
 216     }
 217
 218     unless ( $c->response->content_type ) {
 219         $c->response->content_type('text/html; charset=utf-8');
 220     }
 221
 222     $c->response->body($output);
 223
 224     return 1;
 225 }
 226
 227 sub render {
 228     my ($self, $c, $template, $args) = @_;
 229
 230     $c->log->debug(qq/Rendering template "$template"/) if $c->debug;
 231
 232     my $output;
 233     my $vars = {
 234         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 235         $self->template_vars($c)
 236     };
 237
 238     local $self->{include_path} =
 239         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 240         if ref $vars->{additional_template_paths};
 241
 242     unless ($self->template->process( $template, $vars, \$output ) ) {
 243         return $self->template->error;
 244     } else {
 245         return $output;
 246     }
 247 }
 248
 249 sub template_vars {
 250     my ( $self, $c ) = @_;
 251
 252     my $cvar = $self->config->{CATALYST_VAR};
 253
 254     defined $cvar
 255       ? ( $cvar => $c )
 256       : (
 257         c    => $c,
 258         base => $c->req->base,
 259         name => $c->config->{name}
 260       )
 261 }
 262
 263
 264 1;
 265
 266 __END__
 267
 268 =head1 DESCRIPTION
 269
 270 This is the Catalyst view class for the L<Template Toolkit|Template>.
 271 Your application should defined a view class which is a subclass of
 272 this module.  The easiest way to achieve this is using the
 273 F<myapp_create.pl> script (where F<myapp> should be replaced with
 274 whatever your application is called).  This script is created as part
 275 of the Catalyst setup.
 276
 277     $ script/myapp_create.pl view TT TT
 278
 279 This creates a MyApp::View::TT.pm module in the F<lib> directory (again,
 280 replacing C<MyApp> with the name of your application) which looks
 281 something like this:
 282
 283     package FooBar::View::TT;
 284
 285     use strict;
 286      use base 'Catalyst::View::TT';
 287
 288     __PACKAGE__->config->{DEBUG} = 'all';
 289
 290 Now you can modify your action handlers in the main application and/or
 291 controllers to forward to your view class.  You might choose to do this
 292 in the end() method, for example, to automatically forward all actions
 293 to the TT view class.
 294
 295     # In MyApp or MyApp::Controller::SomeController
 296
 297     sub end : Private {
 298         my( $self, $c ) = @_;
 299         $c->forward('MyApp::View::TT');
 300     }
 301
 302 =head2 CONFIGURATION
 303
 304 There are a three different ways to configure your view class.  The
 305 first way is to call the C<config()> method in the view subclass.  This
 306 happens when the module is first loaded.
 307
 308     package MyApp::View::TT;
 309
 310     use strict;
 311     use base 'Catalyst::View::TT';
 312
 313     MyApp::View::TT->config({
 314         INCLUDE_PATH => [
 315             MyApp->path_to( 'root', 'templates', 'lib' ),
 316             MyApp->path_to( 'root', 'templates', 'src' ),
 317         ],
 318         PRE_PROCESS  => 'config/main',
 319         WRAPPER      => 'site/wrapper',
 320     });
 321
 322 The second way is to define a C<new()> method in your view subclass.
 323 This performs the configuration when the view object is created,
 324 shortly after being loaded.  Remember to delegate to the base class
 325 C<new()> method (via C<$self-E<gt>next::method()> in the example below) after
 326 performing any configuration.
 327
 328     sub new {
 329         my $self = shift;
 330         $self->config({
 331             INCLUDE_PATH => [
 332                 MyApp->path_to( 'root', 'templates', 'lib' ),
 333                 MyApp->path_to( 'root', 'templates', 'src' ),
 334             ],
 335             PRE_PROCESS  => 'config/main',
 336             WRAPPER      => 'site/wrapper',
 337         });
 338         return $self->next::method(@_);
 339     }
 340
 341 The final, and perhaps most direct way, is to define a class
 342 item in your main application configuration, again by calling the
 343 uniquitous C<config()> method.  The items in the class hash are
 344 added to those already defined by the above two methods.  This happens
 345 in the base class new() method (which is one reason why you must
 346 remember to call it via C<MRO::Compat> if you redefine the C<new()>
 347 method in a subclass).
 348
 349     package MyApp;
 350
 351     use strict;
 352     use Catalyst;
 353
 354     MyApp->config({
 355         name     => 'MyApp',
 356         root     => MyApp->path_to('root'),
 357         'View::TT' => {
 358             INCLUDE_PATH => [
 359                 MyApp->path_to( 'root', 'templates', 'lib' ),
 360                 MyApp->path_to( 'root', 'templates', 'src' ),
 361             ],
 362             PRE_PROCESS  => 'config/main',
 363             WRAPPER      => 'site/wrapper',
 364         },
 365     });
 366
 367 Note that any configuration items defined by one of the earlier
 368 methods will be overwritten by items of the same name provided by the
 369 latter methods.
 370
 371 =head2 DYNAMIC INCLUDE_PATH
 372
 373 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 374
 375 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 376 follows:
 377
 378     $c->stash->{additional_template_paths} =
 379         [$c->config->{root} . '/test_include_path'];
 380
 381 If you need to add paths to the end of INCLUDE_PATH, there is also an
 382 include_path() accessor available:
 383
 384     push( @{ $c->view('TT')->include_path }, qw/path/ );
 385
 386 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 387 MUST check for duplicate paths. Without such checking, the above code will add
 388 "path" to INCLUDE_PATH at every request, causing a memory leak.
 389
 390 A safer approach is to use include_path() to overwrite the array of paths
 391 rather than adding to it. This eliminates both the need to perform duplicate
 392 checking and the chance of a memory leak:
 393
 394     @{ $c->view('TT')->include_path } = qw/path another_path/;
 395
 396 If you are calling C<render> directly then you can specify dynamic paths by
 397 having a C<additional_template_paths> key with a value of additonal directories
 398 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 399
 400 =head2 RENDERING VIEWS
 401
 402 The view plugin renders the template specified in the C<template>
 403 item in the stash.
 404
 405     sub message : Global {
 406         my ( $self, $c ) = @_;
 407         $c->stash->{template} = 'message.tt2';
 408         $c->forward( $c->view('TT') );
 409     }
 410
 411 If a stash item isn't defined, then it instead uses the
 412 stringification of the action dispatched to (as defined by $c->action)
 413 in the above example, this would be C<message>, but because the default
 414 is to append '.tt', it would load C<root/message.tt>.
 415
 416 The items defined in the stash are passed to the Template Toolkit for
 417 use as template variables.
 418
 419     sub default : Private {
 420         my ( $self, $c ) = @_;
 421         $c->stash->{template} = 'message.tt2';
 422         $c->stash->{message}  = 'Hello World!';
 423         $c->forward( $c->view('TT') );
 424     }
 425
 426 A number of other template variables are also added:
 427
 428     c      A reference to the context object, $c
 429     base   The URL base, from $c->req->base()
 430     name   The application name, from $c->config->{ name }
 431
 432 These can be accessed from the template in the usual way:
 433
 434 <message.tt2>:
 435
 436     The message is: [% message %]
 437     The base is [% base %]
 438     The name is [% name %]
 439
 440
 441 The output generated by the template is stored in C<< $c->response->body >>.
 442
 443 =head2 CAPTURING TEMPLATE OUTPUT
 444
 445 If you wish to use the output of a template for some other purpose than
 446 displaying in the response, e.g. for sending an email, this is possible using
 447 L<Catalyst::Plugin::Email> and the L<render> method:
 448
 449   sub send_email : Local {
 450     my ($self, $c) = @_;
 451
 452     $c->email(
 453       header => [
 454         To      => 'me@localhost',
 455         Subject => 'A TT Email',
 456       ],
 457       body => $c->view('TT')->render($c, 'email.tt', {
 458         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 459         email_tmpl_param1 => 'foo'
 460         }
 461       ),
 462     );
 463   # Redirect or display a message
 464   }
 465
 466 =head2 TEMPLATE PROFILING
 467
 468 See L<C<TIMER>> property of the L<config> method.
 469
 470 =head2 METHODS
 471
 472 =head2 new
 473
 474 The constructor for the TT view. Sets up the template provider,
 475 and reads the application config.
 476
 477 =head2 process
 478
 479 Renders the template specified in C<< $c->stash->{template} >> or
 480 C<< $c->action >> (the private name of the matched action.  Calls L<render> to
 481 perform actual rendering. Output is stored in C<< $c->response->body >>.
 482
 483 =head2 render($c, $template, \%args)
 484
 485 Renders the given template and returns output, or a L<Template::Exception>
 486 object upon error.
 487
 488 The template variables are set to C<%$args> if $args is a hashref, or
 489 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 490 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 491 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 492 can be defined to specify the name of a template variable through which the
 493 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 494 C<name> variables are omitted.
 495
 496 C<$template> can be anything that Template::process understands how to
 497 process, including the name of a template file or a reference to a test string.
 498 See L<Template::process|Template/process> for a full list of supported formats.
 499
 500 =head2 template_vars
 501
 502 Returns a list of keys/values to be used as the catalyst variables in the
 503 template.
 504
 505 =head2 config
 506
 507 This method allows your view subclass to pass additional settings to
 508 the TT configuration hash, or to set the options as below:
 509
 510 =head2 paths
 511
 512 The list of paths TT will look for templates in.
 513
 514 =head2 C<CATALYST_VAR>
 515
 516 Allows you to change the name of the Catalyst context object. If set, it will also
 517 remove the base and name aliases, so you will have access them through <context>.
 518
 519 For example:
 520
 521     MyApp->config({
 522         name     => 'MyApp',
 523         root     => MyApp->path_to('root'),
 524         'View::TT' => {
 525             CATALYST_VAR => 'Catalyst',
 526         },
 527     });
 528
 529 F<message.tt2>:
 530
 531     The base is [% Catalyst.req.base %]
 532     The name is [% Catalyst.config.name %]
 533
 534 =head2 C<TIMER>
 535
 536 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 537 C<Catalyst::View::TT> will enable profiling of template processing
 538 (using L<Template::Timer>). This will embed HTML comments in the
 539 output from your templates, such as:
 540
 541     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 542     <!-- TIMER START: include mainmenu/cssindex.tt -->
 543     <!-- TIMER START: process mainmenu/cssindex.tt -->
 544     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 545     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 546
 547     ....
 548
 549     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 550
 551
 552 =head2 C<TEMPLATE_EXTENSION>
 553
 554 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 555
 556 For example:
 557
 558   package MyApp::Controller::Test;
 559   sub test : Local { .. }
 560
 561 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 562 <root>/test/test.tt.
 563
 564 =head2 C<PROVIDERS>
 565
 566 Allows you to specify the template providers that TT will use.
 567
 568     MyApp->config({
 569         name     => 'MyApp',
 570         root     => MyApp->path_to('root'),
 571         'View::TT' => {
 572             PROVIDERS => [
 573                 {
 574                     name    => 'DBI',
 575                     args    => {
 576                         DBI_DSN => 'dbi:DB2:books',
 577                         DBI_USER=> 'foo'
 578                     }
 579                 }, {
 580                     name    => '_file_',
 581                     args    => {}
 582                 }
 583             ]
 584         },
 585     });
 586
 587 The 'name' key should correspond to the class name of the provider you
 588 want to use.  The _file_ name is a special case that represents the default
 589 TT file-based provider.  By default the name is will be prefixed with
 590 'Template::Provider::'.  You can fully qualify the name by using a unary
 591 plus:
 592
 593     name => '+MyApp::Provider::Foo'
 594
 595 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 596 from the general config, into the config for the provider:
 597
 598     DEFAULT_ENCODING    => 'utf-8',
 599     PROVIDERS => [
 600         {
 601             name    => 'Encoding',
 602             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 603         }
 604     ]
 605
 606 This can prove useful when you want to use the additional_template_paths hack
 607 in your own provider, or if you need to use Template::Provider::Encoding
 608
 609 =head2 HELPERS
 610
 611 The L<Catalyst::Helper::View::TT> and
 612 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 613 your view module.  There are invoked by the F<myapp_create.pl> script:
 614
 615     $ script/myapp_create.pl view TT TT
 616
 617     $ script/myapp_create.pl view TT TTSite
 618
 619 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 620 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 621 further.  It also creates a default set of templates to get you
 622 started.  It also configures the view module to locate the templates
 623 automatically.
 624
 625 =head1 SEE ALSO
 626
 627 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 628 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 629
 630 =head1 AUTHORS
 631
 632 Sebastian Riedel, C<sri@cpan.org>
 633
 634 Marcus Ramberg, C<mramberg@cpan.org>
 635
 636 Jesse Sheidlower, C<jester@panix.com>
 637
 638 Andy Wardley, C<abw@cpan.org>
 639
 640 =head1 COPYRIGHT
 641
 642 This program is free software, you can redistribute it and/or modify it
 643 under the same terms as Perl itself.
 644
 645 =cut