lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11
  12 our $VERSION = '0.32';
  13
  14 __PACKAGE__->mk_accessors('template');
  15 __PACKAGE__->mk_accessors('include_path');
  16
  17 *paths = \&include_path;
  18
  19 =head1 NAME
  20
  21 Catalyst::View::TT - Template View Class
  22
  23 =head1 SYNOPSIS
  24
  25 # use the helper to create your View
  26
  27     myapp_create.pl view TT TT
  28
  29 # configure in lib/MyApp.pm (Could be set from configfile instead)
  30
  31     MyApp->config(
  32         name     => 'MyApp',
  33         root     => MyApp->path_to('root'),
  34         'View::TT' => {
  35             # any TT configurations items go here
  36             INCLUDE_PATH => [
  37               MyApp->path_to( 'root', 'src' ),
  38               MyApp->path_to( 'root', 'lib' ),
  39             ],
  40             TEMPLATE_EXTENSION => '.tt',
  41             CATALYST_VAR => 'c',
  42             TIMER        => 0,
  43             # Not set by default
  44             PRE_PROCESS        => 'config/main',
  45             WRAPPER            => 'site/wrapper',
  46             render_die => 1, # Default for new apps, see render method docs
  47         },
  48     );
  49
  50 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  51
  52     sub message : Global {
  53         my ( $self, $c ) = @_;
  54         $c->stash->{template} = 'message.tt2';
  55         $c->stash->{message}  = 'Hello World!';
  56         $c->forward( $c->view('TT') );
  57     }
  58
  59 # access variables from template
  60
  61     The message is: [% message %].
  62
  63     # example when CATALYST_VAR is set to 'Catalyst'
  64     Context is [% Catalyst %]
  65     The base is [% Catalyst.req.base %]
  66     The name is [% Catalyst.config.name %]
  67
  68     # example when CATALYST_VAR isn't set
  69     Context is [% c %]
  70     The base is [% base %]
  71     The name is [% name %]
  72
  73 =cut
  74
  75 sub _coerce_paths {
  76     my ( $paths, $dlim ) = shift;
  77     return () if ( !$paths );
  78     return @{$paths} if ( ref $paths eq 'ARRAY' );
  79
  80     # tweak delim to ignore C:/
  81     unless ( defined $dlim ) {
  82         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  83     }
  84     return split( /$dlim/, $paths );
  85 }
  86
  87 sub new {
  88     my ( $class, $c, $arguments ) = @_;
  89     my $config = {
  90         EVAL_PERL          => 0,
  91         TEMPLATE_EXTENSION => '',
  92         %{ $class->config },
  93         %{$arguments},
  94     };
  95     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
  96         my $delim = $config->{DELIMITER};
  97         my @include_path
  98             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
  99         if ( !@include_path ) {
 100             my $root = $c->config->{root};
 101             my $base = Path::Class::dir( $root, 'base' );
 102             @include_path = ( "$root", "$base" );
 103         }
 104         $config->{INCLUDE_PATH} = \@include_path;
 105     }
 106
 107     # if we're debugging and/or the TIMER option is set, then we install
 108     # Template::Timer as a custom CONTEXT object, but only if we haven't
 109     # already got a custom CONTEXT defined
 110
 111     if ( $config->{TIMER} ) {
 112         if ( $config->{CONTEXT} ) {
 113             $c->log->error(
 114                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 115             );
 116         }
 117         else {
 118             $config->{CONTEXT} = Template::Timer->new(%$config);
 119         }
 120     }
 121
 122     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 123         $c->log->debug( "TT Config: ", dump($config) );
 124     }
 125
 126     my $self = $class->next::method(
 127         $c, { %$config },
 128     );
 129
 130     # Set base include paths. Local'd in render if needed
 131     $self->include_path($config->{INCLUDE_PATH});
 132
 133     $self->config($config);
 134
 135     # Creation of template outside of call to new so that we can pass [ $self ]
 136     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 137     # of include paths to search for templates.
 138
 139     # Use a weakend copy of self so we dont have loops preventing GC from working
 140     my $copy = $self;
 141     Scalar::Util::weaken($copy);
 142     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 143
 144     if ( $config->{PROVIDERS} ) {
 145         my @providers = ();
 146         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 147             foreach my $p (@{$config->{PROVIDERS}}) {
 148                 my $pname = $p->{name};
 149                 my $prov = 'Template::Provider';
 150                 if($pname eq '_file_')
 151                 {
 152                     $p->{args} = { %$config };
 153                 }
 154                 else
 155                 {
 156                     if($pname =~ s/^\+//) {
 157                         $prov = $pname;
 158                     }
 159                     else
 160                     {
 161                         $prov .= "::$pname";
 162                     }
 163                     # We copy the args people want from the config
 164                     # to the args
 165                     $p->{args} ||= {};
 166                     if ($p->{copy_config}) {
 167                         map  { $p->{args}->{$_} = $config->{$_}  }
 168                                    grep { exists $config->{$_} }
 169                                    @{ $p->{copy_config} };
 170                     }
 171                 }
 172                 local $@;
 173                 eval "require $prov";
 174                 if(!$@) {
 175                     push @providers, "$prov"->new($p->{args});
 176                 }
 177                 else
 178                 {
 179                     $c->log->warn("Can't load $prov, ($@)");
 180                 }
 181             }
 182         }
 183         delete $config->{PROVIDERS};
 184         if(@providers) {
 185             $config->{LOAD_TEMPLATES} = \@providers;
 186         }
 187     }
 188
 189     $self->{template} =
 190         Template->new($config) || do {
 191             my $error = Template->error();
 192             $c->log->error($error);
 193             $c->error($error);
 194             return undef;
 195         };
 196
 197
 198     return $self;
 199 }
 200
 201 sub process {
 202     my ( $self, $c ) = @_;
 203
 204     my $template = $c->stash->{template}
 205       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 206
 207     unless (defined $template) {
 208         $c->log->debug('No template specified for rendering') if $c->debug;
 209         return 0;
 210     }
 211
 212     local $@;
 213     my $output = eval { $self->render($c, $template) };
 214     if (my $err = $@) {
 215         my $error = qq/Couldn't render template "$template"/;
 216         $c->log->error($error);
 217         $c->error($error);
 218         return 0;
 219     }
 220
 221     unless ( $c->response->content_type ) {
 222         $c->response->content_type('text/html; charset=utf-8');
 223     }
 224
 225     $c->response->body($output);
 226
 227     return 1;
 228 }
 229
 230 sub render {
 231     my ($self, $c, $template, $args) = @_;
 232
 233     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 234
 235     my $output;
 236     my $vars = {
 237         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 238         $self->template_vars($c)
 239     };
 240
 241     local $self->{include_path} =
 242         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 243         if ref $vars->{additional_template_paths};
 244
 245     unless ( $self->template->process( $template, $vars, \$output ) ) {
 246         if (exists $self->{render_die}) {
 247             die $self->template->error if $self->{render_die};
 248             return $self->template->error;
 249         }
 250         require Carp;
 251         Carp::carp('The Catalyst::View::TT render() method of will die on error in a future release. If you want it to continue to return the exception instead, pass render_die => 0 to the constructor');
 252         return $self->template->error;
 253     }
 254     return $output;
 255 }
 256
 257 sub template_vars {
 258     my ( $self, $c ) = @_;
 259
 260     return  () unless $c;
 261     my $cvar = $self->config->{CATALYST_VAR};
 262
 263     defined $cvar
 264       ? ( $cvar => $c )
 265       : (
 266         c    => $c,
 267         base => $c->req->base,
 268         name => $c->config->{name}
 269       )
 270 }
 271
 272
 273 1;
 274
 275 __END__
 276
 277 =head1 DESCRIPTION
 278
 279 This is the Catalyst view class for the L<Template Toolkit|Template>.
 280 Your application should defined a view class which is a subclass of
 281 this module.  The easiest way to achieve this is using the
 282 F<myapp_create.pl> script (where F<myapp> should be replaced with
 283 whatever your application is called).  This script is created as part
 284 of the Catalyst setup.
 285
 286     $ script/myapp_create.pl view TT TT
 287
 288 This creates a MyApp::View::TT.pm module in the F<lib> directory (again,
 289 replacing C<MyApp> with the name of your application) which looks
 290 something like this:
 291
 292     package FooBar::View::TT;
 293
 294     use strict;
 295     use warnings;
 296
 297     use base 'Catalyst::View::TT';
 298
 299     __PACKAGE__->config(DEBUG => 'all');
 300
 301 Now you can modify your action handlers in the main application and/or
 302 controllers to forward to your view class.  You might choose to do this
 303 in the end() method, for example, to automatically forward all actions
 304 to the TT view class.
 305
 306     # In MyApp or MyApp::Controller::SomeController
 307
 308     sub end : Private {
 309         my( $self, $c ) = @_;
 310         $c->forward( $c->view('TT') );
 311     }
 312
 313 But if you are using the standard auto-generated end action, you don't even need
 314 to do this!
 315
 316     # in MyApp::Controller::Root
 317     sub end : ActionClass('RenderView') {} # no need to change this line
 318
 319     # in MyApp.pm
 320     __PACKAGE__->config(
 321         ...
 322         default_view => 'TT',
 323     );
 324
 325 This will Just Work.  And it has the advantages that:
 326
 327 =over 4
 328
 329 =item *
 330
 331 If you want to use a different view for a given request, just set
 332 << $c->stash->{current_view} >>.  (See L<Catalyst>'s C<< $c->view >> method
 333 for details.
 334
 335 =item *
 336
 337 << $c->res->redirect >> is handled by default.  If you just forward to
 338 C<View::TT> in your C<end> routine, you could break this by sending additional
 339 content.
 340
 341 =back
 342
 343 See L<Catalyst::Action::RenderView> for more details.
 344
 345 =head2 CONFIGURATION
 346
 347 There are a three different ways to configure your view class.  The
 348 first way is to call the C<config()> method in the view subclass.  This
 349 happens when the module is first loaded.
 350
 351     package MyApp::View::TT;
 352
 353     use strict;
 354     use base 'Catalyst::View::TT';
 355
 356     MyApp::View::TT->config({
 357         INCLUDE_PATH => [
 358             MyApp->path_to( 'root', 'templates', 'lib' ),
 359             MyApp->path_to( 'root', 'templates', 'src' ),
 360         ],
 361         PRE_PROCESS  => 'config/main',
 362         WRAPPER      => 'site/wrapper',
 363     });
 364
 365 The second way is to define a C<new()> method in your view subclass.
 366 This performs the configuration when the view object is created,
 367 shortly after being loaded.  Remember to delegate to the base class
 368 C<new()> method (via C<$self-E<gt>next::method()> in the example below) after
 369 performing any configuration.
 370
 371     sub new {
 372         my $self = shift;
 373         $self->config({
 374             INCLUDE_PATH => [
 375                 MyApp->path_to( 'root', 'templates', 'lib' ),
 376                 MyApp->path_to( 'root', 'templates', 'src' ),
 377             ],
 378             PRE_PROCESS  => 'config/main',
 379             WRAPPER      => 'site/wrapper',
 380         });
 381         return $self->next::method(@_);
 382     }
 383
 384 The final, and perhaps most direct way, is to define a class
 385 item in your main application configuration, again by calling the
 386 ubiquitous C<config()> method.  The items in the class hash are
 387 added to those already defined by the above two methods.  This happens
 388 in the base class new() method (which is one reason why you must
 389 remember to call it via C<MRO::Compat> if you redefine the C<new()>
 390 method in a subclass).
 391
 392     package MyApp;
 393
 394     use strict;
 395     use Catalyst;
 396
 397     MyApp->config({
 398         name     => 'MyApp',
 399         root     => MyApp->path_to('root'),
 400         'View::TT' => {
 401             INCLUDE_PATH => [
 402                 MyApp->path_to( 'root', 'templates', 'lib' ),
 403                 MyApp->path_to( 'root', 'templates', 'src' ),
 404             ],
 405             PRE_PROCESS  => 'config/main',
 406             WRAPPER      => 'site/wrapper',
 407         },
 408     });
 409
 410 Note that any configuration items defined by one of the earlier
 411 methods will be overwritten by items of the same name provided by the
 412 latter methods.
 413
 414 =head2 DYNAMIC INCLUDE_PATH
 415
 416 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 417
 418 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 419 follows:
 420
 421     $c->stash->{additional_template_paths} =
 422         [$c->config->{root} . '/test_include_path'];
 423
 424 If you need to add paths to the end of INCLUDE_PATH, there is also an
 425 include_path() accessor available:
 426
 427     push( @{ $c->view('TT')->include_path }, qw/path/ );
 428
 429 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 430 MUST check for duplicate paths. Without such checking, the above code will add
 431 "path" to INCLUDE_PATH at every request, causing a memory leak.
 432
 433 A safer approach is to use include_path() to overwrite the array of paths
 434 rather than adding to it. This eliminates both the need to perform duplicate
 435 checking and the chance of a memory leak:
 436
 437     @{ $c->view('TT')->include_path } = qw/path another_path/;
 438
 439 If you are calling C<render> directly then you can specify dynamic paths by
 440 having a C<additional_template_paths> key with a value of additonal directories
 441 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 442
 443 =head2 RENDERING VIEWS
 444
 445 The view plugin renders the template specified in the C<template>
 446 item in the stash.
 447
 448     sub message : Global {
 449         my ( $self, $c ) = @_;
 450         $c->stash->{template} = 'message.tt2';
 451         $c->forward( $c->view('TT') );
 452     }
 453
 454 If a stash item isn't defined, then it instead uses the
 455 stringification of the action dispatched to (as defined by $c->action)
 456 in the above example, this would be C<message>, but because the default
 457 is to append '.tt', it would load C<root/message.tt>.
 458
 459 The items defined in the stash are passed to the Template Toolkit for
 460 use as template variables.
 461
 462     sub default : Private {
 463         my ( $self, $c ) = @_;
 464         $c->stash->{template} = 'message.tt2';
 465         $c->stash->{message}  = 'Hello World!';
 466         $c->forward( $c->view('TT') );
 467     }
 468
 469 A number of other template variables are also added:
 470
 471     c      A reference to the context object, $c
 472     base   The URL base, from $c->req->base()
 473     name   The application name, from $c->config->{ name }
 474
 475 These can be accessed from the template in the usual way:
 476
 477 <message.tt2>:
 478
 479     The message is: [% message %]
 480     The base is [% base %]
 481     The name is [% name %]
 482
 483
 484 The output generated by the template is stored in C<< $c->response->body >>.
 485
 486 =head2 CAPTURING TEMPLATE OUTPUT
 487
 488 If you wish to use the output of a template for some other purpose than
 489 displaying in the response, e.g. for sending an email, this is possible using
 490 L<Catalyst::Plugin::Email> and the L<render> method:
 491
 492   sub send_email : Local {
 493     my ($self, $c) = @_;
 494
 495     $c->email(
 496       header => [
 497         To      => 'me@localhost',
 498         Subject => 'A TT Email',
 499       ],
 500       body => $c->view('TT')->render($c, 'email.tt', {
 501         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 502         email_tmpl_param1 => 'foo'
 503         }
 504       ),
 505     );
 506   # Redirect or display a message
 507   }
 508
 509 =head2 TEMPLATE PROFILING
 510
 511 See L<C<TIMER>> property of the L<config> method.
 512
 513 =head2 METHODS
 514
 515 =head2 new
 516
 517 The constructor for the TT view. Sets up the template provider,
 518 and reads the application config.
 519
 520 =head2 process($c)
 521
 522 Renders the template specified in C<< $c->stash->{template} >> or
 523 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 524 perform actual rendering. Output is stored in C<< $c->response->body >>.
 525
 526 It is possible to forward to the process method of a TT view from inside
 527 Catalyst like this:
 528
 529     $c->forward('View::TT');
 530
 531 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 532
 533 =head2 render($c, $template, \%args)
 534
 535 Renders the given template and returns output. Throws a L<Template::Exception>
 536 object upon error.
 537
 538 The template variables are set to C<%$args> if $args is a hashref, or
 539 $C<< $c->stash >> otherwise. In either case the variables are augmented with
 540 C<base> set to C< << $c->req->base >>, C<c> to C<$c> and C<name> to
 541 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 542 can be defined to specify the name of a template variable through which the
 543 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base> and
 544 C<name> variables are omitted.
 545
 546 C<$template> can be anything that Template::process understands how to
 547 process, including the name of a template file or a reference to a test string.
 548 See L<Template::process|Template/process> for a full list of supported formats.
 549
 550 To use the render method outside of your Catalyst app, just pass a undef context.
 551 This can be useful for tests, for instance.
 552
 553 It is possible to forward to the render method of a TT view from inside Catalyst
 554 to render page fragments like this:
 555
 556     my $fragment = $c->forward("View::TT", "render", $template_name, $c->stash->{fragment_data});
 557
 558 =head3 Backwards compatibility note
 559
 560 The render method used to just return the Template::Exception object, rather
 561 than just throwing it. This is now deprecated and instead the render method
 562 will throw an exception for new applications.
 563
 564 This behaviour can be activated (and is activated in the default skeleton
 565 configuration) by using C<< render_die => 1 >>. If you rely on the legacy
 566 behaviour then a warning will be issued.
 567
 568 To silence this warning, set C<< render_die => 0 >>, but it is recommended
 569 you adjust your code so that it works with C<< render_die => 1 >>.
 570
 571 In a future release, C<< render_die => 1 >> will become the default if
 572 unspecified.
 573
 574 =head2 template_vars
 575
 576 Returns a list of keys/values to be used as the catalyst variables in the
 577 template.
 578
 579 =head2 config
 580
 581 This method allows your view subclass to pass additional settings to
 582 the TT configuration hash, or to set the options as below:
 583
 584 =head2 paths
 585
 586 The list of paths TT will look for templates in.
 587
 588 =head2 C<CATALYST_VAR>
 589
 590 Allows you to change the name of the Catalyst context object. If set, it will also
 591 remove the base and name aliases, so you will have access them through <context>.
 592
 593 For example:
 594
 595     MyApp->config({
 596         name     => 'MyApp',
 597         root     => MyApp->path_to('root'),
 598         'View::TT' => {
 599             CATALYST_VAR => 'Catalyst',
 600         },
 601     });
 602
 603 F<message.tt2>:
 604
 605     The base is [% Catalyst.req.base %]
 606     The name is [% Catalyst.config.name %]
 607
 608 =head2 C<TIMER>
 609
 610 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 611 C<Catalyst::View::TT> will enable profiling of template processing
 612 (using L<Template::Timer>). This will embed HTML comments in the
 613 output from your templates, such as:
 614
 615     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 616     <!-- TIMER START: include mainmenu/cssindex.tt -->
 617     <!-- TIMER START: process mainmenu/cssindex.tt -->
 618     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 619     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 620
 621     ....
 622
 623     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 624
 625
 626 =head2 C<TEMPLATE_EXTENSION>
 627
 628 a sufix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 629
 630 For example:
 631
 632   package MyApp::Controller::Test;
 633   sub test : Local { .. }
 634
 635 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 636 <root>/test/test.tt.
 637
 638 =head2 C<PROVIDERS>
 639
 640 Allows you to specify the template providers that TT will use.
 641
 642     MyApp->config({
 643         name     => 'MyApp',
 644         root     => MyApp->path_to('root'),
 645         'View::TT' => {
 646             PROVIDERS => [
 647                 {
 648                     name    => 'DBI',
 649                     args    => {
 650                         DBI_DSN => 'dbi:DB2:books',
 651                         DBI_USER=> 'foo'
 652                     }
 653                 }, {
 654                     name    => '_file_',
 655                     args    => {}
 656                 }
 657             ]
 658         },
 659     });
 660
 661 The 'name' key should correspond to the class name of the provider you
 662 want to use.  The _file_ name is a special case that represents the default
 663 TT file-based provider.  By default the name is will be prefixed with
 664 'Template::Provider::'.  You can fully qualify the name by using a unary
 665 plus:
 666
 667     name => '+MyApp::Provider::Foo'
 668
 669 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 670 from the general config, into the config for the provider:
 671
 672     DEFAULT_ENCODING    => 'utf-8',
 673     PROVIDERS => [
 674         {
 675             name    => 'Encoding',
 676             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 677         }
 678     ]
 679
 680 This can prove useful when you want to use the additional_template_paths hack
 681 in your own provider, or if you need to use Template::Provider::Encoding
 682
 683 =head2 HELPERS
 684
 685 The L<Catalyst::Helper::View::TT> and
 686 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 687 your view module.  There are invoked by the F<myapp_create.pl> script:
 688
 689     $ script/myapp_create.pl view TT TT
 690
 691     $ script/myapp_create.pl view TT TTSite
 692
 693 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 694 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 695 further.  It also creates a default set of templates to get you
 696 started.  It also configures the view module to locate the templates
 697 automatically.
 698
 699 =head1 NOTES
 700
 701 If you are using the L<CGI> module inside your templates, you will
 702 experience that the Catalyst server appears to hang while rendering
 703 the web page. This is due to the debug mode of L<CGI> (which is
 704 waiting for input in the terminal window). Turning off the
 705 debug mode using the "-no_debug" option solves the
 706 problem, eg.:
 707
 708     [% USE CGI('-no_debug') %]
 709
 710 =head1 SEE ALSO
 711
 712 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 713 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 714
 715 =head1 AUTHORS
 716
 717 Sebastian Riedel, C<sri@cpan.org>
 718
 719 Marcus Ramberg, C<mramberg@cpan.org>
 720
 721 Jesse Sheidlower, C<jester@panix.com>
 722
 723 Andy Wardley, C<abw@cpan.org>
 724
 725 =head1 COPYRIGHT
 726
 727 This program is free software. You can redistribute it and/or modify it
 728 under the same terms as Perl itself.
 729
 730 =cut