lib/Catalyst/View/TT.pm

   1 package Catalyst::View::TT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/Catalyst::View/;
   7 use Data::Dump 'dump';
   8 use Template;
   9 use Template::Timer;
  10 use MRO::Compat;
  11 use Scalar::Util qw/blessed weaken/;
  12
  13 our $VERSION = '0.42';
  14 $VERSION = eval $VERSION;
  15
  16 __PACKAGE__->mk_accessors('template');
  17 __PACKAGE__->mk_accessors('expose_methods');
  18 __PACKAGE__->mk_accessors('include_path');
  19 __PACKAGE__->mk_accessors('content_type');
  20
  21 *paths = \&include_path;
  22
  23 =head1 NAME
  24
  25 Catalyst::View::TT - Template View Class
  26
  27 =head1 SYNOPSIS
  28
  29 # use the helper to create your View
  30
  31     myapp_create.pl view Web TT
  32
  33 # add custom configuration in View/Web.pm
  34
  35     __PACKAGE__->config(
  36         # any TT configuration items go here
  37         TEMPLATE_EXTENSION => '.tt',
  38         CATALYST_VAR => 'c',
  39         TIMER        => 0,
  40         ENCODING     => 'utf-8'
  41         # Not set by default
  42         PRE_PROCESS        => 'config/main',
  43         WRAPPER            => 'site/wrapper',
  44         render_die => 1, # Default for new apps, see render method docs
  45         expose_methods => [qw/method_in_view_class/],
  46     );
  47
  48 # add include path configuration in MyApp.pm
  49
  50     __PACKAGE__->config(
  51         'View::Web' => {
  52             INCLUDE_PATH => [
  53                 __PACKAGE__->path_to( 'root', 'src' ),
  54                 __PACKAGE__->path_to( 'root', 'lib' ),
  55             ],
  56         },
  57     );
  58
  59 # render view from lib/MyApp.pm or lib/MyApp::Controller::SomeController.pm
  60
  61     sub message : Global {
  62         my ( $self, $c ) = @_;
  63         $c->stash->{template} = 'message.tt2';
  64         $c->stash->{message}  = 'Hello World!';
  65         $c->forward( $c->view('Web') );
  66     }
  67
  68 # access variables from template
  69
  70     The message is: [% message %].
  71
  72     # example when CATALYST_VAR is set to 'Catalyst'
  73     Context is [% Catalyst %]
  74     The base is [% Catalyst.req.base %]
  75     The name is [% Catalyst.config.name %]
  76
  77     # example when CATALYST_VAR isn't set
  78     Context is [% c %]
  79     The base is [% base %]
  80     The name is [% name %]
  81
  82 =cut
  83
  84 sub _coerce_paths {
  85     my ( $paths, $dlim ) = shift;
  86     return () if ( !$paths );
  87     return @{$paths} if ( ref $paths eq 'ARRAY' );
  88
  89     # tweak delim to ignore C:/
  90     unless ( defined $dlim ) {
  91         $dlim = ( $^O eq 'MSWin32' ) ? ':(?!\\/)' : ':';
  92     }
  93     return split( /$dlim/, $paths );
  94 }
  95
  96 sub new {
  97     my ( $class, $c, $arguments ) = @_;
  98     my $config = {
  99         EVAL_PERL          => 0,
 100         TEMPLATE_EXTENSION => '',
 101         CLASS              => 'Template',
 102         %{ $class->config },
 103         %{$arguments},
 104     };
 105     if ( ! (ref $config->{INCLUDE_PATH} eq 'ARRAY') ) {
 106         my $delim = $config->{DELIMITER};
 107         my @include_path
 108             = _coerce_paths( $config->{INCLUDE_PATH}, $delim );
 109         if ( !@include_path ) {
 110             my $root = $c->config->{root};
 111             my $base = Path::Class::dir( $root, 'base' );
 112             @include_path = ( "$root", "$base" );
 113         }
 114         $config->{INCLUDE_PATH} = \@include_path;
 115     }
 116
 117     # if we're debugging and/or the TIMER option is set, then we install
 118     # Template::Timer as a custom CONTEXT object, but only if we haven't
 119     # already got a custom CONTEXT defined
 120
 121     if ( $config->{TIMER} ) {
 122         if ( $config->{CONTEXT} ) {
 123             $c->log->error(
 124                 'Cannot use Template::Timer - a TT CONTEXT is already defined'
 125             );
 126         }
 127         else {
 128             $config->{CONTEXT} = Template::Timer->new(%$config);
 129         }
 130     }
 131
 132     if ( $c->debug && $config->{DUMP_CONFIG} ) {
 133         $c->log->debug( "TT Config: ", dump($config) );
 134     }
 135
 136     my $self = $class->next::method(
 137         $c, { %$config },
 138     );
 139
 140     # Set base include paths. Local'd in render if needed
 141     $self->include_path($config->{INCLUDE_PATH});
 142
 143     $self->expose_methods($config->{expose_methods});
 144     $self->config($config);
 145
 146     # Creation of template outside of call to new so that we can pass [ $self ]
 147     # as INCLUDE_PATH config item, which then gets ->paths() called to get list
 148     # of include paths to search for templates.
 149
 150     # Use a weakened copy of self so we don't have loops preventing GC from working
 151     my $copy = $self;
 152     Scalar::Util::weaken($copy);
 153     $config->{INCLUDE_PATH} = [ sub { $copy->paths } ];
 154
 155     if ( $config->{PROVIDERS} ) {
 156         my @providers = ();
 157         if ( ref($config->{PROVIDERS}) eq 'ARRAY') {
 158             foreach my $p (@{$config->{PROVIDERS}}) {
 159                 my $pname = $p->{name};
 160                 my $prov = 'Template::Provider';
 161                 if($pname eq '_file_')
 162                 {
 163                     $p->{args} = { %$config };
 164                 }
 165                 else
 166                 {
 167                     if($pname =~ s/^\+//) {
 168                         $prov = $pname;
 169                     }
 170                     else
 171                     {
 172                         $prov .= "::$pname";
 173                     }
 174                     # We copy the args people want from the config
 175                     # to the args
 176                     $p->{args} ||= {};
 177                     if ($p->{copy_config}) {
 178                         map  { $p->{args}->{$_} = $config->{$_}  }
 179                                    grep { exists $config->{$_} }
 180                                    @{ $p->{copy_config} };
 181                     }
 182                 }
 183                 local $@;
 184                 eval "require $prov";
 185                 if(!$@) {
 186                     push @providers, "$prov"->new($p->{args});
 187                 }
 188                 else
 189                 {
 190                     $c->log->warn("Can't load $prov, ($@)");
 191                 }
 192             }
 193         }
 194         delete $config->{PROVIDERS};
 195         if(@providers) {
 196             $config->{LOAD_TEMPLATES} = \@providers;
 197         }
 198     }
 199
 200     $self->{template} =
 201         $config->{CLASS}->new($config) || do {
 202             my $error = $config->{CLASS}->error();
 203             $c->log->error($error);
 204             $c->error($error);
 205             return undef;
 206         };
 207
 208
 209     return $self;
 210 }
 211
 212 sub process {
 213     my ( $self, $c ) = @_;
 214
 215     my $template = $c->stash->{template}
 216       ||  $c->action . $self->config->{TEMPLATE_EXTENSION};
 217
 218     unless (defined $template) {
 219         $c->log->debug('No template specified for rendering') if $c->debug;
 220         return 0;
 221     }
 222
 223     local $@;
 224     my $output = eval { $self->render($c, $template) };
 225     if (my $err = $@) {
 226         return $self->_rendering_error($c, $template . ': ' . $err);
 227     }
 228     if (blessed($output) && $output->isa('Template::Exception')) {
 229         $self->_rendering_error($c, $output);
 230     }
 231
 232     unless ( $c->response->content_type ) {
 233         my $default = $self->content_type || 'text/html; charset=UTF-8';
 234         $c->response->content_type($default);
 235     }
 236
 237     $c->response->body($output);
 238
 239     return 1;
 240 }
 241
 242 sub _rendering_error {
 243     my ($self, $c, $err) = @_;
 244     my $error = qq/Couldn't render template "$err"/;
 245     $c->log->error($error);
 246     $c->error($error);
 247     return 0;
 248 }
 249
 250 sub render {
 251     my ($self, $c, $template, $args) = @_;
 252
 253     $c->log->debug(qq/Rendering template "$template"/) if $c && $c->debug;
 254
 255     my $output;
 256     my $vars = {
 257         (ref $args eq 'HASH' ? %$args : %{ $c->stash() }),
 258         $self->template_vars($c)
 259     };
 260
 261     local $self->{include_path} =
 262         [ @{ $vars->{additional_template_paths} }, @{ $self->{include_path} } ]
 263         if ref $vars->{additional_template_paths};
 264
 265     unless ( $self->template->process( $template, $vars, \$output ) ) {
 266         if (exists $self->{render_die}) {
 267             die $self->template->error if $self->{render_die};
 268             return $self->template->error;
 269         }
 270         $c->log->debug('The Catalyst::View::TT render() method will start dying on error in a future release. Unless you are calling the render() method manually, you probably want the new behaviour, so set render_die => 1 in config for ' . blessed($self) . '. If you wish to continue to return the exception rather than throwing it, add render_die => 0 to your config.') if $c && $c->debug;
 271         return $self->template->error;
 272     }
 273     return $output;
 274 }
 275
 276 sub template_vars {
 277     my ( $self, $c ) = @_;
 278
 279     return  () unless $c;
 280     my $cvar = $self->config->{CATALYST_VAR};
 281
 282     my %vars = defined $cvar
 283       ? ( $cvar => $c )
 284       : (
 285         c    => $c,
 286         base => $c->req->base,
 287         name => $c->config->{name}
 288       );
 289
 290     if ($self->expose_methods) {
 291         my $meta = $self->meta;
 292         foreach my $method_name (@{$self->expose_methods}) {
 293             my $method = $meta->find_method_by_name( $method_name );
 294             unless ($method) {
 295                 Catalyst::Exception->throw( "$method_name not found in TT view" );
 296             }
 297             my $method_body = $method->body;
 298             my $weak_ctx = $c;
 299             weaken $weak_ctx;
 300             my $sub = sub {
 301                 $self->$method_body($weak_ctx, @_);
 302             };
 303             $vars{$method_name} = $sub;
 304         }
 305     }
 306     return %vars;
 307 }
 308
 309 1;
 310
 311 __END__
 312
 313 =head1 DESCRIPTION
 314
 315 This is the Catalyst view class for the L<Template Toolkit|Template>.
 316 Your application should defined a view class which is a subclass of
 317 this module. Throughout this manual it will be assumed that your application
 318 is named F<MyApp> and you are creating a TT view named F<Web>; these names
 319 are placeholders and should always be replaced with whatever name you've
 320 chosen for your application and your view. The easiest way to create a TT
 321 view class is through the F<myapp_create.pl> script that is created along
 322 with the application:
 323
 324     $ script/myapp_create.pl view Web TT
 325
 326 This creates a F<MyApp::View::Web.pm> module in the F<lib> directory (again,
 327 replacing C<MyApp> with the name of your application) which looks
 328 something like this:
 329
 330     package FooBar::View::Web;
 331     use Moose;
 332
 333     extends 'Catalyst::View::TT';
 334
 335     __PACKAGE__->config(DEBUG => 'all');
 336
 337 Now you can modify your action handlers in the main application and/or
 338 controllers to forward to your view class.  You might choose to do this
 339 in the end() method, for example, to automatically forward all actions
 340 to the TT view class.
 341
 342     # In MyApp or MyApp::Controller::SomeController
 343
 344     sub end : Private {
 345         my( $self, $c ) = @_;
 346         $c->forward( $c->view('Web') );
 347     }
 348
 349 But if you are using the standard auto-generated end action, you don't even need
 350 to do this!
 351
 352     # in MyApp::Controller::Root
 353     sub end : ActionClass('RenderView') {} # no need to change this line
 354
 355     # in MyApp.pm
 356     __PACKAGE__->config(
 357         ...
 358         default_view => 'Web',
 359     );
 360
 361 This will Just Work.  And it has the advantages that:
 362
 363 =over 4
 364
 365 =item *
 366
 367 If you want to use a different view for a given request, just set
 368 << $c->stash->{current_view} >>.  (See L<Catalyst>'s C<< $c->view >> method
 369 for details.
 370
 371 =item *
 372
 373 << $c->res->redirect >> is handled by default.  If you just forward to
 374 C<View::Web> in your C<end> routine, you could break this by sending additional
 375 content.
 376
 377 =back
 378
 379 See L<Catalyst::Action::RenderView> for more details.
 380
 381 =head2 CONFIGURATION
 382
 383 There are a three different ways to configure your view class.  The
 384 first way is to call the C<config()> method in the view subclass.  This
 385 happens when the module is first loaded.
 386
 387     package MyApp::View::Web;
 388     use Moose;
 389     extends 'Catalyst::View::TT';
 390
 391     __PACKAGE__->config({
 392         PRE_PROCESS  => 'config/main',
 393         WRAPPER      => 'site/wrapper',
 394     });
 395
 396 You may also override the configuration provided in the view class by adding
 397 a 'View::Web' section to your application config.
 398
 399 This should generally be used to inject the include paths into the view to
 400 avoid the view trying to load the application to resolve paths.
 401
 402     .. inside MyApp.pm ..
 403     __PACKAGE__->config(
 404         'View::Web' => {
 405             INCLUDE_PATH => [
 406                 __PACKAGE__->path_to( 'root', 'templates', 'lib' ),
 407                 __PACKAGE__->path_to( 'root', 'templates', 'src' ),
 408             ],
 409         },
 410     );
 411
 412 You can also configure your view from within your config file if you're
 413 using L<Catalyst::Plugin::ConfigLoader>. This should be reserved for
 414 deployment-specific concerns. For example:
 415
 416     # MyApp_local.conf (Config::General format)
 417
 418     <View Web>
 419       WRAPPER "custom_wrapper"
 420       INCLUDE_PATH __path_to('root/templates/custom_site')__
 421       INCLUDE_PATH __path_to('root/templates')__
 422     </View>
 423
 424 might be used as part of a simple way to deploy different instances of the
 425 same application with different themes.
 426
 427 =head2 DYNAMIC INCLUDE_PATH
 428
 429 Sometimes it is desirable to modify INCLUDE_PATH for your templates at run time.
 430
 431 Additional paths can be added to the start of INCLUDE_PATH via the stash as
 432 follows:
 433
 434     $c->stash->{additional_template_paths} =
 435         [$c->config->{root} . '/test_include_path'];
 436
 437 If you need to add paths to the end of INCLUDE_PATH, there is also an
 438 include_path() accessor available:
 439
 440     push( @{ $c->view('Web')->include_path }, qw/path/ );
 441
 442 Note that if you use include_path() to add extra paths to INCLUDE_PATH, you
 443 MUST check for duplicate paths. Without such checking, the above code will add
 444 "path" to INCLUDE_PATH at every request, causing a memory leak.
 445
 446 A safer approach is to use include_path() to overwrite the array of paths
 447 rather than adding to it. This eliminates both the need to perform duplicate
 448 checking and the chance of a memory leak:
 449
 450     @{ $c->view('Web')->include_path } = qw/path another_path/;
 451
 452 If you are calling C<render> directly then you can specify dynamic paths by
 453 having a C<additional_template_paths> key with a value of additional directories
 454 to search. See L<CAPTURING TEMPLATE OUTPUT> for an example showing this.
 455
 456 =head2 Unicode
 457
 458 B<NOTE> Starting with L<Catalyst> v5.90080 unicode and encoding has been
 459 baked into core, and the default encoding is UTF-8.  The following advice
 460 is for older versions of L<Catalyst>
 461
 462 Be sure to set C<< ENCODING => 'utf-8' >> and use
 463 L<Catalyst::Plugin::Unicode::Encoding> if you want to use non-ascii
 464 characters (encoded as utf-8) in your templates.
 465
 466 =head2 RENDERING VIEWS
 467
 468 The view plugin renders the template specified in the C<template>
 469 item in the stash.
 470
 471     sub message : Global {
 472         my ( $self, $c ) = @_;
 473         $c->stash->{template} = 'message.tt2';
 474         $c->forward( $c->view('Web') );
 475     }
 476
 477 If a stash item isn't defined, then it instead uses the
 478 stringification of the action dispatched to (as defined by $c->action)
 479 in the above example, this would be C<message>, but because the default
 480 is to append '.tt', it would load C<root/message.tt>.
 481
 482 The items defined in the stash are passed to the Template Toolkit for
 483 use as template variables.
 484
 485     sub default : Private {
 486         my ( $self, $c ) = @_;
 487         $c->stash->{template} = 'message.tt2';
 488         $c->stash->{message}  = 'Hello World!';
 489         $c->forward( $c->view('Web') );
 490     }
 491
 492 A number of other template variables are also added:
 493
 494     c      A reference to the context object, $c
 495     base   The URL base, from $c->req->base()
 496     name   The application name, from $c->config->{ name }
 497
 498 These can be accessed from the template in the usual way:
 499
 500 <message.tt2>:
 501
 502     The message is: [% message %]
 503     The base is [% base %]
 504     The name is [% name %]
 505
 506
 507 The output generated by the template is stored in C<< $c->response->body >>.
 508
 509 =head2 CAPTURING TEMPLATE OUTPUT
 510
 511 If you wish to use the output of a template for some other purpose than
 512 displaying in the response, e.g. for sending an email, this is possible using
 513 L<Catalyst::Plugin::Email> and the L<render> method:
 514
 515   sub send_email : Local {
 516     my ($self, $c) = @_;
 517
 518     $c->email(
 519       header => [
 520         To      => 'me@localhost',
 521         Subject => 'A TT Email',
 522       ],
 523       body => $c->view('Web')->render($c, 'email.tt', {
 524         additional_template_paths => [ $c->config->{root} . '/email_templates'],
 525         email_tmpl_param1 => 'foo'
 526         }
 527       ),
 528     );
 529   # Redirect or display a message
 530   }
 531
 532 =head2 TEMPLATE PROFILING
 533
 534 See L<C<TIMER>> property of the L<config> method.
 535
 536 =head2 METHODS
 537
 538 =head2 new
 539
 540 The constructor for the TT view. Sets up the template provider,
 541 and reads the application config.
 542
 543 =head2 process($c)
 544
 545 Renders the template specified in C<< $c->stash->{template} >> or
 546 C<< $c->action >> (the private name of the matched action).  Calls L<render> to
 547 perform actual rendering. Output is stored in C<< $c->response->body >>.
 548
 549 It is possible to forward to the process method of a TT view from inside
 550 Catalyst like this:
 551
 552     $c->forward('View::Web');
 553
 554 N.B. This is usually done automatically by L<Catalyst::Action::RenderView>.
 555
 556 =head2 render($c, $template, \%args)
 557
 558 Renders the given template and returns output. Throws a L<Template::Exception>
 559 object upon error.
 560
 561 The template variables are set to C<%$args> if C<$args> is a hashref, or
 562 C<< $c->stash >> otherwise. In either case the variables are augmented with
 563 C<base> set to C<< $c->req->base >>, C<c> to C<$c>, and C<name> to
 564 C<< $c->config->{name} >>. Alternately, the C<CATALYST_VAR> configuration item
 565 can be defined to specify the name of a template variable through which the
 566 context reference (C<$c>) can be accessed. In this case, the C<c>, C<base>, and
 567 C<name> variables are omitted.
 568
 569 C<$template> can be anything that Template::process understands how to
 570 process, including the name of a template file or a reference to a test string.
 571 See L<Template::process|Template/process> for a full list of supported formats.
 572
 573 To use the render method outside of your Catalyst app, just pass a undef context.
 574 This can be useful for tests, for instance.
 575
 576 It is possible to forward to the render method of a TT view from inside Catalyst
 577 to render page fragments like this:
 578
 579     my $fragment = $c->forward("View::Web", "render", $template_name, $c->stash->{fragment_data});
 580
 581 =head3 Backwards compatibility note
 582
 583 The render method used to just return the Template::Exception object, rather
 584 than just throwing it. This is now deprecated and instead the render method
 585 will throw an exception for new applications.
 586
 587 This behaviour can be activated (and is activated in the default skeleton
 588 configuration) by using C<< render_die => 1 >>. If you rely on the legacy
 589 behaviour then a warning will be issued.
 590
 591 To silence this warning, set C<< render_die => 0 >>, but it is recommended
 592 you adjust your code so that it works with C<< render_die => 1 >>.
 593
 594 In a future release, C<< render_die => 1 >> will become the default if
 595 unspecified.
 596
 597 =head2 template_vars
 598
 599 Returns a list of keys/values to be used as the catalyst variables in the
 600 template.
 601
 602 =head2 config
 603
 604 This method allows your view subclass to pass additional settings to
 605 the TT configuration hash, or to set the options as below:
 606
 607 =head2 paths
 608
 609 The list of paths TT will look for templates in.
 610
 611 =head2 expose_methods
 612
 613 The list of methods in your View class which should be made available to the templates.
 614
 615 For example:
 616
 617   expose_methods => [qw/uri_for_css/],
 618
 619   ...
 620
 621   sub uri_for_css {
 622     my ($self, $c, $filename) = @_;
 623
 624     # additional complexity like checking file exists here
 625
 626     return $c->uri_for('/static/css/' . $filename);
 627   }
 628
 629 Then in the template:
 630
 631   [% uri_for_css('home.css') %]
 632
 633 =head2 content_type
 634
 635 This lets you override the default content type for the response.  If you do
 636 not set this and if you do not set the content type in your controllers, the
 637 default is C<text/html; charset=utf-8>.
 638
 639 Use this if you are creating alternative view responses, such as text or JSON
 640 and want a global setting.
 641
 642 Any content type set in your controllers before calling this view are respected
 643 and have priority.
 644
 645 =head2 C<CATALYST_VAR>
 646
 647 Allows you to change the name of the Catalyst context object. If set, it will also
 648 remove the base and name aliases, so you will have access them through <context>.
 649
 650 For example, if CATALYST_VAR has been set to "Catalyst", a template might
 651 contain:
 652
 653     The base is [% Catalyst.req.base %]
 654     The name is [% Catalyst.config.name %]
 655
 656 =head2 C<TIMER>
 657
 658 If you have configured Catalyst for debug output, and turned on the TIMER setting,
 659 C<Catalyst::View::TT> will enable profiling of template processing
 660 (using L<Template::Timer>). This will embed HTML comments in the
 661 output from your templates, such as:
 662
 663     <!-- TIMER START: process mainmenu/mainmenu.ttml -->
 664     <!-- TIMER START: include mainmenu/cssindex.tt -->
 665     <!-- TIMER START: process mainmenu/cssindex.tt -->
 666     <!-- TIMER END: process mainmenu/cssindex.tt (0.017279 seconds) -->
 667     <!-- TIMER END: include mainmenu/cssindex.tt (0.017401 seconds) -->
 668
 669     ....
 670
 671     <!-- TIMER END: process mainmenu/footer.tt (0.003016 seconds) -->
 672
 673
 674 =head2 C<TEMPLATE_EXTENSION>
 675
 676 a suffix to add when looking for templates bases on the C<match> method in L<Catalyst::Request>.
 677
 678 For example:
 679
 680   package MyApp::Controller::Test;
 681   sub test : Local { .. }
 682
 683 Would by default look for a template in <root>/test/test. If you set TEMPLATE_EXTENSION to '.tt', it will look for
 684 <root>/test/test.tt.
 685
 686 =head2 C<PROVIDERS>
 687
 688 Allows you to specify the template providers that TT will use.
 689
 690     MyApp->config(
 691         name     => 'MyApp',
 692         root     => MyApp->path_to('root'),
 693         'View::Web' => {
 694             PROVIDERS => [
 695                 {
 696                     name    => 'DBI',
 697                     args    => {
 698                         DBI_DSN => 'dbi:DB2:books',
 699                         DBI_USER=> 'foo'
 700                     }
 701                 }, {
 702                     name    => '_file_',
 703                     args    => {}
 704                 }
 705             ]
 706         },
 707     );
 708
 709 The 'name' key should correspond to the class name of the provider you
 710 want to use.  The _file_ name is a special case that represents the default
 711 TT file-based provider.  By default the name is will be prefixed with
 712 'Template::Provider::'.  You can fully qualify the name by using a unary
 713 plus:
 714
 715     name => '+MyApp::Provider::Foo'
 716
 717 You can also specify the 'copy_config' key as an arrayref, to copy those keys
 718 from the general config, into the config for the provider:
 719
 720     DEFAULT_ENCODING    => 'utf-8',
 721     PROVIDERS => [
 722         {
 723             name    => 'Encoding',
 724             copy_config => [qw(DEFAULT_ENCODING INCLUDE_PATH)]
 725         }
 726     ]
 727
 728 This can prove useful when you want to use the additional_template_paths hack
 729 in your own provider, or if you need to use Template::Provider::Encoding
 730
 731 =head2 C<CLASS>
 732
 733 Allows you to specify a custom class to use as the template class instead of
 734 L<Template>.
 735
 736     package MyApp::View::Web;
 737     use Moose;
 738     extends 'Catalyst::View::TT';
 739
 740     use Template::AutoFilter;
 741
 742     __PACKAGE__->config({
 743         CLASS => 'Template::AutoFilter',
 744     });
 745
 746 This is useful if you want to use your own subclasses of L<Template>, so you
 747 can, for example, prevent XSS by automatically filtering all output through
 748 C<| html>.
 749
 750 =head2 HELPERS
 751
 752 The L<Catalyst::Helper::View::TT> and
 753 L<Catalyst::Helper::View::TTSite> helper modules are provided to create
 754 your view module.  There are invoked by the F<myapp_create.pl> script:
 755
 756     $ script/myapp_create.pl view Web TT
 757
 758     $ script/myapp_create.pl view Web TTSite
 759
 760 The L<Catalyst::Helper::View::TT> module creates a basic TT view
 761 module.  The L<Catalyst::Helper::View::TTSite> module goes a little
 762 further.  It also creates a default set of templates to get you
 763 started.  It also configures the view module to locate the templates
 764 automatically.
 765
 766 =head1 NOTES
 767
 768 If you are using the L<CGI> module inside your templates, you will
 769 experience that the Catalyst server appears to hang while rendering
 770 the web page. This is due to the debug mode of L<CGI> (which is
 771 waiting for input in the terminal window). Turning off the
 772 debug mode using the "-no_debug" option solves the
 773 problem, eg.:
 774
 775     [% USE CGI('-no_debug') %]
 776
 777 =head1 SEE ALSO
 778
 779 L<Catalyst>, L<Catalyst::Helper::View::TT>,
 780 L<Catalyst::Helper::View::TTSite>, L<Template::Manual>
 781
 782 =head1 AUTHORS
 783
 784 Sebastian Riedel, C<sri@cpan.org>
 785
 786 Marcus Ramberg, C<mramberg@cpan.org>
 787
 788 Jesse Sheidlower, C<jester@panix.com>
 789
 790 Andy Wardley, C<abw@cpan.org>
 791
 792 Luke Saunders, C<luke.saunders@gmail.com>
 793
 794 =head1 COPYRIGHT
 795
 796 This program is free software. You can redistribute it and/or modify it
 797 under the same terms as Perl itself.
 798
 799 =cut