lib/Catalyst/Plugin/ConfigLoader.pm

   1 package Catalyst::Plugin::ConfigLoader;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Config::Any;
   7 use NEXT;
   8 use Data::Visitor::Callback;
   9 use Catalyst::Utils ();
  10
  11 our $VERSION = '0.16';
  12
  13 =head1 NAME
  14
  15 Catalyst::Plugin::ConfigLoader - Load config files of various types
  16
  17 =head1 SYNOPSIS
  18
  19     package MyApp;
  20
  21     # ConfigLoader should be first in your list so
  22     # other plugins can get the config information
  23     use Catalyst qw( ConfigLoader ... );
  24
  25     # by default myapp.* will be loaded
  26     # you can specify a file if you'd like
  27     __PACKAGE__->config( file => 'config.yaml' );
  28
  29 =head1 DESCRIPTION
  30
  31 This module will attempt to load find and load a configuration
  32 file of various types. Currently it supports YAML, JSON, XML,
  33 INI and Perl formats.
  34
  35 To support the distinction between development and production environments,
  36 this module will also attemp to load a local config (e.g. myapp_local.yaml)
  37 which will override any duplicate settings.
  38
  39 =head1 METHODS
  40
  41 =head2 setup( )
  42
  43 This method is automatically called by Catalyst's setup routine. It will
  44 attempt to use each plugin and, once a file has been successfully
  45 loaded, set the C<config()> section.
  46
  47 =cut
  48
  49 sub setup {
  50     my $c     = shift;
  51     my @files = $c->find_files;
  52     my $cfg   = Config::Any->load_files( {
  53         files   => \@files,
  54         filter  => \&_fix_syntax,
  55         use_ext => 1
  56     } );
  57
  58     # split the responses into normal and local cfg
  59     my $local_suffix = $c->get_config_local_suffix;
  60     my( @cfg, @localcfg );
  61     for( @$cfg ) {
  62         if( ( keys %$_ )[ 0 ] =~ m{ $local_suffix \. }xms ) {
  63             push @localcfg, $_;
  64         } else {
  65             push @cfg, $_;
  66         }
  67     }
  68
  69     # load all the normal cfgs, then the local cfgs last so they can override
  70     # normal cfgs
  71     $c->load_config( $_ ) for @cfg, @localcfg;
  72
  73     $c->finalize_config;
  74     $c->NEXT::setup( @_ );
  75 }
  76
  77 =head2 load_config
  78
  79 This method handles loading the configuration data into the Catalyst
  80 context object. It does not return a value.
  81
  82 =cut
  83
  84 sub load_config {
  85     my $c   = shift;
  86     my $ref = shift;
  87
  88     my( $file, $config ) = each %$ref;
  89
  90     $c->config( $config );
  91     $c->log->debug( qq(Loaded Config "$file") )
  92         if $c->debug;
  93
  94     return;
  95 }
  96
  97 =head2 find_files
  98
  99 This method determines the potential file paths to be used for config loading.
 100 It returns an array of paths (up to the filename less the extension) to pass to
 101 L<Config::Any|Config::Any> for loading.
 102
 103 =cut
 104
 105 sub find_files {
 106     my $c = shift;
 107     my( $path, $extension ) = $c->get_config_path;
 108     my $suffix     = $c->get_config_local_suffix;
 109     my @extensions = @{ Config::Any->extensions };
 110
 111     my @files;
 112     if ($extension) {
 113         next unless grep { $_ eq $extension } @extensions;
 114         push @files, $path, "${path}_${suffix}";
 115     } else {
 116         @files = map { ( "$path.$_", "${path}_${suffix}.$_" ) } @extensions;
 117     }
 118
 119     @files;
 120 }
 121
 122 =head2 get_config_path
 123
 124 This method determines the path, filename prefix and file extension to be used
 125 for config loading. It returns the path (up to the filename less the
 126 extension) to check and the specific extension to use (if it was specified).
 127
 128 The order of preference is specified as:
 129
 130 =over 4
 131
 132 =item * C<$ENV{ MYAPP_CONFIG }>
 133
 134 =item * C<$ENV{ CATALYST_CONFIG }>
 135
 136 =item * C<$c-E<gt>config-E<gt>{ file }>
 137
 138 =item * C<$c-E<gt>path_to( $application_prefix )>
 139
 140 =back
 141
 142 If either of the first two user-specified options are directories, the
 143 application prefix will be added on to the end of the path.
 144
 145 =cut
 146
 147 sub get_config_path {
 148     my $c       = shift;
 149     my $appname = ref $c || $c;
 150     my $prefix  = Catalyst::Utils::appprefix( $appname );
 151     my $path    = Catalyst::Utils::env_value( $c, 'CONFIG' )
 152         || $c->config->{ file }
 153         || $c->path_to( $prefix );
 154
 155     my( $extension ) = ( $path =~ m{\.(.{1,4})$} );
 156
 157     if( -d $path ) {
 158         $path  =~ s{[\/\\]$}{};
 159         $path .= "/$prefix";
 160     }
 161
 162     return( $path, $extension );
 163 }
 164
 165 =head2 get_config_local_suffix
 166
 167 Determines the suffix of files used to override the main config. By default
 168 this value is C<local>, but it can be specified in the following order of preference:
 169
 170 =over 4
 171
 172 =item * C<$ENV{ MYAPP_CONFIG_LOCAL_SUFFIX }>
 173
 174 =item * C<$ENV{ CATALYST_CONFIG_LOCAL_SUFFIX }>
 175
 176 =item * C<$c-E<gt>config-E<gt>{ config_local_suffix }>
 177
 178 =back
 179
 180 =cut
 181
 182 sub get_config_local_suffix {
 183     my $c       = shift;
 184     my $appname = ref $c || $c;
 185     my $suffix  = Catalyst::Utils::env_value( $c, 'CONFIG_LOCAL_SUFFIX' )
 186         || $c->config->{ config_local_suffix }
 187         || 'local';
 188
 189     return $suffix;
 190 }
 191
 192 sub _fix_syntax {
 193     my $config     = shift;
 194     my @components = (
 195         map +{
 196             prefix => $_ eq 'Component' ? '' : $_ . '::',
 197             values => delete $config->{ lc $_ } || delete $config->{ $_ }
 198         },
 199         grep {
 200             ref $config->{ lc $_ } || ref $config->{ $_ }
 201         }
 202         qw( Component Model M View V Controller C )
 203     );
 204
 205     foreach my $comp ( @components ) {
 206         my $prefix = $comp->{ prefix };
 207         foreach my $element ( keys %{ $comp->{ values } } ) {
 208             $config->{ "$prefix$element" } = $comp->{ values }->{ $element };
 209         }
 210     }
 211 }
 212
 213 =head2 finalize_config
 214
 215 This method is called after the config file is loaded. It can be
 216 used to implement tuning of config values that can only be done
 217 at runtime. If you need to do this to properly configure any
 218 plugins, it's important to load ConfigLoader before them.
 219 ConfigLoader provides a default finalize_config method which
 220 walks through the loaded config hash and calls the C<config_substitutions>
 221 sub on any string.
 222
 223 =cut
 224
 225 sub finalize_config {
 226     my $c = shift;
 227     my $v = Data::Visitor::Callback->new(
 228         plain_value => sub {
 229             return unless defined $_;
 230             $c->config_substitutions( $_ );
 231         }
 232     );
 233     $v->visit( $c->config );
 234 }
 235
 236 =head2 config_substitutions( $value )
 237
 238 This method substitutes macros found with calls to a function. There are three
 239 default macros:
 240
 241 =over 4
 242
 243 =item * C<__HOME__> - replaced with C<$c-E<gt>path_to('')>
 244
 245 =item * C<__path_to(foo/bar)__> - replaced with C<$c-E<gt>path_to('foo/bar')>
 246
 247 =item * C<__literal(__FOO__)__> - leaves __FOO__ alone (allows you to use
 248 C<__DATA__> as a config value, for example)
 249
 250 =back
 251
 252 The parameter list is split on comma (C<,>). You can override this method to
 253 do your own string munging, or you can define your own macros in
 254 C<MyApp->config->{ substitutions }>. Example:
 255
 256     MyApp->config->{ substitutions } = {
 257         baz => sub { my $c = shift; qux( @_ ); }
 258     }
 259
 260 The above will respond to C<__baz(x,y)__> in config strings.
 261
 262 =cut
 263
 264 sub config_substitutions {
 265     my $c = shift;
 266     my $subs = $c->config->{ substitutions } || {};
 267     $subs->{ HOME } ||= sub { shift->path_to( '' ); };
 268     $subs->{ path_to } ||= sub { shift->path_to( @_ ); };
 269     $subs->{ literal } ||= sub { return $_[ 1 ]; };
 270     my $subsre = join( '|', keys %$subs );
 271
 272     for ( @_ ) {
 273         s{__($subsre)(?:\((.+?)\))?__}{ $subs->{ $1 }->( $c, $2 ? split( /,/, $2 ) : () ) }eg;
 274     }
 275 }
 276
 277
 278 =head1 AUTHOR
 279
 280 Brian Cassidy E<lt>bricas@cpan.orgE<gt>
 281
 282 =head1 CONTRIBUTORS
 283
 284 The following people have generously donated their time to the
 285 development of this module:
 286
 287 =over 4
 288
 289 =item * Joel Bernstein E<lt>rataxis@cpan.orgE<gt> - Rewrite to use L<Config::Any>
 290
 291 =item * David Kamholz E<lt>dkamholz@cpan.orgE<gt> - L<Data::Visitor> integration
 292
 293 =back
 294
 295 Work to this module has been generously sponsored by:
 296
 297 =over 4
 298
 299 =item * Portugal Telecom L<http://www.sapo.pt/> - Work done by Joel Bernstein
 300
 301 =back
 302
 303 =head1 COPYRIGHT AND LICENSE
 304
 305 Copyright 2007 by Brian Cassidy
 306
 307 This library is free software; you can redistribute it and/or modify
 308 it under the same terms as Perl itself.
 309
 310 =head1 SEE ALSO
 311
 312 =over 4
 313
 314 =item * L<Catalyst>
 315
 316 =item * L<Catalyst::Plugin::ConfigLoader::Manual>
 317
 318 =item * L<Config::Any>
 319
 320 =back
 321
 322 =cut
 323
 324 1;