many documentation updates
[catagits/Catalyst-Plugin-Authentication.git] / lib / Catalyst / Plugin / Authentication.pm
1 #!/usr/bin/perl
2
3 package Catalyst::Plugin::Authentication;
4
5 use base qw/Class::Accessor::Fast Class::Data::Inheritable/;
6
7 BEGIN {
8     __PACKAGE__->mk_accessors(qw/_user/);
9 }
10
11 use strict;
12 use warnings;
13
14 use Tie::RefHash;
15 use Class::Inspector;
16
17 # this optimization breaks under Template::Toolkit
18 # use user_exists instead
19 #BEGIN {
20 #       require constant;
21 #       constant->import(have_want => eval { require Want });
22 #}
23
24 our $VERSION = "0.09999_01";
25
26 sub set_authenticated {
27     my ( $c, $user, $realmname ) = @_;
28
29     $c->user($user);
30     $c->request->{user} = $user;    # compatibility kludge
31
32     if (!$realmname) {
33         $realmname = 'default';
34     }
35     
36     if (    $c->isa("Catalyst::Plugin::Session")
37         and $c->config->{authentication}{use_session}
38         and $user->supports("session") )
39     {
40         $c->save_user_in_session($user, $realmname);
41     }
42     $user->auth_realm($realmname);
43     
44     $c->NEXT::set_authenticated($user, $realmname);
45 }
46
47 sub _should_save_user_in_session {
48     my ( $c, $user ) = @_;
49
50     $c->_auth_sessions_supported
51     and $c->config->{authentication}{use_session}
52     and $user->supports("session");
53 }
54
55 sub _should_load_user_from_session {
56     my ( $c, $user ) = @_;
57
58     $c->_auth_sessions_supported
59     and $c->config->{authentication}{use_session}
60     and $c->session_is_valid;
61 }
62
63 sub _auth_sessions_supported {
64     my $c = shift;
65     $c->isa("Catalyst::Plugin::Session");
66 }
67
68 sub user {
69     my $c = shift;
70
71     if (@_) {
72         return $c->_user(@_);
73     }
74
75     if ( defined($c->_user) ) {
76         return $c->_user;
77     } else {
78         return $c->auth_restore_user;
79     }
80 }
81
82 # change this to allow specification of a realm - to verify the user is part of that realm
83 # in addition to verifying that they exist. 
84 sub user_exists {
85         my $c = shift;
86         return defined($c->_user) || defined($c->_user_in_session);
87 }
88
89 # works like user_exists - except only returns true if user 
90 # exists AND is in the realm requested.
91 sub user_in_realm {
92     my ($c, $realmname) = @_;
93
94     if (defined($c->_user)) {
95         return ($c->_user->auth_realm eq $realmname);
96     } elsif (defined($c->_user_in_session)) {
97         return ($c->session->{__user_realm} eq $realmname);  
98     } else {
99         return undef;
100     }
101 }
102
103 sub save_user_in_session {
104     my ( $c, $user, $realmname ) = @_;
105
106     $c->session->{__user_realm} = $realmname;
107     
108     # we want to ask the store for a user prepared for the session.
109     # but older modules split this functionality between the user and the
110     # store.  We try the store first.  If not, we use the old method.
111     my $realm = $c->get_auth_realm($realmname);
112     if ($realm->{'store'}->can('for_session')) {
113         $c->session->{__user} = $realm->{'store'}->for_session($c, $user);
114     } else {
115         $c->session->{__user} = $user->for_session;
116     }
117 }
118
119 sub logout {
120     my $c = shift;
121
122     $c->user(undef);
123
124     if (
125         $c->isa("Catalyst::Plugin::Session")
126         and $c->config->{authentication}{use_session}
127         and $c->session_is_valid
128     ) {
129         delete @{ $c->session }{qw/__user __user_realm/};
130     }
131     
132     $c->NEXT::logout(@_);
133 }
134
135 sub find_user {
136     my ( $c, $userinfo, $realmname ) = @_;
137     
138     $realmname ||= 'default';
139     my $realm = $c->get_auth_realm($realmname);
140     if ( $realm->{'store'} ) {
141         return $realm->{'store'}->find_user($userinfo, $c);
142     } else {
143         $c->log->debug('find_user: unable to locate a store matching the requested realm');
144     }
145 }
146
147
148 sub _user_in_session {
149     my $c = shift;
150
151     return unless $c->_should_load_user_from_session;
152
153     return $c->session->{__user};
154 }
155
156 sub auth_restore_user {
157     my ( $c, $frozen_user, $realmname ) = @_;
158
159     $frozen_user ||= $c->_user_in_session;
160     return unless defined($frozen_user);
161
162     $realmname  ||= $c->session->{__user_realm};
163     return unless $realmname; # FIXME die unless? This is an internal inconsistency
164
165     my $realm = $c->get_auth_realm($realmname);
166     $c->_user( my $user = $realm->{'store'}->from_session( $c, $frozen_user ) );
167     
168     # this sets the realm the user originated in.
169     $user->auth_realm($realmname);
170     return $user;
171
172 }
173
174 # we can't actually do our setup in setup because the model has not yet been loaded.  
175 # So we have to trigger off of setup_finished.  :-(
176 sub setup {
177     my $app = shift;
178
179     $app->_authentication_initialize();
180     $app->NEXT::setup(@_);
181 }
182
183 ## the actual initialization routine. whee.
184 sub _authentication_initialize {
185     my $app = shift;
186
187     if ($app->_auth_realms) { return };
188     
189
190     
191     my $cfg = $app->config->{'authentication'} ||= {};
192
193     $cfg->{use_session} = 1;
194
195     ## make classdata where it is used.  
196     $app->mk_classdata( _auth_realms => {});
197     
198     
199
200     if (exists($cfg->{'realms'})) {
201         foreach my $realm (keys %{$cfg->{'realms'}}) {
202             $app->setup_auth_realm($realm, $cfg->{'realms'}{$realm});
203         }
204         #  if we have a 'default-realm' in the config hash and we don't already 
205         # have a realm called 'default', we point default at the realm specified
206         if (exists($cfg->{'default_realm'}) && !$app->get_auth_realm('default')) {
207             $app->_set_default_auth_realm($cfg->{'default_realm'});
208         }
209     } else {
210         
211         ## BACKWARDS COMPATIBILITY - if realm is not defined - then we are probably dealing
212         ## with an old-school config.  The only caveat here is that we must add a classname
213         
214         foreach my $storename (keys %{$cfg->{'stores'}}) {
215             my $realmcfg = {
216                 store => $cfg->{'stores'}{$storename},
217             };
218             $app->setup_auth_realm($storename, $realmcfg);
219         }
220     }
221     
222 }
223
224 # set up realmname.
225 sub setup_auth_realm {
226     my ($app, $realmname, $config) = @_;
227     
228     $app->log->debug("Setting up $realmname");
229     if (!exists($config->{'store'}{'class'})) {
230         Carp::croak "Couldn't setup the authentication realm named '$realmname', no class defined";
231     } 
232         
233     # use the 
234     my $storeclass = $config->{'store'}{'class'};
235     
236     ## follow catalyst class naming - a + prefix means a fully qualified class, otherwise it's
237     ## taken to mean C::P::A::Store::(specifiedclass)
238     if ($storeclass !~ /^\+(.*)$/ ) {
239         $storeclass = "Catalyst::Plugin::Authentication::Store::${storeclass}";
240     } else {
241         $storeclass = $1;
242     }
243     
244
245     # a little niceness - since most systems seem to use the password credential class, 
246     # if no credential class is specified we use password.
247     $config->{credential}{class} ||= "Catalyst::Plugin::Authentication::Credential::Password";
248
249     my $credentialclass = $config->{'credential'}{'class'};
250     
251     ## follow catalyst class naming - a + prefix means a fully qualified class, otherwise it's
252     ## taken to mean C::P::A::Credential::(specifiedclass)
253     if ($credentialclass !~ /^\+(.*)$/ ) {
254         $credentialclass = "Catalyst::Plugin::Authentication::Credential::${credentialclass}";
255     } else {
256         $credentialclass = $1;
257     }
258     
259     # if we made it here - we have what we need to load the classes;
260     Catalyst::Utils::ensure_class_loaded( $credentialclass );
261     Catalyst::Utils::ensure_class_loaded( $storeclass );
262     
263     # BACKWARDS COMPATIBILITY - if the store class does not define find_user, we define it in terms 
264     # of get_user and add it to the class.  this is because the auth routines use find_user, 
265     # and rely on it being present. (this avoids per-call checks)
266     if (!$storeclass->can('find_user')) {
267         no strict 'refs';
268         *{"${storeclass}::find_user"} = sub {
269                                                 my ($self, $info) = @_;
270                                                 my @rest = @{$info->{rest}} if exists($info->{rest});
271                                                 $self->get_user($info->{id}, @rest);
272                                             };
273     }
274     
275     $app->auth_realms->{$realmname}{'store'} = $storeclass->new($config->{'store'}, $app);
276     $app->auth_realms->{$realmname}{'credential'} = $credentialclass->new($config->{'credential'}, $app);
277 }
278
279 sub auth_realms {
280     my $self = shift;
281     return($self->_auth_realms);
282 }
283
284 sub get_auth_realm {
285     my ($app, $realmname) = @_;
286     return $app->auth_realms->{$realmname};
287 }
288
289
290 # Very internal method.  Vital Valuable Urgent, Do not touch on pain of death.
291 # Using this method just assigns the default realm to be the value associated
292 # with the realmname provided.  It WILL overwrite any real realm called 'default'
293 # so can be very confusing if used improperly.  It's used properly already. 
294 # Translation: don't use it.
295 sub _set_default_auth_realm {
296     my ($app, $realmname) = @_;
297     
298     if (exists($app->auth_realms->{$realmname})) {
299         $app->auth_realms->{'default'} = $app->auth_realms->{$realmname};
300     }
301     return $app->get_auth_realm('default');
302 }
303
304 sub authenticate {
305     my ($app, $userinfo, $realmname) = @_;
306     
307     if (!$realmname) {
308         $realmname = 'default';
309     }
310         
311     my $realm = $app->get_auth_realm($realmname);
312     
313     ## note to self - make authenticate throw an exception if realm is invalid.
314     
315     if ($realm && exists($realm->{'credential'})) {
316         my $user = $realm->{'credential'}->authenticate($app, $realm->{store}, $userinfo);
317         if (ref($user)) {
318             $app->set_authenticated($user, $realmname);
319             return $user;
320         }
321     } else {
322         $app->log->debug("The realm requested, '$realmname' does not exist," .
323                          " or there is no credential associated with it.")
324     }
325     return undef;
326 }
327
328 ## BACKWARDS COMPATIBILITY  -- Warning:  Here be monsters!
329 #
330 # What follows are backwards compatibility routines - for use with Stores and Credentials
331 # that have not been updated to work with C::P::Authentication v0.10.  
332 # These are here so as to not break people's existing installations, but will go away
333 # in a future version.
334 #
335 # The old style of configuration only supports a single store, as each store module
336 # sets itself as the default store upon being loaded.  This is the only supported 
337 # 'compatibility' mode.  
338 #
339
340 sub get_user {
341     my ( $c, $uid, @rest ) = @_;
342
343     return $c->find_user( {'id' => $uid, 'rest'=>\@rest }, 'default' );
344 }
345
346
347 ## this should only be called when using old-style authentication plugins.  IF this gets
348 ## called in a new-style config - it will OVERWRITE the store of your default realm.  Don't do it.
349 ## also - this is a partial setup - because no credential is instantiated... in other words it ONLY
350 ## works with old-style auth plugins and C::P::Authentication in compatibility mode.  Trying to combine
351 ## this with a realm-type config will probably crash your app.
352 sub default_auth_store {
353     my $self = shift;
354
355     if ( my $new = shift ) {
356         $self->auth_realms->{'default'}{'store'} = $new;
357         my $storeclass = ref($new);
358         
359         # BACKWARDS COMPATIBILITY - if the store class does not define find_user, we define it in terms 
360         # of get_user and add it to the class.  this is because the auth routines use find_user, 
361         # and rely on it being present. (this avoids per-call checks)
362         if (!$storeclass->can('find_user')) {
363             no strict 'refs';
364             *{"${storeclass}::find_user"} = sub {
365                                                     my ($self, $info) = @_;
366                                                     my @rest = @{$info->{rest}} if exists($info->{rest});
367                                                     $self->get_user($info->{id}, @rest);
368                                                 };
369         }
370     }
371
372     return $self->get_auth_realm('default')->{'store'};
373 }
374
375 ## BACKWARDS COMPATIBILITY
376 ## this only ever returns a hash containing 'default' - as that is the only
377 ## supported mode of calling this.
378 sub auth_store_names {
379     my $self = shift;
380
381     my %hash = (  $self->get_auth_realm('default')->{'store'} => 'default' );
382 }
383
384 sub get_auth_store {
385     my ( $self, $name ) = @_;
386     
387     if ($name ne 'default') {
388         Carp::croak "get_auth_store called on non-default realm '$name'. Only default supported in compatibility mode";        
389     } else {
390         $self->default_auth_store();
391     }
392 }
393
394 sub get_auth_store_name {
395     my ( $self, $store ) = @_;
396     return 'default';
397 }
398
399 # sub auth_stores is only used internally - here for completeness
400 sub auth_stores {
401     my $self = shift;
402
403     my %hash = ( 'default' => $self->get_auth_realm('default')->{'store'});
404 }
405
406 __PACKAGE__;
407
408 __END__
409
410 =pod
411
412 =head1 NAME
413
414 Catalyst::Plugin::Authentication - Infrastructure plugin for the Catalyst
415 authentication framework.
416
417 =head1 SYNOPSIS
418
419     use Catalyst qw/
420         Authentication
421     /;
422
423     # later on ...
424     $c->authenticate({ username => 'myusername', 
425                        password => 'mypassword' });
426     my $age = $c->user->get('age');
427     $c->logout;
428
429 =head1 DESCRIPTION
430
431 The authentication plugin provides generic user support for Catalyst apps. It
432 is the basis for both authentication (checking the user is who they claim to
433 be), and authorization (allowing the user to do what the system authorises
434 them to do).
435
436 Using authentication is split into two parts. A Store is used to actually
437 store the user information, and can store any amount of data related to the
438 user. Credentials are used to verify users, using information from the store,
439 given data from the frontend. A Credential and a Store are paired to form a
440 'Realm'. A Catalyst application using the authentication framework must have
441 at least one realm, and may have several.
442
443 To implement authentication in a Catalyst application you need to add this 
444 module, and specify at least one realm in the configuration. 
445
446 Authentication data can also be stored in a session, if the application 
447 is using the L<Catalyst::Plugin::Session> module.
448
449 B<NOTE> in version 0.10 of this module, the interface to this module changed.
450 Please see L</COMPATIBILITY ROUTINES> for more information.
451
452 =head1 INTRODUCTION
453
454 =head2 The Authentication/Authorization Process
455
456 Web applications typically need to identify a user - to tell the user apart
457 from other users. This is usually done in order to display private information
458 that is only that user's business, or to limit access to the application so
459 that only certain entities can access certain parts.
460
461 This process is split up into several steps. First you ask the user to identify
462 themselves. At this point you can't be sure that the user is really who they
463 claim to be.
464
465 Then the user tells you who they are, and backs this claim with some piece of
466 information that only the real user could give you. For example, a password is
467 a secret that is known to both the user and you. When the user tells you this
468 password you can assume they're in on the secret and can be trusted (ignore
469 identity theft for now). Checking the password, or any other proof is called
470 B<credential verification>.
471
472 By this time you know exactly who the user is - the user's identity is
473 B<authenticated>. This is where this module's job stops, and your application
474 or other plugins step in.  
475
476 The next logical step is B<authorization>, the process of deciding what a user
477 is (or isn't) allowed to do. For example, say your users are split into two
478 main groups - regular users and administrators. You want to verify that the
479 currently logged in user is indeed an administrator before performing the
480 actions in an administrative part of your application. These decisions may be
481 made within your application code using just the information available after
482 authentication, or it may be facilitated by a number of plugins.  
483
484 =head2 The Components In This Framework
485
486 =head3 Realms
487
488 Configuration of the Catalyst::Plugin::Authentication framework is done in
489 terms of realms. In simplest terms, a realm is a pairing of a Credential
490 verifier and a User storage (Store) backend.
491
492 An application can have any number of Realms, each of which operates
493 independant of the others. Each realm has a name, which is used to identify it
494 as the target of an authentication request. This name can be anything, such as
495 'users' or 'members'. One realm must be defined as the default_realm, which is
496 used when no realm name is specified. More information about configuring
497 realms is available in the configuration section.
498
499 =head3 Credential Verifiers
500
501 When user input is transferred to the L<Catalyst> application (typically via
502 form inputs) the application may pass this information into the authentication
503 system through the $c->authenticate() method.  From there, it is passed to the
504 appropriate Credential verifier.
505
506 These plugins check the data, and ensure that it really proves the user is who
507 they claim to be.
508
509 =head3 Storage Backends
510
511 The authentication data also identifies a user, and the Storage backend modules
512 use this data to locate and return a standardized object-oriented
513 representation of a user.
514
515 When a user is retrieved from a store it is not necessarily authenticated.
516 Credential verifiers accept a set of authentication data and use this
517 information to retrieve the user from the store they are paired with.
518
519 =head3 The Core Plugin
520
521 This plugin on its own is the glue, providing realm configuration, session
522 integration, and other goodness for the other plugins.
523
524 =head3 Other Plugins
525
526 More layers of plugins can be stacked on top of the authentication code. For
527 example, L<Catalyst::Plugin::Session::PerUser> provides an abstraction of
528 browser sessions that is more persistent per users.
529 L<Catalyst::Plugin::Authorization::Roles> provides an accepted way to separate
530 and group users into categories, and then check which categories the current
531 user belongs to.
532
533 =head1 EXAMPLE
534
535 Let's say we were storing users in a simple perl hash. Users are
536 verified by supplying a password which is matched within the hash.
537
538 This means that our application will begin like this:
539
540     package MyApp;
541
542     use Catalyst qw/
543         Authentication
544     /;
545
546     __PACKAGE__->config->{authentication} = 
547                 {  
548                     default_realm => 'members',
549                     realms => {
550                         members => {
551                             credential => {
552                                 class => 'Password',
553                                 password_field => 'password',
554                                 password_type => 'clear'
555                             },
556                             store => {
557                                 class => 'Minimal',
558                                 users = {
559                                     bob => {
560                                         password => "s00p3r",                                       
561                                         editor => 'yes',
562                                         roles => [qw/edit delete/],
563                                     },
564                                     william => {
565                                         password => "s3cr3t",
566                                         roles => [qw/comment/],
567                                     }
568                                 }                       
569                             }
570                         }
571                         }
572                 };
573     
574
575 This tells the authentication plugin what realms are available, which
576 credential and store modules are used, and the configuration of each. With
577 this code loaded, we can now attempt to authenticate users.
578
579 To show an example of this, let's create an authentication controller:
580
581     package MyApp::Controller::Auth;
582
583     sub login : Local {
584         my ( $self, $c ) = @_;
585
586         if (    my $user = $c->req->param("user")
587             and my $password = $c->req->param("password") )
588         {
589             if ( $c->authenticate( { username => $user, 
590                                      password => $password } ) ) {
591                 $c->res->body( "hello " . $c->user->get("name") );
592             } else {
593                 # login incorrect
594             }
595         }
596         else {
597             # invalid form input
598         }
599     }
600
601 This code should be very readable. If all the necessary fields are supplied,
602 call the "authenticate" method from the controller. If it succeeds the 
603 user is logged in.
604
605 The credential verifier will attempt to retrieve the user whose details match
606 the authentication information provided to $c->authenticate(). Once it fetches
607 the user the password is checked and if it matches the user will be
608 B<authenticated> and C<< $c->user >> will contain the user object retrieved
609 from the store.
610
611 In the above case, the default realm is checked, but we could just as easily
612 check an alternate realm. If this were an admin login, for example, we could
613 authenticate on the admin realm by simply changing the $c->authenticate()
614 call:
615
616     if ( $c->authenticate( { username => $user, 
617                              password => $password }, 'admin' )l ) {
618         $c->res->body( "hello " . $c->user->get("name") );
619     } ...
620
621
622 Now suppose we want to restrict the ability to edit to a user with an 
623 'editor' value of yes.
624
625 The restricted action might look like this:
626
627     sub edit : Local {
628         my ( $self, $c ) = @_;
629
630         $c->detach("unauthorized")
631           unless $c->user_exists
632           and $c->user->get('editor') eq 'yes';
633
634         # do something restricted here
635     }
636
637 (Note that if you have multiple realms, you can use $c->user_in_realm('realmname')
638 in place of $c->user_exists(); This will essentially perform the same 
639 verification as user_exists, with the added requirement that if there is a 
640 user, it must have come from the realm specified.)
641
642 The above example is somewhat similar to role based access control.  
643 L<Catalyst::Plugin::Authentication::Store::Minimal> treats the roles field as
644 an array of role names. Let's leverage this. Add the role authorization
645 plugin:
646
647     use Catalyst qw/
648         ...
649         Authorization::Roles
650     /;
651
652     sub edit : Local {
653         my ( $self, $c ) = @_;
654
655         $c->detach("unauthorized") unless $c->check_roles("edit");
656
657         # do something restricted here
658     }
659
660 This is somewhat simpler and will work if you change your store, too, since the
661 role interface is consistent.
662
663 Let's say your app grew, and you now have 10000 users. It's no longer
664 efficient to maintain a hash of users, so you move this data to a database.
665 You can accomplish this simply by installing the DBIx::Class Store and
666 changing your config:
667
668     __PACKAGE__->config->{authentication} = 
669                     {  
670                         default_realm => 'members',
671                         realms => {
672                             members => {
673                                 credential => {
674                                     class => 'Password',
675                                     password_field => 'password',
676                                     password_type => 'clear'
677                                 },
678                                 store => {
679                                     class => 'DBIx::Class',
680                                     user_class => 'MyApp::Users',
681                                     role_column => 'roles'                      
682                                 }
683                                 }
684                         }
685                     };
686
687 The authentication system works behind the scenes to load your data from the
688 new source. The rest of your application is completely unchanged.
689
690
691 =head1 CONFIGURATION
692
693 =over 4
694
695     # example
696     __PACKAGE__->config->{authentication} = 
697                 {  
698                     default_realm => 'members',
699                     realms => {
700                         members => {
701                             credential => {
702                                 class => 'Password',
703                                 password_field => 'password',
704                                 password_type => 'clear'
705                             },
706                             store => {
707                                 class => 'DBIx::Class',
708                                     user_class => 'MyApp::Users',
709                                     role_column => 'roles'                      
710                                 }
711                         },
712                         admins => {
713                             credential => {
714                                 class => 'Password',
715                                 password_field => 'password',
716                                 password_type => 'clear'
717                             },
718                             store => {
719                                 class => '+MyApp::Authentication::Store::NetAuth',
720                                 authserver => '192.168.10.17'
721                             }
722                         }
723                         
724                         }
725                 };
726
727 =item use_session
728
729 Whether or not to store the user's logged in state in the session, if the
730 application is also using L<Catalyst::Plugin::Session>. This 
731 value is set to true per default.
732
733 =item default_realm
734
735 This defines which realm should be used as when no realm is provided to methods
736 that require a realm such as authenticate or find_user.
737
738 =item realms
739
740 This contains the series of realm configurations you want to use for your app.
741 The only rule here is that there must be at least one.  A realm consists of a
742 name, which is used to reference the realm, a credential and a store.  
743
744 Each realm config contains two hashes, one called 'credential' and one called 
745 'store', each of which provide configuration details to the respective modules.
746 The contents of these hashes is specific to the module being used, with the 
747 exception of the 'class' element, which tells the core Authentication module the
748 classname to instantiate.  
749
750 The 'class' element follows the standard Catalyst mechanism of class
751 specification. If a class is prefixed with a +, it is assumed to be a complete
752 class name. Otherwise it is considered to be a portion of the class name. For
753 credentials, the classname 'B<Password>', for example, is expanded to
754 Catalyst::Plugin::Authentication::Credential::B<Password>. For stores, the
755 classname 'B<storename>' is expanded to:
756 Catalyst::Plugin::Authentication::Store::B<storename>.
757
758
759 =back
760
761
762 =head1 METHODS
763
764 =over 4 
765
766 =item authenticate( $userinfo, $realm )
767
768 Attempts to authenticate the user using the information in the $userinfo hash
769 reference using the realm $realm. $realm may be omitted, in which case the
770 default realm is checked.
771
772 =item user
773
774 Returns the currently logged in user or undef if there is none.
775
776 =item user_exists
777
778 Returns true if a user is logged in right now. The difference between
779 user_exists and user is that user_exists will return true if a user is logged
780 in, even if it has not been yet retrieved from the storage backend. If you only
781 need to know if the user is logged in, depending on the storage mechanism this
782 can be much more efficient.
783
784 =item user_in_realm ( $realm )
785
786 Works like user_exists, except that it only returns true if a user is both 
787 logged in right now and was retrieved from the realm provided.  
788
789 =item logout
790
791 Logs the user out, Deletes the currently logged in user from $c->user and the session.
792
793 =item find_user( $userinfo, $realm )
794
795 Fetch a particular users details, matching the provided user info, from the realm 
796 specified in $realm.
797
798 =back
799
800 =head1 INTERNAL METHODS
801
802 These methods are for Catalyst::Plugin::Authentication B<INTERNAL USE> only.
803 Please do not use them in your own code, whether application or credential /
804 store modules. If you do, you will very likely get the nasty shock of having
805 to fix / rewrite your code when things change. They are documented here only
806 for reference.
807
808 =over 4
809
810 =item set_authenticated ( $user, $realmname )
811
812 Marks a user as authenticated. This is called from within the authenticate
813 routine when a credential returns a user. $realmname defaults to 'default'
814
815 =item auth_restore_user ( $user, $realmname )
816
817 Used to restore a user from the session. In most cases this is called without
818 arguments to restore the user via the session. Can be called with arguments
819 when restoring a user from some other method.  Currently not used in this way.
820
821 =item save_user_in_session ( $user, $realmname )
822
823 Used to save the user in a session. Saves $user in session, marked as
824 originating in $realmname. Both arguments are required.
825
826 =item auth_realms
827
828 Returns a hashref containing realmname -> realm instance pairs. Realm
829 instances contain an instantiated store and credential object as the 'store'
830 and 'credential' elements, respectively
831
832 =item get_auth_realm ( $realmname )
833
834 Retrieves the realm instance for the realmname provided.
835
836 =item 
837
838 =back
839
840 =head1 SEE ALSO
841
842 This list might not be up to date.  Below are modules known to work with the updated
843 API of 0.10 and are therefore compatible with realms.  
844
845 =head2 User Storage Backends
846
847 L<Catalyst::Plugin::Authentication::Store::Minimal>,
848 L<Catalyst::Plugin::Authentication::Store::DBIx::Class>,
849
850 =head2 Credential verification
851
852 L<Catalyst::Plugin::Authentication::Credential::Password>,
853
854 =head2 Authorization
855
856 L<Catalyst::Plugin::Authorization::ACL>,
857 L<Catalyst::Plugin::Authorization::Roles>
858
859 =head2 Internals Documentation
860
861 L<Catalyst::Plugin::Authentication::Internals>
862
863 =head2 Misc
864
865 L<Catalyst::Plugin::Session>,
866 L<Catalyst::Plugin::Session::PerUser>
867
868 =head1 DON'T SEE ALSO
869
870 This module along with its sub plugins deprecate a great number of other
871 modules. These include L<Catalyst::Plugin::Authentication::Simple>,
872 L<Catalyst::Plugin::Authentication::CDBI>.
873
874 At the time of writing these plugins have not yet been replaced or updated, but
875 should be eventually: L<Catalyst::Plugin::Authentication::OpenID>,
876 L<Catalyst::Plugin::Authentication::LDAP>,
877 L<Catalyst::Plugin::Authentication::CDBI::Basic>,
878 L<Catalyst::Plugin::Authentication::Basic::Remote>.
879
880 =head1 INCOMPATABILITIES
881
882 The realms based configuration and functionality of the 0.10 update 
883 of L<Catalyst::Plugin::Authentication> required a change in the API used by
884 credentials and stores.  It has a compatibility mode which allows use of
885 modules that have not yet been updated. This, however, completely mimics the
886 older api and disables the new realm-based features. In other words you can
887 not mix the older credential and store modules with realms, or realm-based
888 configs. The changes required to update modules are relatively minor and are
889 covered in L<Catalyst::Plugin::Authentication::Internals>.  We hope that most
890 modules will move to the compatible list above very quickly.
891
892 =head1 COMPATIBILITY ROUTINES
893
894 In version 0.10 of L<Catalyst::Plugin::Authentication>, the API
895 changed. For app developers, this change is fairly minor, but for
896 Credential and Store authors, the changes are significant. 
897
898 Please see the documentation in version 0.09 of
899 Catalyst::Plugin::Authentication for a better understanding of how the old API
900 functioned.
901
902 The items below are still present in the plugin, though using them is
903 deprecated. They remain only as a transition tool, for those sites which can
904 not yet be upgraded to use the new system due to local customizations or use
905 of Credential / Store modules that have not yet been updated to work with the 
906 new API.
907
908 These routines should not be used in any application using realms
909 functionality or any of the methods described above. These are for reference
910 purposes only.
911
912 =over 4
913
914 =item login
915
916 This method is used to initiate authentication and user retrieval. Technically
917 this is part of the old Password credential module and it still resides in the
918 L<Password|Catalyst::Plugin::Authentication::Credential::Password> class. It is
919 included here for reference only.
920
921 =item default_auth_store
922
923 Return the store whose name is 'default'.
924
925 This is set to C<< $c->config->{authentication}{store} >> if that value exists,
926 or by using a Store plugin:
927
928     # load the Minimal authentication store.
929         use Catalyst qw/Authentication Authentication::Store::Minimal/;
930
931 Sets the default store to
932 L<Catalyst::Plugin::Authentication::Store::Minimal>.
933
934 =item get_auth_store $name
935
936 Return the store whose name is $name.
937
938 =item get_auth_store_name $store
939
940 Return the name of the store $store.
941
942 =item auth_stores
943
944 A hash keyed by name, with the stores registered in the app.
945
946 =item register_auth_stores %stores_by_name
947
948 Register stores into the application.
949
950 =back
951
952
953
954 =head1 AUTHORS
955
956 Yuval Kogman, C<nothingmuch@woobling.org>
957
958 Jay Kuri, C<jayk@cpan.org>
959
960 Jess Robinson
961
962 David Kamholz
963
964
965 =head1 COPYRIGHT & LICENSE
966
967         Copyright (c) 2005 the aforementioned authors. All rights
968         reserved. This program is free software; you can redistribute
969         it and/or modify it under the same terms as Perl itself.
970
971 =cut
972