lib/Catalyst/Model/DBIC/Schema.pm

   1 package Catalyst::Model::DBIC::Schema;
   2
   3 use strict;
   4 use base qw/Catalyst::Model Class::Accessor::Fast Class::Data::Accessor/;
   5 use NEXT;
   6 use UNIVERSAL::require;
   7 use Carp;
   8 require DBIx::Class;
   9
  10 our $VERSION = '0.14';
  11
  12 __PACKAGE__->mk_classaccessor('composed_schema');
  13 __PACKAGE__->mk_accessors('schema');
  14
  15 =head1 NAME
  16
  17 Catalyst::Model::DBIC::Schema - DBIx::Class::Schema Model Class
  18
  19 =head1 SYNOPSIS
  20
  21 Manual creation of a DBIx::Class::Schema and a Catalyst::Model::DBIC::Schema:
  22
  23 =over
  24
  25 =item 1.
  26
  27 Create the DBIx:Class schema in MyApp/Schema/FilmDB.pm:
  28
  29   package MyApp::Schema::FilmDB;
  30   use base qw/DBIx::Class::Schema/;
  31
  32   __PACKAGE__->load_classes(qw/Actor Role/);
  33
  34 =item 2.
  35
  36 Create some classes for the tables in the database, for example an
  37 Actor in MyApp/Schema/FilmDB/Actor.pm:
  38
  39   package MyApp::Schema::FilmDB::Actor;
  40   use base qw/DBIx::Class/
  41
  42   __PACKAGE__->load_components(qw/Core/);
  43   __PACKAGE__->table('actor');
  44
  45   ...
  46
  47 and a Role in MyApp/Schema/Role.pm:
  48
  49   package MyApp::Schema::FilmDB::Role;
  50   use base qw/DBIx::Class/
  51
  52   __PACKAGE__->load_components(qw/Core/);
  53   __PACKAGE__->table('role');
  54
  55   ...
  56
  57 Notice that the schema is in MyApp::Schema, not in MyApp::Model. This way it's
  58 usable as a standalone module and you can test/run it without Catalyst.
  59
  60 =item 3.
  61
  62 To expose it to Catalyst as a model, you should create a DBIC Model in
  63 MyApp/Model/FilmDB.pm:
  64
  65   package MyApp::Model::FilmDB;
  66   use base qw/Catalyst::Model::DBIC::Schema/;
  67
  68   __PACKAGE__->config(
  69       schema_class => 'MyApp::Schema::FilmDB',
  70       connect_info => [
  71                         "DBI:...",
  72                         "username",
  73                         "password",
  74                         {AutoCommit => 1}
  75                       ]
  76   );
  77
  78 See below for a full list of the possible config parameters.
  79
  80 =back
  81
  82 Now you have a working Model, accessing your separate DBIC Schema. Which can
  83 be used/accessed in the normal Catalyst manner, via $c->model():
  84
  85   my $actor = $c->model('FilmDB::Actor')->find(1);
  86
  87 You can also use it to set up DBIC authentication with
  88 Authentication::Store::DBIC in MyApp.pm:
  89
  90   package MyApp;
  91
  92   use Catalyst qw/... Authentication::Store::DBIC/;
  93
  94   ...
  95
  96   __PACKAGE__->config->{authentication}{dbic} = {
  97       user_class      => 'FilmDB::Actor',
  98       user_field      => 'name',
  99       password_field  => 'password'
 100   }
 101
 102 C<< $c->model() >> returns a L<DBIx::Class::ResultSet> for the source name
 103 parameter passed. To find out more about which methods can be called on a
 104 ResultSet, or how to add your own methods to it, please see the ResultSet
 105 documentation in the L<DBIx::Class> distribution.
 106
 107 Some examples are given below:
 108
 109   # to access schema methods directly:
 110   $c->model('FilmDB')->schema->source(...);
 111
 112   # to access the source object, resultset, and class:
 113   $c->model('FilmDB')->source(...);
 114   $c->model('FilmDB')->resultset(...);
 115   $c->model('FilmDB')->class(...);
 116
 117   # For resultsets, there's an even quicker shortcut:
 118   $c->model('FilmDB::Actor')
 119   # is the same as $c->model('FilmDB')->resultset('Actor')
 120
 121   # To get the composed schema for making new connections:
 122   my $newconn = $c->model('FilmDB')->composed_schema->connect(...);
 123
 124   # Or the same thing via a convenience shortcut:
 125   my $newconn = $c->model('FilmDB')->connect(...);
 126
 127   # or, if your schema works on different storage drivers:
 128   my $newconn = $c->model('FilmDB')->composed_schema->clone();
 129   $newconn->storage_type('::LDAP');
 130   $newconn->connection(...);
 131
 132   # and again, a convenience shortcut
 133   my $newconn = $c->model('FilmDB')->clone();
 134   $newconn->storage_type('::LDAP');
 135   $newconn->connection(...);
 136
 137 =head1 DESCRIPTION
 138
 139 This is a Catalyst Model for L<DBIx::Class::Schema>-based Models.  See
 140 the documentation for L<Catalyst::Helper::Model::DBIC::Schema> for
 141 information on generating these Models via Helper scripts.
 142
 143 =head1 CONFIG PARAMETERS
 144
 145 =over 4
 146
 147 =item schema_class
 148
 149 This is the classname of your L<DBIx::Class::Schema> Schema.  It needs
 150 to be findable in C<@INC>, but it does not need to be inside the
 151 C<Catalyst::Model::> namespace.  This parameter is required.
 152
 153 =item connect_info
 154
 155 This is an arrayref of connection parameters, which are specific to your
 156 C<storage_type> (see your storage type documentation for more details).
 157
 158 This is not required if C<schema_class> already has connection information
 159 defined inside itself (which isn't highly recommended, but can be done)
 160
 161 For L<DBIx::Class::Storage::DBI>, which is the only supported
 162 C<storage_type> in L<DBIx::Class> at the time of this writing, the
 163 parameters are your dsn, username, password, and connect options hashref.
 164
 165 If you need to specify the L<DBIx::Class::Storage::DBI> specific parameter
 166 C<on_connect_do>, or the related C<sql_maker> options C<limit_dialect>,
 167 C<quote_char>, or C<name_sep>, you can place these options into a hashref
 168 as the final element of the C<connect_info> arrayref.  If in doubt, don't
 169 specify these options.  You would know it if you needed them.
 170
 171 Examples:
 172
 173   connect_info => [ 'dbi:Pg:dbname=mypgdb', 'postgres', '' ],
 174
 175   connect_info => [
 176                     'dbi:SQLite:dbname=foo.db',
 177                     {
 178                       on_connect_do => [
 179                         'PRAGMA synchronous = OFF',
 180                       ],
 181                     }
 182                   ],
 183
 184   connect_info => [
 185                     'dbi:Pg:dbname=mypgdb',
 186                     'postgres',
 187                     '',
 188                     { AutoCommit => 0 },
 189                     {
 190                       on_connect_do => [
 191                         'some SQL statement',
 192                         'another SQL statement',
 193                       ],
 194                     }
 195                   ],
 196
 197 =item storage_type
 198
 199 Allows the use of a different C<storage_type> than what is set in your
 200 C<schema_class> (which in turn defaults to C<::DBI> if not set in current
 201 L<DBIx::Class>).  Completely optional, and probably unnecessary for most
 202 people until other storage backends become available for L<DBIx::Class>.
 203
 204 =back
 205
 206 =head1 METHODS
 207
 208 =over 4
 209
 210 =item new
 211
 212 Instantiates the Model based on the above-documented ->config parameters.
 213 The only required parameter is C<schema_class>.  C<connect_info> is
 214 required in the case that C<schema_class> does not already have connection
 215 information defined for it.
 216
 217 =item schema
 218
 219 Accessor which returns the connected schema being used by the this model.
 220 There are direct shortcuts on the model class itself for
 221 schema->resultset, schema->source, and schema->class.
 222
 223 =item composed_schema
 224
 225 Accessor which returns the composed schema, which has no connection info,
 226 which was used in constructing the C<schema> above.  Useful for creating
 227 new connections based on the same schema/model.  There are direct shortcuts
 228 from the model object for composed_schema->clone and composed_schema->connect
 229
 230 =item clone
 231
 232 Shortcut for ->composed_schema->clone
 233
 234 =item connect
 235
 236 Shortcut for ->composed_schema->connect
 237
 238 =item source
 239
 240 Shortcut for ->schema->source
 241
 242 =item class
 243
 244 Shortcut for ->schema->class
 245
 246 =item resultset
 247
 248 Shortcut for ->schema->resultset
 249
 250 =item storage
 251
 252 Provides an accessor for the connected schema's storage object.
 253 Used often for debugging and controlling transactions.
 254
 255 =back
 256
 257 =cut
 258
 259 sub new {
 260     my $self = shift->NEXT::new(@_);
 261
 262     my $class = ref($self);
 263     my $model_name = $class;
 264     $model_name =~ s/^[\w:]+::(?:Model|M):://;
 265
 266     croak "->config->{schema_class} must be defined for this model"
 267         unless $self->{schema_class};
 268
 269     my $schema_class = $self->{schema_class};
 270
 271     $schema_class->require
 272         or croak "Cannot load schema class '$schema_class': $@";
 273
 274     if( !$self->{connect_info} ) {
 275         if($schema_class->storage && $schema_class->storage->connect_info) {
 276             $self->{connect_info} = $schema_class->storage->connect_info;
 277         }
 278         else {
 279             croak "Either ->config->{connect_info} must be defined for $class"
 280                   . " or $schema_class must have connect info defined on it";
 281         }
 282     }
 283
 284     $self->composed_schema($schema_class->compose_namespace($class));
 285     $self->schema($self->composed_schema->clone);
 286
 287     $self->schema->storage_type($self->{storage_type})
 288         if $self->{storage_type};
 289
 290     # XXX This is temporary, until DBIx::Class::Storage::DBI supports the
 291     #  same syntax and we switch our requisite to that version somewhere
 292     #  down the line.  This syntax is already committed into DBIx::Class
 293     #  -current branch post-0.06.
 294     # At that time, this whole block can revert back to just being:
 295     #  $self->schema->connection(@{$self->{connect_info}});
 296
 297     my $connect_info = [ @{$self->{connect_info}} ];
 298     my ($on_connect_do, %sql_maker_opts);
 299     if($DBIx::Class::VERSION < 0.069) {
 300         my $used;
 301         my $last_info = $self->{connect_info}->[-1];
 302         if(ref $last_info eq 'HASH') {
 303             if($on_connect_do = $last_info->{on_connect_do}) {
 304               $used = 1;
 305             }
 306             for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 307               if(my $opt_val = $last_info->{$sql_maker_opt}) {
 308                 $used = 1;
 309                 $sql_maker_opts{$sql_maker_opt} = $opt_val;
 310               }
 311             }
 312             pop(@$connect_info) if $used;
 313         }
 314     }
 315
 316     $self->schema->connection(@$connect_info);
 317
 318     if($DBIx::Class::VERSION < 0.069) {
 319         $self->schema->storage->on_connect_do($on_connect_do)
 320             if $on_connect_do;
 321         foreach my $sql_maker_opt (keys %sql_maker_opts) {
 322             $self->schema->storage->sql_maker->$sql_maker_opt(
 323                 $sql_maker_opts{$sql_maker_opt}
 324             );
 325         }
 326     }
 327
 328     # XXX end of compatibility block referenced above
 329
 330     no strict 'refs';
 331     foreach my $moniker ($self->schema->sources) {
 332         my $classname = "${class}::$moniker";
 333         *{"${classname}::ACCEPT_CONTEXT"} = sub {
 334             shift;
 335             shift->model($model_name)->resultset($moniker);
 336         }
 337     }
 338
 339     return $self;
 340 }
 341
 342 sub clone { shift->composed_schema->clone(@_); }
 343
 344 sub connect { shift->composed_schema->connect(@_); }
 345
 346 sub storage { shift->schema->storage(@_); }
 347
 348 =head1 SEE ALSO
 349
 350 General Catalyst Stuff:
 351
 352 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 353 L<Catalyst::Response>, L<Catalyst::Helper>, L<Catalyst>,
 354
 355 Stuff related to DBIC and this Model style:
 356
 357 L<DBIx::Class>, L<DBIx::Class::Schema>,
 358 L<DBIx::Class::Schema::Loader>, L<Catalyst::Helper::Model::DBIC::Schema>
 359
 360 =head1 AUTHOR
 361
 362 Brandon L Black, C<blblack@gmail.com>
 363
 364 =head1 COPYRIGHT
 365
 366 This program is free software, you can redistribute it and/or modify it
 367 under the same terms as Perl itself.
 368
 369 =cut
 370
 371 1;