3 Catalyst::Manual::Intro - Introduction to Catalyst
7 This is a brief introduction to Catalyst. It explains the most important
8 features of how Catalyst works and shows how to get a simple application
9 up and running quickly. For an introduction (without code) to Catalyst
10 itself, and why you should be using it, see L<Catalyst::Manual::About>.
11 For a systematic step-by-step introduction to writing an application
12 with Catalyst, see L<Catalyst::Manual::Tutorial>.
14 =head2 What is Catalyst?
16 Catalyst is an elegant web application framework, extremely flexible yet
17 extremely simple. It's similar to Ruby on Rails, Spring (Java), and
18 L<Maypole>, upon which it was originally based. Its most important
19 design philosphy is to provide easy access to all the tools you need to
20 develop web applications, with few restrictions on how you need to use
21 these tools. Under Catalyst, it is always possible to do things in a
22 different way. However, this does mean that it is always possible to do
23 things in a different way. Other web frameworks are simpler to use and
24 easy to get up and running, but achieve this by locking the programmer
25 into a single set of tools. Catalyst's emphasis on flexibility means
26 that you have to think more to use it. We view this as a feature.
30 Catalyst follows the Model-View-Controller (MVC) design pattern,
31 allowing you to easily separate concerns, like content, presentation,
32 and flow control, into separate modules. This separation allows you to
33 modify code that handles one concern without affecting code that handles
34 the others. Catalyst promotes the re-use of existing Perl modules that
35 already handle common web application concerns well.
37 Here's how the M, V, and C map to those concerns, with examples of
38 well-known Perl modules you may want to use for each.
44 Access and modify content (data). L<DBIx::Class>, L<Class::DBI>,
45 L<Xapian>, L<Net::LDAP>...
49 Present content to the user. L<Template Toolkit|Template>,
50 L<Mason|HTML::Mason>, L<HTML::Template>...
54 Control the whole request phase, check parameters, dispatch actions, flow
55 control. Catalyst itself!
59 If you're unfamiliar with MVC and design patterns, you may want to
60 check out the original book on the subject, I<Design Patterns>, by
61 Gamma, Helm, Johnson, and Vlissides, also known as the Gang of Four
62 (GoF). Many, many web application frameworks are based on MVC, which
63 is becoming a popular design method for web applications.
67 Catalyst is much more flexible than many other frameworks. We'll talk
68 more about this later, but rest assured you can use your favorite Perl
69 modules with Catalyst.
73 =item * B<Multiple Models, Views, and Controllers>
75 To build a Catalyst application, you handle each type of concern inside
76 special modules called L</Components>. Often this code will be very
77 simple, just calling out to Perl modules like those listed above under
78 L</MVC>. Catalyst handles these components in a very flexible way. Use
79 as many Models, Views, and Controllers as you like, using as many
80 different Perl modules as you like, all in the same application. Want to
81 manipulate multiple databases, and retrieve some data via LDAP? No
82 problem. Want to present data from the same Model using L<Template
83 Toolkit|Template> and L<PDF::Template>? Easy.
85 =item * B<Reuseable Components>
87 Not only does Catalyst promote the re-use of already existing Perl
88 modules, it also allows you to re-use your Catalyst components in
89 multiple Catalyst applications.
91 =item * B<Unrestrained URL-to-Action Dispatching>
93 Catalyst allows you to dispatch any URLs to any application L</Actions>,
94 even through regular expressions! Unlike most other frameworks, it
95 doesn't require mod_rewrite or class and method names in URLs.
97 With Catalyst you register your actions and address them directly. For
101 my ( $self, $context ) = @_;
102 $context->response->body('Hello World!');
105 Now http://localhost:3000/hello prints "Hello World!".
107 =item * B<Support for CGI, mod_perl, Apache::Request>
109 Use L<Catalyst::Engine::Apache> or L<Catalyst::Engine::CGI>.
115 The best part is that Catalyst implements all this flexibility in a very
120 =item * B<Building Block Interface>
122 Components interoperate very smoothly. For example, Catalyst
123 automatically makes a L</Context> object available to every
124 component. Via the context, you can access the request object, share
125 data between components, and control the flow of your
126 application. Building a Catalyst application feels a lot like snapping
127 together toy building blocks, and everything just works.
129 =item * B<Component Auto-Discovery>
131 No need to C<use> all of your components. Catalyst automatically finds
134 =item * B<Pre-Built Components for Popular Modules>
136 See L<Catalyst::Model::DBIC::Schema> for L<DBIx::Class>, or
137 L<Catalyst::View::TT> for L<Template Toolkit|Template>.
139 =item * B<Built-in Test Framework>
141 Catalyst comes with a built-in, lightweight http server and test
142 framework, making it easy to test applications from the command line.
144 =item * B<Helper Scripts>
146 Catalyst provides helper scripts to quickly generate running starter
147 code for components and unit tests. See L<Catalyst::Helper>.
153 Here's how to install Catalyst and get a simple application up and
154 running, using the helper scripts described above.
158 $ perl -MCPAN -e 'install Task::Catalyst'
165 $ script/myapp_create.pl controller Library::Login
169 $ script/myapp_server.pl
171 Now visit these locations with your favorite browser or user agent to see
174 (NOTE: Although we create a controller here, we don't actually use it.
175 Both of these URLs should take you to the welcome page.)
180 =item http://localhost:3000/
182 =item http://localhost:3000/library/login/
190 Let's see how Catalyst works, by taking a closer look at the components
191 and other parts of a Catalyst application.
193 =head3 Application Class
195 In addition to the Model, View, and Controller components, there's a
196 single class that represents your application itself. This is where you
197 configure your application, load plugins, and extend Catalyst.
202 use Catalyst qw/-Debug/;
205 name => 'My Application',
207 # You can put anything else you want in here:
208 my_configuration_variable => 'something',
212 In older versions of Catalyst, the application class was where you put
213 global actions. However, as of version 5.66, the recommended practice is
214 to place such actions in a special Root controller (see L</Actions>,
215 below), to avoid namespace collisions.
221 The name of your application.
225 Optionally, you can specify a B<root> parameter for templates and static
226 data. If omitted, Catalyst will try to auto-detect the directory's
227 location. You can define as many parameters as you want for plugins or
228 whatever you need. You can access them anywhere in your application via
229 C<$context-E<gt>config-E<gt>{$param_name}>.
233 Catalyst automatically blesses a Context object into your application
234 class and makes it available everywhere in your application. Use the
235 Context to directly interact with Catalyst and glue your L</Components>
236 together. For example, if you need to use the Context from within a
237 Template Toolkit template, it's already there:
239 <h1>Welcome to [% c.config.name %]!</h1>
241 As illustrated in our URL-to-Action dispatching example, the Context is
242 always the second method parameter, behind the Component object
243 reference or class name itself. Previously we called it C<$context> for
244 clarity, but most Catalyst developers just call it C<$c>:
247 my ( $self, $c ) = @_;
248 $c->res->body('Hello World!');
251 The Context contains several important objects:
255 =item * L<Catalyst::Request>
260 The request object contains all kinds of request-specific information, like
261 query parameters, cookies, uploads, headers, and more.
263 $c->req->params->{foo};
264 $c->req->cookies->{sessionid};
265 $c->req->headers->content_type;
267 $c->req->uri_with( { page = $pager->next_page } );
269 =item * L<Catalyst::Response>
274 The response is like the request, but contains just response-specific
277 $c->res->body('Hello World');
278 $c->res->status(404);
279 $c->res->redirect('http://oook.de');
281 =item * L<Catalyst::Config>
287 =item * L<Catalyst::Log>
290 $c->log->debug('Something happened');
291 $c->log->info('Something you should know');
296 $c->stash->{foo} = 'bar';
297 $c->stash->{baz} = {baz => 'qox'};
298 $c->stash->{fred} = [qw/ wilma pebbles/];
304 The last of these, the stash, is a universal hash for sharing data among
305 application components. For an example, we return to our 'hello' action:
308 my ( $self, $c ) = @_;
309 $c->stash->{message} = 'Hello World!';
310 $c->forward('show_message');
313 sub show_message : Private {
314 my ( $self, $c ) = @_;
315 $c->res->body( $c->stash->{message} );
318 Note that the stash should be used only for passing data in an
319 individual request cycle; it gets cleared at a new request. If you need
320 to maintain persistent data, use a session. See
321 L<Catalyst::Plugin::Session> for a comprehensive set of
322 Catalyst-friendly session-handling tools.
326 A Catalyst controller is defined by its actions. An action is a
327 subroutine with a special attribute. You've already seen some examples
328 of actions in this document. The URL (for example
329 http://localhost.3000/foo/bar) consists of two parts, the base
330 (http://localhost:3000/ in this example) and the path (foo/bar). Please
331 note that the trailing slash after the hostname[:port] always belongs to
332 base and not to the action.
336 =item * B<Application Wide Actions>
338 Actions which are called at the root level of the application
339 (e.g. http://localhost:3000/ ) go in MyApp::Controller::Root, like
342 package MyApp::Controller::Root;
343 use base 'Catalyst::Controller';
344 # Sets the actions in this controller to be registered with no prefix
345 # so they function identically to actions created in MyApp.pm
346 __PACKAGE__->config->{namespace} = '';
347 sub default : Private {
348 my ( $self, $context ) = @_;
349 $context->response->body('Catalyst rocks!');
357 Catalyst supports several types of actions:
361 =item * B<Literal> (B<Path> actions)
363 package MyApp::Controller::My::Controller;
364 sub bar : Path('foo/bar') { }
366 Literal C<Path> actions will act relative to their current
367 namespace. The above example matches only
368 http://localhost:3000/my/controller/foo/bar. If you start your path with
369 a forward slash, it will match from the root. Example:
371 package MyApp::Controller::My::Controller;
372 sub bar : Path('/foo/bar') { }
374 Matches only http://localhost:3000/foo/bar.
376 package MyApp::Controller::My::Controller;
379 By leaving the C<Path> definition empty, it will match on the namespace
380 root. The above code matches http://localhost:3000/my/controller.
384 sub bar : Regex('^item(\d+)/order(\d+)$') { }
386 Matches any URL that matches the pattern in the action key, e.g.
387 http://localhost:3000/item23/order42. The '' around the regexp is
388 optional, but perltidy likes it. :)
390 Regex matches act globally, i.e. without reference to the namespace from
391 which it is called, so that a C<bar> method in the
392 C<MyApp::Controller::Catalog::Order::Process> namespace won't match any
393 form of C<bar>, C<Catalog>, C<Order>, or C<Process> unless you
394 explicitly put this in the regex. To achieve the above, you should
395 consider using a C<LocalRegex> action.
397 =item * B<LocalRegex>
399 sub bar : LocalRegex('^widget(\d+)$') { }
401 LocalRegex actions act locally. If you were to use C<bar> in
402 C<MyApp::Controller::Catalog>, the above example would match urls like
403 http://localhost:3000/catalog/widget23.
405 If you omit the "C<^>" from your regex, then it will match any depth
406 from the controller and not immediately off of the controller name. The
407 following example differs from the above code in that it will match
408 http://localhost:3000/catalog/foo/widget23 as well.
410 package MyApp::Controller::Catalog;
411 sub bar : LocalRegex('widget(\d+)$') { }
413 For both LocalRegex and Regex actions, if you use capturing parentheses
414 to extract values within the matching URL, those values are available in
415 the C<$c-E<gt>req-E<gt>captures> array. In the above example, "widget23"
416 would capture "23" in the above example, and
417 C<$c-E<gt>req-E<gt>captures-E<gt>[0]> would be "23". If you want to pass
418 arguments at the end of your URL, you must use regex action keys. See
419 L</URL Path Handling> below.
421 =item * B<Top-level> (B<Global>)
423 package MyApp::Controller::Foo;
426 Matches http://localhost:3000/foo. The function name is mapped
427 directly to the application base. You can provide an equivalent
428 function in this case by doing the following:
430 package MyApp::Controller::Root
433 =item * B<Namespace-Prefixed> (B<Local>)
435 package MyApp::Controller::My::Controller;
438 Matches http://localhost:3000/my/controller/foo.
440 This action type indicates that the matching URL must be prefixed with a
441 modified form of the component's class (package) name. This modified
442 class name excludes the parts that have a pre-defined meaning in
443 Catalyst ("MyApp::Controller" in the above example), replaces "::" with
444 "/", and converts the name to lower case. See L</Components> for a full
445 explanation of the pre-defined meaning of Catalyst component class
450 Catalyst also provides a method to build and dispatch chains of actions,
453 sub foo : Chained : CaptureArgs(1) {
454 my ( $self, $c, $arg ) = @_;
458 sub bar : Chained('foo') : Args(1) {
459 my ( $self, $c, $arg ) = @_;
463 to handle a C</foo/*/bar/*> path. For extensive information about this
464 dispatch type, please see L<Catalyst::DispatchType::Chained>.
468 sub foo : Private { }
470 Matches no URL, and cannot be executed by requesting a URL that
471 corresponds to the action key. Private actions can be executed only
472 inside a Catalyst application, by calling the C<forward> method:
476 See L</Flow Control> for a full explanation of C<forward>. Note that, as
477 discussed there, when forwarding from another component, you must use
478 the absolute path to the method, so that a private C<bar> method in your
479 C<MyApp::Controller::Catalog::Order::Process> controller must, if called
480 from elsewhere, be reached with
481 C<$c-E<gt>forward('/catalog/order/process/bar')>.
485 Args is not an action type per se, but an action modifier - it adds a match
486 restriction to any action it's provided to, requiring only as many path parts
487 as are specified for the action to be valid - for example in
488 MyApp::Controller::Foo,
492 would match any URL starting /foo/bar/. To restrict this you can do
494 sub bar :Local :Args(1)
496 to only match /foo/bar/*/
500 B<Note:> After seeing these examples, you probably wonder what the point
501 is of defining names for regex and path actions. Every public action is
502 also a private one, so you have one unified way of addressing components
505 =head4 Built-in Private Actions
507 In response to specific application states, Catalyst will automatically
508 call these built-in private actions in your application class:
512 =item * B<default : Private>
514 Called when no other action matches. Could be used, for example, for
515 displaying a generic frontpage for the main app, or an error page for
516 individual controllers.
518 If C<default> isn't acting how you would expect, look at using a
519 L</Literal> C<Path> action (with an empty path string). The difference
520 is that C<Path> takes arguments relative from the namespace and
521 C<default> I<always> takes arguments relative from the root, regardless
522 of what controller it's in. Indeed, this is now the recommended way of
523 handling default situations; the C<default> private controller should
524 be considered deprecated.
526 =item * B<index : Private>
528 C<index> is much like C<default> except that it takes no arguments
529 and it is weighted slightly higher in the matching process. It is
530 useful as a static entry point to a controller, e.g. to have a static
531 welcome page. Note that it's also weighted higher than Path.
533 =item * B<begin : Private>
535 Called at the beginning of a request, before any matching actions are
538 =item * B<end : Private>
540 Called at the end of a request, after all matching actions are called.
544 =head4 Built-in actions in controllers/autochaining
546 Package MyApp::Controller::Foo;
547 sub begin : Private { }
548 sub default : Private { }
549 sub auto : Private { }
551 You can define built-in private actions within your controllers as
552 well. The actions will override the ones in less-specific controllers,
553 or your application class. In other words, for each of the three
554 built-in private actions, only one will be run in any request
555 cycle. Thus, if C<MyApp::Controller::Catalog::begin> exists, it will be
556 run in place of C<MyApp::begin> if you're in the C<catalog> namespace,
557 and C<MyApp::Controller::Catalog::Order::begin> would override this in
560 In addition to the normal built-in actions, you have a special action
561 for making chains, C<auto>. Such C<auto> actions will be run after any
562 C<begin>, but before your action is processed. Unlike the other
563 built-ins, C<auto> actions I<do not> override each other; they will be
564 called in turn, starting with the application class and going through to
565 the I<most> specific class. I<This is the reverse of the order in which
566 the normal built-ins override each other>.
568 Here are some examples of the order in which the various built-ins
573 =item for a request for C</foo/foo>
577 MyApp::Controller::Foo::default # in the absence of MyApp::Controller::Foo::Foo
580 =item for a request for C</foo/bar/foo>
582 MyApp::Controller::Foo::Bar::begin
584 MyApp::Controller::Foo::auto
585 MyApp::Controller::Foo::Bar::auto
586 MyApp::Controller::Foo::Bar::default # for MyApp::Controller::Foo::Bar::foo
587 MyApp::Controller::Foo::Bar::end
591 The C<auto> action is also distinguished by the fact that you can break
592 out of the processing chain by returning 0. If an C<auto> action returns
593 0, any remaining actions will be skipped, except for C<end>. So, for the
594 request above, if the first auto returns false, the chain would look
599 =item for a request for C</foo/bar/foo> where first C<auto> returns
602 MyApp::Controller::Foo::Bar::begin
604 MyApp::Controller::Foo::Bar::end
608 An example of why one might use this is an authentication action: you
609 could set up a C<auto> action to handle authentication in your
610 application class (which will always be called first), and if
611 authentication fails, returning 0 would skip any remaining methods
614 B<Note:> Looking at it another way, C<auto> actions have to return a
615 true value to continue processing! You can also C<die> in the autochain
616 action; in that case, the request will go straight to the finalize
617 stage, without processing further actions.
619 =head4 URL Path Handling
621 You can pass variable arguments as part of the URL path, separated with
622 forward slashes (/). If the action is a Regex or LocalRegex, the '$' anchor
623 must be used. For example, suppose you want to handle C</foo/$bar/$baz>,
624 where C<$bar> and C<$baz> may vary:
626 sub foo : Regex('^foo$') { my ($self, $context, $bar, $baz) = @_; }
628 But what if you also defined actions for C</foo/boo> and C</foo/boo/hoo>?
630 sub boo : Path('foo/boo') { .. }
631 sub hoo : Path('foo/boo/hoo') { .. }
633 Catalyst matches actions in most specific to least specific order:
637 /foo # might be /foo/bar/baz but won't be /foo/boo/hoo
639 So Catalyst would never mistakenly dispatch the first two URLs to the
642 If a Regex or LocalRegex action doesn't use the '$' anchor, the action will
643 still match a URL containing arguments, however the arguments won't be
646 =head4 Parameter Processing
648 Parameters passed in the URL query string are handled with methods in
649 the L<Catalyst::Request> class. The C<param> method is functionally
650 equivalent to the C<param> method of C<CGI.pm> and can be used in
651 modules that require this.
653 # http://localhost:3000/catalog/view/?category=hardware&page=3
654 my $category = $c->req->param('category');
655 my $current_page = $c->req->param('page') || 1;
657 # multiple values for single parameter name
658 my @values = $c->req->param('scrolling_list');
660 # DFV requires a CGI.pm-like input hash
661 my $results = Data::FormValidator->check($c->req->params, \%dfv_profile);
665 You control the application flow with the C<forward> method, which
666 accepts the key of an action to execute. This can be an action in the
667 same or another Catalyst controller, or a Class name, optionally
668 followed by a method name. After a C<forward>, the control flow will
669 return to the method from which the C<forward> was issued.
671 A C<forward> is similar to a method call. The main differences are that
672 it wraps the call in an C<eval> to allow exception handling; it
673 automatically passes along the context object (C<$c> or C<$context>);
674 and it allows profiling of each call (displayed in the log with
678 my ( $self, $c ) = @_;
679 $c->stash->{message} = 'Hello World!';
680 $c->forward('check_message'); # $c is automatically included
683 sub check_message : Private {
684 my ( $self, $c ) = @_;
685 return unless $c->stash->{message};
686 $c->forward('show_message');
689 sub show_message : Private {
690 my ( $self, $c ) = @_;
691 $c->res->body( $c->stash->{message} );
694 A C<forward> does not create a new request, so your request object
695 (C<$c-E<gt>req>) will remain unchanged. This is a key difference between
696 using C<forward> and issuing a redirect.
698 You can pass new arguments to a C<forward> by adding them
699 in an anonymous array. In this case C<$c-E<gt>req-E<gt>args>
700 will be changed for the duration of the C<forward> only; upon
701 return, the original value of C<$c-E<gt>req-E<gt>args> will
705 my ( $self, $c ) = @_;
706 $c->stash->{message} = 'Hello World!';
707 $c->forward('check_message',[qw/test1/]);
708 # now $c->req->args is back to what it was before
711 sub check_message : Private {
712 my ( $self, $c ) = @_;
713 my $first_argument = $c->req->args->[0]; # now = 'test1'
717 As you can see from these examples, you can just use the method name as
718 long as you are referring to methods in the same controller. If you want
719 to forward to a method in another controller, or the main application,
720 you will have to refer to the method by absolute path.
722 $c->forward('/my/controller/action');
723 $c->forward('/default'); # calls default in main application
725 Here are some examples of how to forward to classes and methods.
728 my ( $self, $c ) = @_;
729 $c->forward(qw/MyApp::Model::Hello say_hello/);
733 my ( $self, $c ) = @_;
734 $c->forward('MyApp::Model::Hello'); # no method: will try 'process'
737 package MyApp::Model::Hello;
740 my ( $self, $c ) = @_;
741 $c->res->body('Hello World!');
745 my ( $self, $c ) = @_;
746 $c->res->body('Goodbye World!');
749 Note that C<forward> returns to the calling action and continues
750 processing after the action finishes. If you want all further processing
751 in the calling action to stop, use C<detach> instead, which will execute
752 the C<detach>ed action and not return to the calling sub. In both cases,
753 Catalyst will automatically try to call process() if you omit the
758 Catalyst has an uncommonly flexible component system. You can define as
759 many L</Models>, L</Views>, and L</Controllers> as you like.
761 All components must inherit from L<Catalyst::Base>, which provides a
762 simple class structure and some common class methods like C<config> and
763 C<new> (constructor).
765 package MyApp::Controller::Catalog;
768 use base 'Catalyst::Base';
770 __PACKAGE__->config( foo => 'bar' );
774 You don't have to C<use> or otherwise register Models, Views, and
775 Controllers. Catalyst automatically discovers and instantiates them
776 when you call C<setup> in the main application. All you need to do is
777 put them in directories named for each Component type. Notice that you
778 can use a terse alias for each one.
782 =item * B<MyApp/Model/>
786 =item * B<MyApp/View/>
790 =item * B<MyApp/Controller/>
796 In older versions of Catalyst, the recommended practice (and the one
797 automatically created by helper scripts) was to name the directories
798 C<M/>, C<V/>, and C<C/>. Though these still work, we now recommend
799 the use of the full names.
803 To show how to define views, we'll use an already-existing base class for the
804 L<Template Toolkit|Template>, L<Catalyst::View::TT>. All we need to do is
805 inherit from this class:
807 package MyApp::View::TT;
810 use base 'Catalyst::View::TT';
814 (You can also generate this automatically by using the helper script:
816 script/myapp_create.pl view TT TT
818 where the first C<TT> tells the script that the name of the view should
819 be C<TT>, and the second that it should be a Template Toolkit view.)
821 This gives us a process() method and we can now just do
822 $c->forward('MyApp::View::TT') to render our templates. The base class
823 makes process() implicit, so we don't have to say
824 C<$c-E<gt>forward(qw/MyApp::View::TT process/)>.
827 my ( $self, $c ) = @_;
828 $c->stash->{template} = 'hello.tt';
832 my ( $self, $c ) = @_;
833 $c->forward('MyApp::View::TT');
836 You normally render templates at the end of a request, so it's a perfect
837 use for the global C<end> action. (In practice, however, you would use a
838 default C<end> action as supplied by L<Catalyst::Action::RenderView>.)
840 Also, be sure to put the template under the directory specified in
841 C<$c-E<gt>config-E<gt>{root}>, or you'll end up looking at the debug
846 To show how to define models, again we'll use an already-existing base
847 class, this time for L<DBIx::Class>: L<Catalyst::Model::DBIC::Schema>.
848 We'll also need L<DBIx::Class::Schema::Loader>.
850 But first, we need a database.
854 id INTEGER PRIMARY KEY,
859 id INTEGER PRIMARY KEY,
860 foo INTEGER REFERENCES foo,
864 INSERT INTO foo (data) VALUES ('TEST!');
867 % sqlite /tmp/myapp.db < myapp.sql
869 Now we can create a DBIC::SchemaLoader component for this database.
871 script/myapp_create.pl model DBIC DBIC::SchemaLoader 'dbi:SQLite:/tmp/myapp.db'
873 L<DBIx::Class::Schema::Loader> automatically loads table layouts and
874 relationships. Use the stash to pass data to your templates.
876 We add the following to MyApp/Controller/Root.pm
879 my ( $self, $c, $id ) = @_;
881 $c->stash->{item} = $c->model('DBIC::Foo')->find($id);
887 my ( $self, $c ) = @_;
889 $c->stash->{template} ||= 'index.tt';
890 $c->forward( $c->view('TT') );
893 We then create a new template file "root/index.tt" containing:
895 The Id's data is [% item.data %]
897 Models do not have to be part of your Catalyst application; you
898 can always call an outside module that serves as your Model:
902 my ( $self, $c ) = @_;
904 $c->stash->{template} = 'list.tt';
906 use Some::Outside::Database::Module;
907 my @records = Some::Outside::Database::Module->search({
908 artist => 'Led Zeppelin',
911 $c->stash->{records} = \@records;
914 But by using a Model that is part of your Catalyst application, you gain
915 several things: you don't have to C<use> each component, Catalyst will
916 find and load it automatically at compile-time; you can C<forward> to
917 the module, which can only be done to Catalyst components; and only
918 Catalyst components can be fetched with
919 C<$c-E<gt>model('SomeModel')>.
921 Happily, since many people have existing Model classes that they
922 would like to use with Catalyst (or, conversely, they want to
923 write Catalyst models that can be used outside of Catalyst, e.g.
924 in a cron job), it's trivial to write a simple component in
925 Catalyst that slurps in an outside Model:
927 package MyApp::Model::DB;
928 use base qw/Catalyst::Model::DBIC::Schema/;
930 schema_class => 'Some::DBIC::Schema',
931 connect_info => ['dbi:SQLite:foo.db', '', '', {AutoCommit=>1}]
935 and that's it! Now C<Some::DBIC::Schema> is part of your
936 Cat app as C<MyApp::Model::DB>.
940 Multiple controllers are a good way to separate logical domains of your
943 package MyApp::Controller::Login;
945 use base qw/Catalyst::Controller/;
947 sub sign_in : Path("sign-in") { }
948 sub new_password : Path("new-password") { }
949 sub sign_out : Path("sign-out") { }
951 package MyApp::Controller::Catalog;
953 use base qw/Catalyst::Controller/;
958 package MyApp::Controller::Cart;
960 use base qw/Catalyst::Controller/;
963 sub update : Local { }
964 sub order : Local { }
966 Note that you can also supply attributes via the Controller's config so long
967 as you have at least one attribute on a subref to be exported (:Action is
968 commonly used for this) - for example the following is equivalent to the same
971 package MyApp::Controller::Login;
973 use base qw/Catalyst::Controller/;
977 'sign_in' => { Path => 'sign-in' },
978 'new_password' => { Path => 'new-password' },
979 'sign_out' => { Path => 'sign-out' },
983 sub sign_in : Action { }
984 sub new_password : Action { }
985 sub sign_out : Action { }
989 Models are providers of data. This data could come from anywhere - a search
990 engine index, a database table, etc. Typically the data source does not have
991 much to do with web applications or Catalyst - it could be used to write an
992 offline report generator or a command line tool just the same.
994 The common approach to writing a Catalyst-style model for your application is
995 wrapping a generic model (e.g. L<DBIx::Class::Schema>, a bunch of XMLs, or
996 anything really) with an object that contains configuration data, convenience
997 methods, and so forth.
999 #### editor: move this part to =head3 Components somehow, right after this
1000 #### section - this will require deeply rephrasing this paragraph.
1002 Technically, within Catalyst a model is a B<component> - an instance of the
1003 model's class belonging to the application. It is important to stress that the
1004 lifetime of these objects is per application, not per request.
1006 While the model base class (L<Catalyst::Model>) provides things like C<config>
1007 and stuff to better integrate the model into the application, sometimes this is
1008 not enough, and the model requires access to C<$c> itself.
1010 Situations where this need might arise include:
1016 Interacting with another model
1020 Using per-request data to control behavior
1024 Using plugins in (for example L<Catalyst::Plugin::Cache>).
1028 From a style perspective usually it's bad to make your model "too smart"
1029 about things - it should worry about business logic and leave the
1030 integration details to the controllers. If, however, you find that it
1031 does not make sense at all to use an auxillary controller around the
1032 model, and the model's need to access C<$c> cannot be sidestepped, there
1033 exists a power tool called C<ACCEPT_CONTEXT>.
1035 #### editor note: this part is "generic" - it also applies to views and
1038 =head3 ACCEPT_CONTEXT
1040 Whenever you call $c->component("Foo") you get back an object - the
1041 instance of the model. If the component supports the C<ACCEPT_CONTEXT>
1042 method instead of returning the model itself, the return value of C<<
1043 $model->ACCEPT_CONTEXT( $c ) >> will be used.
1045 This means that whenever your model/view/controller needs to talk to C<$c> it
1046 gets a chance to do this when it's needed.
1048 A typical C<ACCEPT_CONTEXT> method will either clone the model and return one
1049 with the context object set, or it will return a thin wrapper that contains
1050 C<$c> and delegates to the per-application model object.
1052 A typical C<ACCEPT_CONTEXT> method could look like this:
1054 sub ACCEPT_CONTEXT {
1055 my ( $self, $c, @extra_arguments ) = @_;
1056 bless { %$self, c => $c }, ref($self);
1059 effectively treating $self as a B<prototype object> that gets a new parameter.
1060 C<@extra_arguments> comes from any trailing arguments to
1061 C<< $c->component( $bah, @extra_arguments ) >> (or C<< $c->model(...) >>,
1062 C<< $c->view(...) >> etc).
1064 The life time of this value is B<per usage>, and not per request. To make this
1065 per request you can use the following technique:
1067 Add a field to C<$c>, like C<my_model_instance>. Then write your
1068 C<ACCEPT_CONTEXT> method to look like this:
1070 sub ACCEPT_CONTEXT {
1071 my ( $self, $c ) = @_;
1073 if ( my $per_request = $c->my_model_instance ) {
1074 return $per_request;
1076 my $new_instance = bless { %$self, c => $c }, ref($self);
1077 Scalar::Util::weaken($new_instance->{c}); # or we have a circular reference
1078 $c->my_model_instance( $new_instance );
1079 return $new_instance;
1086 Catalyst has a built-in http server for testing. (Later, you can easily
1087 use a more powerful server, e.g. Apache/mod_perl or FastCGI, in a
1088 production environment.)
1090 Start your application on the command line...
1092 script/myapp_server.pl
1094 ...then visit http://localhost:3000/ in a browser to view the output.
1096 You can also do it all from the command line:
1098 script/myapp_test.pl http://localhost/
1106 Join #catalyst on irc.perl.org.
1110 http://lists.rawmode.org/mailman/listinfo/catalyst
1111 http://lists.rawmode.org/mailman/listinfo/catalyst-dev
1115 Sebastian Riedel, C<sri@oook.de>
1116 David Naughton, C<naughton@umn.edu>
1117 Marcus Ramberg, C<mramberg@cpan.org>
1118 Jesse Sheidlower, C<jester@panix.com>
1119 Danijel Milicevic, C<me@danijel.de>
1120 Kieren Diment, C<kd@totaldatasolution.com>
1121 Yuval Kogman, C<nothingmuch@woobling.org>
1125 This program is free software, you can redistribute it and/or modify it
1126 under the same terms as Perl itself.