3 Catalyst::Manual::Intro - Introduction to Catalyst
7 This is a brief introduction to Catalyst. It explains the most important
8 features of how Catalyst works and shows how to get a simple application
9 up and running quickly. For an introduction (without code) to Catalyst
10 itself, and why you should be using it, see L<Catalyst::Manual::About>.
11 For a systematic step-by-step introduction to writing an application
12 with Catalyst, see L<Catalyst::Manual::Tutorial>.
14 =head2 What is Catalyst?
16 Catalyst is an elegant web application framework, extremely flexible yet
17 extremely simple. It's similar to Ruby on Rails, Spring (Java), and
18 L<Maypole>, upon which it was originally based. Its most important
19 design philosphy is to provide easy access to all the tools you need to
20 develop web applications, with few restrictions on how you need to use
21 these tools. Under Catalyst, it is always possible to do things in a
22 different way. However, this does mean that it is always possible to do
23 things in a different way. Other web frameworks are simpler to use and
24 easy to get up and running, but achieve this by locking the programmer
25 into a single set of tools. Catalyst's emphasis on flexibility means
26 that you have to think more to use it. We view this as a feature.
30 Catalyst follows the Model-View-Controller (MVC) design pattern,
31 allowing you to easily separate concerns, like content, presentation,
32 and flow control, into separate modules. This separation allows you to
33 modify code that handles one concern without affecting code that handles
34 the others. Catalyst promotes the re-use of existing Perl modules that
35 already handle common web application concerns well.
37 Here's how the M, V, and C map to those concerns, with examples of
38 well-known Perl modules you may want to use for each.
44 Access and modify content (data). L<DBIx::Class>, L<Class::DBI>,
45 L<Xapian>, L<Net::LDAP>...
49 Present content to the user. L<Template Toolkit|Template>,
50 L<Mason|HTML::Mason>, L<HTML::Template>...
54 Control the whole request phase, check parameters, dispatch actions, flow
55 control. Catalyst itself!
59 If you're unfamiliar with MVC and design patterns, you may want to
60 check out the original book on the subject, I<Design Patterns>, by
61 Gamma, Helm, Johnson, and Vlissides, also known as the Gang of Four
62 (GoF). Many, many web application frameworks are based on MVC, which
63 is becoming a popular design method for web applications.
67 Catalyst is much more flexible than many other frameworks. We'll talk
68 more about this later, but rest assured you can use your favorite Perl
69 modules with Catalyst.
73 =item * B<Multiple Models, Views, and Controllers>
75 To build a Catalyst application, you handle each type of concern inside
76 special modules called L</Components>. Often this code will be very
77 simple, just calling out to Perl modules like those listed above under
78 L</MVC>. Catalyst handles these components in a very flexible way. Use
79 as many Models, Views, and Controllers as you like, using as many
80 different Perl modules as you like, all in the same application. Want to
81 manipulate multiple databases, and retrieve some data via LDAP? No
82 problem. Want to present data from the same Model using L<Template
83 Toolkit|Template> and L<PDF::Template>? Easy.
85 =item * B<Reuseable Components>
87 Not only does Catalyst promote the re-use of already existing Perl
88 modules, it also allows you to re-use your Catalyst components in
89 multiple Catalyst applications.
91 =item * B<Unrestrained URL-to-Action Dispatching>
93 Catalyst allows you to dispatch any URLs to any application L</Actions>,
94 even through regular expressions! Unlike most other frameworks, it
95 doesn't require mod_rewrite or class and method names in URLs.
97 With Catalyst you register your actions and address them directly. For
101 my ( $self, $context ) = @_;
102 $context->response->body('Hello World!');
105 Now http://localhost:3000/hello prints "Hello World!".
107 =item * B<Support for CGI, mod_perl, Apache::Request>
109 Use L<Catalyst::Engine::Apache> or L<Catalyst::Engine::CGI>.
115 The best part is that Catalyst implements all this flexibility in a very
120 =item * B<Building Block Interface>
122 Components interoperate very smoothly. For example, Catalyst
123 automatically makes a L</Context> object available to every
124 component. Via the context, you can access the request object, share
125 data between components, and control the flow of your
126 application. Building a Catalyst application feels a lot like snapping
127 together toy building blocks, and everything just works.
129 =item * B<Component Auto-Discovery>
131 No need to C<use> all of your components. Catalyst automatically finds
134 =item * B<Pre-Built Components for Popular Modules>
136 See L<Catalyst::Model::DBIC::Schema> for L<DBIx::Class>, or
137 L<Catalyst::View::TT> for L<Template Toolkit|Template>.
139 =item * B<Built-in Test Framework>
141 Catalyst comes with a built-in, lightweight http server and test
142 framework, making it easy to test applications from the command line.
144 =item * B<Helper Scripts>
146 Catalyst provides helper scripts to quickly generate running starter
147 code for components and unit tests. See L<Catalyst::Helper>.
153 Here's how to install Catalyst and get a simple application up and
154 running, using the helper scripts described above.
158 $ perl -MCPAN -e 'install Task::Catalyst'
165 $ script/myapp_create.pl controller Library::Login
169 $ script/myapp_server.pl
171 Now visit these locations with your favorite browser or user agent to see
174 (NOTE: Although we create a controller here, we don't actually use it.
175 Both of these URLs should take you to the welcome page.)
180 =item http://localhost:3000/
182 =item http://localhost:3000/library/login/
190 Let's see how Catalyst works, by taking a closer look at the components
191 and other parts of a Catalyst application.
193 =head3 Application Class
195 In addition to the Model, View, and Controller components, there's a
196 single class that represents your application itself. This is where you
197 configure your application, load plugins, and extend Catalyst.
202 use Catalyst qw/-Debug/;
205 name => 'My Application',
207 # You can put anything else you want in here:
208 my_configuration_variable => 'something',
212 In older versions of Catalyst, the application class was where you put
213 global actions. However, as of version 5.66, the recommended practice is
214 to place such actions in a special Root controller (see #####, below),
215 to avoid namespace collisions.
221 The name of your application.
225 Optionally, you can specify a B<root> parameter for templates and static
226 data. If omitted, Catalyst will try to auto-detect the directory's
227 location. You can define as many parameters as you want for plugins or
228 whatever you need. You can access them anywhere in your application via
229 C<$context-E<gt>config-E<gt>{$param_name}>.
231 ###### We need a short section on configuration here.
235 Catalyst automatically blesses a Context object into your application
236 class and makes it available everywhere in your application. Use the
237 Context to directly interact with Catalyst and glue your L</Components>
238 together. For example, if you need to use the Context from within a
239 Template Toolkit template, it's already there:
241 <h1>Welcome to [% c.config.name %]!</h1>
243 As illustrated in our URL-to-Action dispatching example, the Context is
244 always the second method parameter, behind the Component object
245 reference or class name itself. Previously we called it C<$context> for
246 clarity, but most Catalyst developers just call it C<$c>:
249 my ( $self, $c ) = @_;
250 $c->res->body('Hello World!');
253 The Context contains several important objects:
257 =item * L<Catalyst::Request>
262 The request object contains all kinds of request-specific information, like
263 query parameters, cookies, uploads, headers, and more.
265 $c->req->params->{foo};
266 $c->req->cookies->{sessionid};
267 $c->req->headers->content_type;
270 =item * L<Catalyst::Response>
275 The response is like the request, but contains just response-specific
278 $c->res->body('Hello World');
279 $c->res->status(404);
280 $c->res->redirect('http://oook.de');
282 =item * L<Catalyst::Config>
288 =item * L<Catalyst::Log>
291 $c->log->debug('Something happened');
292 $c->log->info('Something you should know');
297 $c->stash->{foo} = 'bar';
298 $c->stash->{baz} = {baz => 'qox'};
299 $c->stash->{fred} = [qw/ wilma pebbles/];
305 The last of these, the stash, is a universal hash for sharing data among
306 application components. For an example, we return to our 'hello' action:
309 my ( $self, $c ) = @_;
310 $c->stash->{message} = 'Hello World!';
311 $c->forward('show_message');
314 sub show_message : Private {
315 my ( $self, $c ) = @_;
316 $c->res->body( $c->stash->{message} );
319 Note that the stash should be used only for passing data in an
320 individual request cycle; it gets cleared at a new request. If you need
321 to maintain more persistent data, use a session.
325 A Catalyst controller is defined by its actions. An action is a
326 subroutine with a special attribute. You've already seen some examples
327 of actions in this document. The URL (for example
328 http://localhost.3000/foo/bar) consists of two parts, the base
329 (http://localhost:3000/ in this example) and the path (foo/bar). Please
330 note that the trailing slash after the hostname[:port] always belongs to
331 base and not to the action.
335 =item * B<Application Wide Actions>
337 Actions which are called at the root level of the application
338 (e.g. http://localhost:3000/ ) go in MyApp::Controller::Root, like
341 package MyApp::Controller::Root;
342 use base 'Catalyst::Controller';
343 # Sets the actions in this controller to be registered with no prefix
344 # so they function identically to actions created in MyApp.pm
345 __PACKAGE__->config->{namespace} = '';
346 sub default : Private {
347 my ( $self, $context ) = @_;
348 $context->response->body('Catalyst rocks!');
355 For most applications, Catalyst requires you to define only one config
360 Catalyst supports several types of actions:
364 =item * B<Literal> (B<Path> actions)
366 package MyApp::Controller::My::Controller;
367 sub bar : Path('foo/bar') { }
369 Literal C<Path> actions will act relative to their current
370 namespace. The above example matches only
371 http://localhost:3000/my/controller/foo/bar. If you start your path with
372 a forward slash, it will match from the root. Example:
374 package MyApp::Controller::My::Controller;
375 sub bar : Path('/foo/bar') { }
377 Matches only http://localhost:3000/foo/bar.
379 package MyApp::Controller::My::Controller;
382 By leaving the C<Path> definition empty, it will match on the namespace
383 root. The above code matches http://localhost:3000/my/controller.
387 sub bar : Regex('^item(\d+)/order(\d+)$') { }
389 Matches any URL that matches the pattern in the action key, e.g.
390 http://localhost:3000/item23/order42. The '' around the regexp is
391 optional, but perltidy likes it. :)
393 Regex matches act globally, i.e. without reference to the namespace from
394 which it is called, so that a C<bar> method in the
395 C<MyApp::Controller::Catalog::Order::Process> namespace won't match any
396 form of C<bar>, C<Catalog>, C<Order>, or C<Process> unless you
397 explicitly put this in the regex. To achieve the above, you should
398 consider using a C<LocalRegex> action.
400 =item * B<LocalRegex>
402 sub bar : LocalRegex('^widget(\d+)$') { }
404 LocalRegex actions act locally. If you were to use C<bar> in
405 C<MyApp::Controller::Catalog>, the above example would match urls like
406 http://localhost:3000/catalog/widget23.
408 If you omit the "C<^>" from your regex, then it will match any depth
409 from the controller and not immediately off of the controller name. The
410 following example differs from the above code in that it will match
411 http://localhost:3000/catalog/foo/widget23 as well.
413 package MyApp::Controller::Catalog;
414 sub bar : LocalRegex('widget(\d+)$') { }
416 For both LocalRegex and Regex actions, if you use capturing parentheses
417 to extract values within the matching URL, those values are available in
418 the C<$c-E<gt>req-E<gt>captures> array. In the above example, "widget23"
419 would capture "23" in the above example, and
420 C<$c-E<gt>req-E<gt>captures-E<gt>[0]> would be "23". If you want to pass
421 arguments at the end of your URL, you must use regex action keys. See
422 L</URL Path Handling> below.
424 =item * B<Top-level> (B<Global>)
426 package MyApp::Controller::Foo;
429 Matches http://localhost:3000/foo. The function name is mapped
430 directly to the application base. You can provide an equivalent
431 function in this case by doing the following:
433 package MyApp::Controller::Root
436 =item * B<Namespace-Prefixed> (B<Local>)
438 package MyApp::Controller::My::Controller;
441 Matches http://localhost:3000/my/controller/foo.
443 This action type indicates that the matching URL must be prefixed with a
444 modified form of the component's class (package) name. This modified
445 class name excludes the parts that have a pre-defined meaning in
446 Catalyst ("MyApp::Controller" in the above example), replaces "::" with
447 "/", and converts the name to lower case. See L</Components> for a full
448 explanation of the pre-defined meaning of Catalyst component class
453 sub foo : Private { }
455 Matches no URL, and cannot be executed by requesting a URL that
456 corresponds to the action key. Private actions can be executed only
457 inside a Catalyst application, by calling the C<forward> method:
461 See L</Flow Control> for a full explanation of C<forward>. Note that, as
462 discussed there, when forwarding from another component, you must use
463 the absolute path to the method, so that a private C<bar> method in your
464 C<MyApp::Controller::Catalog::Order::Process> controller must, if called
465 from elsewhere, be reached with
466 C<$c-E<gt>forward('/catalog/order/process/bar')>.
470 Args is not an action type per se, but an action modifier - it adds a match
471 restriction to any action it's provided to, requiring only as many path parts
472 as are specified for the action to be valid - for example in
473 MyApp::Controller::Foo,
477 would match any URL starting /foo/bar/. To restrict this you can do
479 sub bar :Local :Args(1)
481 to only match /foo/bar/*/
485 B<Note:> After seeing these examples, you probably wonder what the point
486 is of defining names for regex and path actions. Every public action is
487 also a private one, so you have one unified way of addressing components
490 =head4 Built-in Private Actions
492 In response to specific application states, Catalyst will automatically
493 call these built-in private actions in your application class:
497 =item * B<default : Private>
499 Called when no other action matches. Could be used, for example, for
500 displaying a generic frontpage for the main app, or an error page for
501 individual controllers.
503 If C<default> isn't acting how you would expect, look at using a
504 L</Literal> C<Path> action (with an empty path string). The difference is
505 that C<Path> takes arguments relative from the namespace and C<default>
506 I<always> takes arguments relative from the root, regardless of what
509 =item * B<index : Private>
511 C<index> is much like C<default> except that it takes no arguments
512 and it is weighted slightly higher in the matching process. It is
513 useful as a static entry point to a controller, e.g. to have a static
514 welcome page. Note that it's also weighted higher than Path.
516 =item * B<begin : Private>
518 Called at the beginning of a request, before any matching actions are
521 =item * B<end : Private>
523 Called at the end of a request, after all matching actions are called.
527 =head4 Built-in actions in controllers/autochaining
529 Package MyApp::Controller::Foo;
530 sub begin : Private { }
531 sub default : Private { }
532 sub auto : Private { }
534 You can define built-in private actions within your controllers as
535 well. The actions will override the ones in less-specific controllers,
536 or your application class. In other words, for each of the three
537 built-in private actions, only one will be run in any request
538 cycle. Thus, if C<MyApp::Controller::Catalog::begin> exists, it will be
539 run in place of C<MyApp::begin> if you're in the C<catalog> namespace,
540 and C<MyApp::Controller::Catalog::Order::begin> would override this in
543 In addition to the normal built-in actions, you have a special action
544 for making chains, C<auto>. Such C<auto> actions will be run after any
545 C<begin>, but before your action is processed. Unlike the other
546 built-ins, C<auto> actions I<do not> override each other; they will be
547 called in turn, starting with the application class and going through to
548 the I<most> specific class. I<This is the reverse of the order in which
549 the normal built-ins override each other>.
551 Here are some examples of the order in which the various built-ins
556 =item for a request for C</foo/foo>
560 MyApp::Controller::Foo::default # in the absence of MyApp::Controller::Foo::Foo
563 =item for a request for C</foo/bar/foo>
565 MyApp::Controller::Foo::Bar::begin
567 MyApp::Controller::Foo::auto
568 MyApp::Controller::Foo::Bar::auto
569 MyApp::Controller::Foo::Bar::default # for MyApp::Controller::Foo::Bar::foo
570 MyApp::Controller::Foo::Bar::end
574 The C<auto> action is also distinguished by the fact that you can break
575 out of the processing chain by returning 0. If an C<auto> action returns
576 0, any remaining actions will be skipped, except for C<end>. So, for the
577 request above, if the first auto returns false, the chain would look
582 =item for a request for C</foo/bar/foo> where first C<auto> returns
585 MyApp::Controller::Foo::Bar::begin
587 MyApp::Controller::Foo::Bar::end
591 An example of why one might use this is an authentication action: you
592 could set up a C<auto> action to handle authentication in your
593 application class (which will always be called first), and if
594 authentication fails, returning 0 would skip any remaining methods
597 B<Note:> Looking at it another way, C<auto> actions have to return a
598 true value to continue processing! You can also C<die> in the autochain
599 action; in that case, the request will go straight to the finalize
600 stage, without processing further actions.
602 =head4 URL Path Handling
604 You can pass variable arguments as part of the URL path, separated with
605 forward slashes (/). If the action is a Regex or LocalRegex, the '$' anchor
606 must be used. For example, suppose you want to handle C</foo/$bar/$baz>,
607 where C<$bar> and C<$baz> may vary:
609 sub foo : Regex('^foo$') { my ($self, $context, $bar, $baz) = @_; }
611 But what if you also defined actions for C</foo/boo> and C</foo/boo/hoo>?
613 sub boo : Path('foo/boo') { .. }
614 sub hoo : Path('foo/boo/hoo') { .. }
616 Catalyst matches actions in most specific to least specific order:
620 /foo # might be /foo/bar/baz but won't be /foo/boo/hoo
622 So Catalyst would never mistakenly dispatch the first two URLs to the
625 If a Regex or LocalRegex action doesn't use the '$' anchor, the action will
626 still match a URL containing arguments, however the arguments won't be
629 =head4 Parameter Processing
631 Parameters passed in the URL query string are handled with methods in
632 the L<Catalyst::Request> class. The C<param> method is functionally
633 equivalent to the C<param> method of C<CGI.pm> and can be used in
634 modules that require this.
636 # http://localhost:3000/catalog/view/?category=hardware&page=3
637 my $category = $c->req->param('category');
638 my $current_page = $c->req->param('page') || 1;
640 # multiple values for single parameter name
641 my @values = $c->req->param('scrolling_list');
643 # DFV requires a CGI.pm-like input hash
644 my $results = Data::FormValidator->check($c->req->params, \%dfv_profile);
648 You control the application flow with the C<forward> method, which
649 accepts the key of an action to execute. This can be an action in the
650 same or another Catalyst controller, or a Class name, optionally
651 followed by a method name. After a C<forward>, the control flow will
652 return to the method from which the C<forward> was issued.
654 A C<forward> is similar to a method call. The main differences are that
655 it wraps the call in an C<eval> to allow exception handling; it
656 automatically passes along the context object (C<$c> or C<$context>);
657 and it allows profiling of each call (displayed in the log with
661 my ( $self, $c ) = @_;
662 $c->stash->{message} = 'Hello World!';
663 $c->forward('check_message'); # $c is automatically included
666 sub check_message : Private {
667 my ( $self, $c ) = @_;
668 return unless $c->stash->{message};
669 $c->forward('show_message');
672 sub show_message : Private {
673 my ( $self, $c ) = @_;
674 $c->res->body( $c->stash->{message} );
677 A C<forward> does not create a new request, so your request object
678 (C<$c-E<gt>req>) will remain unchanged. This is a key difference between
679 using C<forward> and issuing a redirect.
681 You can pass new arguments to a C<forward> by adding them
682 in an anonymous array. In this case C<$c-E<gt>req-E<gt>args>
683 will be changed for the duration of the C<forward> only; upon
684 return, the original value of C<$c-E<gt>req-E<gt>args> will
688 my ( $self, $c ) = @_;
689 $c->stash->{message} = 'Hello World!';
690 $c->forward('check_message',[qw/test1/]);
691 # now $c->req->args is back to what it was before
694 sub check_message : Private {
695 my ( $self, $c ) = @_;
696 my $first_argument = $c->req->args->[0]; # now = 'test1'
700 As you can see from these examples, you can just use the method name as
701 long as you are referring to methods in the same controller. If you want
702 to forward to a method in another controller, or the main application,
703 you will have to refer to the method by absolute path.
705 $c->forward('/my/controller/action');
706 $c->forward('/default'); # calls default in main application
708 Here are some examples of how to forward to classes and methods.
711 my ( $self, $c ) = @_;
712 $c->forward(qw/MyApp::Model::Hello say_hello/);
716 my ( $self, $c ) = @_;
717 $c->forward('MyApp::Model::Hello'); # no method: will try 'process'
720 package MyApp::Model::Hello;
723 my ( $self, $c ) = @_;
724 $c->res->body('Hello World!');
728 my ( $self, $c ) = @_;
729 $c->res->body('Goodbye World!');
732 Note that C<forward> returns to the calling action and continues
733 processing after the action finishes. If you want all further processing
734 in the calling action to stop, use C<detach> instead, which will execute
735 the C<detach>ed action and not return to the calling sub. In both cases,
736 Catalyst will automatically try to call process() if you omit the
741 Catalyst has an uncommonly flexible component system. You can define as
742 many L</Models>, L</Views>, and L</Controllers> as you like.
744 All components must inherit from L<Catalyst::Base>, which provides a
745 simple class structure and some common class methods like C<config> and
746 C<new> (constructor).
748 package MyApp::Controller::Catalog;
751 use base 'Catalyst::Base';
753 __PACKAGE__->config( foo => 'bar' );
757 You don't have to C<use> or otherwise register Models, Views, and
758 Controllers. Catalyst automatically discovers and instantiates them
759 when you call C<setup> in the main application. All you need to do is
760 put them in directories named for each Component type. Notice that you
761 can use a terse alias for each one.
765 =item * B<MyApp/Model/>
769 =item * B<MyApp/View/>
773 =item * B<MyApp/Controller/>
779 In older versions of Catalyst, the recommended practice (and the one
780 automatically created by helper scripts) was to name the directories
781 C<M/>, C<V/>, and C<C/>. Though these still work, we now recommend
782 the use of the full names.
786 To show how to define views, we'll use an already-existing base class for the
787 L<Template Toolkit|Template>, L<Catalyst::View::TT>. All we need to do is
788 inherit from this class:
790 package MyApp::View::TT;
793 use base 'Catalyst::View::TT';
797 (You can also generate this automatically by using the helper script:
799 script/myapp_create.pl view TT TT
801 where the first C<TT> tells the script that the name of the view should
802 be C<TT>, and the second that it should be a Template Toolkit view.)
804 This gives us a process() method and we can now just do
805 $c->forward('MyApp::View::TT') to render our templates. The base class
806 makes process() implicit, so we don't have to say
807 C<$c-E<gt>forward(qw/MyApp::View::TT process/)>.
810 my ( $self, $c ) = @_;
811 $c->stash->{template} = 'hello.tt';
815 my ( $self, $c ) = @_;
816 $c->forward('MyApp::View::TT');
819 You normally render templates at the end of a request, so it's a perfect
820 use for the global C<end> action.
822 Also, be sure to put the template under the directory specified in
823 C<$c-E<gt>config-E<gt>{root}>, or you'll be forced to look at our
824 eyecandy debug screen. ;)
828 To show how to define models, again we'll use an already-existing base
829 class, this time for L<DBIx::Class>: L<Catalyst::Model::DBIC::Schema>.
830 We'll also need L<DBIx::Class::Schema::Loader>.
832 But first, we need a database.
836 id INTEGER PRIMARY KEY,
841 id INTEGER PRIMARY KEY,
842 foo INTEGER REFERENCES foo,
846 INSERT INTO foo (data) VALUES ('TEST!');
849 % sqlite /tmp/myapp.db < myapp.sql
851 Now we can create a DBIC::SchemaLoader component for this database.
853 script/myapp_create.pl model DBIC DBIC::SchemaLoader 'dbi:SQLite:/tmp/myapp.db'
855 L<DBIx::Class::Schema::Loader> automatically loads table layouts and
856 relationships. Use the stash to pass data to your templates.
858 We add the following to MyApp/Controller/Root.pm
861 my ( $self, $c, $id ) = @_;
863 $c->stash->{item} = $c->model('DBIC::Foo')->find($id);
869 my ( $self, $c ) = @_;
871 $c->stash->{template} ||= 'index.tt';
872 $c->forward( $c->view('TT') );
875 We then create a new template file "root/index.tt" containing:
877 The Id's data is [% item.data %]
879 Models do not have to be part of your Catalyst application; you
880 can always call an outside module that serves as your Model:
884 my ( $self, $c ) = @_;
886 $c->stash->{template} = 'list.tt';
888 use Some::Outside::DBIC::Module;
889 my @records = Some::Outside::DBIC::Module->search({
893 $c->stash->{records} = \@records;
896 But by using a Model that is part of your Catalyst application, you gain
897 several things: you don't have to C<use> each component, Catalyst will
898 find and load it automatically at compile-time; you can C<forward> to
899 the module, which can only be done to Catalyst components; and only
900 Catalyst components can be fetched with
901 C<$c-E<gt>model('SomeModel')>.
903 Happily, since many people have existing Model classes that they
904 would like to use with Catalyst (or, conversely, they want to
905 write Catalyst models that can be used outside of Catalyst, e.g.
906 in a cron job), it's trivial to write a simple component in
907 Catalyst that slurps in an outside Model:
909 package MyApp::Model::DB;
910 use base qw/Catalyst::Model::DBIC::Schema/;
912 schema_class => 'Some::DBIC::Schema',
913 connect_info => ['dbi:SQLite:foo.db', '', '', {AutoCommit=>1}]
917 and that's it! Now C<Some::DBIC::Schema> is part of your
918 Cat app as C<MyApp::Model::DB>.
922 Multiple controllers are a good way to separate logical domains of your
925 package MyApp::Controller::Login;
927 use base qw/Catalyst::Controller/;
929 sub sign_in : Path("sign-in") { }
930 sub new_password : Path("new-password") { }
931 sub sign_out : Path("sign-out") { }
933 package MyApp::Controller::Catalog;
935 use base qw/Catalyst::Controller/;
940 package MyApp::Controller::Cart;
942 use base qw/Catalyst::Controller/;
945 sub update : Local { }
946 sub order : Local { }
948 Note that you can also supply attributes via the Controller's config so long
949 as you have at least one attribute on a subref to be exported (:Action is
950 commonly used for this) - for example the following is equivalent to the same
953 package MyApp::Controller::Login;
955 use base qw/Catalyst::Controller/;
959 'sign_in' => { Path => 'sign-in' },
960 'new_password' => { Path => 'new-password' },
961 'sign_out' => { Path => 'sign-out' },
965 sub sign_in : Action { }
966 sub new_password : Action { }
967 sub sign_out : Action { }
971 Models are providers of data. This data could come from anywhere - a search
972 engine index, a database table, etc. Typically the data source does not have
973 much to do with web applications or Catalyst - it could be used to write an
974 offline report generator or a command line tool just the same.
976 The common approach to writing a Catalyst-style model for your application is
977 wrapping a generic model (e.g. L<DBIx::Class::Schema>, a bunch of XMLs, or
978 anything really) with an object that contains configuration data, convenience
979 methods, and so forth.
981 #### editor: move this part to =head3 Components somehow, right after this
982 #### section - this will require deeply rephrasing this paragraph.
984 Technically, within Catalyst a model is a B<component> - an instance of the
985 model's class belonging to the application. It is important to stress that the
986 lifetime of these objects is per application, not per request.
988 While the model base class (L<Catalyst::Model>) provides things like C<config>
989 and stuff to better integrate the model into the application, sometimes this is
990 not enough, and the model requires access to C<$c> itself.
992 Situations where this need might arise include:
998 Interacting with another model
1002 Using per-request data to control behavior
1006 Using plugins in (for example L<Catalyst::Plugin::Cache>).
1010 From a style perspective usually it's bad to make your model "too smart"
1011 about things - it should worry about business logic and leave the
1012 integration details to the controllers. If, however, you find that it
1013 does not make sense at all to use an auxillary controller around the
1014 model, and the model's need to access C<$c> cannot be sidestepped, there
1015 exists a power tool called C<ACCEPT_CONTEXT>.
1017 #### editor note: this part is "generic" - it also applies to views and
1020 =head3 ACCEPT_CONTEXT
1022 Whenever you call $c->component("Foo") you get back an object - the
1023 instance of the model. If the component supports the C<ACCEPT_CONTEXT>
1024 method instead of returning the model itself, the return value of C<<
1025 $model->ACCEPT_CONTEXT( $c ) >> will be used.
1027 This means that whenever your model/view/controller needs to talk to C<$c> it
1028 gets a chance to do this when it's needed.
1030 A typical C<ACCEPT_CONTEXT> method will either clone the model and return one
1031 with the context object set, or it will return a thin wrapper that contains
1032 C<$c> and delegates to the per-application model object.
1034 A typical C<ACCEPT_CONTEXT> method could look like this:
1036 sub ACCEPT_CONTEXT {
1037 my ( $self, $c, @extra_arguments ) = @_;
1038 bless { %$self, c => $c }, ref($self);
1041 effectively treating $self as a B<prototype object> that gets a new parameter.
1042 C<@extra_arguments> comes from any trailing arguments to
1043 C<< $c->component( $bah, @extra_arguments ) >> (or C<< $c->model(...) >>,
1044 C<< $c->view(...) >> etc).
1046 The life time of this value is B<per usage>, and not per request. To make this
1047 per request you can use the following technique:
1049 Add a field to C<$c>, like C<my_model_instance>. Then write your
1050 C<ACCEPT_CONTEXT> method to look like this:
1052 sub ACCEPT_CONTEXT {
1053 my ( $self, $c ) = @_;
1055 if ( my $per_request = $c->my_model_instance ) {
1056 return $per_request;
1058 my $new_instance = bless { %$self, c => $c }, ref($self);
1059 Scalar::Util::weaken($new_instance->{c}); # or we have a circular reference
1060 $c->my_model_instance( $new_instance );
1061 return $new_instance;
1068 Catalyst has a built-in http server for testing. (Later, you can easily
1069 use a more powerful server, e.g. Apache/mod_perl or FastCGI, in a
1070 production environment.)
1072 Start your application on the command line...
1074 script/myapp_server.pl
1076 ...then visit http://localhost:3000/ in a browser to view the output.
1078 You can also do it all from the command line:
1080 script/myapp_test.pl http://localhost/
1088 Join #catalyst on irc.perl.org.
1092 http://lists.rawmode.org/mailman/listinfo/catalyst
1093 http://lists.rawmode.org/mailman/listinfo/catalyst-dev
1097 Sebastian Riedel, C<sri@oook.de>
1098 David Naughton, C<naughton@umn.edu>
1099 Marcus Ramberg, C<mramberg@cpan.org>
1100 Jesse Sheidlower, C<jester@panix.com>
1101 Danijel Milicevic, C<me@danijel.de>
1102 Kieren Diment, C<kd@totaldatasolution.com>
1103 Yuval Kogman, C<nothingmuch@woobling.org>
1107 This program is free software, you can redistribute it and/or modify it
1108 under the same terms as Perl itself.