3 Catalyst::Manual::Intro - Introduction to Catalyst
7 This is a brief introduction to Catalyst. It explains the most important
8 features of how Catalyst works and shows how to get a simple application
9 up and running quickly. For an introduction (without code) to Catalyst
10 itself, and why you should be using it, see L<Catalyst::Manual::About>.
11 For a systematic step-by-step introduction to writing an application
12 with Catalyst, see L<Catalyst::Manual::Tutorial>.
14 =head2 What is Catalyst?
16 Catalyst is an elegant web application framework, extremely flexible
17 yet extremely simple. It's similar to Ruby on Rails, Spring (Java), and
18 L<Maypole|Maypole>, upon which it was originally based. Its most
19 important design philosphy is to provide easy access to all the tools
20 you need to develop web applications, with few restrictions on how you
21 need to use these tools. However, this does mean that it is always
22 possible to do things in a different way. Other web frameworks are
23 I<initially> simpler to use, but achieve this by locking the programmer
24 into a single set of tools. Catalyst's emphasis on flexibility means
25 that you have to think more to use it. We view this as a feature. For
26 example, this leads to Catalyst being better suited to system integration
27 tasks than other web frameworks.
31 Catalyst follows the Model-View-Controller (MVC) design pattern,
32 allowing you to easily separate concerns, like content, presentation,
33 and flow control, into separate modules. This separation allows you to
34 modify code that handles one concern without affecting code that handles
35 the others. Catalyst promotes the re-use of existing Perl modules that
36 already handle common web application concerns well.
38 Here's how the Model, View, and Controller map to those concerns, with
39 examples of well-known Perl modules you may want to use for each.
45 Access and modify content (data). L<DBIx::Class>, L<Class::DBI>,
46 L<Xapian>, L<Net::LDAP>...
50 Present content to the user. L<Template Toolkit|Template>,
51 L<Mason|HTML::Mason>, L<HTML::Template>...
55 Control the whole request phase, check parameters, dispatch actions, flow
56 control. This is the meat of where Catalyst works.
60 If you're unfamiliar with MVC and design patterns, you may want to
61 check out the original book on the subject, I<Design Patterns>, by
62 Gamma, Helm, Johnson, and Vlissides, also known as the Gang of Four
63 (GoF). Many, many web application frameworks are based on MVC, which
64 is becoming a popular design paradigm for the world wide web.
68 Catalyst is much more flexible than many other frameworks. Rest assured
69 you can use your favorite Perl modules with Catalyst.
73 =item * B<Multiple Models, Views, and Controllers>
75 To build a Catalyst application, you handle each type of concern inside
76 special modules called L</Components>. Often this code will be very
77 simple, just calling out to Perl modules like those listed above under
78 L</MVC>. Catalyst handles these components in a very flexible way. Use
79 as many Models, Views, and Controllers as you like, using as many
80 different Perl modules as you like, all in the same application. Want to
81 manipulate multiple databases, and retrieve some data via LDAP? No
82 problem. Want to present data from the same Model using L<Template
83 Toolkit|Template> and L<PDF::Template>? Easy.
85 =item * B<Reuseable Components>
87 Not only does Catalyst promote the re-use of already existing Perl
88 modules, it also allows you to re-use your Catalyst components in
89 multiple Catalyst applications.
91 =item * B<Unrestrained URL-to-Action Dispatching>
93 Catalyst allows you to dispatch any URLs to any application L</Actions>,
94 even through regular expressions! Unlike most other frameworks, it
95 doesn't require mod_rewrite or class and method names in URLs.
97 With Catalyst you register your actions and address them directly. For
101 my ( $self, $context ) = @_;
102 $context->response->body('Hello World!');
105 Now http://localhost:3000/hello prints "Hello World!".
107 Note that actions with the C< :Local > attribute are equivalent to
108 using a C<:Path('action_name') > attribute, so our action could be
111 sub hi : Path('hello') {
112 my ( $self, $context ) = @_;
113 $context->response->body('Hello World!');
117 =item * B<Support for CGI, mod_perl, Apache::Request, FastCGI>
119 Use L<Catalyst::Engine::Apache> or L<Catalyst::Engine::CGI>. Another
120 interesting engine is L<Catalyst::Engine::HTTP::Prefork> - available from CPAN
121 separately - which will turn the built server into a fully fledged production
122 ready server (although you'll probably want to run it behind a front end proxy
123 if you end up using it).
127 Starting with Catalyst version 5.9 Catalyst ships with L<PSGI> integration
128 for even more powerful and flexible testing and deployment options. See
129 L<Catalyst::PSGI> for details.
135 The best part is that Catalyst implements all this flexibility in a very
140 =item * B<Building Block Interface>
142 Components interoperate very smoothly. For example, Catalyst
143 automatically makes a L</Context> object available to every
144 component. Via the context, you can access the request object, share
145 data between components, and control the flow of your
146 application. Building a Catalyst application feels a lot like snapping
147 together toy building blocks, and everything just works.
149 =item * B<Component Auto-Discovery>
151 No need to C<use> all of your components. Catalyst automatically finds
154 =item * B<Pre-Built Components for Popular Modules>
156 See L<Catalyst::Model::DBIC::Schema> for L<DBIx::Class>, or
157 L<Catalyst::View::TT> for L<Template Toolkit|Template>.
159 =item * B<Built-in Test Framework>
161 Catalyst comes with a built-in, lightweight http server and test
162 framework, making it easy to test applications from the web browser,
163 and the command line.
165 =item * B<Helper Scripts>
167 Catalyst provides helper scripts to quickly generate running starter
168 code for components and unit tests. Install L<Catalyst::Devel> and see
175 Here's how to install Catalyst and get a simple application up and
176 running, using the helper scripts described above.
180 Installation of Catalyst should be straightforward:
182 # perl -MCPAN -e 'install Catalyst::Runtime'
183 # perl -MCPAN -e 'install Catalyst::Devel'
190 $ script/myapp_create.pl controller Library::Login
192 =head4 Frank Speiser's Amazon EC2 Catalyst SDK
194 There are currently two flavors of publicly available Amazon Machine
195 Images (AMI) that include all the elements you'd need to begin
196 developing in a fully functional Catalyst environment within
198 L<Catalyst::Manual::Installation|Catalyst::Manual::Installation> for
204 $ script/myapp_server.pl
206 Now visit these locations with your favorite browser or user agent to see
209 (NOTE: Although we create a controller here, we don't actually use it.
210 Both of these URLs should take you to the welcome page.)
215 =item http://localhost:3000/
217 =item http://localhost:3000/library/login/
223 Let's see how Catalyst works, by taking a closer look at the components
224 and other parts of a Catalyst application.
228 Catalyst has an uncommonly flexible component system. You can define as
229 many L</Models>, L</Views>, and L</Controllers> as you like. As discussed
230 previously, the general idea is that the View is responsible for the
231 output of data to the user (typically via a web browser, but a View can
232 also generate PDFs or e-mails, for example); the Model is responsible
233 for providing data (typically from a relational database); and the
234 Controller is responsible for interacting with the user and deciding
235 how user input determines what actions the application takes.
237 In the world of MVC, there are frequent discussions and disagreements
238 about the nature of each element - whether certain types of logic
239 belong in the Model or the Controller, etc. Catalyst's flexibility
240 means that this decision is entirely up to you, the programmer;
241 Catalyst doesn't enforce anything. See L<Catalyst::Manual::About> for
242 a general discussion of these issues.
244 Model, View and Controller components must inherit from L<Catalyst::Model>,
245 L<Catalyst::View> and L<Catalyst::Controller>, respectively. These, in turn, inherit
246 from L<Catalyst::Component> which provides a simple class structure and some
247 common class methods like C<config> and C<new> (constructor).
249 package MyApp::Controller::Catalog;
251 use namespace::autoclean;
253 BEGIN { extends 'Catalyst::Controller' }
255 __PACKAGE__->config( foo => 'bar' );
259 You don't have to C<use> or otherwise register Models, Views, and
260 Controllers. Catalyst automatically discovers and instantiates them
261 when you call C<setup> in the main application. All you need to do is
262 put them in directories named for each Component type. You can use a
263 short alias for each one.
267 =item * B<MyApp/Model/>
271 =item * B<MyApp/View/>
275 =item * B<MyApp/Controller/>
281 In older versions of Catalyst, the recommended practice (and the one
282 automatically created by helper scripts) was to name the directories
283 C<M/>, C<V/>, and C<C/>. Though these still work, they are deprecated
284 and we now recommend the use of the full names.
288 To show how to define views, we'll use an already-existing base class for the
289 L<Template Toolkit|Template>, L<Catalyst::View::TT>. All we need to do is
290 inherit from this class:
292 package MyApp::View::TT;
295 use base 'Catalyst::View::TT';
299 (You can also generate this automatically by using the helper script:
301 script/myapp_create.pl view TT TT
303 where the first C<TT> tells the script that the name of the view should
304 be C<TT>, and the second that it should be a Template Toolkit view.)
306 This gives us a process() method and we can now just do
307 $c->forward('MyApp::View::TT') to render our templates. The base class
308 makes process() implicit, so we don't have to say
309 C<$c-E<gt>forward(qw/MyApp::View::TT process/)>.
312 my ( $self, $c ) = @_;
313 $c->stash->{template} = 'hello.tt';
317 my ( $self, $c ) = @_;
318 $c->forward( $c->view('TT') );
321 You normally render templates at the end of a request, so it's a perfect
322 use for the global C<end> action.
324 In practice, however, you would use a default C<end> action as supplied
325 by L<Catalyst::Action::RenderView>.
327 Also, be sure to put the template under the directory specified in
328 C<$c-E<gt>config-E<gt>{root}>, or you'll end up looking at the debug
333 Models are providers of data. This data could come from anywhere - a
334 search engine index, a spreadsheet, the file system - but typically a
335 Model represents a database table. The data source does not
336 intrinsically have much to do with web applications or Catalyst - it
337 could just as easily be used to write an offline report generator or a
340 To show how to define models, again we'll use an already-existing base
341 class, this time for L<DBIx::Class>: L<Catalyst::Model::DBIC::Schema>.
342 We'll also need L<DBIx::Class::Schema::Loader>.
344 But first, we need a database.
348 id INTEGER PRIMARY KEY,
353 id INTEGER PRIMARY KEY,
354 foo INTEGER REFERENCES foo,
358 INSERT INTO foo (data) VALUES ('TEST!');
360 % sqlite3 /tmp/myapp.db < myapp.sql
362 Now we can create a DBIC::Schema model for this database.
364 script/myapp_create.pl model MyModel DBIC::Schema MySchema create=static 'dbi:SQLite:/tmp/myapp.db'
366 L<DBIx::Class::Schema::Loader> can automatically load table layouts and
367 relationships, and convert them into a static schema definition
368 C<MySchema>, which you can edit later.
370 Use the stash to pass data to your templates.
372 We add the following to MyApp/Controller/Root.pm
375 my ( $self, $c, $id ) = @_;
377 $c->stash->{item} = $c->model('MyModel::Foo')->find($id);
383 my ( $self, $c ) = @_;
385 $c->stash->{template} ||= 'index.tt';
386 $c->forward( $c->view('TT') );
389 We then create a new template file "root/index.tt" containing:
391 The Id's data is [% item.data %]
393 Models do not have to be part of your Catalyst application; you
394 can always call an outside module that serves as your Model:
398 my ( $self, $c ) = @_;
400 $c->stash->{template} = 'list.tt';
402 use Some::Outside::Database::Module;
403 my @records = Some::Outside::Database::Module->search({
404 artist => 'Led Zeppelin',
407 $c->stash->{records} = \@records;
410 But by using a Model that is part of your Catalyst application, you
411 gain several things: you don't have to C<use> each component, Catalyst
412 will find and load it automatically at compile-time; you can
413 C<forward> to the module, which can only be done to Catalyst
414 components. Only Catalyst components can be fetched with
415 C<$c-E<gt>model('SomeModel')>.
417 Happily, since many people have existing Model classes that they
418 would like to use with Catalyst (or, conversely, they want to
419 write Catalyst models that can be used outside of Catalyst, e.g.
420 in a cron job), it's trivial to write a simple component in
421 Catalyst that slurps in an outside Model:
423 package MyApp::Model::DB;
424 use base qw/Catalyst::Model::DBIC::Schema/;
426 schema_class => 'Some::DBIC::Schema',
427 connect_info => ['dbi:SQLite:foo.db', '', '', {AutoCommit=>1}]
431 and that's it! Now C<Some::DBIC::Schema> is part of your
432 Cat app as C<MyApp::Model::DB>.
434 Within Catalyst, the common approach to writing a model for your
435 application is wrapping a generic model (e.g. L<DBIx::Class::Schema>, a
436 bunch of XMLs, or anything really) with an object that contains
437 configuration data, convenience methods, and so forth. Thus you
438 will in effect have two models - a wrapper model that knows something
439 about Catalyst and your web application, and a generic model that is
440 totally independent of these needs.
442 Technically, within Catalyst a model is a B<component> - an instance of
443 the model's class belonging to the application. It is important to
444 stress that the lifetime of these objects is per application, not per
447 While the model base class (L<Catalyst::Model>) provides things like
448 C<config> to better integrate the model into the application, sometimes
449 this is not enough, and the model requires access to C<$c> itself.
451 Situations where this need might arise include:
457 Interacting with another model
461 Using per-request data to control behavior
465 Using plugins from a Model (for example L<Catalyst::Plugin::Cache>).
469 From a style perspective it's usually considered bad form to make your
470 model "too smart" about things - it should worry about business logic
471 and leave the integration details to the controllers. If, however, you
472 find that it does not make sense at all to use an auxillary controller
473 around the model, and the model's need to access C<$c> cannot be
474 sidestepped, there exists a power tool called L</ACCEPT_CONTEXT>.
478 Multiple controllers are a good way to separate logical domains of your
481 package MyApp::Controller::Login;
483 use base qw/Catalyst::Controller/;
485 sub login : Path("login") { }
486 sub new_password : Path("new-password") { }
487 sub logout : Path("logout") { }
489 package MyApp::Controller::Catalog;
491 use base qw/Catalyst::Controller/;
496 package MyApp::Controller::Cart;
498 use base qw/Catalyst::Controller/;
501 sub update : Local { }
502 sub order : Local { }
504 Note that you can also supply attributes via the Controller's config so
505 long as you have at least one attribute on a subref to be exported
506 (:Action is commonly used for this) - for example the following is
507 equivalent to the same controller above:
509 package MyApp::Controller::Login;
511 use base qw/Catalyst::Controller/;
515 'sign_in' => { Path => 'sign-in' },
516 'new_password' => { Path => 'new-password' },
517 'sign_out' => { Path => 'sign-out' },
521 sub sign_in : Action { }
522 sub new_password : Action { }
523 sub sign_out : Action { }
525 =head3 ACCEPT_CONTEXT
527 Whenever you call $c->component("Foo") you get back an object - the
528 instance of the model. If the component supports the C<ACCEPT_CONTEXT>
529 method instead of returning the model itself, the return value of C<<
530 $model->ACCEPT_CONTEXT( $c ) >> will be used.
532 This means that whenever your model/view/controller needs to talk to
533 C<$c> it gets a chance to do this when it's needed.
535 A typical C<ACCEPT_CONTEXT> method will either clone the model and return one
536 with the context object set, or it will return a thin wrapper that contains
537 C<$c> and delegates to the per-application model object.
539 Generally it's a bad idea to expose the context object (C<$c>) in your
540 model or view code. Instead you use the C<ACCEPT_CONTEXT> subroutine
541 to grab the bits of the context object that you need, and provide
542 accessors to them in the model. This ensures that C<$c> is only in
543 scope where it is neaded which reduces maintenance and debugging
544 headaches. So, if for example you needed two
545 L<Catalyst::Model::DBIC::Schema> models in the same Catalyst model
546 code, you might do something like this:
548 __PACKAGE__->mk_accessors(qw(model1_schema model2_schema));
550 my ( $self, $c, @extra_arguments ) = @_;
551 $self = bless({ %$self,
552 model1_schema => $c->model('Model1')->schema,
553 model2_schema => $c->model('Model2')->schema
558 This effectively treats $self as a B<prototype object> that gets a new
559 parameter. C<@extra_arguments> comes from any trailing arguments to
560 C<< $c->component( $bah, @extra_arguments ) >> (or C<< $c->model(...)
561 >>, C<< $c->view(...) >> etc).
563 In a subroutine in the model code, we can then do this:
567 my $schema1 = $self->model1_schema;
568 my $schema2 = $self->model2_schema;
572 Note that we still want the Catalyst models to be a thin wrapper
573 around classes that will work independently of the Catalyst
574 application to promote reusability of code. Here we might just want
575 to grab the $c->model('DB')->schema so as to get the connection
576 information from the Catalyst application's configuration for example.
578 The life time of this value is B<per usage>, and not per request. To
579 make this per request you can use the following technique:
581 Add a field to C<$c>, like C<my_model_instance>. Then write your
582 C<ACCEPT_CONTEXT> method to look like this:
585 my ( $self, $c ) = @_;
587 if ( my $per_request = $c->my_model_instance ) {
590 my $new_instance = bless { %$self, c => $c }, ref($self);
591 Scalar::Util::weaken($new_instance->{c}); # or we have a circular reference
592 $c->my_model_instance( $new_instance );
593 return $new_instance;
597 For a similar technique to grab a new component instance on each
598 request, see L<Catalyst::Component::InstancePerContext>.
600 =head3 Application Class
602 In addition to the Model, View, and Controller components, there's a
603 single class that represents your application itself. This is where you
604 configure your application, load plugins, and extend Catalyst.
609 use parent qw/Catalyst/;
610 use Catalyst qw/-Debug ConfigLoader Static::Simple/;
612 name => 'My Application',
614 # You can put anything else you want in here:
615 my_configuration_variable => 'something',
619 In older versions of Catalyst, the application class was where you put
620 global actions. However, as of version 5.66, the recommended practice is
621 to place such actions in a special Root controller (see L</Actions>,
622 below), to avoid namespace collisions.
628 The name of your application.
632 Optionally, you can specify a B<root> parameter for templates and static
633 data. If omitted, Catalyst will try to auto-detect the directory's
634 location. You can define as many parameters as you want for plugins or
635 whatever you need. You can access them anywhere in your application via
636 C<$context-E<gt>config-E<gt>{$param_name}>.
640 Catalyst automatically blesses a Context object into your application
641 class and makes it available everywhere in your application. Use the
642 Context to directly interact with Catalyst and glue your L</Components>
643 together. For example, if you need to use the Context from within a
644 Template Toolkit template, it's already there:
646 <h1>Welcome to [% c.config.name %]!</h1>
648 As illustrated in our URL-to-Action dispatching example, the Context is
649 always the second method parameter, behind the Component object
650 reference or class name itself. Previously we called it C<$context> for
651 clarity, but most Catalyst developers just call it C<$c>:
654 my ( $self, $c ) = @_;
655 $c->res->body('Hello World!');
658 The Context contains several important objects:
662 =item * L<Catalyst::Request>
667 The request object contains all kinds of request-specific information, like
668 query parameters, cookies, uploads, headers, and more.
670 $c->req->params->{foo};
671 $c->req->cookies->{sessionid};
672 $c->req->headers->content_type;
674 $c->req->uri_with( { page = $pager->next_page } );
676 =item * L<Catalyst::Response>
681 The response is like the request, but contains just response-specific
684 $c->res->body('Hello World');
685 $c->res->status(404);
686 $c->res->redirect('http://oook.de');
694 =item * L<Catalyst::Log>
697 $c->log->debug('Something happened');
698 $c->log->info('Something you should know');
703 $c->stash->{foo} = 'bar';
704 $c->stash->{baz} = {baz => 'qox'};
705 $c->stash->{fred} = [qw/wilma pebbles/];
711 The last of these, the stash, is a universal hash for sharing data among
712 application components. For an example, we return to our 'hello' action:
715 my ( $self, $c ) = @_;
716 $c->stash->{message} = 'Hello World!';
717 $c->forward('show_message');
720 sub show_message : Private {
721 my ( $self, $c ) = @_;
722 $c->res->body( $c->stash->{message} );
725 Note that the stash should be used only for passing data in an
726 individual request cycle; it gets cleared at a new request. If you need
727 to maintain persistent data, use a session. See
728 L<Catalyst::Plugin::Session> for a comprehensive set of
729 Catalyst-friendly session-handling tools.
733 You've already seen some examples of actions in this document:
734 subroutines with C<:Path> and C<:Local> attributes attached.
735 Here, we explain what actions are and how these attributes affect
738 When Catalyst processes a webpage request, it looks for actions to
739 take that will deal with the incoming request and produce a response
740 such as a webpage. You create these actions for your application by
741 writing subroutines within your controller and marking them with
742 special attributes. The attributes, the namespace, and the function
743 name determine when Catalyst will call the subroutine.
745 These action subroutines call certain functions to say what response
746 the webserver will give to the web request. They can also tell
747 Catalyst to run other actions on the request (one example of this is
748 called forwarding the request; this is discussed later).
750 Action subroutines must have a special attribute on to show that they
751 are actions - as well as marking when to call them, this shows that
752 they take a specific set of arguments and behave in a specific way.
753 At startup, Catalyst looks for all the actions in controllers,
754 registers them and creates L<Catalyst::Action> objects describing
755 them. When requests come in, Catalyst chooses which actions should be
756 called to handle the request.
758 (Occasionally, you might use the action objects directly, but in
759 general, when we talk about actions, we're talking about the
760 subroutines in your application that do things to process a request.)
762 You can choose one of several attributes for action subroutines; these
763 specify which requests are processed by that subroutine. Catalyst
764 will look at the URL it is processing, and the actions that it has
765 found, and automatically call the actions it finds that match the
766 circumstances of the request.
768 The URL (for example http://localhost:3000/foo/bar) consists of two
769 parts, the base, describing how to connect to the server
770 (http://localhost:3000/ in this example) and the path, which the
771 server uses to decide what to return (foo/bar). Please note that the
772 trailing slash after the hostname[:port] always belongs to base and
773 not to the path. Catalyst uses only the path part when trying to find
776 Depending on the type of action used, the URLs may match a combination
777 of the controller namespace, the arguments passed to the action
778 attribute, and the name of the subroutine.
782 =item * B<Controller namespaces>
784 The namespace is a modified form of the component's class (package)
785 name. This modified class name excludes the parts that have a
786 pre-defined meaning in Catalyst ("MyApp::Controller" in the above
787 example), replaces "::" with "/", and converts the name to lower case.
788 See L</Components> for a full explanation of the pre-defined meaning
789 of Catalyst component class names.
791 =item * B<Overriding the namespace>
793 Note that I<< __PACKAGE__->config->(namespace => ... ) >> can be used to override the
794 current namespace when matching. So:
796 package MyApp::Controller::Example;
798 would normally use 'example' as its namespace for matching, but if
799 this is specially overridden with
801 __PACKAGE__->config( namespace => 'thing' );
803 it matches using the namespace 'thing' instead.
805 =item * B<Application Wide Actions>
807 MyApp::Controller::Root, as created by the catalyst.pl script, will
808 typically contain actions which are called for the top level of the
809 application (e.g. http://localhost:3000/ ):
811 package MyApp::Controller::Root;
812 use base 'Catalyst::Controller';
814 # Sets the actions in this controller to be registered with no prefix
815 # so they function identically to actions created in MyApp.pm
817 __PACKAGE__->config( namespace => '');
820 my ( $self, $context ) = @_;
821 $context->response->status(404);
822 $context->response->body('404 not found');
830 __PACKAGE__->config( namespace => '' );
832 makes the controller act as if its namespace is empty. As you'll see
833 below, an empty namespace makes many of the URL-matching attributes, such
834 as :Path and :Local match at the start of the URL path (i.e. the
841 Catalyst supports several types of actions. These mainly correspond
842 to ways of matching a URL to an action subroutine. Internally, these
843 matching types are implemented by L<Catalyst::DispatchType>-derived
844 classes; the documentation there can be helpful in seeing how they
847 They will all attempt to match the start of the path. The remainder
848 of the path is passed as arguments.
852 =item * Namespace-prefixed (C<:Local>)
854 package MyApp::Controller::My::Controller;
857 Matches any URL beginning with> http://localhost:3000/my/controller/foo. The namespace and
858 subroutine name together determine the path.
860 =item * Root-level (C<:Global>)
862 package MyApp::Controller::Foo;
867 $c->res->body('sub bar in Controller::Foo triggered on a request for '
873 Matches http://localhost:3000/bar - that is, the action is mapped
874 directly to the method name, ignoring the controller namespace.
876 C<:Global> always matches from the application root: it is simply
877 shorthandfor C<:Path('/methodname')>. C<:Local> is shorthand for
878 C<:Path('methodname')>, which takes the controller namespace as described
881 Usage of the C<Global> handler is rare in all but very old Catalyst
882 applications (e.g. before Catalyst 5.7). The use cases where C<Global>
883 used to make sense are now largely replaced by the C<Chained> dispatch
884 type, or by empty C<Path> declarations on an controller action. C<Global>
885 is still included in Catalyst for backwards compatibility, although
886 legitimate use-cases for it may still exist.
888 =item * Changing handler behaviour: eating arguments (C<:Args>)
890 Args is not an action type per se, but an action modifier - it adds a
891 match restriction to any action it's provided to, additionally
892 requiring as many path parts as are specified for the action to be
893 matched. For example, in MyApp::Controller::Foo,
897 would match any URL starting /foo/bar. To restrict this you can do
899 sub bar :Local :Args(1)
901 to only match URLs starting /foo/bar/* - with one additional path
902 element required after 'bar'.
904 NOTE that adding C<:Args(0)> and missing out :Args completely are B<not>
907 C<:Args(0)> means that no arguments are taken. Thus, the URL and path must
910 No :Args at all means that B<any number> of arguments are taken. Thus, any
911 URL that B<starts with> the controller's path will match. Obviously, this means
912 you cannot chain from an action that does not specify args, as the next action
913 in the chain will be swallowed as an arg to the first!
916 =item * Literal match (C<:Path>)
918 C<Path> actions match things starting with a precise specified path,
921 C<Path> actions without a leading forward slash match a specified path
922 relative to their current namespace. This example matches URLs
923 starting http://localhost:3000/my/controller/foo/bar :
925 package MyApp::Controller::My::Controller;
926 sub bar : Path('foo/bar') { }
928 C<Path> actions B<with> a leading slash ignore their namespace, and
929 match from the start of the URL path. Example:
931 package MyApp::Controller::My::Controller;
932 sub bar : Path('/foo/bar') { }
934 This matches URLs beginning http://localhost:3000/foo/bar.
936 Empty C<Path> definitions match on the namespace only, exactly like
939 package MyApp::Controller::My::Controller;
942 The above code matches http://localhost:3000/my/controller.
944 Actions with the C<:Local> attribute are similarly equivalent to
945 C<:Path('action_name')>:
951 sub foo : Path('foo') { }
953 =item * Pattern-match (C<:Regex> and C<:LocalRegex>)
955 package MyApp::Controller::My::Controller;
956 sub bar : Regex('^item(\d+)/order(\d+)$') { }
958 This matches any URL that matches the pattern in the action key, e.g.
959 http://localhost:3000/item23/order42. The '' around the regexp is
960 optional, but perltidy likes it. :)
962 C<:Regex> matches act globally, i.e. without reference to the namespace
963 from which they are called. So the above will B<not> match
964 http://localhost:3000/my/controller/item23/order42 - use a
965 C<:LocalRegex> action instead.
967 package MyApp::Controller::My::Controller;
968 sub bar : LocalRegex('^widget(\d+)$') { }
970 C<:LocalRegex> actions act locally, i.e. the namespace is matched
971 first. The above example would match urls like
972 http://localhost:3000/my/controller/widget23.
974 If you omit the "C<^>" from either sort of regex, then it will match any depth
977 package MyApp::Controller::Catalog;
978 sub bar : LocalRegex('widget(\d+)$') { }
980 This differs from the previous example in that it will match
981 http://localhost:3000/my/controller/foo/widget23 - and a number of
984 For both C<:LocalRegex> and C<:Regex> actions, if you use capturing
985 parentheses to extract values within the matching URL, those values
986 are available in the C<$c-E<gt>req-E<gt>captures> array. In the above
987 example, "widget23" would capture "23" in the above example, and
988 C<$c-E<gt>req-E<gt>captures-E<gt>[0]> would be "23". If you want to
989 pass arguments at the end of your URL, you must use regex action
990 keys. See L</URL Path Handling> below.
992 =item * Chained handlers (C<:Chained>)
994 Catalyst also provides a method to build and dispatch chains of actions,
997 sub catalog : Chained : CaptureArgs(1) {
998 my ( $self, $c, $arg ) = @_;
1002 sub item : Chained('catalog') : Args(1) {
1003 my ( $self, $c, $arg ) = @_;
1007 to handle a C</catalog/*/item/*> path. Matching actions are called
1008 one after another - C<catalog()> gets called and handed one path
1009 element, then C<item()> gets called with another one. For further
1010 information about this dispatch type, please see
1011 L<Catalyst::DispatchType::Chained>.
1015 sub foo : Private { }
1017 This will never match a URL - it provides a private action which can
1018 be called programmatically from within Catalyst, but is never called
1019 automatically due to the URL being requested.
1021 Catalyst's C<:Private> attribute is exclusive and doesn't work with other
1022 attributes (so will not work combined with C<:Path> or C<:Chained>
1023 attributes, for instance).
1025 Private actions can only be executed explicitly from inside a Catalyst
1026 application. You might do this in your controllers by calling
1027 catalyst methods such as C<forward> or C<detach> to fire them:
1033 See L</Flow Control> for a full explanation of how you can pass
1034 requests on to other actions. Note that, as discussed there, when
1035 forwarding from another component, you must use the absolute path to
1036 the method, so that a private C<bar> method in your
1037 C<MyApp::Controller::Catalog::Order::Process> controller must, if
1038 called from elsewhere, be reached with
1039 C<$c-E<gt>forward('/catalog/order/process/bar')>.
1043 B<Note:> After seeing these examples, you probably wonder what the
1044 point is of defining subroutine names for regex and path
1045 actions. However, every public action is also a private one with a
1046 path corresponding to its namespace and subroutine name, so you have
1047 one unified way of addressing components in your C<forward>s.
1049 =head4 Built-in special actions
1051 If present, the special actions C< index >, C< auto >, C<begin>,
1052 C<end> and C< default > are called at certain points in the request
1055 In response to specific application states, Catalyst will automatically
1056 call these built-in actions in your application class:
1060 =item * B<default : Path>
1062 This is called when no other action matches. It could be used, for
1063 example, for displaying a generic frontpage for the main app, or an
1064 error page for individual controllers. B<Note>: in older Catalyst
1065 applications you will see C<default : Private> which is roughly
1066 speaking equivalent.
1069 =item * B<index : Path : Args (0) >
1071 C<index> is much like C<default> except that it takes no arguments and
1072 it is weighted slightly higher in the matching process. It is useful
1073 as a static entry point to a controller, e.g. to have a static welcome
1074 page. Note that it's also weighted higher than Path. Actually the sub
1075 name C<index> can be called anything you want. The sub attributes are
1076 what determines the behaviour of the action. B<Note>: in older
1077 Catalyst applications, you will see C<index : Private> used, which is
1078 roughly speaking equivalent.
1080 =item * B<begin : Private>
1082 Called at the beginning of a request, once the controller that will
1083 run has been identified, but before any URL-matching actions are
1084 called. Catalyst will call the C<begin> function in the controller
1085 which contains the action matching the URL.
1087 =item * B<end : Private>
1089 Called at the end of a request, after all URL-matching actions are called.
1090 Catalyst will call the C<end> function in the controller
1091 which contains the action matching the URL.
1093 =item * B<auto : Private>
1095 In addition to the normal built-in actions, you have a special action
1096 for making chains, C<auto>. C<auto> actions will be run after any
1097 C<begin>, but before your URL-matching action is processed. Unlike the other
1098 built-ins, multiple C<auto> actions can be called; they will be
1099 called in turn, starting with the application class and going through
1100 to the most specific class.
1104 =head4 Built-in actions in controllers/autochaining
1106 package MyApp::Controller::Foo;
1107 sub begin : Private { }
1108 sub default : Path { }
1111 You can define built-in actions within your controllers as well as on
1112 your application class. In other words, for each of the three built-in
1113 actions above, only one will be run in any request cycle. Thus, if
1114 C<MyApp::Controller::Catalog::begin> exists, it will be run in place
1115 of C<MyApp::begin> if you're in the C<catalog> namespace, and
1116 C<MyApp::Controller::Catalog::Order::begin> would override this in
1119 sub auto : Private { }
1121 C<auto>, however, doesn't override like this: providing they exist,
1122 C<MyApp::Controller::Root::auto>, C<MyApp::Controller::Catalog::auto> and
1123 C<MyApp::Catalog::Order::auto> would be called in turn.
1125 Here are some examples of the order in which the various built-ins
1130 =item for a request for C</foo/foo>
1132 MyApp::Controller::Foo::auto
1133 MyApp::Controller::Foo::default # in the absence of MyApp::Controller::Foo::Foo
1134 MyApp::Controller::Foo::end
1136 =item for a request for C</foo/bar/foo>
1138 MyApp::Controller::Foo::Bar::begin
1139 MyApp::Controller::Foo::auto
1140 MyApp::Controller::Foo::Bar::auto
1141 MyApp::Controller::Foo::Bar::default # for MyApp::Controller::Foo::Bar::foo
1142 MyApp::Controller::Foo::Bar::end
1146 The C<auto> action is also distinguished by the fact that you can break
1147 out of the processing chain by returning 0. If an C<auto> action returns
1148 0, any remaining actions will be skipped, except for C<end>. So, for the
1149 request above, if the first auto returns false, the chain would look
1154 =item for a request for C</foo/bar/foo> where first C<auto> returns
1157 MyApp::Controller::Foo::Bar::begin
1158 MyApp::Controller::Foo::auto # returns false, skips some calls:
1159 # MyApp::Controller::Foo::Bar::auto - never called
1160 # MyApp::Controller::Foo::Bar::foo - never called
1161 MyApp::Controller::Foo::Bar::end
1163 You can also C<die> in the auto action; in that case, the request will
1164 go straight to the finalize stage, without processing further
1165 actions. So in the above example, C<MyApp::Controller::Foo::Bar::end>
1170 An example of why one might use C<auto> is an authentication action:
1171 you could set up a C<auto> action to handle authentication in your
1172 application class (which will always be called first), and if
1173 authentication fails, returning 0 would skip any remaining methods for
1176 B<Note:> Looking at it another way, C<auto> actions have to return a
1177 true value to continue processing!
1179 =head4 URL Path Handling
1181 You can pass arguments as part of the URL path, separated with forward
1182 slashes (/). If the action is a Regex or LocalRegex, the '$' anchor
1183 must be used. For example, suppose you want to handle
1184 C</foo/$bar/$baz>, where C<$bar> and C<$baz> may vary:
1186 sub foo : Regex('^foo$') { my ($self, $context, $bar, $baz) = @_; }
1188 But what if you also defined actions for C</foo/boo> and C</foo/boo/hoo>?
1190 sub boo : Path('foo/boo') { .. }
1191 sub hoo : Path('foo/boo/hoo') { .. }
1193 Catalyst matches actions in most specific to least specific order - that is, whatever matches the most pieces of the path wins:
1197 /foo # might be /foo/bar/baz but won't be /foo/boo/hoo
1199 So Catalyst would never mistakenly dispatch the first two URLs to the
1202 If a Regex or LocalRegex action doesn't use the '$' anchor, the action will
1203 still match a URL containing arguments; however the arguments won't be
1204 available via C<@_>, because the Regex will 'eat' them.
1206 Beware! If you write two matchers, that match the same path, with the
1207 same specificity (that is, they match the same quantity of the path),
1208 there's no guarantee which will actually get called. Non-regex
1209 matchers get tried first, followed by regex ones, but if you have, for
1212 package MyApp::Controller::Root;
1214 sub match1 :Path('/a/b') { }
1216 package MyApp::Controller::A;
1218 sub b :Local { } # Matches /a/b
1220 then Catalyst will call the one it finds first. In summary, Don't Do
1223 =head4 Query Parameter Processing
1225 Parameters passed in the URL query string are handled with methods in
1226 the L<Catalyst::Request> class. The C<param> method is functionally
1227 equivalent to the C<param> method of C<CGI.pm> and can be used in
1228 modules that require this.
1230 # http://localhost:3000/catalog/view/?category=hardware&page=3
1231 my $category = $c->req->param('category');
1232 my $current_page = $c->req->param('page') || 1;
1234 # multiple values for single parameter name
1235 my @values = $c->req->param('scrolling_list');
1237 # DFV requires a CGI.pm-like input hash
1238 my $results = Data::FormValidator->check($c->req->params, \%dfv_profile);
1242 You control the application flow with the C<forward> method, which
1243 accepts the key of an action to execute. This can be an action in the
1244 same or another Catalyst controller, or a Class name, optionally
1245 followed by a method name. After a C<forward>, the control flow will
1246 return to the method from which the C<forward> was issued.
1248 A C<forward> is similar to a method call. The main differences are that
1249 it wraps the call in an C<eval> to allow exception handling; it
1250 automatically passes along the context object (C<$c> or C<$context>);
1251 and it allows profiling of each call (displayed in the log with
1254 sub hello : Global {
1255 my ( $self, $c ) = @_;
1256 $c->stash->{message} = 'Hello World!';
1257 $c->forward('check_message'); # $c is automatically included
1260 sub check_message : Private {
1261 my ( $self, $c ) = @_;
1262 return unless $c->stash->{message};
1263 $c->forward('show_message');
1266 sub show_message : Private {
1267 my ( $self, $c ) = @_;
1268 $c->res->body( $c->stash->{message} );
1271 A C<forward> does not create a new request, so your request object
1272 (C<$c-E<gt>req>) will remain unchanged. This is a key difference between
1273 using C<forward> and issuing a redirect.
1275 You can pass new arguments to a C<forward> by adding them
1276 in an anonymous array. In this case C<$c-E<gt>req-E<gt>args>
1277 will be changed for the duration of the C<forward> only; upon
1278 return, the original value of C<$c-E<gt>req-E<gt>args> will
1281 sub hello : Global {
1282 my ( $self, $c ) = @_;
1283 $c->stash->{message} = 'Hello World!';
1284 $c->forward('check_message',[qw/test1/]);
1285 # now $c->req->args is back to what it was before
1288 sub check_message : Action {
1289 my ( $self, $c, $first_argument ) = @_;
1290 my $also_first_argument = $c->req->args->[0]; # now = 'test1'
1294 As you can see from these examples, you can just use the method name as
1295 long as you are referring to methods in the same controller. If you want
1296 to forward to a method in another controller, or the main application,
1297 you will have to refer to the method by absolute path.
1299 $c->forward('/my/controller/action');
1300 $c->forward('/default'); # calls default in main application
1302 You can also forward to classes and methods.
1304 sub hello : Global {
1305 my ( $self, $c ) = @_;
1306 $c->forward(qw/MyApp::View:Hello say_hello/);
1310 my ( $self, $c ) = @_;
1311 $c->forward('MyApp::Model::Hello'); # no method: will try 'process'
1314 package MyApp::View::Hello;
1317 my ( $self, $c ) = @_;
1318 $c->res->body('Hello World!');
1322 my ( $self, $c ) = @_;
1323 $c->res->body('Goodbye World!');
1326 This mechanism is used by L<Catalyst::Action::RenderView> to forward
1327 to the C<process> method in a view class.
1329 It should be noted that whilst forward is useful, it is not the only way
1330 of calling other code in Catalyst. Forward just gives you stats in the debug
1331 screen, wraps the code you're calling in an exception handler and localises
1332 C<< $c->request->args >>.
1334 If you don't want or need these features then it's perfectly acceptable
1335 (and faster) to do something like this:
1337 sub hello : Global {
1338 my ( $self, $c ) = @_;
1339 $c->stash->{message} = 'Hello World!';
1340 $self->check_message( $c, 'test1' );
1344 my ( $self, $c, $first_argument ) = @_;
1348 Note that C<forward> returns to the calling action and continues
1349 processing after the action finishes. If you want all further processing
1350 in the calling action to stop, use C<detach> instead, which will execute
1351 the C<detach>ed action and not return to the calling sub. In both cases,
1352 Catalyst will automatically try to call process() if you omit the
1357 Catalyst has a built-in http server for testing or local
1358 deployment. (Later, you can easily use a more powerful server, for
1359 example Apache/mod_perl or FastCGI, in a production environment.)
1361 Start your application on the command line...
1363 script/myapp_server.pl
1365 ...then visit http://localhost:3000/ in a browser to view the output.
1367 You can also do it all from the command line:
1369 script/myapp_test.pl http://localhost/
1371 Catalyst has a number of tools for actual regression testing of
1372 applications. The helper scripts will automatically generate basic tests
1373 that can be extended as you develop your project. To write your own
1374 comprehensive test scripts, L<Test::WWW::Mechanize::Catalyst> is an
1377 For more testing ideas, see L<Catalyst::Manual::Tutorial::Testing>.
1385 =item * L<Catalyst::Manual::About>
1387 =item * L<Catalyst::Manual::Tutorial>
1397 Join #catalyst on irc.perl.org.
1398 Join #catalyst-dev on irc.perl.org to help with development.
1402 http://lists.scsys.co.uk/mailman/listinfo/catalyst
1403 http://lists.scsys.co.uk/mailman/listinfo/catalyst-dev
1407 http://dev.catalystframework.org/wiki
1411 http://dev.catalystframework.org/wiki/faq
1415 Catalyst Contributors, see Catalyst.pm
1419 This library is free software. You can redistribute it and/or modify it under
1420 the same terms as Perl itself.