3 Catalyst::Manual::Intro - Introduction to Catalyst
7 This is a brief introduction to Catalyst. It explains the most important
8 features of how Catalyst works and shows how to get a simple application
9 up and running quickly. For an introduction (without code) to Catalyst
10 itself, and why you should be using it, see L<Catalyst::Manual::About>.
11 For a systematic step-by-step introduction to writing an application
12 with Catalyst, see L<Catalyst::Manual::Tutorial>.
14 =head2 What is Catalyst?
16 Catalyst is an elegant web application framework, extremely flexible
17 yet extremely simple. It's similar to Ruby on Rails, Spring (Java), and
18 L<Maypole|Maypole>, upon which it was originally based. Its most
19 important design philosphy is to provide easy access to all the tools
20 you need to develop web applications, with few restrictions on how you
21 need to use these tools. However, this does mean that it is always
22 possible to do things in a different way. Other web frameworks are
23 I<initially> simpler to use, but achieve this by locking the programmer
24 into a single set of tools. Catalyst's emphasis on flexibility means
25 that you have to think more to use it. We view this as a feature. For
26 example, this leads to Catalyst being better suited to system integration
27 tasks than other web frameworks.
31 Catalyst follows the Model-View-Controller (MVC) design pattern,
32 allowing you to easily separate concerns, like content, presentation,
33 and flow control, into separate modules. This separation allows you to
34 modify code that handles one concern without affecting code that handles
35 the others. Catalyst promotes the re-use of existing Perl modules that
36 already handle common web application concerns well.
38 Here's how the Model, View, and Controller map to those concerns, with
39 examples of well-known Perl modules you may want to use for each.
45 Access and modify content (data). L<DBIx::Class>, L<Class::DBI>,
46 L<Xapian>, L<Net::LDAP>...
50 Present content to the user. L<Template Toolkit|Template>,
51 L<Mason|HTML::Mason>, L<HTML::Template>...
55 Control the whole request phase, check parameters, dispatch actions, flow
56 control. This is the meat of where Catalyst works.
60 If you're unfamiliar with MVC and design patterns, you may want to
61 check out the original book on the subject, I<Design Patterns>, by
62 Gamma, Helm, Johnson, and Vlissides, also known as the Gang of Four
63 (GoF). Many, many web application frameworks are based on MVC, which
64 is becoming a popular design paradigm for the world wide web.
68 Catalyst is much more flexible than many other frameworks. Rest assured
69 you can use your favorite Perl modules with Catalyst.
73 =item * B<Multiple Models, Views, and Controllers>
75 To build a Catalyst application, you handle each type of concern inside
76 special modules called L</Components>. Often this code will be very
77 simple, just calling out to Perl modules like those listed above under
78 L</MVC>. Catalyst handles these components in a very flexible way. Use
79 as many Models, Views, and Controllers as you like, using as many
80 different Perl modules as you like, all in the same application. Want to
81 manipulate multiple databases, and retrieve some data via LDAP? No
82 problem. Want to present data from the same Model using L<Template
83 Toolkit|Template> and L<PDF::Template>? Easy.
85 =item * B<Reuseable Components>
87 Not only does Catalyst promote the re-use of already existing Perl
88 modules, it also allows you to re-use your Catalyst components in
89 multiple Catalyst applications.
91 =item * B<Unrestrained URL-to-Action Dispatching>
93 Catalyst allows you to dispatch any URLs to any application L</Actions>,
94 even through regular expressions! Unlike most other frameworks, it
95 doesn't require mod_rewrite or class and method names in URLs.
97 With Catalyst you register your actions and address them directly. For
101 my ( $self, $context ) = @_;
102 $context->response->body('Hello World!');
105 Now http://localhost:3000/hello prints "Hello World!".
107 Note that actions with the C< :Local > attribute are equivalent to
108 using a C<:Path('action_name') > attribute, so our action could be
111 sub hi : Path('hello') {
112 my ( $self, $context ) = @_;
113 $context->response->body('Hello World!');
117 =item * B<Support for CGI, mod_perl, Apache::Request, FastCGI>
119 Use L<Catalyst::Engine::Apache> or L<Catalyst::Engine::CGI>. Another
120 interesting engine is L<Catalyst::Engine::HTTP::Prefork> - available from CPAN
121 separately - which will turn the built server into a fully fledged production
122 ready server (although you'll probably want to run it behind a front end proxy
123 if you end up using it).
127 Starting with Catalyst version 5.9 Catalyst ships with L<PSGI> integration
128 for even more powerful and flexible testing and deployment options. See
129 L<Catalyst::PSGI> for details.
135 The best part is that Catalyst implements all this flexibility in a very
140 =item * B<Building Block Interface>
142 Components interoperate very smoothly. For example, Catalyst
143 automatically makes a L</Context> object available to every
144 component. Via the context, you can access the request object, share
145 data between components, and control the flow of your
146 application. Building a Catalyst application feels a lot like snapping
147 together toy building blocks, and everything just works.
149 =item * B<Component Auto-Discovery>
151 No need to C<use> all of your components. Catalyst automatically finds
154 =item * B<Pre-Built Components for Popular Modules>
156 See L<Catalyst::Model::DBIC::Schema> for L<DBIx::Class>, or
157 L<Catalyst::View::TT> for L<Template Toolkit|Template>.
159 =item * B<Built-in Test Framework>
161 Catalyst comes with a built-in, lightweight http server and test
162 framework, making it easy to test applications from the web browser,
163 and the command line.
165 =item * B<Helper Scripts>
167 Catalyst provides helper scripts to quickly generate running starter
168 code for components and unit tests. Install L<Catalyst::Devel> and see
175 Here's how to install Catalyst and get a simple application up and
176 running, using the helper scripts described above.
180 Installation of Catalyst should be straightforward:
182 # perl -MCPAN -e 'install Catalyst::Runtime'
183 # perl -MCPAN -e 'install Catalyst::Devel'
190 $ script/myapp_create.pl controller Library::Login
192 =head4 Frank Speiser's Amazon EC2 Catalyst SDK
194 There are currently two flavors of publicly available Amazon Machine
195 Images (AMI) that include all the elements you'd need to begin
196 developing in a fully functional Catalyst environment within
198 L<Catalyst::Manual::Installation|Catalyst::Manual::Installation> for
204 $ script/myapp_server.pl
206 Now visit these locations with your favorite browser or user agent to see
209 (NOTE: Although we create a controller here, we don't actually use it.
210 Both of these URLs should take you to the welcome page.)
215 =item http://localhost:3000/
217 =item http://localhost:3000/library/login/
223 Let's see how Catalyst works, by taking a closer look at the components
224 and other parts of a Catalyst application.
228 Catalyst has an uncommonly flexible component system. You can define as
229 many L</Models>, L</Views>, and L</Controllers> as you like. As discussed
230 previously, the general idea is that the View is responsible for the
231 output of data to the user (typically via a web browser, but a View can
232 also generate PDFs or e-mails, for example); the Model is responsible
233 for providing data (typically from a relational database); and the
234 Controller is responsible for interacting with the user and deciding
235 how user input determines what actions the application takes.
237 In the world of MVC, there are frequent discussions and disagreements
238 about the nature of each element - whether certain types of logic
239 belong in the Model or the Controller, etc. Catalyst's flexibility
240 means that this decision is entirely up to you, the programmer;
241 Catalyst doesn't enforce anything. See L<Catalyst::Manual::About> for
242 a general discussion of these issues.
244 Model, View and Controller components must inherit from L<Catalyst::Model>,
245 L<Catalyst::View> and L<Catalyst::Controller>, respectively. These, in turn, inherit
246 from L<Catalyst::Component> which provides a simple class structure and some
247 common class methods like C<config> and C<new> (constructor).
249 package MyApp::Controller::Catalog;
251 use namespace::autoclean;
253 BEGIN { extends 'Catalyst::Controller' }
255 __PACKAGE__->config( foo => 'bar' );
259 You don't have to C<use> or otherwise register Models, Views, and
260 Controllers. Catalyst automatically discovers and instantiates them
261 when you call C<setup> in the main application. All you need to do is
262 put them in directories named for each Component type. You can use a
263 short alias for each one.
267 =item * B<MyApp/Model/>
269 =item * B<MyApp/View/>
271 =item * B<MyApp/Controller/>
277 To show how to define views, we'll use an already-existing base class for the
278 L<Template Toolkit|Template>, L<Catalyst::View::TT>. All we need to do is
279 inherit from this class:
281 package MyApp::View::TT;
284 use base 'Catalyst::View::TT';
288 (You can also generate this automatically by using the helper script:
290 script/myapp_create.pl view TT TT
292 where the first C<TT> tells the script that the name of the view should
293 be C<TT>, and the second that it should be a Template Toolkit view.)
295 This gives us a process() method and we can now just do
296 $c->forward('MyApp::View::TT') to render our templates. The base class
297 makes process() implicit, so we don't have to say
298 C<$c-E<gt>forward(qw/MyApp::View::TT process/)>.
301 my ( $self, $c ) = @_;
302 $c->stash->{template} = 'hello.tt';
306 my ( $self, $c ) = @_;
307 $c->forward( $c->view('TT') );
310 You normally render templates at the end of a request, so it's a perfect
311 use for the global C<end> action.
313 In practice, however, you would use a default C<end> action as supplied
314 by L<Catalyst::Action::RenderView>.
316 Also, be sure to put the template under the directory specified in
317 C<$c-E<gt>config-E<gt>{root}>, or you'll end up looking at the debug
322 Models are providers of data. This data could come from anywhere - a
323 search engine index, a spreadsheet, the file system - but typically a
324 Model represents a database table. The data source does not
325 intrinsically have much to do with web applications or Catalyst - it
326 could just as easily be used to write an offline report generator or a
329 To show how to define models, again we'll use an already-existing base
330 class, this time for L<DBIx::Class>: L<Catalyst::Model::DBIC::Schema>.
331 We'll also need L<DBIx::Class::Schema::Loader>.
333 But first, we need a database.
337 id INTEGER PRIMARY KEY,
342 id INTEGER PRIMARY KEY,
343 foo INTEGER REFERENCES foo,
347 INSERT INTO foo (data) VALUES ('TEST!');
349 % sqlite3 /tmp/myapp.db < myapp.sql
351 Now we can create a DBIC::Schema model for this database.
353 script/myapp_create.pl model MyModel DBIC::Schema MySchema create=static 'dbi:SQLite:/tmp/myapp.db'
355 L<DBIx::Class::Schema::Loader> can automatically load table layouts and
356 relationships, and convert them into a static schema definition
357 C<MySchema>, which you can edit later.
359 Use the stash to pass data to your templates.
361 We add the following to MyApp/Controller/Root.pm
364 my ( $self, $c, $id ) = @_;
366 $c->stash->{item} = $c->model('MyModel::Foo')->find($id);
372 my ( $self, $c ) = @_;
374 $c->stash->{template} ||= 'index.tt';
375 $c->forward( $c->view('TT') );
378 We then create a new template file "root/index.tt" containing:
380 The Id's data is [% item.data %]
382 Models do not have to be part of your Catalyst application; you
383 can always call an outside module that serves as your Model:
387 my ( $self, $c ) = @_;
389 $c->stash->{template} = 'list.tt';
391 use Some::Outside::Database::Module;
392 my @records = Some::Outside::Database::Module->search({
393 artist => 'Led Zeppelin',
396 $c->stash->{records} = \@records;
399 But by using a Model that is part of your Catalyst application, you
400 gain several things: you don't have to C<use> each component, Catalyst
401 will find and load it automatically at compile-time; you can
402 C<forward> to the module, which can only be done to Catalyst
403 components. Only Catalyst components can be fetched with
404 C<$c-E<gt>model('SomeModel')>.
406 Happily, since many people have existing Model classes that they
407 would like to use with Catalyst (or, conversely, they want to
408 write Catalyst models that can be used outside of Catalyst, e.g.
409 in a cron job), it's trivial to write a simple component in
410 Catalyst that slurps in an outside Model:
412 package MyApp::Model::DB;
413 use base qw/Catalyst::Model::DBIC::Schema/;
415 schema_class => 'Some::DBIC::Schema',
416 connect_info => ['dbi:SQLite:foo.db', '', '', {AutoCommit=>1}]
420 and that's it! Now C<Some::DBIC::Schema> is part of your
421 Cat app as C<MyApp::Model::DB>.
423 Within Catalyst, the common approach to writing a model for your
424 application is wrapping a generic model (e.g. L<DBIx::Class::Schema>, a
425 bunch of XMLs, or anything really) with an object that contains
426 configuration data, convenience methods, and so forth. Thus you
427 will in effect have two models - a wrapper model that knows something
428 about Catalyst and your web application, and a generic model that is
429 totally independent of these needs.
431 Technically, within Catalyst a model is a B<component> - an instance of
432 the model's class belonging to the application. It is important to
433 stress that the lifetime of these objects is per application, not per
436 While the model base class (L<Catalyst::Model>) provides things like
437 C<config> to better integrate the model into the application, sometimes
438 this is not enough, and the model requires access to C<$c> itself.
440 Situations where this need might arise include:
446 Interacting with another model
450 Using per-request data to control behavior
454 Using plugins from a Model (for example L<Catalyst::Plugin::Cache>).
458 From a style perspective it's usually considered bad form to make your
459 model "too smart" about things - it should worry about business logic
460 and leave the integration details to the controllers. If, however, you
461 find that it does not make sense at all to use an auxillary controller
462 around the model, and the model's need to access C<$c> cannot be
463 sidestepped, there exists a power tool called L</ACCEPT_CONTEXT>.
467 Multiple controllers are a good way to separate logical domains of your
470 package MyApp::Controller::Login;
472 use base qw/Catalyst::Controller/;
474 sub sign_in : Path("sign-in") { }
475 sub new_password : Path("new-password") { }
476 sub sign_out : Path("sign-out") { }
478 package MyApp::Controller::Catalog;
480 use base qw/Catalyst::Controller/;
485 package MyApp::Controller::Cart;
487 use base qw/Catalyst::Controller/;
490 sub update : Local { }
491 sub order : Local { }
493 Note that you can also supply attributes via the Controller's config so
494 long as you have at least one attribute on a subref to be exported
495 (:Action is commonly used for this) - for example the following is
496 equivalent to the same controller above:
498 package MyApp::Controller::Login;
500 use base qw/Catalyst::Controller/;
504 'sign_in' => { Path => 'sign-in' },
505 'new_password' => { Path => 'new-password' },
506 'sign_out' => { Path => 'sign-out' },
510 sub sign_in : Action { }
511 sub new_password : Action { }
512 sub sign_out : Action { }
514 =head3 ACCEPT_CONTEXT
516 Whenever you call $c->component("Foo") you get back an object - the
517 instance of the model. If the component supports the C<ACCEPT_CONTEXT>
518 method instead of returning the model itself, the return value of C<<
519 $model->ACCEPT_CONTEXT( $c ) >> will be used.
521 This means that whenever your model/view/controller needs to talk to
522 C<$c> it gets a chance to do this when it's needed.
524 A typical C<ACCEPT_CONTEXT> method will either clone the model and return one
525 with the context object set, or it will return a thin wrapper that contains
526 C<$c> and delegates to the per-application model object.
528 Generally it's a bad idea to expose the context object (C<$c>) in your
529 model or view code. Instead you use the C<ACCEPT_CONTEXT> subroutine
530 to grab the bits of the context object that you need, and provide
531 accessors to them in the model. This ensures that C<$c> is only in
532 scope where it is needed which reduces maintenance and debugging
533 headaches. So, if for example you needed two
534 L<Catalyst::Model::DBIC::Schema> models in the same Catalyst model
535 code, you might do something like this:
537 __PACKAGE__->mk_accessors(qw(model1_schema model2_schema));
539 my ( $self, $c, @extra_arguments ) = @_;
540 $self = bless({ %$self,
541 model1_schema => $c->model('Model1')->schema,
542 model2_schema => $c->model('Model2')->schema
547 This effectively treats $self as a B<prototype object> that gets a new
548 parameter. C<@extra_arguments> comes from any trailing arguments to
549 C<< $c->component( $bah, @extra_arguments ) >> (or C<< $c->model(...)
550 >>, C<< $c->view(...) >> etc).
552 In a subroutine in the model code, we can then do this:
556 my $schema1 = $self->model1_schema;
557 my $schema2 = $self->model2_schema;
561 Note that we still want the Catalyst models to be a thin wrapper
562 around classes that will work independently of the Catalyst
563 application to promote reusability of code. Here we might just want
564 to grab the $c->model('DB')->schema so as to get the connection
565 information from the Catalyst application's configuration for example.
567 The life time of this value is B<per usage>, and not per request. To
568 make this per request you can use the following technique:
570 Add a field to C<$c>, like C<my_model_instance>. Then write your
571 C<ACCEPT_CONTEXT> method to look like this:
574 my ( $self, $c ) = @_;
576 if ( my $per_request = $c->my_model_instance ) {
579 my $new_instance = bless { %$self, c => $c }, ref($self);
580 Scalar::Util::weaken($new_instance->{c}); # or we have a circular reference
581 $c->my_model_instance( $new_instance );
582 return $new_instance;
586 For a similar technique to grab a new component instance on each
587 request, see L<Catalyst::Component::InstancePerContext>.
589 =head3 Application Class
591 In addition to the Model, View, and Controller components, there's a
592 single class that represents your application itself. This is where you
593 configure your application, load plugins, and extend Catalyst.
598 use parent qw/Catalyst/;
599 use Catalyst qw/-Debug ConfigLoader Static::Simple/;
601 name => 'My Application',
603 # You can put anything else you want in here:
604 my_configuration_variable => 'something',
608 In older versions of Catalyst, the application class was where you put
609 global actions. However, as of version 5.66, the recommended practice is
610 to place such actions in a special Root controller (see L</Actions>,
611 below), to avoid namespace collisions.
617 The name of your application.
621 Optionally, you can specify a B<root> parameter for templates and static
622 data. If omitted, Catalyst will try to auto-detect the directory's
623 location. You can define as many parameters as you want for plugins or
624 whatever you need. You can access them anywhere in your application via
625 C<$context-E<gt>config-E<gt>{$param_name}>.
629 Catalyst automatically blesses a Context object into your application
630 class and makes it available everywhere in your application. Use the
631 Context to directly interact with Catalyst and glue your L</Components>
632 together. For example, if you need to use the Context from within a
633 Template Toolkit template, it's already there:
635 <h1>Welcome to [% c.config.name %]!</h1>
637 As illustrated in our URL-to-Action dispatching example, the Context is
638 always the second method parameter, behind the Component object
639 reference or class name itself. Previously we called it C<$context> for
640 clarity, but most Catalyst developers just call it C<$c>:
643 my ( $self, $c ) = @_;
644 $c->res->body('Hello World!');
647 The Context contains several important objects:
651 =item * L<Catalyst::Request>
656 The request object contains all kinds of request-specific information, like
657 query parameters, cookies, uploads, headers, and more.
659 $c->req->params->{foo};
660 $c->req->cookies->{sessionid};
661 $c->req->headers->content_type;
663 $c->req->uri_with( { page = $pager->next_page } );
665 =item * L<Catalyst::Response>
670 The response is like the request, but contains just response-specific
673 $c->res->body('Hello World');
674 $c->res->status(404);
675 $c->res->redirect('http://oook.de');
683 =item * L<Catalyst::Log>
686 $c->log->debug('Something happened');
687 $c->log->info('Something you should know');
692 $c->stash->{foo} = 'bar';
693 $c->stash->{baz} = {baz => 'qox'};
694 $c->stash->{fred} = [qw/wilma pebbles/];
700 The last of these, the stash, is a universal hash for sharing data among
701 application components. For an example, we return to our 'hello' action:
704 my ( $self, $c ) = @_;
705 $c->stash->{message} = 'Hello World!';
706 $c->forward('show_message');
709 sub show_message : Private {
710 my ( $self, $c ) = @_;
711 $c->res->body( $c->stash->{message} );
714 Note that the stash should be used only for passing data in an
715 individual request cycle; it gets cleared at a new request. If you need
716 to maintain persistent data, use a session. See
717 L<Catalyst::Plugin::Session> for a comprehensive set of
718 Catalyst-friendly session-handling tools.
722 You've already seen some examples of actions in this document:
723 subroutines with C<:Path> and C<:Local> attributes attached.
724 Here, we explain what actions are and how these attributes affect
727 When Catalyst processes a webpage request, it looks for actions to
728 take that will deal with the incoming request and produce a response
729 such as a webpage. You create these actions for your application by
730 writing subroutines within your controller and marking them with
731 special attributes. The attributes, the namespace, and the function
732 name determine when Catalyst will call the subroutine.
734 These action subroutines call certain functions to say what response
735 the webserver will give to the web request. They can also tell
736 Catalyst to run other actions on the request (one example of this is
737 called forwarding the request; this is discussed later).
739 Action subroutines must have a special attribute on to show that they
740 are actions - as well as marking when to call them, this shows that
741 they take a specific set of arguments and behave in a specific way.
742 At startup, Catalyst looks for all the actions in controllers,
743 registers them and creates L<Catalyst::Action> objects describing
744 them. When requests come in, Catalyst chooses which actions should be
745 called to handle the request.
747 (Occasionally, you might use the action objects directly, but in
748 general, when we talk about actions, we're talking about the
749 subroutines in your application that do things to process a request.)
751 You can choose one of several attributes for action subroutines; these
752 specify which requests are processed by that subroutine. Catalyst
753 will look at the URL it is processing, and the actions that it has
754 found, and automatically call the actions it finds that match the
755 circumstances of the request.
757 The URL (for example http://localhost:3000/foo/bar) consists of two
758 parts, the base, describing how to connect to the server
759 (http://localhost:3000/ in this example) and the path, which the
760 server uses to decide what to return (foo/bar). Please note that the
761 trailing slash after the hostname[:port] always belongs to base and
762 not to the path. Catalyst uses only the path part when trying to find
765 Depending on the type of action used, the URLs may match a combination
766 of the controller namespace, the arguments passed to the action
767 attribute, and the name of the subroutine.
771 =item * B<Controller namespaces>
773 The namespace is a modified form of the component's class (package)
774 name. This modified class name excludes the parts that have a
775 pre-defined meaning in Catalyst ("MyApp::Controller" in the above
776 example), replaces "::" with "/", and converts the name to lower case.
777 See L</Components> for a full explanation of the pre-defined meaning
778 of Catalyst component class names.
780 =item * B<Overriding the namespace>
782 Note that C<< __PACKAGE__->config->(namespace => ... ) >> can be used to override the
783 current namespace when matching. So:
785 package MyApp::Controller::Example;
787 would normally use 'example' as its namespace for matching, but if
788 this is specially overridden with
790 __PACKAGE__->config( namespace => 'thing' );
792 it matches using the namespace 'thing' instead.
794 =item * B<Application Wide Actions>
796 MyApp::Controller::Root, as created by the catalyst.pl script, will
797 typically contain actions which are called for the top level of the
798 application (e.g. http://localhost:3000/ ):
800 package MyApp::Controller::Root;
801 use base 'Catalyst::Controller';
803 # Sets the actions in this controller to be registered with no prefix
804 # so they function identically to actions created in MyApp.pm
806 __PACKAGE__->config( namespace => '');
809 my ( $self, $context ) = @_;
810 $context->response->status(404);
811 $context->response->body('404 not found');
819 __PACKAGE__->config( namespace => '' );
821 makes the controller act as if its namespace is empty. As you'll see
822 below, an empty namespace makes many of the URL-matching attributes, such
823 as :Path and :Local match at the start of the URL path (i.e. the
830 Catalyst supports several types of actions. These mainly correspond
831 to ways of matching a URL to an action subroutine. Internally, these
832 matching types are implemented by L<Catalyst::DispatchType>-derived
833 classes; the documentation there can be helpful in seeing how they
836 They will all attempt to match the start of the path. The remainder
837 of the path is passed as arguments.
841 =item * Namespace-prefixed (C<:Local>)
843 package MyApp::Controller::My::Controller;
846 Matches any URL beginning with> http://localhost:3000/my/controller/foo. The namespace and
847 subroutine name together determine the path.
849 =item * Root-level (C<:Global>)
851 package MyApp::Controller::Foo;
856 $c->res->body('sub bar in Controller::Foo triggered on a request for '
862 Matches http://localhost:3000/bar - that is, the action is mapped
863 directly to the method name, ignoring the controller namespace.
865 C<:Global> always matches from the application root: it is simply
866 shorthandfor C<:Path('/methodname')>. C<:Local> is shorthand for
867 C<:Path('methodname')>, which takes the controller namespace as described
870 Usage of the C<Global> handler is rare in all but very old Catalyst
871 applications (e.g. before Catalyst 5.7). The use cases where C<Global>
872 used to make sense are now largely replaced by the C<Chained> dispatch
873 type, or by empty C<Path> declarations on an controller action. C<Global>
874 is still included in Catalyst for backwards compatibility, although
875 legitimate use-cases for it may still exist.
877 =item * Changing handler behaviour: eating arguments (C<:Args>)
879 Args is not an action type per se, but an action modifier - it adds a
880 match restriction to any action it's provided to, additionally
881 requiring as many path parts as are specified for the action to be
882 matched. For example, in MyApp::Controller::Foo,
886 would match any URL starting /foo/bar. To restrict this you can do
888 sub bar :Local :Args(1)
890 to only match URLs starting /foo/bar/* - with one additional path
891 element required after 'bar'.
893 NOTE that adding C<:Args(0)> and missing out :Args completely are B<not>
896 C<:Args(0)> means that no arguments are taken. Thus, the URL and path must
899 No :Args at all means that B<any number> of arguments are taken. Thus, any
900 URL that B<starts with> the controller's path will match. Obviously, this means
901 you cannot chain from an action that does not specify args, as the next action
902 in the chain will be swallowed as an arg to the first!
905 =item * Literal match (C<:Path>)
907 C<Path> actions match things starting with a precise specified path,
910 C<Path> actions without a leading forward slash match a specified path
911 relative to their current namespace. This example matches URLs
912 starting http://localhost:3000/my/controller/foo/bar :
914 package MyApp::Controller::My::Controller;
915 sub bar : Path('foo/bar') { }
917 C<Path> actions B<with> a leading slash ignore their namespace, and
918 match from the start of the URL path. Example:
920 package MyApp::Controller::My::Controller;
921 sub bar : Path('/foo/bar') { }
923 This matches URLs beginning http://localhost:3000/foo/bar.
925 Empty C<Path> definitions match on the namespace only, exactly like
928 package MyApp::Controller::My::Controller;
931 The above code matches http://localhost:3000/my/controller.
933 Actions with the C<:Local> attribute are similarly equivalent to
934 C<:Path('action_name')>:
940 sub foo : Path('foo') { }
942 =item * Pattern-match (C<:Regex> and C<:LocalRegex>)
944 package MyApp::Controller::My::Controller;
945 sub bar : Regex('^item(\d+)/order(\d+)$') { }
947 This matches any URL that matches the pattern in the action key, e.g.
948 http://localhost:3000/item23/order42. The '' around the regexp is
949 optional, but perltidy likes it. :)
951 C<:Regex> matches act globally, i.e. without reference to the namespace
952 from which they are called. So the above will B<not> match
953 http://localhost:3000/my/controller/item23/order42 - use a
954 C<:LocalRegex> action instead.
956 package MyApp::Controller::My::Controller;
957 sub bar : LocalRegex('^widget(\d+)$') { }
959 C<:LocalRegex> actions act locally, i.e. the namespace is matched
960 first. The above example would match urls like
961 http://localhost:3000/my/controller/widget23.
963 If you omit the "C<^>" from either sort of regex, then it will match any depth
966 package MyApp::Controller::Catalog;
967 sub bar : LocalRegex('widget(\d+)$') { }
969 This differs from the previous example in that it will match
970 http://localhost:3000/my/controller/foo/widget23 - and a number of
973 For both C<:LocalRegex> and C<:Regex> actions, if you use capturing
974 parentheses to extract values within the matching URL, those values
975 are available in the C<$c-E<gt>req-E<gt>captures> array. In the above
976 example, "widget23" would capture "23" in the above example, and
977 C<$c-E<gt>req-E<gt>captures-E<gt>[0]> would be "23". If you want to
978 pass arguments at the end of your URL, you must use regex action
979 keys. See L</URL Path Handling> below.
981 =item * Chained handlers (C<:Chained>)
983 Catalyst also provides a method to build and dispatch chains of actions,
986 sub catalog : Chained : CaptureArgs(1) {
987 my ( $self, $c, $arg ) = @_;
991 sub item : Chained('catalog') : Args(1) {
992 my ( $self, $c, $arg ) = @_;
996 to handle a C</catalog/*/item/*> path. Matching actions are called
997 one after another - C<catalog()> gets called and handed one path
998 element, then C<item()> gets called with another one. For further
999 information about this dispatch type, please see
1000 L<Catalyst::DispatchType::Chained>.
1004 sub foo : Private { }
1006 This will never match a URL - it provides a private action which can
1007 be called programmatically from within Catalyst, but is never called
1008 automatically due to the URL being requested.
1010 Catalyst's C<:Private> attribute is exclusive and doesn't work with other
1011 attributes (so will not work combined with C<:Path> or C<:Chained>
1012 attributes, for instance).
1014 Private actions can only be executed explicitly from inside a Catalyst
1015 application. You might do this in your controllers by calling
1016 catalyst methods such as C<forward> or C<detach> to fire them:
1022 See L</Flow Control> for a full explanation of how you can pass
1023 requests on to other actions. Note that, as discussed there, when
1024 forwarding from another component, you must use the absolute path to
1025 the method, so that a private C<bar> method in your
1026 C<MyApp::Controller::Catalog::Order::Process> controller must, if
1027 called from elsewhere, be reached with
1028 C<$c-E<gt>forward('/catalog/order/process/bar')>.
1032 B<Note:> After seeing these examples, you probably wonder what the
1033 point is of defining subroutine names for regex and path
1034 actions. However, every public action is also a private one with a
1035 path corresponding to its namespace and subroutine name, so you have
1036 one unified way of addressing components in your C<forward>s.
1038 =head4 Built-in special actions
1040 If present, the special actions C< index >, C< auto >, C<begin>,
1041 C<end> and C< default > are called at certain points in the request
1044 In response to specific application states, Catalyst will automatically
1045 call these built-in actions in your application class:
1049 =item * B<default : Path>
1051 This is called when no other action matches. It could be used, for
1052 example, for displaying a generic frontpage for the main app, or an
1053 error page for individual controllers. B<Note>: in older Catalyst
1054 applications you will see C<default : Private> which is roughly
1055 speaking equivalent.
1058 =item * B<index : Path : Args (0) >
1060 C<index> is much like C<default> except that it takes no arguments and
1061 it is weighted slightly higher in the matching process. It is useful
1062 as a static entry point to a controller, e.g. to have a static welcome
1063 page. Note that it's also weighted higher than Path. Actually the sub
1064 name C<index> can be called anything you want. The sub attributes are
1065 what determines the behaviour of the action. B<Note>: in older
1066 Catalyst applications, you will see C<index : Private> used, which is
1067 roughly speaking equivalent.
1069 =item * B<begin : Private>
1071 Called at the beginning of a request, once the controller that will
1072 run has been identified, but before any URL-matching actions are
1073 called. Catalyst will call the C<begin> function in the controller
1074 which contains the action matching the URL.
1076 =item * B<end : Private>
1078 Called at the end of a request, after all URL-matching actions are called.
1079 Catalyst will call the C<end> function in the controller
1080 which contains the action matching the URL.
1082 =item * B<auto : Private>
1084 In addition to the normal built-in actions, you have a special action
1085 for making chains, C<auto>. C<auto> actions will be run after any
1086 C<begin>, but before your URL-matching action is processed. Unlike the other
1087 built-ins, multiple C<auto> actions can be called; they will be
1088 called in turn, starting with the application class and going through
1089 to the most specific class.
1093 =head4 Built-in actions in controllers/autochaining
1095 package MyApp::Controller::Foo;
1096 sub begin : Private { }
1097 sub default : Path { }
1100 You can define built-in actions within your controllers as well as on
1101 your application class. In other words, for each of the three built-in
1102 actions above, only one will be run in any request cycle. Thus, if
1103 C<MyApp::Controller::Catalog::begin> exists, it will be run in place
1104 of C<MyApp::begin> if you're in the C<catalog> namespace, and
1105 C<MyApp::Controller::Catalog::Order::begin> would override this in
1108 sub auto : Private { }
1110 C<auto>, however, doesn't override like this: providing they exist,
1111 C<MyApp::Controller::Root::auto>, C<MyApp::Controller::Catalog::auto> and
1112 C<MyApp::Catalog::Order::auto> would be called in turn.
1114 Here are some examples of the order in which the various built-ins
1119 =item for a request for C</foo/foo>
1121 MyApp::Controller::Foo::auto
1122 MyApp::Controller::Foo::default # in the absence of MyApp::Controller::Foo::Foo
1123 MyApp::Controller::Foo::end
1125 =item for a request for C</foo/bar/foo>
1127 MyApp::Controller::Foo::Bar::begin
1128 MyApp::Controller::Foo::auto
1129 MyApp::Controller::Foo::Bar::auto
1130 MyApp::Controller::Foo::Bar::default # for MyApp::Controller::Foo::Bar::foo
1131 MyApp::Controller::Foo::Bar::end
1135 The C<auto> action is also distinguished by the fact that you can break
1136 out of the processing chain by returning 0. If an C<auto> action returns
1137 0, any remaining actions will be skipped, except for C<end>. So, for the
1138 request above, if the first auto returns false, the chain would look
1143 =item for a request for C</foo/bar/foo> where first C<auto> returns
1146 MyApp::Controller::Foo::Bar::begin
1147 MyApp::Controller::Foo::auto # returns false, skips some calls:
1148 # MyApp::Controller::Foo::Bar::auto - never called
1149 # MyApp::Controller::Foo::Bar::foo - never called
1150 MyApp::Controller::Foo::Bar::end
1152 You can also C<die> in the auto action; in that case, the request will
1153 go straight to the finalize stage, without processing further
1154 actions. So in the above example, C<MyApp::Controller::Foo::Bar::end>
1159 An example of why one might use C<auto> is an authentication action:
1160 you could set up a C<auto> action to handle authentication in your
1161 application class (which will always be called first), and if
1162 authentication fails, returning 0 would skip any remaining methods for
1165 B<Note:> Looking at it another way, C<auto> actions have to return a
1166 true value to continue processing!
1168 =head4 URL Path Handling
1170 You can pass arguments as part of the URL path, separated with forward
1171 slashes (/). If the action is a Regex or LocalRegex, the '$' anchor
1172 must be used. For example, suppose you want to handle
1173 C</foo/$bar/$baz>, where C<$bar> and C<$baz> may vary:
1175 sub foo : Regex('^foo$') { my ($self, $context, $bar, $baz) = @_; }
1177 But what if you also defined actions for C</foo/boo> and C</foo/boo/hoo>?
1179 sub boo : Path('foo/boo') { .. }
1180 sub hoo : Path('foo/boo/hoo') { .. }
1182 Catalyst matches actions in most specific to least specific order - that is, whatever matches the most pieces of the path wins:
1186 /foo # might be /foo/bar/baz but won't be /foo/boo/hoo
1188 So Catalyst would never mistakenly dispatch the first two URLs to the
1191 If a Regex or LocalRegex action doesn't use the '$' anchor, the action will
1192 still match a URL containing arguments; however the arguments won't be
1193 available via C<@_>, because the Regex will 'eat' them.
1195 Beware! If you write two matchers, that match the same path, with the
1196 same specificity (that is, they match the same quantity of the path),
1197 there's no guarantee which will actually get called. Non-regex
1198 matchers get tried first, followed by regex ones, but if you have, for
1201 package MyApp::Controller::Root;
1203 sub match1 :Path('/a/b') { }
1205 package MyApp::Controller::A;
1207 sub b :Local { } # Matches /a/b
1209 then Catalyst will call the one it finds first. In summary, Don't Do
1212 =head4 Query Parameter Processing
1214 Parameters passed in the URL query string are handled with methods in
1215 the L<Catalyst::Request> class. The C<param> method is functionally
1216 equivalent to the C<param> method of C<CGI.pm> and can be used in
1217 modules that require this.
1219 # http://localhost:3000/catalog/view/?category=hardware&page=3
1220 my $category = $c->req->param('category');
1221 my $current_page = $c->req->param('page') || 1;
1223 # multiple values for single parameter name
1224 my @values = $c->req->param('scrolling_list');
1226 # DFV requires a CGI.pm-like input hash
1227 my $results = Data::FormValidator->check($c->req->params, \%dfv_profile);
1231 You control the application flow with the C<forward> method, which
1232 accepts the key of an action to execute. This can be an action in the
1233 same or another Catalyst controller, or a Class name, optionally
1234 followed by a method name. After a C<forward>, the control flow will
1235 return to the method from which the C<forward> was issued.
1237 A C<forward> is similar to a method call. The main differences are that
1238 it wraps the call in an C<eval> to allow exception handling; it
1239 automatically passes along the context object (C<$c> or C<$context>);
1240 and it allows profiling of each call (displayed in the log with
1243 sub hello : Global {
1244 my ( $self, $c ) = @_;
1245 $c->stash->{message} = 'Hello World!';
1246 $c->forward('check_message'); # $c is automatically included
1249 sub check_message : Private {
1250 my ( $self, $c ) = @_;
1251 return unless $c->stash->{message};
1252 $c->forward('show_message');
1255 sub show_message : Private {
1256 my ( $self, $c ) = @_;
1257 $c->res->body( $c->stash->{message} );
1260 A C<forward> does not create a new request, so your request object
1261 (C<$c-E<gt>req>) will remain unchanged. This is a key difference between
1262 using C<forward> and issuing a redirect.
1264 You can pass new arguments to a C<forward> by adding them
1265 in an anonymous array. In this case C<$c-E<gt>req-E<gt>args>
1266 will be changed for the duration of the C<forward> only; upon
1267 return, the original value of C<$c-E<gt>req-E<gt>args> will
1270 sub hello : Global {
1271 my ( $self, $c ) = @_;
1272 $c->stash->{message} = 'Hello World!';
1273 $c->forward('check_message',[qw/test1/]);
1274 # now $c->req->args is back to what it was before
1277 sub check_message : Action {
1278 my ( $self, $c, $first_argument ) = @_;
1279 my $also_first_argument = $c->req->args->[0]; # now = 'test1'
1283 As you can see from these examples, you can just use the method name as
1284 long as you are referring to methods in the same controller. If you want
1285 to forward to a method in another controller, or the main application,
1286 you will have to refer to the method by absolute path.
1288 $c->forward('/my/controller/action');
1289 $c->forward('/default'); # calls default in main application
1291 You can also forward to classes and methods.
1293 sub hello : Global {
1294 my ( $self, $c ) = @_;
1295 $c->forward(qw/MyApp::View:Hello say_hello/);
1299 my ( $self, $c ) = @_;
1300 $c->forward('MyApp::Model::Hello'); # no method: will try 'process'
1303 package MyApp::View::Hello;
1306 my ( $self, $c ) = @_;
1307 $c->res->body('Hello World!');
1311 my ( $self, $c ) = @_;
1312 $c->res->body('Goodbye World!');
1315 This mechanism is used by L<Catalyst::Action::RenderView> to forward
1316 to the C<process> method in a view class.
1318 It should be noted that whilst forward is useful, it is not the only way
1319 of calling other code in Catalyst. Forward just gives you stats in the debug
1320 screen, wraps the code you're calling in an exception handler and localises
1321 C<< $c->request->args >>.
1323 If you don't want or need these features then it's perfectly acceptable
1324 (and faster) to do something like this:
1326 sub hello : Global {
1327 my ( $self, $c ) = @_;
1328 $c->stash->{message} = 'Hello World!';
1329 $self->check_message( $c, 'test1' );
1333 my ( $self, $c, $first_argument ) = @_;
1337 Note that C<forward> returns to the calling action and continues
1338 processing after the action finishes. If you want all further processing
1339 in the calling action to stop, use C<detach> instead, which will execute
1340 the C<detach>ed action and not return to the calling sub. In both cases,
1341 Catalyst will automatically try to call process() if you omit the
1346 Catalyst has a built-in http server for testing or local
1347 deployment. (Later, you can easily use a more powerful server, for
1348 example Apache/mod_perl or FastCGI, in a production environment.)
1350 Start your application on the command line...
1352 script/myapp_server.pl
1354 ...then visit http://localhost:3000/ in a browser to view the output.
1356 You can also do it all from the command line:
1358 script/myapp_test.pl http://localhost/
1360 Catalyst has a number of tools for actual regression testing of
1361 applications. The helper scripts will automatically generate basic tests
1362 that can be extended as you develop your project. To write your own
1363 comprehensive test scripts, L<Test::WWW::Mechanize::Catalyst> is an
1366 For more testing ideas, see L<Catalyst::Manual::Tutorial::Testing>.
1374 =item * L<Catalyst::Manual::About>
1376 =item * L<Catalyst::Manual::Tutorial>
1386 Join #catalyst on irc.perl.org.
1387 Join #catalyst-dev on irc.perl.org to help with development.
1391 http://lists.scsys.co.uk/mailman/listinfo/catalyst
1392 http://lists.scsys.co.uk/mailman/listinfo/catalyst-dev
1396 http://dev.catalystframework.org/wiki
1400 http://dev.catalystframework.org/wiki/faq
1404 Catalyst Contributors, see Catalyst.pm
1408 This library is free software. You can redistribute it and/or modify it under
1409 the same terms as Perl itself.