3 Catalyst::Manual::Intro - Introduction to Catalyst
7 This is a brief introduction to Catalyst. It explains the most important
8 features of how Catalyst works and shows how to get a simple application
9 up and running quickly. For an introduction (without code) to Catalyst
10 itself, and why you should be using it, see L<Catalyst::Manual::About>.
11 For a systematic step-by-step introduction to writing an application
12 with Catalyst, see L<Catalyst::Manual::Tutorial>.
14 =head2 What is Catalyst?
16 Catalyst is an elegant web application framework, extremely flexible yet
17 extremely simple. It's similar to Ruby on Rails, Spring (Java), and
18 L<Maypole>, upon which it was originally based. Its most important
19 design philosphy is to provide easy access to all the tools you need to
20 develop web applications, with few restrictions on how you need to use
21 these tools. Under Catalyst, it is always possible to do things in a
22 different way. However, this does mean that it is always possible to do
23 things in a different way. Other web frameworks are simpler to use and
24 easy to get up and running, but achieve this by locking the programmer
25 into a single set of tools. Catalyst's emphasis on flexibility means
26 that you have to think more to use it. We view this as a feature.
30 Catalyst follows the Model-View-Controller (MVC) design pattern,
31 allowing you to easily separate concerns, like content, presentation,
32 and flow control, into separate modules. This separation allows you to
33 modify code that handles one concern without affecting code that handles
34 the others. Catalyst promotes the re-use of existing Perl modules that
35 already handle common web application concerns well.
37 Here's how the M, V, and C map to those concerns, with examples of
38 well-known Perl modules you may want to use for each.
44 Access and modify content (data). L<DBIx::Class>, L<Class::DBI>,
45 L<Xapian>, L<Net::LDAP>...
49 Present content to the user. L<Template Toolkit|Template>,
50 L<Mason|HTML::Mason>, L<HTML::Template>...
54 Control the whole request phase, check parameters, dispatch actions, flow
55 control. Catalyst itself!
59 If you're unfamiliar with MVC and design patterns, you may want to
60 check out the original book on the subject, I<Design Patterns>, by
61 Gamma, Helm, Johnson, and Vlissides, also known as the Gang of Four
62 (GoF). Many, many web application frameworks are based on MVC, which
63 is becoming a popular design method for web applications.
67 Catalyst is much more flexible than many other frameworks. We'll talk
68 more about this later, but rest assured you can use your favorite Perl
69 modules with Catalyst.
73 =item * B<Multiple Models, Views, and Controllers>
75 To build a Catalyst application, you handle each type of concern inside
76 special modules called L</Components>. Often this code will be very
77 simple, just calling out to Perl modules like those listed above under
78 L</MVC>. Catalyst handles these components in a very flexible way. Use
79 as many Models, Views, and Controllers as you like, using as many
80 different Perl modules as you like, all in the same application. Want to
81 manipulate multiple databases, and retrieve some data via LDAP? No
82 problem. Want to present data from the same Model using L<Template
83 Toolkit|Template> and L<PDF::Template>? Easy.
85 =item * B<Reuseable Components>
87 Not only does Catalyst promote the re-use of already existing Perl
88 modules, it also allows you to re-use your Catalyst components in
89 multiple Catalyst applications.
91 =item * B<Unrestrained URL-to-Action Dispatching>
93 Catalyst allows you to dispatch any URLs to any application L</Actions>,
94 even through regular expressions! Unlike most other frameworks, it
95 doesn't require mod_rewrite or class and method names in URLs.
97 With Catalyst you register your actions and address them directly. For
101 my ( $self, $context ) = @_;
102 $context->response->body('Hello World!');
105 Now http://localhost:3000/hello prints "Hello World!".
107 =item * B<Support for CGI, mod_perl, Apache::Request>
109 Use L<Catalyst::Engine::Apache> or L<Catalyst::Engine::CGI>.
115 The best part is that Catalyst implements all this flexibility in a very
120 =item * B<Building Block Interface>
122 Components interoperate very smoothly. For example, Catalyst
123 automatically makes a L</Context> object available to every
124 component. Via the context, you can access the request object, share
125 data between components, and control the flow of your
126 application. Building a Catalyst application feels a lot like snapping
127 together toy building blocks, and everything just works.
129 =item * B<Component Auto-Discovery>
131 No need to C<use> all of your components. Catalyst automatically finds
134 =item * B<Pre-Built Components for Popular Modules>
136 See L<Catalyst::Model::DBIC::Schema> for L<DBIx::Class>, or
137 L<Catalyst::View::TT> for L<Template Toolkit|Template>.
139 =item * B<Built-in Test Framework>
141 Catalyst comes with a built-in, lightweight http server and test
142 framework, making it easy to test applications from the command line.
144 =item * B<Helper Scripts>
146 Catalyst provides helper scripts to quickly generate running starter
147 code for components and unit tests. See L<Catalyst::Helper>.
153 Here's how to install Catalyst and get a simple application up and
154 running, using the helper scripts described above.
158 $ perl -MCPAN -e 'install Task::Catalyst'
165 $ script/myapp_create.pl controller Library::Login
169 $ script/myapp_server.pl
171 Now visit these locations with your favorite browser or user agent to see
174 (NOTE: Although we create a controller here, we don't actually use it.
175 Both of these URLs should take you to the welcome page.)
180 =item http://localhost:3000/
182 =item http://localhost:3000/library/login/
190 Let's see how Catalyst works, by taking a closer look at the components
191 and other parts of a Catalyst application.
193 =head3 Application Class
195 In addition to the Model, View, and Controller components, there's a
196 single class that represents your application itself. This is where you
197 configure your application, load plugins, and extend Catalyst.
202 use Catalyst qw/-Debug/;
205 name => 'My Application',
207 # You can put anything else you want in here:
208 my_configuration_variable => 'something',
212 In older versions of Catalyst, the application class was where you put
213 global actions. However, as of version 5.66, the recommended practice is
214 to place such actions in a special Root controller (see #####, below),
215 to avoid namespace collisions.
221 The name of your application.
225 Optionally, you can specify a B<root> parameter for templates and static
226 data. If omitted, Catalyst will try to auto-detect the directory's
227 location. You can define as many parameters as you want for plugins or
228 whatever you need. You can access them anywhere in your application via
229 C<$context-E<gt>config-E<gt>{$param_name}>.
231 ###### We need a short section on configuration here.
235 Catalyst automatically blesses a Context object into your application
236 class and makes it available everywhere in your application. Use the
237 Context to directly interact with Catalyst and glue your L</Components>
238 together. For example, if you need to use the Context from within a
239 Template Toolkit template, it's already there:
241 <h1>Welcome to [% c.config.name %]!</h1>
243 As illustrated in our URL-to-Action dispatching example, the Context is
244 always the second method parameter, behind the Component object
245 reference or class name itself. Previously we called it C<$context> for
246 clarity, but most Catalyst developers just call it C<$c>:
249 my ( $self, $c ) = @_;
250 $c->res->body('Hello World!');
253 The Context contains several important objects:
257 =item * L<Catalyst::Request>
262 The request object contains all kinds of request-specific information, like
263 query parameters, cookies, uploads, headers, and more.
265 $c->req->params->{foo};
266 $c->req->cookies->{sessionid};
267 $c->req->headers->content_type;
270 =item * L<Catalyst::Response>
275 The response is like the request, but contains just response-specific
278 $c->res->body('Hello World');
279 $c->res->status(404);
280 $c->res->redirect('http://oook.de');
282 =item * L<Catalyst::Config>
288 =item * L<Catalyst::Log>
291 $c->log->debug('Something happened');
292 $c->log->info('Something you should know');
297 $c->stash->{foo} = 'bar';
298 $c->stash->{baz} = {baz => 'qox'};
299 $c->stash->{fred} = [qw/ wilma pebbles/];
305 The last of these, the stash, is a universal hash for sharing data among
306 application components. For an example, we return to our 'hello' action:
309 my ( $self, $c ) = @_;
310 $c->stash->{message} = 'Hello World!';
311 $c->forward('show_message');
314 sub show_message : Private {
315 my ( $self, $c ) = @_;
316 $c->res->body( $c->stash->{message} );
319 Note that the stash should be used only for passing data in an
320 individual request cycle; it gets cleared at a new request. If you need
321 to maintain more persistent data, use a session.
325 A Catalyst controller is defined by its actions. An action is a
326 subroutine with a special attribute. You've already seen some examples
327 of actions in this document. The URL (for example
328 http://localhost.3000/foo/bar) consists of two parts, the base
329 (http://localhost:3000/ in this example) and the path (foo/bar). Please
330 note that the trailing slash after the hostname[:port] always belongs to
331 base and not to the action.
335 =item * B<Application Wide Actions>
337 Actions which are called at the root level of the application
338 (e.g. http://localhost:3000/ ) go in MyApp::Controller::Root, like
341 package MyApp::Controller::Root;
342 use base 'Catalyst::Controller';
343 # Sets the actions in this controller to be registered with no prefix
344 # so they function identically to actions created in MyApp.pm
345 __PACKAGE__->config->{namespace} = '';
346 sub default : Private {
347 my ( $self, $context ) = @_;
348 $context->response->body('Catalyst rocks!');
356 Catalyst supports several types of actions:
360 =item * B<Literal> (B<Path> actions)
362 package MyApp::Controller::My::Controller;
363 sub bar : Path('foo/bar') { }
365 Literal C<Path> actions will act relative to their current
366 namespace. The above example matches only
367 http://localhost:3000/my/controller/foo/bar. If you start your path with
368 a forward slash, it will match from the root. Example:
370 package MyApp::Controller::My::Controller;
371 sub bar : Path('/foo/bar') { }
373 Matches only http://localhost:3000/foo/bar.
375 package MyApp::Controller::My::Controller;
378 By leaving the C<Path> definition empty, it will match on the namespace
379 root. The above code matches http://localhost:3000/my/controller.
383 sub bar : Regex('^item(\d+)/order(\d+)$') { }
385 Matches any URL that matches the pattern in the action key, e.g.
386 http://localhost:3000/item23/order42. The '' around the regexp is
387 optional, but perltidy likes it. :)
389 Regex matches act globally, i.e. without reference to the namespace from
390 which it is called, so that a C<bar> method in the
391 C<MyApp::Controller::Catalog::Order::Process> namespace won't match any
392 form of C<bar>, C<Catalog>, C<Order>, or C<Process> unless you
393 explicitly put this in the regex. To achieve the above, you should
394 consider using a C<LocalRegex> action.
396 =item * B<LocalRegex>
398 sub bar : LocalRegex('^widget(\d+)$') { }
400 LocalRegex actions act locally. If you were to use C<bar> in
401 C<MyApp::Controller::Catalog>, the above example would match urls like
402 http://localhost:3000/catalog/widget23.
404 If you omit the "C<^>" from your regex, then it will match any depth
405 from the controller and not immediately off of the controller name. The
406 following example differs from the above code in that it will match
407 http://localhost:3000/catalog/foo/widget23 as well.
409 package MyApp::Controller::Catalog;
410 sub bar : LocalRegex('widget(\d+)$') { }
412 For both LocalRegex and Regex actions, if you use capturing parentheses
413 to extract values within the matching URL, those values are available in
414 the C<$c-E<gt>req-E<gt>captures> array. In the above example, "widget23"
415 would capture "23" in the above example, and
416 C<$c-E<gt>req-E<gt>captures-E<gt>[0]> would be "23". If you want to pass
417 arguments at the end of your URL, you must use regex action keys. See
418 L</URL Path Handling> below.
420 =item * B<Top-level> (B<Global>)
422 package MyApp::Controller::Foo;
425 Matches http://localhost:3000/foo. The function name is mapped
426 directly to the application base. You can provide an equivalent
427 function in this case by doing the following:
429 package MyApp::Controller::Root
432 =item * B<Namespace-Prefixed> (B<Local>)
434 package MyApp::Controller::My::Controller;
437 Matches http://localhost:3000/my/controller/foo.
439 This action type indicates that the matching URL must be prefixed with a
440 modified form of the component's class (package) name. This modified
441 class name excludes the parts that have a pre-defined meaning in
442 Catalyst ("MyApp::Controller" in the above example), replaces "::" with
443 "/", and converts the name to lower case. See L</Components> for a full
444 explanation of the pre-defined meaning of Catalyst component class
449 Catalyst also provides a method to build and dispatch chains of actions,
452 sub foo : Chained : CaptureArgs(1) {
453 my ( $self, $c, $arg ) = @_;
457 sub bar : Chained('foo') : Args(1) {
458 my ( $self, $c, $arg ) = @_;
462 to handle a C</foo/*/bar/*> path. For more information about this dispatch
463 type, please read L<Catalyst::DispatchType::Chained>.
467 sub foo : Private { }
469 Matches no URL, and cannot be executed by requesting a URL that
470 corresponds to the action key. Private actions can be executed only
471 inside a Catalyst application, by calling the C<forward> method:
475 See L</Flow Control> for a full explanation of C<forward>. Note that, as
476 discussed there, when forwarding from another component, you must use
477 the absolute path to the method, so that a private C<bar> method in your
478 C<MyApp::Controller::Catalog::Order::Process> controller must, if called
479 from elsewhere, be reached with
480 C<$c-E<gt>forward('/catalog/order/process/bar')>.
484 Args is not an action type per se, but an action modifier - it adds a match
485 restriction to any action it's provided to, requiring only as many path parts
486 as are specified for the action to be valid - for example in
487 MyApp::Controller::Foo,
491 would match any URL starting /foo/bar/. To restrict this you can do
493 sub bar :Local :Args(1)
495 to only match /foo/bar/*/
499 B<Note:> After seeing these examples, you probably wonder what the point
500 is of defining names for regex and path actions. Every public action is
501 also a private one, so you have one unified way of addressing components
504 =head4 Built-in Private Actions
506 In response to specific application states, Catalyst will automatically
507 call these built-in private actions in your application class:
511 =item * B<default : Private>
513 Called when no other action matches. Could be used, for example, for
514 displaying a generic frontpage for the main app, or an error page for
515 individual controllers.
517 If C<default> isn't acting how you would expect, look at using a
518 L</Literal> C<Path> action (with an empty path string). The difference is
519 that C<Path> takes arguments relative from the namespace and C<default>
520 I<always> takes arguments relative from the root, regardless of what
523 =item * B<index : Private>
525 C<index> is much like C<default> except that it takes no arguments
526 and it is weighted slightly higher in the matching process. It is
527 useful as a static entry point to a controller, e.g. to have a static
528 welcome page. Note that it's also weighted higher than Path.
530 =item * B<begin : Private>
532 Called at the beginning of a request, before any matching actions are
535 =item * B<end : Private>
537 Called at the end of a request, after all matching actions are called.
541 =head4 Built-in actions in controllers/autochaining
543 Package MyApp::Controller::Foo;
544 sub begin : Private { }
545 sub default : Private { }
546 sub auto : Private { }
548 You can define built-in private actions within your controllers as
549 well. The actions will override the ones in less-specific controllers,
550 or your application class. In other words, for each of the three
551 built-in private actions, only one will be run in any request
552 cycle. Thus, if C<MyApp::Controller::Catalog::begin> exists, it will be
553 run in place of C<MyApp::begin> if you're in the C<catalog> namespace,
554 and C<MyApp::Controller::Catalog::Order::begin> would override this in
557 In addition to the normal built-in actions, you have a special action
558 for making chains, C<auto>. Such C<auto> actions will be run after any
559 C<begin>, but before your action is processed. Unlike the other
560 built-ins, C<auto> actions I<do not> override each other; they will be
561 called in turn, starting with the application class and going through to
562 the I<most> specific class. I<This is the reverse of the order in which
563 the normal built-ins override each other>.
565 Here are some examples of the order in which the various built-ins
570 =item for a request for C</foo/foo>
574 MyApp::Controller::Foo::default # in the absence of MyApp::Controller::Foo::Foo
577 =item for a request for C</foo/bar/foo>
579 MyApp::Controller::Foo::Bar::begin
581 MyApp::Controller::Foo::auto
582 MyApp::Controller::Foo::Bar::auto
583 MyApp::Controller::Foo::Bar::default # for MyApp::Controller::Foo::Bar::foo
584 MyApp::Controller::Foo::Bar::end
588 The C<auto> action is also distinguished by the fact that you can break
589 out of the processing chain by returning 0. If an C<auto> action returns
590 0, any remaining actions will be skipped, except for C<end>. So, for the
591 request above, if the first auto returns false, the chain would look
596 =item for a request for C</foo/bar/foo> where first C<auto> returns
599 MyApp::Controller::Foo::Bar::begin
601 MyApp::Controller::Foo::Bar::end
605 An example of why one might use this is an authentication action: you
606 could set up a C<auto> action to handle authentication in your
607 application class (which will always be called first), and if
608 authentication fails, returning 0 would skip any remaining methods
611 B<Note:> Looking at it another way, C<auto> actions have to return a
612 true value to continue processing! You can also C<die> in the autochain
613 action; in that case, the request will go straight to the finalize
614 stage, without processing further actions.
616 =head4 URL Path Handling
618 You can pass variable arguments as part of the URL path, separated with
619 forward slashes (/). If the action is a Regex or LocalRegex, the '$' anchor
620 must be used. For example, suppose you want to handle C</foo/$bar/$baz>,
621 where C<$bar> and C<$baz> may vary:
623 sub foo : Regex('^foo$') { my ($self, $context, $bar, $baz) = @_; }
625 But what if you also defined actions for C</foo/boo> and C</foo/boo/hoo>?
627 sub boo : Path('foo/boo') { .. }
628 sub hoo : Path('foo/boo/hoo') { .. }
630 Catalyst matches actions in most specific to least specific order:
634 /foo # might be /foo/bar/baz but won't be /foo/boo/hoo
636 So Catalyst would never mistakenly dispatch the first two URLs to the
639 If a Regex or LocalRegex action doesn't use the '$' anchor, the action will
640 still match a URL containing arguments, however the arguments won't be
643 =head4 Parameter Processing
645 Parameters passed in the URL query string are handled with methods in
646 the L<Catalyst::Request> class. The C<param> method is functionally
647 equivalent to the C<param> method of C<CGI.pm> and can be used in
648 modules that require this.
650 # http://localhost:3000/catalog/view/?category=hardware&page=3
651 my $category = $c->req->param('category');
652 my $current_page = $c->req->param('page') || 1;
654 # multiple values for single parameter name
655 my @values = $c->req->param('scrolling_list');
657 # DFV requires a CGI.pm-like input hash
658 my $results = Data::FormValidator->check($c->req->params, \%dfv_profile);
662 You control the application flow with the C<forward> method, which
663 accepts the key of an action to execute. This can be an action in the
664 same or another Catalyst controller, or a Class name, optionally
665 followed by a method name. After a C<forward>, the control flow will
666 return to the method from which the C<forward> was issued.
668 A C<forward> is similar to a method call. The main differences are that
669 it wraps the call in an C<eval> to allow exception handling; it
670 automatically passes along the context object (C<$c> or C<$context>);
671 and it allows profiling of each call (displayed in the log with
675 my ( $self, $c ) = @_;
676 $c->stash->{message} = 'Hello World!';
677 $c->forward('check_message'); # $c is automatically included
680 sub check_message : Private {
681 my ( $self, $c ) = @_;
682 return unless $c->stash->{message};
683 $c->forward('show_message');
686 sub show_message : Private {
687 my ( $self, $c ) = @_;
688 $c->res->body( $c->stash->{message} );
691 A C<forward> does not create a new request, so your request object
692 (C<$c-E<gt>req>) will remain unchanged. This is a key difference between
693 using C<forward> and issuing a redirect.
695 You can pass new arguments to a C<forward> by adding them
696 in an anonymous array. In this case C<$c-E<gt>req-E<gt>args>
697 will be changed for the duration of the C<forward> only; upon
698 return, the original value of C<$c-E<gt>req-E<gt>args> will
702 my ( $self, $c ) = @_;
703 $c->stash->{message} = 'Hello World!';
704 $c->forward('check_message',[qw/test1/]);
705 # now $c->req->args is back to what it was before
708 sub check_message : Private {
709 my ( $self, $c ) = @_;
710 my $first_argument = $c->req->args->[0]; # now = 'test1'
714 As you can see from these examples, you can just use the method name as
715 long as you are referring to methods in the same controller. If you want
716 to forward to a method in another controller, or the main application,
717 you will have to refer to the method by absolute path.
719 $c->forward('/my/controller/action');
720 $c->forward('/default'); # calls default in main application
722 Here are some examples of how to forward to classes and methods.
725 my ( $self, $c ) = @_;
726 $c->forward(qw/MyApp::Model::Hello say_hello/);
730 my ( $self, $c ) = @_;
731 $c->forward('MyApp::Model::Hello'); # no method: will try 'process'
734 package MyApp::Model::Hello;
737 my ( $self, $c ) = @_;
738 $c->res->body('Hello World!');
742 my ( $self, $c ) = @_;
743 $c->res->body('Goodbye World!');
746 Note that C<forward> returns to the calling action and continues
747 processing after the action finishes. If you want all further processing
748 in the calling action to stop, use C<detach> instead, which will execute
749 the C<detach>ed action and not return to the calling sub. In both cases,
750 Catalyst will automatically try to call process() if you omit the
755 Catalyst has an uncommonly flexible component system. You can define as
756 many L</Models>, L</Views>, and L</Controllers> as you like.
758 All components must inherit from L<Catalyst::Base>, which provides a
759 simple class structure and some common class methods like C<config> and
760 C<new> (constructor).
762 package MyApp::Controller::Catalog;
765 use base 'Catalyst::Base';
767 __PACKAGE__->config( foo => 'bar' );
771 You don't have to C<use> or otherwise register Models, Views, and
772 Controllers. Catalyst automatically discovers and instantiates them
773 when you call C<setup> in the main application. All you need to do is
774 put them in directories named for each Component type. Notice that you
775 can use a terse alias for each one.
779 =item * B<MyApp/Model/>
783 =item * B<MyApp/View/>
787 =item * B<MyApp/Controller/>
793 In older versions of Catalyst, the recommended practice (and the one
794 automatically created by helper scripts) was to name the directories
795 C<M/>, C<V/>, and C<C/>. Though these still work, we now recommend
796 the use of the full names.
800 To show how to define views, we'll use an already-existing base class for the
801 L<Template Toolkit|Template>, L<Catalyst::View::TT>. All we need to do is
802 inherit from this class:
804 package MyApp::View::TT;
807 use base 'Catalyst::View::TT';
811 (You can also generate this automatically by using the helper script:
813 script/myapp_create.pl view TT TT
815 where the first C<TT> tells the script that the name of the view should
816 be C<TT>, and the second that it should be a Template Toolkit view.)
818 This gives us a process() method and we can now just do
819 $c->forward('MyApp::View::TT') to render our templates. The base class
820 makes process() implicit, so we don't have to say
821 C<$c-E<gt>forward(qw/MyApp::View::TT process/)>.
824 my ( $self, $c ) = @_;
825 $c->stash->{template} = 'hello.tt';
829 my ( $self, $c ) = @_;
830 $c->forward('MyApp::View::TT');
833 You normally render templates at the end of a request, so it's a perfect
834 use for the global C<end> action.
836 Also, be sure to put the template under the directory specified in
837 C<$c-E<gt>config-E<gt>{root}>, or you'll be forced to look at our
838 eyecandy debug screen. ;)
842 To show how to define models, again we'll use an already-existing base
843 class, this time for L<DBIx::Class>: L<Catalyst::Model::DBIC::Schema>.
844 We'll also need L<DBIx::Class::Schema::Loader>.
846 But first, we need a database.
850 id INTEGER PRIMARY KEY,
855 id INTEGER PRIMARY KEY,
856 foo INTEGER REFERENCES foo,
860 INSERT INTO foo (data) VALUES ('TEST!');
863 % sqlite /tmp/myapp.db < myapp.sql
865 Now we can create a DBIC::SchemaLoader component for this database.
867 script/myapp_create.pl model DBIC DBIC::SchemaLoader 'dbi:SQLite:/tmp/myapp.db'
869 L<DBIx::Class::Schema::Loader> automatically loads table layouts and
870 relationships. Use the stash to pass data to your templates.
872 We add the following to MyApp/Controller/Root.pm
875 my ( $self, $c, $id ) = @_;
877 $c->stash->{item} = $c->model('DBIC::Foo')->find($id);
883 my ( $self, $c ) = @_;
885 $c->stash->{template} ||= 'index.tt';
886 $c->forward( $c->view('TT') );
889 We then create a new template file "root/index.tt" containing:
891 The Id's data is [% item.data %]
893 Models do not have to be part of your Catalyst application; you
894 can always call an outside module that serves as your Model:
898 my ( $self, $c ) = @_;
900 $c->stash->{template} = 'list.tt';
902 use Some::Outside::DBIC::Module;
903 my @records = Some::Outside::DBIC::Module->search({
907 $c->stash->{records} = \@records;
910 But by using a Model that is part of your Catalyst application, you gain
911 several things: you don't have to C<use> each component, Catalyst will
912 find and load it automatically at compile-time; you can C<forward> to
913 the module, which can only be done to Catalyst components; and only
914 Catalyst components can be fetched with
915 C<$c-E<gt>model('SomeModel')>.
917 Happily, since many people have existing Model classes that they
918 would like to use with Catalyst (or, conversely, they want to
919 write Catalyst models that can be used outside of Catalyst, e.g.
920 in a cron job), it's trivial to write a simple component in
921 Catalyst that slurps in an outside Model:
923 package MyApp::Model::DB;
924 use base qw/Catalyst::Model::DBIC::Schema/;
926 schema_class => 'Some::DBIC::Schema',
927 connect_info => ['dbi:SQLite:foo.db', '', '', {AutoCommit=>1}]
931 and that's it! Now C<Some::DBIC::Schema> is part of your
932 Cat app as C<MyApp::Model::DB>.
936 Multiple controllers are a good way to separate logical domains of your
939 package MyApp::Controller::Login;
941 use base qw/Catalyst::Controller/;
943 sub sign_in : Path("sign-in") { }
944 sub new_password : Path("new-password") { }
945 sub sign_out : Path("sign-out") { }
947 package MyApp::Controller::Catalog;
949 use base qw/Catalyst::Controller/;
954 package MyApp::Controller::Cart;
956 use base qw/Catalyst::Controller/;
959 sub update : Local { }
960 sub order : Local { }
962 Note that you can also supply attributes via the Controller's config so long
963 as you have at least one attribute on a subref to be exported (:Action is
964 commonly used for this) - for example the following is equivalent to the same
967 package MyApp::Controller::Login;
969 use base qw/Catalyst::Controller/;
973 'sign_in' => { Path => 'sign-in' },
974 'new_password' => { Path => 'new-password' },
975 'sign_out' => { Path => 'sign-out' },
979 sub sign_in : Action { }
980 sub new_password : Action { }
981 sub sign_out : Action { }
985 Models are providers of data. This data could come from anywhere - a search
986 engine index, a database table, etc. Typically the data source does not have
987 much to do with web applications or Catalyst - it could be used to write an
988 offline report generator or a command line tool just the same.
990 The common approach to writing a Catalyst-style model for your application is
991 wrapping a generic model (e.g. L<DBIx::Class::Schema>, a bunch of XMLs, or
992 anything really) with an object that contains configuration data, convenience
993 methods, and so forth.
995 #### editor: move this part to =head3 Components somehow, right after this
996 #### section - this will require deeply rephrasing this paragraph.
998 Technically, within Catalyst a model is a B<component> - an instance of the
999 model's class belonging to the application. It is important to stress that the
1000 lifetime of these objects is per application, not per request.
1002 While the model base class (L<Catalyst::Model>) provides things like C<config>
1003 and stuff to better integrate the model into the application, sometimes this is
1004 not enough, and the model requires access to C<$c> itself.
1006 Situations where this need might arise include:
1012 Interacting with another model
1016 Using per-request data to control behavior
1020 Using plugins in (for example L<Catalyst::Plugin::Cache>).
1024 From a style perspective usually it's bad to make your model "too smart"
1025 about things - it should worry about business logic and leave the
1026 integration details to the controllers. If, however, you find that it
1027 does not make sense at all to use an auxillary controller around the
1028 model, and the model's need to access C<$c> cannot be sidestepped, there
1029 exists a power tool called C<ACCEPT_CONTEXT>.
1031 #### editor note: this part is "generic" - it also applies to views and
1034 =head3 ACCEPT_CONTEXT
1036 Whenever you call $c->component("Foo") you get back an object - the
1037 instance of the model. If the component supports the C<ACCEPT_CONTEXT>
1038 method instead of returning the model itself, the return value of C<<
1039 $model->ACCEPT_CONTEXT( $c ) >> will be used.
1041 This means that whenever your model/view/controller needs to talk to C<$c> it
1042 gets a chance to do this when it's needed.
1044 A typical C<ACCEPT_CONTEXT> method will either clone the model and return one
1045 with the context object set, or it will return a thin wrapper that contains
1046 C<$c> and delegates to the per-application model object.
1048 A typical C<ACCEPT_CONTEXT> method could look like this:
1050 sub ACCEPT_CONTEXT {
1051 my ( $self, $c, @extra_arguments ) = @_;
1052 bless { %$self, c => $c }, ref($self);
1055 effectively treating $self as a B<prototype object> that gets a new parameter.
1056 C<@extra_arguments> comes from any trailing arguments to
1057 C<< $c->component( $bah, @extra_arguments ) >> (or C<< $c->model(...) >>,
1058 C<< $c->view(...) >> etc).
1060 The life time of this value is B<per usage>, and not per request. To make this
1061 per request you can use the following technique:
1063 Add a field to C<$c>, like C<my_model_instance>. Then write your
1064 C<ACCEPT_CONTEXT> method to look like this:
1066 sub ACCEPT_CONTEXT {
1067 my ( $self, $c ) = @_;
1069 if ( my $per_request = $c->my_model_instance ) {
1070 return $per_request;
1072 my $new_instance = bless { %$self, c => $c }, ref($self);
1073 Scalar::Util::weaken($new_instance->{c}); # or we have a circular reference
1074 $c->my_model_instance( $new_instance );
1075 return $new_instance;
1082 Catalyst has a built-in http server for testing. (Later, you can easily
1083 use a more powerful server, e.g. Apache/mod_perl or FastCGI, in a
1084 production environment.)
1086 Start your application on the command line...
1088 script/myapp_server.pl
1090 ...then visit http://localhost:3000/ in a browser to view the output.
1092 You can also do it all from the command line:
1094 script/myapp_test.pl http://localhost/
1102 Join #catalyst on irc.perl.org.
1106 http://lists.rawmode.org/mailman/listinfo/catalyst
1107 http://lists.rawmode.org/mailman/listinfo/catalyst-dev
1111 Sebastian Riedel, C<sri@oook.de>
1112 David Naughton, C<naughton@umn.edu>
1113 Marcus Ramberg, C<mramberg@cpan.org>
1114 Jesse Sheidlower, C<jester@panix.com>
1115 Danijel Milicevic, C<me@danijel.de>
1116 Kieren Diment, C<kd@totaldatasolution.com>
1117 Yuval Kogman, C<nothingmuch@woobling.org>
1121 This program is free software, you can redistribute it and/or modify it
1122 under the same terms as Perl itself.