1 package Catalyst::DispatchType::Chained;
4 extends 'Catalyst::DispatchType';
7 use Catalyst::ActionChain;
35 # please don't perltidy this. hairy code within.
39 Catalyst::DispatchType::Chained - Path Part DispatchType
43 Path part matching, allowing several actions to sequentially take care of processing a request:
45 # root action - captures one argument after it
46 sub foo_setup : Chained('/') PathPart('foo') CaptureArgs(1) {
47 my ( $self, $c, $foo_arg ) = @_;
51 # child action endpoint - takes one argument
52 sub bar : Chained('foo_setup') Args(1) {
53 my ( $self, $c, $bar_arg ) = @_;
59 Dispatch type managing default behaviour. For more information on
64 =item * L<Catalyst::Manual::Intro> for how they affect application authors
66 =item * L<Catalyst::DispatchType> for implementation information.
72 =head2 $self->list($c)
74 Debug output for Path Part dispatch points
79 my ( $self, $c ) = @_;
81 return unless $self->_endpoints;
83 my $avail_width = Catalyst::Utils::term_width() - 9;
84 my $col1_width = ($avail_width * .50) < 35 ? 35 : int($avail_width * .50);
85 my $col2_width = $avail_width - $col1_width;
86 my $paths = Text::SimpleTable->new(
87 [ $col1_width, 'Path Spec' ], [ $col2_width, 'Private' ],
90 my $has_unattached_actions;
91 my $unattached_actions = Text::SimpleTable->new(
92 [ $col1_width, 'Private' ], [ $col2_width, 'Missing parent' ],
95 ENDPOINT: foreach my $endpoint (
96 sort { $a->reverse cmp $b->reverse }
97 @{ $self->_endpoints }
99 my $args = $endpoint->attributes->{Args}->[0];
100 my @parts = (defined($args) ? (("*") x $args) : '...');
102 my $parent = "DUMMY";
103 my $curr = $endpoint;
105 if (my $cap = $curr->attributes->{CaptureArgs}) {
106 unshift(@parts, (("*") x $cap->[0]));
108 if (my $pp = $curr->attributes->{PathPart}) {
109 unshift(@parts, $pp->[0])
110 if (defined $pp->[0] && length $pp->[0]);
112 $parent = $curr->attributes->{Chained}->[0];
113 $curr = $self->_actions->{$parent};
114 unshift(@parents, $curr) if $curr;
116 if ($parent ne '/') {
117 $has_unattached_actions = 1;
118 $unattached_actions->row('/' . ($parents[0] || $endpoint)->reverse, $parent);
122 foreach my $p (@parents) {
124 if (my $cap = $p->attributes->{CaptureArgs}) {
125 $name .= ' ('.$cap->[0].')';
127 unless ($p eq $parents[0]) {
128 $name = "-> ${name}";
130 push(@rows, [ '', $name ]);
132 push(@rows, [ '', (@rows ? "=> " : '')."/${endpoint}" ]);
133 $rows[0][0] = join('/', '', @parts) || '/';
134 $paths->row(@$_) for @rows;
137 $c->log->debug( "Loaded Chained actions:\n" . $paths->draw . "\n" );
138 $c->log->debug( "Unattached Chained actions:\n", $unattached_actions->draw . "\n" )
139 if $has_unattached_actions;
142 =head2 $self->match( $c, $path )
144 Calls C<recurse_match> to see if a chain matches the C<$path>.
149 my ( $self, $c, $path ) = @_;
151 my $request = $c->request;
152 return 0 if @{$request->args};
154 my @parts = split('/', $path);
156 my ($chain, $captures, $parts) = $self->recurse_match($c, '/', \@parts);
158 if ($parts && @$parts) {
159 for my $arg (@$parts) {
160 $arg =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
161 push @{$request->args}, $arg;
165 return 0 unless $chain;
167 my $action = Catalyst::ActionChain->from_chain($chain);
169 $request->action("/${action}");
170 $request->match("/${action}");
171 $request->captures($captures);
173 $c->namespace( $action->namespace );
178 =head2 $self->recurse_match( $c, $parent, \@path_parts )
180 Recursive search for a matching chain.
185 my ( $self, $c, $parent, $path_parts ) = @_;
186 my $children = $self->_children_of->{$parent};
187 return () unless $children;
190 TRY: foreach my $try_part (sort { length($b) <=> length($a) }
192 # $b then $a to try longest part first
193 my @parts = @$path_parts;
194 if (length $try_part) { # test and strip PathPart
196 ($try_part eq join('/', # assemble equal number of parts
197 splice( # and strip them off @parts as well
198 @parts, 0, scalar(@{[split('/', $try_part)]})
199 ))); # @{[]} to avoid split to @_
201 my @try_actions = @{$children->{$try_part}};
202 TRY_ACTION: foreach my $action (@try_actions) {
203 if (my $capture_attr = $action->attributes->{CaptureArgs}) {
205 # Short-circuit if not enough remaining parts
206 next TRY_ACTION unless @parts >= ($capture_attr->[0]||0);
209 my @parts = @parts; # localise
211 # strip CaptureArgs into list
212 push(@captures, splice(@parts, 0, $capture_attr->[0]));
214 # check if the action may fit, depending on a given test by the app
215 if ($action->can('match_captures')) { next TRY_ACTION unless $action->match_captures($c, \@captures) }
217 # try the remaining parts against children of this action
218 my ($actions, $captures, $action_parts, $n_pathparts) = $self->recurse_match(
219 $c, '/'.$action->reverse, \@parts
221 # No best action currently
222 # OR The action has less parts
223 # OR The action has equal parts but less captured data (ergo more defined)
226 $#$action_parts < $#{$best_action->{parts}} ||
227 ($#$action_parts == $#{$best_action->{parts}} &&
228 $#$captures < $#{$best_action->{captures}} &&
229 $n_pathparts > $best_action->{n_pathparts}))) {
230 my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
232 actions => [ $action, @$actions ],
233 captures=> [ @captures, @$captures ],
234 parts => $action_parts,
235 n_pathparts => scalar(@pathparts) + $n_pathparts,
241 local $c->req->{arguments} = [ @{$c->req->args}, @parts ];
242 next TRY_ACTION unless $action->match($c);
244 my $args_attr = $action->attributes->{Args}->[0];
245 my @pathparts = split /\//, $action->attributes->{PathPart}->[0];
246 # No best action currently
247 # OR This one matches with fewer parts left than the current best action,
248 # And therefore is a better match
249 # OR No parts and this expects 0
250 # The current best action might also be Args(0),
251 # but we couldn't chose between then anyway so we'll take the last seen
254 @parts < @{$best_action->{parts}} ||
255 (!@parts && $args_attr eq 0)){
257 actions => [ $action ],
260 n_pathparts => scalar(@pathparts),
266 return @$best_action{qw/actions captures parts n_pathparts/} if $best_action;
270 =head2 $self->register( $c, $action )
272 Calls register_path for every Path attribute for the given $action.
277 my ( $self, $c, $action ) = @_;
279 my @chained_attr = @{ $action->attributes->{Chained} || [] };
281 return 0 unless @chained_attr;
283 if (@chained_attr > 1) {
284 Catalyst::Exception->throw(
285 "Multiple Chained attributes not supported registering ${action}"
288 my $chained_to = $chained_attr[0];
290 Catalyst::Exception->throw(
291 "Actions cannot chain to themselves registering /${action}"
292 ) if ($chained_to eq '/' . $action);
294 my $children = ($self->_children_of->{ $chained_to } ||= {});
296 my @path_part = @{ $action->attributes->{PathPart} || [] };
298 my $part = $action->name;
300 if (@path_part == 1 && defined $path_part[0]) {
301 $part = $path_part[0];
302 } elsif (@path_part > 1) {
303 Catalyst::Exception->throw(
304 "Multiple PathPart attributes not supported registering " . $action->reverse()
308 if ($part =~ m(^/)) {
309 Catalyst::Exception->throw(
310 "Absolute parameters to PathPart not allowed registering " . $action->reverse()
314 $action->attributes->{PathPart} = [ $part ];
316 unshift(@{ $children->{$part} ||= [] }, $action);
318 $self->_actions->{'/'.$action->reverse} = $action;
320 if (exists $action->attributes->{Args}) {
321 my $args = $action->attributes->{Args}->[0];
322 if (defined($args) and not (
323 Scalar::Util::looks_like_number($args) and
326 require Data::Dumper;
327 local $Data::Dumper::Terse = 1;
328 local $Data::Dumper::Indent = 0;
329 $args = Data::Dumper::Dumper($args);
330 Catalyst::Exception->throw(
331 "Invalid Args($args) for action " . $action->reverse() .
332 " (use 'Args' or 'Args(<number>)'"
337 unless ($action->attributes->{CaptureArgs}) {
338 unshift(@{ $self->_endpoints }, $action);
344 =head2 $self->uri_for_action($action, $captures)
346 Get the URI part for the action, using C<$captures> to fill
352 my ( $self, $action, $captures ) = @_;
354 return undef unless ($action->attributes->{Chained}
355 && !$action->attributes->{CaptureArgs});
358 my @captures = @$captures;
359 my $parent = "DUMMY";
362 if (my $cap = $curr->attributes->{CaptureArgs}) {
363 return undef unless @captures >= $cap->[0]; # not enough captures
365 unshift(@parts, splice(@captures, -$cap->[0]));
368 if (my $pp = $curr->attributes->{PathPart}) {
369 unshift(@parts, $pp->[0])
370 if (defined($pp->[0]) && length($pp->[0]));
372 $parent = $curr->attributes->{Chained}->[0];
373 $curr = $self->_actions->{$parent};
376 return undef unless $parent eq '/'; # fail for dangling action
378 return undef if @captures; # fail for too many captures
380 return join('/', '', @parts);
384 =head2 $c->expand_action($action)
386 Return a list of actions that represents a chained action. See
387 L<Catalyst::Dispatcher> for more info. You probably want to
388 use the expand_action it provides rather than this directly.
393 my ($self, $action) = @_;
395 return unless $action->attributes && $action->attributes->{Chained};
402 my $parent = $curr->attributes->{Chained}->[0];
403 $curr = $self->_actions->{$parent};
406 return Catalyst::ActionChain->from_chain([reverse @chain]);
409 __PACKAGE__->meta->make_immutable;
416 The C<Chained> attribute allows you to chain public path parts together
417 by their private names. A chain part's path can be specified with
418 C<PathPart> and can be declared to expect an arbitrary number of
419 arguments. The endpoint of the chain specifies how many arguments it
420 gets through the C<Args> attribute. C<:Args(0)> would be none at all,
421 C<:Args> without an integer would be unlimited. The path parts that
422 aren't endpoints are using C<CaptureArgs> to specify how many parameters
423 they expect to receive. As an example setup:
425 package MyApp::Controller::Greeting;
426 use base qw/ Catalyst::Controller /;
428 # this is the beginning of our chain
429 sub hello : PathPart('hello') Chained('/') CaptureArgs(1) {
430 my ( $self, $c, $integer ) = @_;
431 $c->stash->{ message } = "Hello ";
432 $c->stash->{ arg_sum } = $integer;
435 # this is our endpoint, because it has no :CaptureArgs
436 sub world : PathPart('world') Chained('hello') Args(1) {
437 my ( $self, $c, $integer ) = @_;
438 $c->stash->{ message } .= "World!";
439 $c->stash->{ arg_sum } += $integer;
441 $c->response->body( join "<br/>\n" =>
442 $c->stash->{ message }, $c->stash->{ arg_sum } );
445 The debug output provides a separate table for chained actions, showing
446 the whole chain as it would match and the actions it contains. Here's an
447 example of the startup output with our actions above:
450 [debug] Loaded Path Part actions:
451 .-----------------------+------------------------------.
452 | Path Spec | Private |
453 +-----------------------+------------------------------+
454 | /hello/*/world/* | /greeting/hello (1) |
455 | | => /greeting/world |
456 '-----------------------+------------------------------'
459 As you can see, Catalyst only deals with chains as whole paths and
460 builds one for each endpoint, which are the actions with C<:Chained> but
461 without C<:CaptureArgs>.
463 Let's assume this application gets a request at the path
464 C</hello/23/world/12>. What happens then? First, Catalyst will dispatch
465 to the C<hello> action and pass the value C<23> as an argument to it
466 after the context. It does so because we have previously used
467 C<:CaptureArgs(1)> to declare that it has one path part after itself as
468 its argument. We told Catalyst that this is the beginning of the chain
469 by specifying C<:Chained('/')>. Also note that instead of saying
470 C<:PathPart('hello')> we could also just have said C<:PathPart>, as it
471 defaults to the name of the action.
473 After C<hello> has run, Catalyst goes on to dispatch to the C<world>
474 action. This is the last action to be called: Catalyst knows this is an
475 endpoint because we did not specify a C<:CaptureArgs>
476 attribute. Nevertheless we specify that this action expects an argument,
477 but at this point we're using C<:Args(1)> to do that. We could also have
478 said C<:Args> or left it out altogether, which would mean this action
479 would get all arguments that are there. This action's C<:Chained>
480 attribute says C<hello> and tells Catalyst that the C<hello> action in
481 the current controller is its parent.
483 With this we have built a chain consisting of two public path parts.
484 C<hello> captures one part of the path as its argument, and also
485 specifies the path root as its parent. So this part is
486 C</hello/$arg>. The next part is the endpoint C<world>, expecting one
487 argument. It sums up to the path part C<world/$arg>. This leads to a
488 complete chain of C</hello/$arg/world/$arg> which is matched against the
491 This example application would, if run and called by e.g.
492 C</hello/23/world/12>, set the stash value C<message> to "Hello" and the
493 value C<arg_sum> to "23". The C<world> action would then append "World!"
494 to C<message> and add C<12> to the stash's C<arg_sum> value. For the
495 sake of simplicity no view is shown. Instead we just put the values of
496 the stash into our body. So the output would look like:
501 And our test server would have given us this debugging output for the
505 [debug] "GET" request for "hello/23/world/12" from "127.0.0.1"
506 [debug] Path is "/greeting/world"
507 [debug] Arguments are "12"
508 [info] Request took 0.164113s (6.093/s)
509 .------------------------------------------+-----------.
511 +------------------------------------------+-----------+
512 | /greeting/hello | 0.000029s |
513 | /greeting/world | 0.000024s |
514 '------------------------------------------+-----------'
517 What would be common uses of this dispatch technique? It gives the
518 possibility to split up logic that contains steps that each depend on
519 each other. An example would be, for example, a wiki path like
520 C</wiki/FooBarPage/rev/23/view>. This chain can be easily built with
523 sub wiki : PathPart('wiki') Chained('/') CaptureArgs(1) {
524 my ( $self, $c, $page_name ) = @_;
525 # load the page named $page_name and put the object
529 sub rev : PathPart('rev') Chained('wiki') CaptureArgs(1) {
530 my ( $self, $c, $revision_id ) = @_;
531 # use the page object in the stash to get at its
532 # revision with number $revision_id
535 sub view : PathPart Chained('rev') Args(0) {
536 my ( $self, $c ) = @_;
537 # display the revision in our stash. Another option
538 # would be to forward a compatible object to the action
539 # that displays the default wiki pages, unless we want
540 # a different interface here, for example restore
544 It would now be possible to add other endpoints, for example C<restore>
545 to restore this specific revision as the current state.
547 You don't have to put all the chained actions in one controller. The
548 specification of the parent through C<:Chained> also takes an absolute
549 action path as its argument. Just specify it with a leading C</>.
551 If you want, for example, to have actions for the public paths
552 C</foo/12/edit> and C</foo/12>, just specify two actions with
553 C<:PathPart('foo')> and C<:Chained('/')>. The handler for the former
554 path needs a C<:CaptureArgs(1)> attribute and a endpoint with
555 C<:PathPart('edit')> and C<:Chained('foo')>. For the latter path give
556 the action just a C<:Args(1)> to mark it as endpoint. This sums up to
557 this debugging output:
560 [debug] Loaded Path Part actions:
561 .-----------------------+------------------------------.
562 | Path Spec | Private |
563 +-----------------------+------------------------------+
564 | /foo/* | /controller/foo_view |
565 | /foo/*/edit | /controller/foo_load (1) |
566 | | => /controller/edit |
567 '-----------------------+------------------------------'
570 Here's a more detailed specification of the attributes belonging to
579 Sets the name of this part of the chain. If it is specified without
580 arguments, it takes the name of the action as default. So basically
581 C<sub foo :PathPart> and C<sub foo :PathPart('foo')> are identical.
582 This can also contain slashes to bind to a deeper level. An action
583 with C<sub bar :PathPart('foo/bar') :Chained('/')> would bind to
584 C</foo/bar/...>. If you don't specify C<:PathPart> it has the same
585 effect as using C<:PathPart>, it would default to the action name.
589 Sets PathPart to the path_prefix of the current controller.
593 Has to be specified for every child in the chain. Possible values are
594 absolute and relative private action paths or a single slash C</> to
595 tell Catalyst that this is the root of a chain. The attribute
596 C<:Chained> without arguments also defaults to the C</> behavior.
597 Relative action paths may use C<../> to refer to actions in parent
600 Because you can specify an absolute path to the parent action, it
601 doesn't matter to Catalyst where that parent is located. So, if your
602 design requests it, you can redispatch a chain through any controller or
605 Another interesting possibility gives C<:Chained('.')>, which chains
606 itself to an action with the path of the current controller's namespace.
609 # in MyApp::Controller::Foo
610 sub bar : Chained CaptureArgs(1) { ... }
612 # in MyApp::Controller::Foo::Bar
613 sub baz : Chained('.') Args(1) { ... }
615 This builds up a chain like C</bar/*/baz/*>. The specification of C<.>
616 as the argument to Chained here chains the C<baz> action to an action
617 with the path of the current controller namespace, namely
618 C</foo/bar>. That action chains directly to C</>, so the C</bar/*/baz/*>
619 chain comes out as the end product.
623 Chains an action to another action with the same name in the parent
624 controller. For Example:
626 # in MyApp::Controller::Foo
627 sub bar : Chained CaptureArgs(1) { ... }
629 # in MyApp::Controller::Foo::Moo
630 sub bar : ChainedParent Args(1) { ... }
632 This builds a chain like C</bar/*/bar/*>.
636 Must be specified for every part of the chain that is not an
637 endpoint. With this attribute Catalyst knows how many of the following
638 parts of the path (separated by C</>) this action wants to capture as
639 its arguments. If it doesn't expect any, just specify
640 C<:CaptureArgs(0)>. The captures get passed to the action's C<@_> right
641 after the context, but you can also find them as array references in
642 C<$c-E<gt>request-E<gt>captures-E<gt>[$level]>. The C<$level> is the
643 level of the action in the chain that captured the parts of the path.
645 An action that is part of a chain (that is, one that has a C<:Chained>
646 attribute) but has no C<:CaptureArgs> attribute is treated by Catalyst
651 By default, endpoints receive the rest of the arguments in the path. You
652 can tell Catalyst through C<:Args> explicitly how many arguments your
653 endpoint expects, just like you can with C<:CaptureArgs>. Note that this
654 also affects whether this chain is invoked on a request. A chain with an
655 endpoint specifying one argument will only match if exactly one argument
658 You can specify an exact number of arguments like C<:Args(3)>, including
659 C<0>. If you just say C<:Args> without any arguments, it is the same as
660 leaving it out altogether: The chain is matched regardless of the number
661 of path parts after the endpoint.
663 Just as with C<:CaptureArgs>, the arguments get passed to the action in
664 C<@_> after the context object. They can also be reached through
665 C<$c-E<gt>request-E<gt>arguments>.
669 =head2 Auto actions, dispatching and forwarding
671 Note that the list of C<auto> actions called depends on the private path
672 of the endpoint of the chain, not on the chained actions way. The
673 C<auto> actions will be run before the chain dispatching begins. In
674 every other aspect, C<auto> actions behave as documented.
676 The C<forward>ing to other actions does just what you would expect. But if
677 you C<detach> out of a chain, the rest of the chain will not get called
682 Catalyst Contributors, see Catalyst.pm
686 This library is free software. You can redistribute it and/or modify it under
687 the same terms as Perl itself.