lib/Catalyst/Authentication/Store/LDAP/Backend.pm

   1
   2 =pod
   3
   4 =head1 NAME
   5
   6 Catalyst::Authentication::Store::LDAP::Backend
   7   - LDAP authentication storage backend.
   8
   9 =head1 SYNOPSIS
  10
  11     # you probably just want Store::LDAP under most cases,
  12     # but if you insist you can instantiate your own store:
  13
  14     use Catalyst::Authentication::Store::LDAP::Backend;
  15
  16     use Catalyst qw/
  17         Authentication
  18         Authentication::Credential::Password
  19     /;
  20
  21     my %config = (
  22             'ldap_server' => 'ldap1.yourcompany.com',
  23             'ldap_server_options' => {
  24                 'timeout' => 30,
  25             },
  26             'binddn' => 'anonymous',
  27             'bindpw' => 'dontcarehow',
  28             'start_tls' => 1,
  29             'start_tls_options' => {
  30                 'verify' => 'none',
  31             },
  32             'user_basedn' => 'ou=people,dc=yourcompany,dc=com',
  33             'user_filter' => '(&(objectClass=posixAccount)(uid=%s))',
  34             'user_scope' => 'one',  # or 'sub' for Active Directory
  35             'user_field' => 'uid',
  36             'user_search_options' => {
  37                 'deref' => 'always',
  38                 'attrs' => [qw( distinguishedname name mail )],
  39             },
  40             'user_results_filter' => sub { return shift->pop_entry },
  41             'entry_class' => 'MyApp::LDAP::Entry',
  42             'user_class' => 'MyUser',
  43             'use_roles' => 1,
  44             'role_basedn' => 'ou=groups,dc=yourcompany,dc=com',
  45             'role_filter' => '(&(objectClass=posixGroup)(member=%s))',
  46             'role_scope' => 'one',
  47             'role_field' => 'cn',
  48             'role_value' => 'dn',
  49             'role_search_options' => {
  50                 'deref' => 'always',
  51             },
  52             'role_search_as_user' => 0,
  53             'persist_in_session'  => 'all',
  54     );
  55
  56     our $users = Catalyst::Authentication::Store::LDAP::Backend->new(\%config);
  57
  58 =head1 DESCRIPTION
  59
  60 You probably want L<Catalyst::Authentication::Store::LDAP>.
  61
  62 Otherwise, this lets you create a store manually.
  63
  64 See the L<Catalyst::Authentication::Store::LDAP> documentation for
  65 an explanation of the configuration options.
  66
  67 =head1 METHODS
  68
  69 =cut
  70
  71 package Catalyst::Authentication::Store::LDAP::Backend;
  72 use base qw( Class::Accessor::Fast );
  73
  74 use strict;
  75 use warnings;
  76
  77 our $VERSION = '1.015';
  78
  79 use Catalyst::Authentication::Store::LDAP::User;
  80 use Net::LDAP;
  81 use Catalyst::Utils ();
  82
  83 BEGIN {
  84     __PACKAGE__->mk_accessors(
  85         qw( ldap_server ldap_server_options binddn
  86             bindpw entry_class user_search_options
  87             user_filter user_basedn user_scope
  88             user_attrs user_field use_roles role_basedn
  89             role_filter role_scope role_field role_value
  90             role_search_options start_tls start_tls_options
  91             user_results_filter user_class role_search_as_user
  92             persist_in_session
  93             )
  94     );
  95 }
  96
  97 =head2 new($config)
  98
  99 Creates a new L<Catalyst::Authentication::Store::LDAP::Backend> object.
 100 $config should be a hashref, which should contain the configuration options
 101 listed in L<Catalyst::Authentication::Store::LDAP>'s documentation.
 102
 103 Also sets a few sensible defaults.
 104
 105 =cut
 106
 107 sub new {
 108     my ( $class, $config ) = @_;
 109
 110     unless ( defined($config) && ref($config) eq "HASH" ) {
 111         Catalyst::Exception->throw(
 112             "Catalyst::Authentication::Store::LDAP::Backend needs to be configured with a hashref."
 113         );
 114     }
 115     my %config_hash = %{$config};
 116     $config_hash{'binddn'}      ||= 'anonymous';
 117     $config_hash{'user_filter'} ||= '(uid=%s)';
 118     $config_hash{'user_scope'}  ||= 'sub';
 119     $config_hash{'user_field'}  ||= 'uid';
 120     $config_hash{'role_filter'} ||= '(memberUid=%s)';
 121     $config_hash{'role_scope'}  ||= 'sub';
 122     $config_hash{'role_field'}  ||= 'cn';
 123     $config_hash{'use_roles'}   ||= '1';
 124     $config_hash{'start_tls'}   ||= '0';
 125     $config_hash{'entry_class'} ||= 'Catalyst::Model::LDAP::Entry';
 126     $config_hash{'user_class'}
 127         ||= 'Catalyst::Authentication::Store::LDAP::User';
 128     $config_hash{'role_search_as_user'} ||= 0;
 129
 130     Catalyst::Utils::ensure_class_loaded( $config_hash{'user_class'} );
 131     my $self = \%config_hash;
 132     bless( $self, $class );
 133     return $self;
 134 }
 135
 136 =head2 find_user( I<authinfo>, $c )
 137
 138 Creates a L<Catalyst::Authentication::Store::LDAP::User> object
 139 for the given User ID.  This is the preferred mechanism for getting a
 140 given User out of the Store.
 141
 142 I<authinfo> should be a hashref with a key of either C<id> or
 143 C<username>. The value will be compared against the LDAP C<user_field> field.
 144
 145 =cut
 146
 147 sub find_user {
 148     my ( $self, $authinfo, $c ) = @_;
 149     return $self->get_user( $authinfo->{id} || $authinfo->{username}, $c );
 150 }
 151
 152 =head2 get_user( I<id>, $c)
 153
 154 Creates a L<Catalyst::Authentication::Store::LDAP::User> object
 155 for the given User ID, or calls C<new> on the class specified in
 156 C<user_class>.  This instance of the store object, the results of
 157 C<lookup_user> and $c are passed as arguments (in that order) to C<new>.
 158 This is the preferred mechanism for getting a given User out of the Store.
 159
 160 =cut
 161
 162 sub get_user {
 163     my ( $self, $id, $c ) = @_;
 164     my $user = $self->user_class->new( $self, $self->lookup_user($id), $c );
 165     return $user;
 166 }
 167
 168 =head2 ldap_connect
 169
 170 Returns a L<Net::LDAP> object, connected to your LDAP server. (According
 171 to how you configured the Backend, of course)
 172
 173 =cut
 174
 175 sub ldap_connect {
 176     my ($self) = shift;
 177     my $ldap;
 178     if ( defined( $self->ldap_server_options() ) ) {
 179         $ldap
 180             = Net::LDAP->new( $self->ldap_server,
 181             %{ $self->ldap_server_options } )
 182             or Catalyst::Exception->throw($@);
 183     }
 184     else {
 185         $ldap = Net::LDAP->new( $self->ldap_server )
 186             or Catalyst::Exception->throw($@);
 187     }
 188     if ( defined( $self->start_tls ) && $self->start_tls =~ /(1|true)/i ) {
 189         my $mesg;
 190         if ( defined( $self->start_tls_options ) ) {
 191             $mesg = $ldap->start_tls( %{ $self->start_tls_options } );
 192         }
 193         else {
 194             $mesg = $ldap->start_tls;
 195         }
 196         if ( $mesg->is_error ) {
 197             Catalyst::Exception->throw( "TLS Error: " . $mesg->error );
 198         }
 199     }
 200     return $ldap;
 201 }
 202
 203 =head2 ldap_bind($ldap, $binddn, $bindpw)
 204
 205 Bind's to the directory.  If $ldap is undef, it will connect to the
 206 LDAP server first.  $binddn should be the DN of the object you wish
 207 to bind as, and $bindpw the password.
 208
 209 If $binddn is "anonymous", an anonymous bind will be performed.
 210
 211 =cut
 212
 213 sub ldap_bind {
 214     my ( $self, $ldap, $binddn, $bindpw ) = @_;
 215     $ldap ||= $self->ldap_connect;
 216     if ( !defined($ldap) ) {
 217         Catalyst::Exception->throw("LDAP Server undefined!");
 218     }
 219
 220     # if username is present, make sure password is present too.
 221     # see https://rt.cpan.org/Ticket/Display.html?id=81908
 222     if ( !defined $binddn ) {
 223         $binddn = $self->binddn;
 224         $bindpw = $self->bindpw;
 225     }
 226
 227     if ( $binddn eq "anonymous" ) {
 228         $self->_ldap_bind_anon($ldap);
 229     }
 230     else {
 231         if ($bindpw) {
 232             my $mesg = $ldap->bind( $binddn, 'password' => $bindpw );
 233             if ( $mesg->is_error ) {
 234                 Catalyst::Exception->throw(
 235                     "Error on Initial Bind: " . $mesg->error );
 236             }
 237         }
 238         else {
 239             $self->_ldap_bind_anon( $ldap, $binddn );
 240         }
 241     }
 242     return $ldap;
 243 }
 244
 245 sub _ldap_bind_anon {
 246     my ( $self, $ldap, $dn ) = @_;
 247     my $mesg = $ldap->bind($dn);
 248     if ( $mesg->is_error ) {
 249         Catalyst::Exception->throw( "Error on Bind: " . $mesg->error );
 250     }
 251 }
 252
 253 =head2 ldap_auth( $binddn, $bindpw )
 254
 255 Connect to the LDAP server and do an authenticated bind against the
 256 directory. Throws an exception if connecting to the LDAP server fails.
 257 Returns 1 if binding succeeds, 0 if it fails.
 258
 259 =cut
 260
 261 sub ldap_auth {
 262     my ( $self, $binddn, $bindpw ) = @_;
 263     my $ldap = $self->ldap_connect;
 264     if ( !defined $ldap ) {
 265         Catalyst::Exception->throw("LDAP server undefined!");
 266     }
 267     my $mesg = $ldap->bind( $binddn, password => $bindpw );
 268     return $mesg->is_error ? 0 : 1;
 269 }
 270
 271 =head2 lookup_user($id)
 272
 273 Given a User ID, this method will:
 274
 275   A) Bind to the directory using the configured binddn and bindpw
 276   B) Perform a search for the User Object in the directory, using
 277      user_basedn, user_filter, and user_scope.
 278   C) Assuming we found the object, we will walk it's attributes
 279      using L<Net::LDAP::Entry>'s get_value method.  We store the
 280      results in a hashref. If we do not find the object, then
 281      undef is returned.
 282   D) Return a hashref that looks like:
 283
 284      $results = {
 285         'ldap_entry' => $entry, # The Net::LDAP::Entry object
 286         'attributes' => $attributes,
 287      }
 288
 289 This method is usually only called by find_user().
 290
 291 =cut
 292
 293 sub lookup_user {
 294     my ( $self, $id ) = @_;
 295
 296     # Trim trailing space or we confuse ourselves
 297     $id =~ s/\s+$//;
 298     my $ldap = $self->ldap_bind;
 299     my @searchopts;
 300     if ( defined( $self->user_basedn ) ) {
 301         push( @searchopts, 'base' => $self->user_basedn );
 302     }
 303     else {
 304         Catalyst::Exception->throw(
 305             "You must set user_basedn before looking up users!");
 306     }
 307     my $filter = $self->_replace_filter( $self->user_filter, $id );
 308     push( @searchopts, 'filter' => $filter );
 309     push( @searchopts, 'scope'  => $self->user_scope );
 310     if ( defined( $self->user_search_options ) ) {
 311         push( @searchopts, %{ $self->user_search_options } );
 312     }
 313     my $usersearch = $ldap->search(@searchopts);
 314
 315     return undef if ( $usersearch->is_error );
 316
 317     my $userentry;
 318     my $user_field     = $self->user_field;
 319     my $results_filter = $self->user_results_filter;
 320     my $entry;
 321     if ( defined($results_filter) ) {
 322         $entry = &$results_filter($usersearch);
 323     }
 324     else {
 325         $entry = $usersearch->pop_entry;
 326     }
 327     if ( $usersearch->pop_entry ) {
 328         Catalyst::Exception->throw(
 329                   "More than one entry matches user search.\n"
 330                 . "Consider defining a user_results_filter sub." );
 331     }
 332
 333     # a little extra sanity check with the 'eq' since LDAP already
 334     # says it matches.
 335     # NOTE that Net::LDAP returns exactly what you asked for, but
 336     # because LDAP is often case insensitive, FoO can match foo
 337     # and so we normalize with lc().
 338     if ( defined($entry) ) {
 339         unless ( lc( $entry->get_value($user_field) ) eq lc($id) ) {
 340             Catalyst::Exception->throw(
 341                 "LDAP claims '$user_field' equals '$id' but results entry does not match."
 342             );
 343         }
 344         $userentry = $entry;
 345     }
 346
 347     $ldap->unbind;
 348     $ldap->disconnect;
 349     unless ($userentry) {
 350         return undef;
 351     }
 352     my $attrhash;
 353     foreach my $attr ( $userentry->attributes ) {
 354         my @attrvalues = $userentry->get_value($attr);
 355         if ( scalar(@attrvalues) == 1 ) {
 356             $attrhash->{ lc($attr) } = $attrvalues[0];
 357         }
 358         else {
 359             $attrhash->{ lc($attr) } = \@attrvalues;
 360         }
 361     }
 362
 363     eval { Catalyst::Utils::ensure_class_loaded( $self->entry_class ) };
 364     if ( !$@ ) {
 365         bless( $userentry, $self->entry_class );
 366         $userentry->{_use_unicode}++;
 367     }
 368     my $rv = {
 369         'ldap_entry' => $userentry,
 370         'attributes' => $attrhash,
 371     };
 372     return $rv;
 373 }
 374
 375 =head2 lookup_roles($userobj, [$ldap])
 376
 377 This method looks up the roles for a given user.  It takes a
 378 L<Catalyst::Authentication::Store::LDAP::User> object
 379 as it's first argument, and can optionally take a I<Net::LDAP> object which
 380 is used rather than the default binding if supplied.
 381
 382 It returns an array containing the role_field attribute from all the
 383 objects that match it's criteria.
 384
 385 =cut
 386
 387 sub lookup_roles {
 388     my ( $self, $userobj, $ldap ) = @_;
 389     if ( $self->use_roles == 0 || $self->use_roles =~ /^false$/i ) {
 390         return undef;
 391     }
 392     $ldap ||= $self->role_search_as_user
 393         ? $userobj->ldap_connection : $self->ldap_bind;
 394     my @searchopts;
 395     if ( defined( $self->role_basedn ) ) {
 396         push( @searchopts, 'base' => $self->role_basedn );
 397     }
 398     else {
 399         Catalyst::Exception->throw(
 400             "You must set up role_basedn before looking up roles!");
 401     }
 402     my $filter_value = $userobj->has_attribute( $self->role_value );
 403     if ( !defined($filter_value) ) {
 404         Catalyst::Exception->throw( "User object "
 405                 . $userobj->username
 406                 . " has no "
 407                 . $self->role_value
 408                 . " attribute, so I can't look up it's roles!" );
 409     }
 410     my $filter = $self->_replace_filter( $self->role_filter, $filter_value );
 411     push( @searchopts, 'filter' => $filter );
 412     push( @searchopts, 'scope'  => $self->role_scope );
 413     push( @searchopts, 'attrs'  => [ $self->role_field ] );
 414     if ( defined( $self->role_search_options ) ) {
 415         push( @searchopts, %{ $self->role_search_options } );
 416     }
 417     my $rolesearch = $ldap->search(@searchopts);
 418     my @roles;
 419 RESULT: foreach my $entry ( $rolesearch->entries ) {
 420         push( @roles, $entry->get_value( $self->role_field ) );
 421     }
 422     return @roles;
 423 }
 424
 425 sub _replace_filter {
 426     my $self    = shift;
 427     my $filter  = shift;
 428     my $replace = shift;
 429     $replace =~ s/([*()\\\x{0}])/sprintf '\\%02x', ord($1)/ge;
 430     $filter =~ s/\%s/$replace/g;
 431     return $filter;
 432 }
 433
 434 =head2 user_supports
 435
 436 Returns the value of
 437 Catalyst::Authentication::Store::LDAP::User->supports(@_).
 438
 439 =cut
 440
 441 sub user_supports {
 442     my $self = shift;
 443
 444     # this can work as a class method
 445     Catalyst::Authentication::Store::LDAP::User->supports(@_);
 446 }
 447
 448 =head2 from_session( I<id>, I<$c> )
 449
 450 Returns get_user() for I<id>.
 451
 452 =cut
 453
 454 sub from_session {
 455     my ( $self, $c, $frozenuser ) = @_;
 456
 457     if ( $self->persist_in_session eq 'all' ) {
 458         return $self->user_class->new( $self, $frozenuser->{user}, $c, $frozenuser->{_roles} );
 459     }
 460
 461     return $self->get_user( $frozenuser, $c );
 462 }
 463
 464 1;
 465
 466 __END__
 467
 468 =head1 AUTHORS
 469
 470 Adam Jacob <holoway@cpan.org>
 471
 472 Some parts stolen shamelessly and entirely from
 473 L<Catalyst::Plugin::Authentication::Store::Htpasswd>.
 474
 475 Currently maintained by Peter Karman <karman@cpan.org>.
 476
 477 =head1 THANKS
 478
 479 To nothingmuch, ghenry, castaway and the rest of #catalyst for the help. :)
 480
 481 =head1 SEE ALSO
 482
 483 L<Catalyst::Authentication::Store::LDAP>, L<Catalyst::Authentication::Store::LDAP::User>, L<Catalyst::Plugin::Authentication>, L<Net::LDAP>
 484
 485 =head1 COPYRIGHT & LICENSE
 486
 487 Copyright (c) 2005 the aforementioned authors. All rights
 488 reserved. This program is free software; you can redistribute
 489 it and/or modify it under the same terms as Perl itself.
 490
 491 =cut
 492