lib/Catalyst/Action/REST.pm

   1 package Catalyst::Action::REST;
   2
   3 use Moose;
   4 use namespace::autoclean;
   5
   6 extends 'Catalyst::Action';
   7 use Class::Inspector;
   8 use Catalyst::Request::REST;
   9 use Catalyst::Controller::REST;
  10
  11 BEGIN { require 5.008001; }
  12
  13 # VERSION
  14
  15 sub BUILDARGS {
  16     my $class  = shift;
  17     my $config = shift;
  18     Catalyst::Request::REST->_insert_self_into( $config->{class} );
  19     return $class->SUPER::BUILDARGS($config, @_);
  20 }
  21
  22 =head1 NAME
  23
  24 Catalyst::Action::REST - Automated REST Method Dispatching
  25
  26 =head1 SYNOPSIS
  27
  28     sub foo :Local :ActionClass('REST') {
  29       ... do setup for HTTP method specific handlers ...
  30     }
  31
  32     sub foo_GET {
  33       ... do something for GET requests ...
  34     }
  35
  36     # alternatively use an Action
  37     sub foo_PUT : Action {
  38       ... do something for PUT requests ...
  39     }
  40
  41 =head1 DESCRIPTION
  42
  43 This Action handles doing automatic method dispatching for REST requests.  It
  44 takes a normal Catalyst action, and changes the dispatch to append an
  45 underscore and method name.  First it will try dispatching to an action with
  46 the generated name, and failing that it will try to dispatch to a regular
  47 method.
  48
  49 For example, in the synopsis above, calling GET on "/foo" would result in
  50 the foo_GET method being dispatched.
  51
  52 If a method is requested that is not implemented, this action will
  53 return a status 405 (Method Not Found).  It will populate the "Allow" header
  54 with the list of implemented request methods.  You can override this behavior
  55 by implementing a custom 405 handler like so:
  56
  57    sub foo_not_implemented {
  58       ... handle not implemented methods ...
  59    }
  60
  61 If you do not provide an _OPTIONS subroutine, we will automatically respond
  62 with a 200 OK.  The "Allow" header will be populated with the list of
  63 implemented request methods. If you do not provide an _HEAD either, we will
  64 auto dispatch to the _GET one in case it exists.
  65
  66 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  67 which brings this class together with automatic Serialization of requests
  68 and responses.
  69
  70 When you use this module, it adds the L<Catalyst::TraitFor::Request::REST>
  71 role to your request class.
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item dispatch
  78
  79 This method overrides the default dispatch mechanism to the re-dispatching
  80 mechanism described above.
  81
  82 =cut
  83
  84 sub dispatch {
  85     my $self = shift;
  86     my $c    = shift;
  87
  88     my $rest_method = $self->name . "_" . uc( $c->request->method );
  89
  90     return $self->_dispatch_rest_method( $c, $rest_method );
  91 }
  92
  93 sub _dispatch_rest_method {
  94     my $self        = shift;
  95     my $c           = shift;
  96     my $rest_method = shift;
  97     my $req         = $c->request;
  98
  99     my $controller = $c->component( $self->class );
 100
 101     my ($code, $name);
 102
 103     # Execute normal 'foo' action.
 104     $c->execute( $self->class, $self, @{ $req->args } );
 105
 106     # Common case, for foo_GET etc
 107     if ( $code = $controller->action_for($rest_method) ) {
 108         return $c->forward( $code,  $req->args ); # Forward to foo_GET if it's an action
 109     }
 110     elsif ($code = $controller->can($rest_method)) {
 111         $name = $rest_method; # Stash name and code to run 'foo_GET' like an action below.
 112     }
 113
 114     # Generic handling for foo_*
 115     if (!$code) {
 116         my $code_action = {
 117             OPTIONS => sub {
 118                 $name = $rest_method;
 119                 $code = sub { $self->_return_options($self->name, @_) };
 120             },
 121             HEAD => sub {
 122               $rest_method =~ s{_HEAD$}{_GET}i;
 123               $self->_dispatch_rest_method($c, $rest_method);
 124             },
 125             default => sub {
 126                 # Otherwise, not implemented.
 127                 $name = $self->name . "_not_implemented";
 128                 $code = $controller->can($name) # User method
 129                     # Generic not implemented
 130                     || sub { $self->_return_not_implemented($self->name, @_) };
 131             },
 132         };
 133         my ( $http_method, $action_name ) = ( $rest_method, $self->name );
 134         $http_method =~ s{\Q$action_name\E\_}{};
 135         my $respond = ($code_action->{$http_method}
 136                        || $code_action->{'default'})->();
 137         return $respond unless $name;
 138     }
 139
 140     # localise stuff so we can dispatch the action 'as normal, but get
 141     # different stats shown, and different code run.
 142     # Also get the full path for the action, and make it look like a forward
 143     local $self->{code} = $code;
 144     my @name = split m{/}, $self->reverse;
 145     $name[-1] = $name;
 146     local $self->{reverse} = "-> " . join('/', @name);
 147
 148     $c->execute( $self->class, $self, @{ $req->args } );
 149 }
 150
 151 sub get_allowed_methods {
 152     my ( $self, $controller, $c, $name ) = @_;
 153     my $class = ref($controller) ? ref($controller) : $controller;
 154     my $methods = {
 155       map { /^$name\_(.+)$/ ? ( $1 => 1 ) : () }
 156         @{ Class::Inspector->methods($class) }
 157     };
 158     $methods->{'HEAD'} = 1 if $methods->{'GET'};
 159     delete $methods->{'not_implemented'};
 160     return sort keys %$methods;
 161 };
 162
 163 sub _return_options {
 164     my ( $self, $method_name, $controller, $c) = @_;
 165     my @allowed = $self->get_allowed_methods($controller, $c, $method_name);
 166     $c->response->content_type('text/plain');
 167     $c->response->status(200);
 168     $c->response->header( 'Allow' => \@allowed );
 169     $c->response->body(q{});
 170 }
 171
 172 sub _return_not_implemented {
 173     my ( $self, $method_name, $controller, $c ) = @_;
 174
 175     my @allowed = $self->get_allowed_methods($controller, $c, $method_name);
 176     $c->response->content_type('text/plain');
 177     $c->response->status(405);
 178     $c->response->header( 'Allow' => \@allowed );
 179     $c->response->body( "Method "
 180           . $c->request->method
 181           . " not implemented for "
 182           . $c->uri_for( $method_name ) );
 183 }
 184
 185 __PACKAGE__->meta->make_immutable;
 186
 187 1;
 188
 189 =back
 190
 191 =head1 SEE ALSO
 192
 193 You likely want to look at L<Catalyst::Controller::REST>, which implements a
 194 sensible set of defaults for a controller doing REST.
 195
 196 This class automatically adds the L<Catalyst::TraitFor::Request::REST> role to
 197 your request class.  If you're writing a web application which provides RESTful
 198 responses and still needs to accommodate web browsers, you may prefer to use
 199 L<Catalyst::TraitFor::Request::REST::ForBrowsers> instead.
 200
 201 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 202
 203 =head1 TROUBLESHOOTING
 204
 205 =over 4
 206
 207 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 208
 209 A:  Most likely, you haven't set Content-type equal to "application/json", or
 210 one of the accepted return formats.  You can do this by setting it in your query
 211 accepted return formats.  You can do this by setting it in your query string
 212 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 213
 214 B<NOTE> Apache will refuse %2F unless configured otherwise.
 215 Make sure C<AllowEncodedSlashes On> is in your httpd.conf file in order
 216 for this to run smoothly.
 217
 218 =back
 219
 220 =head1 AUTHOR
 221
 222 Adam Jacob E<lt>adam@stalecoffee.orgE<gt>, with lots of help from mst and jrockway
 223
 224 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 225
 226 =head1 CONTRIBUTORS
 227
 228 Tomas Doran (t0m) E<lt>bobtfish@bobtfish.netE<gt>
 229
 230 John Goulah
 231
 232 Christopher Laco
 233
 234 Daisuke Maki E<lt>daisuke@endeworks.jpE<gt>
 235
 236 Hans Dieter Pearcey
 237
 238 Brian Phillips E<lt>bphillips@cpan.orgE<gt>
 239
 240 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 241
 242 Luke Saunders
 243
 244 Arthur Axel "fREW" Schmidt E<lt>frioux@gmail.comE<gt>
 245
 246 J. Shirley E<lt>jshirley@gmail.comE<gt>
 247
 248 Gavin Henry E<lt>ghenry@surevoip.co.ukE<gt>
 249
 250 Gerv http://www.gerv.net/
 251
 252 Colin Newell <colin@opusvl.com>
 253
 254 Wallace Reis E<lt>wreis@cpan.orgE<gt>
 255
 256 =head1 COPYRIGHT
 257
 258 Copyright (c) 2006-2012 the above named AUTHOR and CONTRIBUTORS
 259
 260 =head1 LICENSE
 261
 262 You may distribute this code under the same terms as Perl itself.
 263
 264 =cut
 265