lib/Catalyst/Action/REST.pm

   1 #
   2 # REST.pm
   3 # Created by: Adam Jacob, Marchex, <adam@hjksolutions.com>
   4 # Created on: 10/12/2006 03:00:32 PM PDT
   5 #
   6 # $Id$
   7
   8 package Catalyst::Action::REST;
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'Catalyst::Action';
  14 use Class::Inspector;
  15 use Moose::Util qw(does_role);
  16 use Catalyst;
  17 use Catalyst::RequestRole::REST;
  18 use Catalyst::Controller::REST;
  19 use namespace::clean -except => 'meta';
  20
  21 BEGIN { require 5.008001; }
  22
  23 our $VERSION = '0.73';
  24
  25 =head1 NAME
  26
  27 Catalyst::Action::REST - Automated REST Method Dispatching
  28
  29 =head1 SYNOPSIS
  30
  31     sub foo :Local :ActionClass('REST') {
  32       ... do setup for HTTP method specific handlers ...
  33     }
  34
  35     sub foo_GET {
  36       ... do something for GET requests ...
  37     }
  38
  39     sub foo_PUT {
  40       ... do somethign for PUT requests ...
  41     }
  42
  43 =head1 DESCRIPTION
  44
  45 This Action handles doing automatic method dispatching for REST requests.  It
  46 takes a normal Catalyst action, and changes the dispatch to append an
  47 underscore and method name.
  48
  49 For example, in the synopsis above, calling GET on "/foo" would result in
  50 the foo_GET method being dispatched.
  51
  52 If a method is requested that is not implemented, this action will
  53 return a status 405 (Method Not Found).  It will populate the "Allow" header
  54 with the list of implemented request methods.  You can override this behavior
  55 by implementing a custom 405 handler like so:
  56
  57    sub foo_not_implemented {
  58       ... handle not implemented methods ...
  59    }
  60
  61 If you do not provide an _OPTIONS subroutine, we will automatically respond
  62 with a 200 OK.  The "Allow" header will be populated with the list of
  63 implemented request methods.
  64
  65 It is likely that you really want to look at L<Catalyst::Controller::REST>,
  66 which brings this class together with automatic Serialization of requests
  67 and responses.
  68
  69 When you use this module, the request class will be changed to
  70 L<Catalyst::Request::REST>.
  71
  72 =head1 METHODS
  73
  74 =over 4
  75
  76 =item dispatch
  77
  78 This method overrides the default dispatch mechanism to the re-dispatching
  79 mechanism described above.
  80
  81 =cut
  82
  83 sub dispatch {
  84     my $self = shift;
  85     my $c    = shift;
  86
  87     Catalyst::RequestRole::REST->meta->apply($c->request)
  88         unless does_role($c->request, 'Catalyst::RequestRole::REST');
  89
  90     my $controller = $c->component( $self->class );
  91     my $rest_method = $self->name . "_" . uc( $c->request->method );
  92
  93     my ($code, $name);
  94
  95     # Common case, for foo_GET etc
  96     if ($code = $controller->can($rest_method)) {
  97         # Exceute normal action
  98         $c->execute( $self->class, $self, @{ $c->req->args } );
  99         $name = $rest_method;
 100     }
 101
 102     # Generic handling for foo_OPTIONS
 103     if (!$code && $c->request->method eq "OPTIONS") {
 104         $name = $rest_method;
 105         $code = sub { $self->_return_options($self->name, @_) };
 106     }
 107
 108     # Otherwise, not implemented.
 109     if (!$code) {
 110         $name = $self->name . "_not_implemented";
 111         $code = $controller->can($name) # User method
 112             # Generic not implemented
 113             || sub { $self->_return_not_implemented($self->name, @_) };
 114     }
 115
 116     # localise stuff so we can dispatch the action 'as normal, but get
 117     # different stats shown, and different code run.
 118     local $self->{code} = $code;
 119     local $self->{reverse} = $name;
 120
 121     $c->execute( $self->class, $self, @{ $c->req->args } );
 122 }
 123
 124 sub _get_allowed_methods {
 125     my ( $self, $controller, $c, $name ) = @_;
 126     my $class = ref($controller) ? ref($controller) : $controller;
 127     my $methods    = Class::Inspector->methods($class);
 128     my @allowed;
 129     foreach my $method ( @{$methods} ) {
 130         if ( $method =~ /^$name\_(.+)$/ ) {
 131             push( @allowed, $1 );
 132         }
 133     }
 134     return @allowed;
 135 };
 136
 137 sub _return_options {
 138     my ( $self, $method_name, $controller, $c) = @_;
 139     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 140     $c->response->content_type('text/plain');
 141     $c->response->status(200);
 142     $c->response->header( 'Allow' => \@allowed );
 143 }
 144
 145 sub _return_not_implemented {
 146     my ( $self, $method_name, $controller, $c ) = @_;
 147
 148     my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
 149     $c->response->content_type('text/plain');
 150     $c->response->status(405);
 151     $c->response->header( 'Allow' => \@allowed );
 152     $c->response->body( "Method "
 153           . $c->request->method
 154           . " not implemented for "
 155           . $c->uri_for( $method_name ) );
 156 }
 157
 158 1;
 159
 160 =back
 161
 162 =head1 SEE ALSO
 163
 164 You likely want to look at L<Catalyst::Controller::REST>, which implements
 165 a sensible set of defaults for a controller doing REST.
 166
 167 L<Catalyst::Action::Serialize>, L<Catalyst::Action::Deserialize>
 168
 169 =head1 TROUBLESHOOTING
 170
 171 =over 4
 172
 173 =item Q: I'm getting a "415 Unsupported Media Type" error. What gives?!
 174
 175 A:  Most likely, you haven't set Content-type equal to "application/json", or
 176 one of the accepted return formats.  You can do this by setting it in your query
 177 accepted return formats.  You can do this by setting it in your query string
 178 thusly: C<< ?content-type=application%2Fjson (where %2F == / uri escaped). >>
 179
 180 B<NOTE> Apache will refuse %2F unless configured otherise.
 181 Make sure C<< AllowEncodedSlashes On >> is in your httpd.conf file in orde
 182 for this to run smoothly.
 183
 184 =back
 185
 186 =head1 MAINTAINER
 187
 188 Hans Dieter Pearcey
 189
 190 =head1 CONTRIBUTORS
 191
 192 Christopher Laco
 193
 194 Luke Saunders
 195
 196 John Goulah
 197
 198 Daisuke Maki <daisuke@endeworks.jp>
 199
 200 J. Shirley <jshirley@gmail.com>
 201
 202 Tomas Doran (t0m) <bobtfish@bobtfish.net>
 203
 204 =head1 AUTHOR
 205
 206 Adam Jacob <adam@stalecoffee.org>, with lots of help from mst and jrockway
 207
 208 Marchex, Inc. paid me while I developed this module. (L<http://www.marchex.com>)
 209
 210 =head1 LICENSE
 211
 212 You may distribute this code under the same terms as Perl itself.
 213
 214 =cut
 215