lib/CGI.pm

   1 package CGI;
   2 require 5.004;
   3 use Carp 'croak';
   4
   5 # See the bottom of this file for the POD documentation.  Search for the
   6 # string '=head'.
   7
   8 # You can run this file through either pod2man or pod2html to produce pretty
   9 # documentation in manual or html file format (these utilities are part of the
  10 # Perl 5 distribution).
  11
  12 # Copyright 1995-1998 Lincoln D. Stein.  All rights reserved.
  13 # It may be used and modified freely, but I do request that this copyright
  14 # notice remain attached to the file.  You may modify this module as you
  15 # wish, but if you redistribute a modified version, please attach a note
  16 # listing the modifications you have made.
  17
  18 # The most recent version and complete docs are available at:
  19 #   http://stein.cshl.org/WWW/software/CGI/
  20
  21 $CGI::revision = '$Id: CGI.pm,v 1.202 2006/02/24 19:03:29 lstein Exp $';
  22 $CGI::VERSION='3.17_01';
  23
  24 # HARD-CODED LOCATION FOR FILE UPLOAD TEMPORARY FILES.
  25 # UNCOMMENT THIS ONLY IF YOU KNOW WHAT YOU'RE DOING.
  26 # $CGITempFile::TMPDIRECTORY = '/usr/tmp';
  27 use CGI::Util qw(rearrange make_attributes unescape escape expires ebcdic2ascii ascii2ebcdic);
  28
  29 #use constant XHTML_DTD => ['-//W3C//DTD XHTML Basic 1.0//EN',
  30 #                           'http://www.w3.org/TR/xhtml-basic/xhtml-basic10.dtd'];
  31
  32 use constant XHTML_DTD => ['-//W3C//DTD XHTML 1.0 Transitional//EN',
  33                            'http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd'];
  34
  35 {
  36   local $^W = 0;
  37   $TAINTED = substr("$0$^X",0,0);
  38 }
  39
  40 $MOD_PERL = 0; # no mod_perl by default
  41 @SAVED_SYMBOLS = ();
  42
  43 # >>>>> Here are some globals that you might want to adjust <<<<<<
  44 sub initialize_globals {
  45     # Set this to 1 to enable copious autoloader debugging messages
  46     $AUTOLOAD_DEBUG = 0;
  47
  48     # Set this to 1 to generate XTML-compatible output
  49     $XHTML = 1;
  50
  51     # Change this to the preferred DTD to print in start_html()
  52     # or use default_dtd('text of DTD to use');
  53     $DEFAULT_DTD = [ '-//W3C//DTD HTML 4.01 Transitional//EN',
  54                      'http://www.w3.org/TR/html4/loose.dtd' ] ;
  55
  56     # Set this to 1 to enable NOSTICKY scripts
  57     # or:
  58     #    1) use CGI qw(-nosticky)
  59     #    2) $CGI::nosticky(1)
  60     $NOSTICKY = 0;
  61
  62     # Set this to 1 to enable NPH scripts
  63     # or:
  64     #    1) use CGI qw(-nph)
  65     #    2) CGI::nph(1)
  66     #    3) print header(-nph=>1)
  67     $NPH = 0;
  68
  69     # Set this to 1 to enable debugging from @ARGV
  70     # Set to 2 to enable debugging from STDIN
  71     $DEBUG = 1;
  72
  73     # Set this to 1 to make the temporary files created
  74     # during file uploads safe from prying eyes
  75     # or do...
  76     #    1) use CGI qw(:private_tempfiles)
  77     #    2) CGI::private_tempfiles(1);
  78     $PRIVATE_TEMPFILES = 0;
  79
  80     # Set this to 1 to generate automatic tab indexes
  81     $TABINDEX = 0;
  82
  83     # Set this to 1 to cause files uploaded in multipart documents
  84     # to be closed, instead of caching the file handle
  85     # or:
  86     #    1) use CGI qw(:close_upload_files)
  87     #    2) $CGI::close_upload_files(1);
  88     # Uploads with many files run out of file handles.
  89     # Also, for performance, since the file is already on disk,
  90     # it can just be renamed, instead of read and written.
  91     $CLOSE_UPLOAD_FILES = 0;
  92
  93     # Set this to a positive value to limit the size of a POSTing
  94     # to a certain number of bytes:
  95     $POST_MAX = -1;
  96
  97     # Change this to 1 to disable uploads entirely:
  98     $DISABLE_UPLOADS = 0;
  99
 100     # Automatically determined -- don't change
 101     $EBCDIC = 0;
 102
 103     # Change this to 1 to suppress redundant HTTP headers
 104     $HEADERS_ONCE = 0;
 105
 106     # separate the name=value pairs by semicolons rather than ampersands
 107     $USE_PARAM_SEMICOLONS = 1;
 108
 109     # Do not include undefined params parsed from query string
 110     # use CGI qw(-no_undef_params);
 111     $NO_UNDEF_PARAMS = 0;
 112
 113     # Other globals that you shouldn't worry about.
 114     undef $Q;
 115     $BEEN_THERE = 0;
 116     $DTD_PUBLIC_IDENTIFIER = "";
 117     undef @QUERY_PARAM;
 118     undef %EXPORT;
 119     undef $QUERY_CHARSET;
 120     undef %QUERY_FIELDNAMES;
 121
 122     # prevent complaints by mod_perl
 123     1;
 124 }
 125
 126 # ------------------ START OF THE LIBRARY ------------
 127
 128 *end_form = \&endform;
 129
 130 # make mod_perlhappy
 131 initialize_globals();
 132
 133 # FIGURE OUT THE OS WE'RE RUNNING UNDER
 134 # Some systems support the $^O variable.  If not
 135 # available then require() the Config library
 136 unless ($OS) {
 137     unless ($OS = $^O) {
 138         require Config;
 139         $OS = $Config::Config{'osname'};
 140     }
 141 }
 142 if ($OS =~ /^MSWin/i) {
 143   $OS = 'WINDOWS';
 144 } elsif ($OS =~ /^VMS/i) {
 145   $OS = 'VMS';
 146 } elsif ($OS =~ /^dos/i) {
 147   $OS = 'DOS';
 148 } elsif ($OS =~ /^MacOS/i) {
 149     $OS = 'MACINTOSH';
 150 } elsif ($OS =~ /^os2/i) {
 151     $OS = 'OS2';
 152 } elsif ($OS =~ /^epoc/i) {
 153     $OS = 'EPOC';
 154 } elsif ($OS =~ /^cygwin/i) {
 155     $OS = 'CYGWIN';
 156 } else {
 157     $OS = 'UNIX';
 158 }
 159
 160 # Some OS logic.  Binary mode enabled on DOS, NT and VMS
 161 $needs_binmode = $OS=~/^(WINDOWS|DOS|OS2|MSWin|CYGWIN)/;
 162
 163 # This is the default class for the CGI object to use when all else fails.
 164 $DefaultClass = 'CGI' unless defined $CGI::DefaultClass;
 165
 166 # This is where to look for autoloaded routines.
 167 $AutoloadClass = $DefaultClass unless defined $CGI::AutoloadClass;
 168
 169 # The path separator is a slash, backslash or semicolon, depending
 170 # on the paltform.
 171 $SL = {
 172      UNIX    => '/',  OS2 => '\\', EPOC      => '/', CYGWIN => '/',
 173      WINDOWS => '\\', DOS => '\\', MACINTOSH => ':', VMS    => '/'
 174     }->{$OS};
 175
 176 # This no longer seems to be necessary
 177 # Turn on NPH scripts by default when running under IIS server!
 178 # $NPH++ if defined($ENV{'SERVER_SOFTWARE'}) && $ENV{'SERVER_SOFTWARE'}=~/IIS/;
 179 $IIS++ if defined($ENV{'SERVER_SOFTWARE'}) && $ENV{'SERVER_SOFTWARE'}=~/IIS/;
 180
 181 # Turn on special checking for Doug MacEachern's modperl
 182 if (exists $ENV{MOD_PERL}) {
 183   # mod_perl handlers may run system() on scripts using CGI.pm;
 184   # Make sure so we don't get fooled by inherited $ENV{MOD_PERL}
 185   if (exists $ENV{MOD_PERL_API_VERSION} && $ENV{MOD_PERL_API_VERSION} == 2) {
 186     $MOD_PERL = 2;
 187     require Apache2::Response;
 188     require Apache2::RequestRec;
 189     require Apache2::RequestUtil;
 190     require Apache2::RequestIO;
 191     require APR::Pool;
 192   } else {
 193     $MOD_PERL = 1;
 194     require Apache;
 195   }
 196 }
 197
 198 # Turn on special checking for ActiveState's PerlEx
 199 $PERLEX++ if defined($ENV{'GATEWAY_INTERFACE'}) && $ENV{'GATEWAY_INTERFACE'} =~ /^CGI-PerlEx/;
 200
 201 # Define the CRLF sequence.  I can't use a simple "\r\n" because the meaning
 202 # of "\n" is different on different OS's (sometimes it generates CRLF, sometimes LF
 203 # and sometimes CR).  The most popular VMS web server
 204 # doesn't accept CRLF -- instead it wants a LR.  EBCDIC machines don't
 205 # use ASCII, so \015\012 means something different.  I find this all
 206 # really annoying.
 207 $EBCDIC = "\t" ne "\011";
 208 if ($OS eq 'VMS') {
 209   $CRLF = "\n";
 210 } elsif ($EBCDIC) {
 211   $CRLF= "\r\n";
 212 } else {
 213   $CRLF = "\015\012";
 214 }
 215
 216 if ($needs_binmode) {
 217     $CGI::DefaultClass->binmode(\*main::STDOUT);
 218     $CGI::DefaultClass->binmode(\*main::STDIN);
 219     $CGI::DefaultClass->binmode(\*main::STDERR);
 220 }
 221
 222 %EXPORT_TAGS = (
 223                 ':html2'=>['h1'..'h6',qw/p br hr ol ul li dl dt dd menu code var strong em
 224                            tt u i b blockquote pre img a address cite samp dfn html head
 225                            base body Link nextid title meta kbd start_html end_html
 226                            input Select option comment charset escapeHTML/],
 227                 ':html3'=>[qw/div table caption th td TR Tr sup Sub strike applet Param
 228                            embed basefont style span layer ilayer font frameset frame script small big Area Map/],
 229                 ':html4'=>[qw/abbr acronym bdo col colgroup del fieldset iframe
 230                             ins label legend noframes noscript object optgroup Q
 231                             thead tbody tfoot/],
 232                 ':netscape'=>[qw/blink fontsize center/],
 233                 ':form'=>[qw/textfield textarea filefield password_field hidden checkbox checkbox_group
 234                           submit reset defaults radio_group popup_menu button autoEscape
 235                           scrolling_list image_button start_form end_form startform endform
 236                           start_multipart_form end_multipart_form isindex tmpFileName uploadInfo URL_ENCODED MULTIPART/],
 237                 ':cgi'=>[qw/param upload path_info path_translated request_uri url self_url script_name
 238                          cookie Dump
 239                          raw_cookie request_method query_string Accept user_agent remote_host content_type
 240                          remote_addr referer server_name server_software server_port server_protocol virtual_port
 241                          virtual_host remote_ident auth_type http append
 242                          save_parameters restore_parameters param_fetch
 243                          remote_user user_name header redirect import_names put
 244                          Delete Delete_all url_param cgi_error/],
 245                 ':ssl' => [qw/https/],
 246                 ':cgi-lib' => [qw/ReadParse PrintHeader HtmlTop HtmlBot SplitParam Vars/],
 247                 ':html' => [qw/:html2 :html3 :html4 :netscape/],
 248                 ':standard' => [qw/:html2 :html3 :html4 :form :cgi/],
 249                 ':push' => [qw/multipart_init multipart_start multipart_end multipart_final/],
 250                 ':all' => [qw/:html2 :html3 :netscape :form :cgi :internal :html4/]
 251                 );
 252
 253 # Custom 'can' method for both autoloaded and non-autoloaded subroutines.
 254 # Author: Cees Hek <cees@sitesuite.com.au>
 255
 256 sub can {
 257         my($class, $method) = @_;
 258
 259         # See if UNIVERSAL::can finds it.
 260
 261         if (my $func = $class -> SUPER::can($method) ){
 262                 return $func;
 263         }
 264
 265         # Try to compile the function.
 266
 267         eval {
 268                 # _compile looks at $AUTOLOAD for the function name.
 269
 270                 local $AUTOLOAD = join "::", $class, $method;
 271                 &_compile;
 272         };
 273
 274         # Now that the function is loaded (if it exists)
 275         # just use UNIVERSAL::can again to do the work.
 276
 277         return $class -> SUPER::can($method);
 278 }
 279
 280 # to import symbols into caller
 281 sub import {
 282     my $self = shift;
 283
 284     # This causes modules to clash.
 285     undef %EXPORT_OK;
 286     undef %EXPORT;
 287
 288     $self->_setup_symbols(@_);
 289     my ($callpack, $callfile, $callline) = caller;
 290
 291     # To allow overriding, search through the packages
 292     # Till we find one in which the correct subroutine is defined.
 293     my @packages = ($self,@{"$self\:\:ISA"});
 294     foreach $sym (keys %EXPORT) {
 295         my $pck;
 296         my $def = ${"$self\:\:AutoloadClass"} || $DefaultClass;
 297         foreach $pck (@packages) {
 298             if (defined(&{"$pck\:\:$sym"})) {
 299                 $def = $pck;
 300                 last;
 301             }
 302         }
 303         *{"${callpack}::$sym"} = \&{"$def\:\:$sym"};
 304     }
 305 }
 306
 307 sub compile {
 308     my $pack = shift;
 309     $pack->_setup_symbols('-compile',@_);
 310 }
 311
 312 sub expand_tags {
 313     my($tag) = @_;
 314     return ("start_$1","end_$1") if $tag=~/^(?:\*|start_|end_)(.+)/;
 315     my(@r);
 316     return ($tag) unless $EXPORT_TAGS{$tag};
 317     foreach (@{$EXPORT_TAGS{$tag}}) {
 318         push(@r,&expand_tags($_));
 319     }
 320     return @r;
 321 }
 322
 323 #### Method: new
 324 # The new routine.  This will check the current environment
 325 # for an existing query string, and initialize itself, if so.
 326 ####
 327 sub new {
 328   my($class,@initializer) = @_;
 329   my $self = {};
 330
 331   bless $self,ref $class || $class || $DefaultClass;
 332   if (ref($initializer[0])
 333       && (UNIVERSAL::isa($initializer[0],'Apache')
 334           ||
 335           UNIVERSAL::isa($initializer[0],'Apache2::RequestRec')
 336          )) {
 337     $self->r(shift @initializer);
 338   }
 339  if (ref($initializer[0])
 340      && (UNIVERSAL::isa($initializer[0],'CODE'))) {
 341     $self->upload_hook(shift @initializer, shift @initializer);
 342   }
 343   if ($MOD_PERL) {
 344     if ($MOD_PERL == 1) {
 345       $self->r(Apache->request) unless $self->r;
 346       my $r = $self->r;
 347       $r->register_cleanup(\&CGI::_reset_globals);
 348     }
 349     else {
 350       # XXX: once we have the new API
 351       # will do a real PerlOptions -SetupEnv check
 352       $self->r(Apache2::RequestUtil->request) unless $self->r;
 353       my $r = $self->r;
 354       $r->subprocess_env unless exists $ENV{REQUEST_METHOD};
 355       $r->pool->cleanup_register(\&CGI::_reset_globals);
 356     }
 357     undef $NPH;
 358   }
 359   $self->_reset_globals if $PERLEX;
 360   $self->init(@initializer);
 361   return $self;
 362 }
 363
 364 # We provide a DESTROY method so that we can ensure that
 365 # temporary files are closed (via Fh->DESTROY) before they
 366 # are unlinked (via CGITempFile->DESTROY) because it is not
 367 # possible to unlink an open file on Win32. We explicitly
 368 # call DESTROY on each, rather than just undefing them and
 369 # letting Perl DESTROY them by garbage collection, in case the
 370 # user is still holding any reference to them as well.
 371 sub DESTROY {
 372   my $self = shift;
 373   if ($OS eq 'WINDOWS') {
 374     foreach my $href (values %{$self->{'.tmpfiles'}}) {
 375       $href->{hndl}->DESTROY if defined $href->{hndl};
 376       $href->{name}->DESTROY if defined $href->{name};
 377     }
 378   }
 379 }
 380
 381 sub r {
 382   my $self = shift;
 383   my $r = $self->{'.r'};
 384   $self->{'.r'} = shift if @_;
 385   $r;
 386 }
 387
 388 sub upload_hook {
 389   my $self;
 390   if (ref $_[0] eq 'CODE') {
 391     $CGI::Q = $self = $CGI::DefaultClass->new(@_);
 392   } else {
 393     $self = shift;
 394   }
 395   my ($hook,$data) = @_;
 396   $self->{'.upload_hook'} = $hook;
 397   $self->{'.upload_data'} = $data;
 398 }
 399
 400 #### Method: param
 401 # Returns the value(s)of a named parameter.
 402 # If invoked in a list context, returns the
 403 # entire list.  Otherwise returns the first
 404 # member of the list.
 405 # If name is not provided, return a list of all
 406 # the known parameters names available.
 407 # If more than one argument is provided, the
 408 # second and subsequent arguments are used to
 409 # set the value of the parameter.
 410 ####
 411 sub param {
 412     my($self,@p) = self_or_default(@_);
 413     return $self->all_parameters unless @p;
 414     my($name,$value,@other);
 415
 416     # For compatibility between old calling style and use_named_parameters() style,
 417     # we have to special case for a single parameter present.
 418     if (@p > 1) {
 419         ($name,$value,@other) = rearrange([NAME,[DEFAULT,VALUE,VALUES]],@p);
 420         my(@values);
 421
 422         if (substr($p[0],0,1) eq '-') {
 423             @values = defined($value) ? (ref($value) && ref($value) eq 'ARRAY' ? @{$value} : $value) : ();
 424         } else {
 425             foreach ($value,@other) {
 426                 push(@values,$_) if defined($_);
 427             }
 428         }
 429         # If values is provided, then we set it.
 430         if (@values) {
 431             $self->add_parameter($name);
 432             $self->{$name}=[@values];
 433         }
 434     } else {
 435         $name = $p[0];
 436     }
 437
 438     return unless defined($name) && $self->{$name};
 439     return wantarray ? @{$self->{$name}} : $self->{$name}->[0];
 440 }
 441
 442 sub self_or_default {
 443     return @_ if defined($_[0]) && (!ref($_[0])) &&($_[0] eq 'CGI');
 444     unless (defined($_[0]) &&
 445             (ref($_[0]) eq 'CGI' || UNIVERSAL::isa($_[0],'CGI')) # slightly optimized for common case
 446             ) {
 447         $Q = $CGI::DefaultClass->new unless defined($Q);
 448         unshift(@_,$Q);
 449     }
 450     return wantarray ? @_ : $Q;
 451 }
 452
 453 sub self_or_CGI {
 454     local $^W=0;                # prevent a warning
 455     if (defined($_[0]) &&
 456         (substr(ref($_[0]),0,3) eq 'CGI'
 457          || UNIVERSAL::isa($_[0],'CGI'))) {
 458         return @_;
 459     } else {
 460         return ($DefaultClass,@_);
 461     }
 462 }
 463
 464 ########################################
 465 # THESE METHODS ARE MORE OR LESS PRIVATE
 466 # GO TO THE __DATA__ SECTION TO SEE MORE
 467 # PUBLIC METHODS
 468 ########################################
 469
 470 # Initialize the query object from the environment.
 471 # If a parameter list is found, this object will be set
 472 # to an associative array in which parameter names are keys
 473 # and the values are stored as lists
 474 # If a keyword list is found, this method creates a bogus
 475 # parameter list with the single parameter 'keywords'.
 476
 477 sub init {
 478   my $self = shift;
 479   my($query_string,$meth,$content_length,$fh,@lines) = ('','','','');
 480
 481   my $initializer = shift;  # for backward compatibility
 482   local($/) = "\n";
 483
 484     # set autoescaping on by default
 485     $self->{'escape'} = 1;
 486
 487     # if we get called more than once, we want to initialize
 488     # ourselves from the original query (which may be gone
 489     # if it was read from STDIN originally.)
 490     if (defined(@QUERY_PARAM) && !defined($initializer)) {
 491         foreach (@QUERY_PARAM) {
 492             $self->param('-name'=>$_,'-value'=>$QUERY_PARAM{$_});
 493         }
 494         $self->charset($QUERY_CHARSET);
 495         $self->{'.fieldnames'} = {%QUERY_FIELDNAMES};
 496         return;
 497     }
 498
 499     $meth=$ENV{'REQUEST_METHOD'} if defined($ENV{'REQUEST_METHOD'});
 500     $content_length = defined($ENV{'CONTENT_LENGTH'}) ? $ENV{'CONTENT_LENGTH'} : 0;
 501
 502     $fh = to_filehandle($initializer) if $initializer;
 503
 504     # set charset to the safe ISO-8859-1
 505     $self->charset('ISO-8859-1');
 506
 507   METHOD: {
 508
 509       # avoid unreasonably large postings
 510       if (($POST_MAX > 0) && ($content_length > $POST_MAX)) {
 511         # quietly read and discard the post
 512           my $buffer;
 513           my $tmplength = $content_length;
 514           while($tmplength > 0) {
 515                  my $maxbuffer = ($tmplength < 10000)?$tmplength:10000;
 516                  my $bytesread = $MOD_PERL ? $self->r->read($buffer,$maxbuffer) : read(STDIN,$buffer,$maxbuffer);
 517                  $tmplength -= $bytesread;
 518           }
 519           $self->cgi_error("413 Request entity too large");
 520           last METHOD;
 521        }
 522
 523       # Process multipart postings, but only if the initializer is
 524       # not defined.
 525       if ($meth eq 'POST'
 526           && defined($ENV{'CONTENT_TYPE'})
 527           && $ENV{'CONTENT_TYPE'}=~m|^multipart/form-data|
 528           && !defined($initializer)
 529           ) {
 530           my($boundary) = $ENV{'CONTENT_TYPE'} =~ /boundary=\"?([^\";,]+)\"?/;
 531           $self->read_multipart($boundary,$content_length);
 532           last METHOD;
 533       }
 534
 535       # If initializer is defined, then read parameters
 536       # from it.
 537       if (defined($initializer)) {
 538           if (UNIVERSAL::isa($initializer,'CGI')) {
 539               $query_string = $initializer->query_string;
 540               last METHOD;
 541           }
 542           if (ref($initializer) && ref($initializer) eq 'HASH') {
 543               foreach (keys %$initializer) {
 544                   $self->param('-name'=>$_,'-value'=>$initializer->{$_});
 545               }
 546               last METHOD;
 547           }
 548
 549           if (defined($fh) && ($fh ne '')) {
 550               while (<$fh>) {
 551                   chomp;
 552                   last if /^=/;
 553                   push(@lines,$_);
 554               }
 555               # massage back into standard format
 556               if ("@lines" =~ /=/) {
 557                   $query_string=join("&",@lines);
 558               } else {
 559                   $query_string=join("+",@lines);
 560               }
 561               last METHOD;
 562           }
 563
 564           if (defined($fh) && ($fh ne '')) {
 565               while (<$fh>) {
 566                   chomp;
 567                   last if /^=/;
 568                   push(@lines,$_);
 569               }
 570               # massage back into standard format
 571               if ("@lines" =~ /=/) {
 572                   $query_string=join("&",@lines);
 573               } else {
 574                   $query_string=join("+",@lines);
 575               }
 576               last METHOD;
 577           }
 578
 579           # last chance -- treat it as a string
 580           $initializer = $$initializer if ref($initializer) eq 'SCALAR';
 581           $query_string = $initializer;
 582
 583           last METHOD;
 584       }
 585
 586       # If method is GET or HEAD, fetch the query from
 587       # the environment.
 588       if ($meth=~/^(GET|HEAD)$/) {
 589           if ($MOD_PERL) {
 590             $query_string = $self->r->args;
 591           } else {
 592               $query_string = $ENV{'QUERY_STRING'} if defined $ENV{'QUERY_STRING'};
 593               $query_string ||= $ENV{'REDIRECT_QUERY_STRING'} if defined $ENV{'REDIRECT_QUERY_STRING'};
 594           }
 595           last METHOD;
 596       }
 597
 598       if ($meth eq 'POST') {
 599           $self->read_from_client(\$query_string,$content_length,0)
 600               if $content_length > 0;
 601           # Some people want to have their cake and eat it too!
 602           # Uncomment this line to have the contents of the query string
 603           # APPENDED to the POST data.
 604           # $query_string .= (length($query_string) ? '&' : '') . $ENV{'QUERY_STRING'} if defined $ENV{'QUERY_STRING'};
 605           last METHOD;
 606       }
 607
 608       # If $meth is not of GET, POST or HEAD, assume we're being debugged offline.
 609       # Check the command line and then the standard input for data.
 610       # We use the shellwords package in order to behave the way that
 611       # UN*X programmers expect.
 612       if ($DEBUG)
 613       {
 614           my $cmdline_ret = read_from_cmdline();
 615           $query_string = $cmdline_ret->{'query_string'};
 616           if (defined($cmdline_ret->{'subpath'}))
 617           {
 618               $self->path_info($cmdline_ret->{'subpath'});
 619           }
 620       }
 621   }
 622
 623 # YL: Begin Change for XML handler 10/19/2001
 624     if ($meth eq 'POST'
 625         && defined($ENV{'CONTENT_TYPE'})
 626         && $ENV{'CONTENT_TYPE'} !~ m|^application/x-www-form-urlencoded|
 627         && $ENV{'CONTENT_TYPE'} !~ m|^multipart/form-data| ) {
 628         my($param) = 'POSTDATA' ;
 629         $self->add_parameter($param) ;
 630       push (@{$self->{$param}},$query_string);
 631       undef $query_string ;
 632     }
 633 # YL: End Change for XML handler 10/19/2001
 634
 635     # We now have the query string in hand.  We do slightly
 636     # different things for keyword lists and parameter lists.
 637     if (defined $query_string && length $query_string) {
 638         if ($query_string =~ /[&=;]/) {
 639             $self->parse_params($query_string);
 640         } else {
 641             $self->add_parameter('keywords');
 642             $self->{'keywords'} = [$self->parse_keywordlist($query_string)];
 643         }
 644     }
 645
 646     # Special case.  Erase everything if there is a field named
 647     # .defaults.
 648     if ($self->param('.defaults')) {
 649       $self->delete_all();
 650     }
 651
 652     # Associative array containing our defined fieldnames
 653     $self->{'.fieldnames'} = {};
 654     foreach ($self->param('.cgifields')) {
 655         $self->{'.fieldnames'}->{$_}++;
 656     }
 657
 658     # Clear out our default submission button flag if present
 659     $self->delete('.submit');
 660     $self->delete('.cgifields');
 661
 662     $self->save_request unless defined $initializer;
 663 }
 664
 665 # FUNCTIONS TO OVERRIDE:
 666 # Turn a string into a filehandle
 667 sub to_filehandle {
 668     my $thingy = shift;
 669     return undef unless $thingy;
 670     return $thingy if UNIVERSAL::isa($thingy,'GLOB');
 671     return $thingy if UNIVERSAL::isa($thingy,'FileHandle');
 672     if (!ref($thingy)) {
 673         my $caller = 1;
 674         while (my $package = caller($caller++)) {
 675             my($tmp) = $thingy=~/[\':]/ ? $thingy : "$package\:\:$thingy";
 676             return $tmp if defined(fileno($tmp));
 677         }
 678     }
 679     return undef;
 680 }
 681
 682 # send output to the browser
 683 sub put {
 684     my($self,@p) = self_or_default(@_);
 685     $self->print(@p);
 686 }
 687
 688 # print to standard output (for overriding in mod_perl)
 689 sub print {
 690     shift;
 691     CORE::print(@_);
 692 }
 693
 694 # get/set last cgi_error
 695 sub cgi_error {
 696     my ($self,$err) = self_or_default(@_);
 697     $self->{'.cgi_error'} = $err if defined $err;
 698     return $self->{'.cgi_error'};
 699 }
 700
 701 sub save_request {
 702     my($self) = @_;
 703     # We're going to play with the package globals now so that if we get called
 704     # again, we initialize ourselves in exactly the same way.  This allows
 705     # us to have several of these objects.
 706     @QUERY_PARAM = $self->param; # save list of parameters
 707     foreach (@QUERY_PARAM) {
 708       next unless defined $_;
 709       $QUERY_PARAM{$_}=$self->{$_};
 710     }
 711     $QUERY_CHARSET = $self->charset;
 712     %QUERY_FIELDNAMES = %{$self->{'.fieldnames'}};
 713 }
 714
 715 sub parse_params {
 716     my($self,$tosplit) = @_;
 717     my(@pairs) = split(/[&;]/,$tosplit);
 718     my($param,$value);
 719     foreach (@pairs) {
 720         ($param,$value) = split('=',$_,2);
 721         next unless defined $param;
 722         next if $NO_UNDEF_PARAMS and not defined $value;
 723         $value = '' unless defined $value;
 724         $param = unescape($param);
 725         $value = unescape($value);
 726         $self->add_parameter($param);
 727         push (@{$self->{$param}},$value);
 728     }
 729 }
 730
 731 sub add_parameter {
 732     my($self,$param)=@_;
 733     return unless defined $param;
 734     push (@{$self->{'.parameters'}},$param)
 735         unless defined($self->{$param});
 736 }
 737
 738 sub all_parameters {
 739     my $self = shift;
 740     return () unless defined($self) && $self->{'.parameters'};
 741     return () unless @{$self->{'.parameters'}};
 742     return @{$self->{'.parameters'}};
 743 }
 744
 745 # put a filehandle into binary mode (DOS)
 746 sub binmode {
 747     return unless defined($_[1]) && defined fileno($_[1]);
 748     CORE::binmode($_[1]);
 749 }
 750
 751 sub _make_tag_func {
 752     my ($self,$tagname) = @_;
 753     my $func = qq(
 754         sub $tagname {
 755          my (\$q,\$a,\@rest) = self_or_default(\@_);
 756          my(\$attr) = '';
 757          if (ref(\$a) && ref(\$a) eq 'HASH') {
 758             my(\@attr) = make_attributes(\$a,\$q->{'escape'});
 759             \$attr = " \@attr" if \@attr;
 760           } else {
 761             unshift \@rest,\$a if defined \$a;
 762           }
 763         );
 764     if ($tagname=~/start_(\w+)/i) {
 765         $func .= qq! return "<\L$1\E\$attr>";} !;
 766     } elsif ($tagname=~/end_(\w+)/i) {
 767         $func .= qq! return "<\L/$1\E>"; } !;
 768     } else {
 769         $func .= qq#
 770             return \$XHTML ? "\L<$tagname\E\$attr />" : "\L<$tagname\E\$attr>" unless \@rest;
 771             my(\$tag,\$untag) = ("\L<$tagname\E\$attr>","\L</$tagname>\E");
 772             my \@result = map { "\$tag\$_\$untag" }
 773                               (ref(\$rest[0]) eq 'ARRAY') ? \@{\$rest[0]} : "\@rest";
 774             return "\@result";
 775             }#;
 776     }
 777 return $func;
 778 }
 779
 780 sub AUTOLOAD {
 781     print STDERR "CGI::AUTOLOAD for $AUTOLOAD\n" if $CGI::AUTOLOAD_DEBUG;
 782     my $func = &_compile;
 783     goto &$func;
 784 }
 785
 786 sub _compile {
 787     my($func) = $AUTOLOAD;
 788     my($pack,$func_name);
 789     {
 790         local($1,$2); # this fixes an obscure variable suicide problem.
 791         $func=~/(.+)::([^:]+)$/;
 792         ($pack,$func_name) = ($1,$2);
 793         $pack=~s/::SUPER$//;    # fix another obscure problem
 794         $pack = ${"$pack\:\:AutoloadClass"} || $CGI::DefaultClass
 795             unless defined(${"$pack\:\:AUTOLOADED_ROUTINES"});
 796
 797         my($sub) = \%{"$pack\:\:SUBS"};
 798         unless (%$sub) {
 799            my($auto) = \${"$pack\:\:AUTOLOADED_ROUTINES"};
 800            local ($@,$!);
 801            eval "package $pack; $$auto";
 802            croak("$AUTOLOAD: $@") if $@;
 803            $$auto = '';  # Free the unneeded storage (but don't undef it!!!)
 804        }
 805        my($code) = $sub->{$func_name};
 806
 807        $code = "sub $AUTOLOAD { }" if (!$code and $func_name eq 'DESTROY');
 808        if (!$code) {
 809            (my $base = $func_name) =~ s/^(start_|end_)//i;
 810            if ($EXPORT{':any'} ||
 811                $EXPORT{'-any'} ||
 812                $EXPORT{$base} ||
 813                (%EXPORT_OK || grep(++$EXPORT_OK{$_},&expand_tags(':html')))
 814                    && $EXPORT_OK{$base}) {
 815                $code = $CGI::DefaultClass->_make_tag_func($func_name);
 816            }
 817        }
 818        croak("Undefined subroutine $AUTOLOAD\n") unless $code;
 819        local ($@,$!);
 820        eval "package $pack; $code";
 821        if ($@) {
 822            $@ =~ s/ at .*\n//;
 823            croak("$AUTOLOAD: $@");
 824        }
 825     }
 826     CORE::delete($sub->{$func_name});  #free storage
 827     return "$pack\:\:$func_name";
 828 }
 829
 830 sub _selected {
 831   my $self = shift;
 832   my $value = shift;
 833   return '' unless $value;
 834   return $XHTML ? qq(selected="selected" ) : qq(selected );
 835 }
 836
 837 sub _checked {
 838   my $self = shift;
 839   my $value = shift;
 840   return '' unless $value;
 841   return $XHTML ? qq(checked="checked" ) : qq(checked );
 842 }
 843
 844 sub _reset_globals { initialize_globals(); }
 845
 846 sub _setup_symbols {
 847     my $self = shift;
 848     my $compile = 0;
 849
 850     # to avoid reexporting unwanted variables
 851     undef %EXPORT;
 852
 853     foreach (@_) {
 854         $HEADERS_ONCE++,         next if /^[:-]unique_headers$/;
 855         $NPH++,                  next if /^[:-]nph$/;
 856         $NOSTICKY++,             next if /^[:-]nosticky$/;
 857         $DEBUG=0,                next if /^[:-]no_?[Dd]ebug$/;
 858         $DEBUG=2,                next if /^[:-][Dd]ebug$/;
 859         $USE_PARAM_SEMICOLONS++, next if /^[:-]newstyle_urls$/;
 860         $XHTML++,                next if /^[:-]xhtml$/;
 861         $XHTML=0,                next if /^[:-]no_?xhtml$/;
 862         $USE_PARAM_SEMICOLONS=0, next if /^[:-]oldstyle_urls$/;
 863         $PRIVATE_TEMPFILES++,    next if /^[:-]private_tempfiles$/;
 864         $TABINDEX++,             next if /^[:-]tabindex$/;
 865         $CLOSE_UPLOAD_FILES++,   next if /^[:-]close_upload_files$/;
 866         $EXPORT{$_}++,           next if /^[:-]any$/;
 867         $compile++,              next if /^[:-]compile$/;
 868         $NO_UNDEF_PARAMS++,      next if /^[:-]no_undef_params$/;
 869
 870         # This is probably extremely evil code -- to be deleted some day.
 871         if (/^[-]autoload$/) {
 872             my($pkg) = caller(1);
 873             *{"${pkg}::AUTOLOAD"} = sub {
 874                 my($routine) = $AUTOLOAD;
 875                 $routine =~ s/^.*::/CGI::/;
 876                 &$routine;
 877             };
 878             next;
 879         }
 880
 881         foreach (&expand_tags($_)) {
 882             tr/a-zA-Z0-9_//cd;  # don't allow weird function names
 883             $EXPORT{$_}++;
 884         }
 885     }
 886     _compile_all(keys %EXPORT) if $compile;
 887     @SAVED_SYMBOLS = @_;
 888 }
 889
 890 sub charset {
 891   my ($self,$charset) = self_or_default(@_);
 892   $self->{'.charset'} = $charset if defined $charset;
 893   $self->{'.charset'};
 894 }
 895
 896 sub element_id {
 897   my ($self,$new_value) = self_or_default(@_);
 898   $self->{'.elid'} = $new_value if defined $new_value;
 899   sprintf('%010d',$self->{'.elid'}++);
 900 }
 901
 902 sub element_tab {
 903   my ($self,$new_value) = self_or_default(@_);
 904   $self->{'.etab'} ||= 1;
 905   $self->{'.etab'} = $new_value if defined $new_value;
 906   my $tab = $self->{'.etab'}++;
 907   return '' unless $TABINDEX or defined $new_value;
 908   return qq(tabindex="$tab" );
 909 }
 910
 911 ###############################################################################
 912 ################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
 913 ###############################################################################
 914 $AUTOLOADED_ROUTINES = '';      # get rid of -w warning
 915 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
 916
 917 %SUBS = (
 918
 919 'URL_ENCODED'=> <<'END_OF_FUNC',
 920 sub URL_ENCODED { 'application/x-www-form-urlencoded'; }
 921 END_OF_FUNC
 922
 923 'MULTIPART' => <<'END_OF_FUNC',
 924 sub MULTIPART {  'multipart/form-data'; }
 925 END_OF_FUNC
 926
 927 'SERVER_PUSH' => <<'END_OF_FUNC',
 928 sub SERVER_PUSH { 'multipart/x-mixed-replace;boundary="' . shift() . '"'; }
 929 END_OF_FUNC
 930
 931 'new_MultipartBuffer' => <<'END_OF_FUNC',
 932 # Create a new multipart buffer
 933 sub new_MultipartBuffer {
 934     my($self,$boundary,$length) = @_;
 935     return MultipartBuffer->new($self,$boundary,$length);
 936 }
 937 END_OF_FUNC
 938
 939 'read_from_client' => <<'END_OF_FUNC',
 940 # Read data from a file handle
 941 sub read_from_client {
 942     my($self, $buff, $len, $offset) = @_;
 943     local $^W=0;                # prevent a warning
 944     return $MOD_PERL
 945         ? $self->r->read($$buff, $len, $offset)
 946         : read(\*STDIN, $$buff, $len, $offset);
 947 }
 948 END_OF_FUNC
 949
 950 'delete' => <<'END_OF_FUNC',
 951 #### Method: delete
 952 # Deletes the named parameter entirely.
 953 ####
 954 sub delete {
 955     my($self,@p) = self_or_default(@_);
 956     my(@names) = rearrange([NAME],@p);
 957     my @to_delete = ref($names[0]) eq 'ARRAY' ? @$names[0] : @names;
 958     my %to_delete;
 959     foreach my $name (@to_delete)
 960     {
 961         CORE::delete $self->{$name};
 962         CORE::delete $self->{'.fieldnames'}->{$name};
 963         $to_delete{$name}++;
 964     }
 965     @{$self->{'.parameters'}}=grep { !exists($to_delete{$_}) } $self->param();
 966     return;
 967 }
 968 END_OF_FUNC
 969
 970 #### Method: import_names
 971 # Import all parameters into the given namespace.
 972 # Assumes namespace 'Q' if not specified
 973 ####
 974 'import_names' => <<'END_OF_FUNC',
 975 sub import_names {
 976     my($self,$namespace,$delete) = self_or_default(@_);
 977     $namespace = 'Q' unless defined($namespace);
 978     die "Can't import names into \"main\"\n" if \%{"${namespace}::"} == \%::;
 979     if ($delete || $MOD_PERL || exists $ENV{'FCGI_ROLE'}) {
 980         # can anyone find an easier way to do this?
 981         foreach (keys %{"${namespace}::"}) {
 982             local *symbol = "${namespace}::${_}";
 983             undef $symbol;
 984             undef @symbol;
 985             undef %symbol;
 986         }
 987     }
 988     my($param,@value,$var);
 989     foreach $param ($self->param) {
 990         # protect against silly names
 991         ($var = $param)=~tr/a-zA-Z0-9_/_/c;
 992         $var =~ s/^(?=\d)/_/;
 993         local *symbol = "${namespace}::$var";
 994         @value = $self->param($param);
 995         @symbol = @value;
 996         $symbol = $value[0];
 997     }
 998 }
 999 END_OF_FUNC
1000
1001 #### Method: keywords
1002 # Keywords acts a bit differently.  Calling it in a list context
1003 # returns the list of keywords.
1004 # Calling it in a scalar context gives you the size of the list.
1005 ####
1006 'keywords' => <<'END_OF_FUNC',
1007 sub keywords {
1008     my($self,@values) = self_or_default(@_);
1009     # If values is provided, then we set it.
1010     $self->{'keywords'}=[@values] if @values;
1011     my(@result) = defined($self->{'keywords'}) ? @{$self->{'keywords'}} : ();
1012     @result;
1013 }
1014 END_OF_FUNC
1015
1016 # These are some tie() interfaces for compatibility
1017 # with Steve Brenner's cgi-lib.pl routines
1018 'Vars' => <<'END_OF_FUNC',
1019 sub Vars {
1020     my $q = shift;
1021     my %in;
1022     tie(%in,CGI,$q);
1023     return %in if wantarray;
1024     return \%in;
1025 }
1026 END_OF_FUNC
1027
1028 # These are some tie() interfaces for compatibility
1029 # with Steve Brenner's cgi-lib.pl routines
1030 'ReadParse' => <<'END_OF_FUNC',
1031 sub ReadParse {
1032     local(*in);
1033     if (@_) {
1034         *in = $_[0];
1035     } else {
1036         my $pkg = caller();
1037         *in=*{"${pkg}::in"};
1038     }
1039     tie(%in,CGI);
1040     return scalar(keys %in);
1041 }
1042 END_OF_FUNC
1043
1044 'PrintHeader' => <<'END_OF_FUNC',
1045 sub PrintHeader {
1046     my($self) = self_or_default(@_);
1047     return $self->header();
1048 }
1049 END_OF_FUNC
1050
1051 'HtmlTop' => <<'END_OF_FUNC',
1052 sub HtmlTop {
1053     my($self,@p) = self_or_default(@_);
1054     return $self->start_html(@p);
1055 }
1056 END_OF_FUNC
1057
1058 'HtmlBot' => <<'END_OF_FUNC',
1059 sub HtmlBot {
1060     my($self,@p) = self_or_default(@_);
1061     return $self->end_html(@p);
1062 }
1063 END_OF_FUNC
1064
1065 'SplitParam' => <<'END_OF_FUNC',
1066 sub SplitParam {
1067     my ($param) = @_;
1068     my (@params) = split ("\0", $param);
1069     return (wantarray ? @params : $params[0]);
1070 }
1071 END_OF_FUNC
1072
1073 'MethGet' => <<'END_OF_FUNC',
1074 sub MethGet {
1075     return request_method() eq 'GET';
1076 }
1077 END_OF_FUNC
1078
1079 'MethPost' => <<'END_OF_FUNC',
1080 sub MethPost {
1081     return request_method() eq 'POST';
1082 }
1083 END_OF_FUNC
1084
1085 'TIEHASH' => <<'END_OF_FUNC',
1086 sub TIEHASH {
1087     my $class = shift;
1088     my $arg   = $_[0];
1089     if (ref($arg) && UNIVERSAL::isa($arg,'CGI')) {
1090        return $arg;
1091     }
1092     return $Q ||= $class->new(@_);
1093 }
1094 END_OF_FUNC
1095
1096 'STORE' => <<'END_OF_FUNC',
1097 sub STORE {
1098     my $self = shift;
1099     my $tag  = shift;
1100     my $vals = shift;
1101     my @vals = index($vals,"\0")!=-1 ? split("\0",$vals) : $vals;
1102     $self->param(-name=>$tag,-value=>\@vals);
1103 }
1104 END_OF_FUNC
1105
1106 'FETCH' => <<'END_OF_FUNC',
1107 sub FETCH {
1108     return $_[0] if $_[1] eq 'CGI';
1109     return undef unless defined $_[0]->param($_[1]);
1110     return join("\0",$_[0]->param($_[1]));
1111 }
1112 END_OF_FUNC
1113
1114 'FIRSTKEY' => <<'END_OF_FUNC',
1115 sub FIRSTKEY {
1116     $_[0]->{'.iterator'}=0;
1117     $_[0]->{'.parameters'}->[$_[0]->{'.iterator'}++];
1118 }
1119 END_OF_FUNC
1120
1121 'NEXTKEY' => <<'END_OF_FUNC',
1122 sub NEXTKEY {
1123     $_[0]->{'.parameters'}->[$_[0]->{'.iterator'}++];
1124 }
1125 END_OF_FUNC
1126
1127 'EXISTS' => <<'END_OF_FUNC',
1128 sub EXISTS {
1129     exists $_[0]->{$_[1]};
1130 }
1131 END_OF_FUNC
1132
1133 'DELETE' => <<'END_OF_FUNC',
1134 sub DELETE {
1135     $_[0]->delete($_[1]);
1136 }
1137 END_OF_FUNC
1138
1139 'CLEAR' => <<'END_OF_FUNC',
1140 sub CLEAR {
1141     %{$_[0]}=();
1142 }
1143 ####
1144 END_OF_FUNC
1145
1146 ####
1147 # Append a new value to an existing query
1148 ####
1149 'append' => <<'EOF',
1150 sub append {
1151     my($self,@p) = self_or_default(@_);
1152     my($name,$value) = rearrange([NAME,[VALUE,VALUES]],@p);
1153     my(@values) = defined($value) ? (ref($value) ? @{$value} : $value) : ();
1154     if (@values) {
1155         $self->add_parameter($name);
1156         push(@{$self->{$name}},@values);
1157     }
1158     return $self->param($name);
1159 }
1160 EOF
1161
1162 #### Method: delete_all
1163 # Delete all parameters
1164 ####
1165 'delete_all' => <<'EOF',
1166 sub delete_all {
1167     my($self) = self_or_default(@_);
1168     my @param = $self->param();
1169     $self->delete(@param);
1170 }
1171 EOF
1172
1173 'Delete' => <<'EOF',
1174 sub Delete {
1175     my($self,@p) = self_or_default(@_);
1176     $self->delete(@p);
1177 }
1178 EOF
1179
1180 'Delete_all' => <<'EOF',
1181 sub Delete_all {
1182     my($self,@p) = self_or_default(@_);
1183     $self->delete_all(@p);
1184 }
1185 EOF
1186
1187 #### Method: autoescape
1188 # If you want to turn off the autoescaping features,
1189 # call this method with undef as the argument
1190 'autoEscape' => <<'END_OF_FUNC',
1191 sub autoEscape {
1192     my($self,$escape) = self_or_default(@_);
1193     my $d = $self->{'escape'};
1194     $self->{'escape'} = $escape;
1195     $d;
1196 }
1197 END_OF_FUNC
1198
1199
1200 #### Method: version
1201 # Return the current version
1202 ####
1203 'version' => <<'END_OF_FUNC',
1204 sub version {
1205     return $VERSION;
1206 }
1207 END_OF_FUNC
1208
1209 #### Method: url_param
1210 # Return a parameter in the QUERY_STRING, regardless of
1211 # whether this was a POST or a GET
1212 ####
1213 'url_param' => <<'END_OF_FUNC',
1214 sub url_param {
1215     my ($self,@p) = self_or_default(@_);
1216     my $name = shift(@p);
1217     return undef unless exists($ENV{QUERY_STRING});
1218     unless (exists($self->{'.url_param'})) {
1219         $self->{'.url_param'}={}; # empty hash
1220         if ($ENV{QUERY_STRING} =~ /=/) {
1221             my(@pairs) = split(/[&;]/,$ENV{QUERY_STRING});
1222             my($param,$value);
1223             foreach (@pairs) {
1224                 ($param,$value) = split('=',$_,2);
1225                 $param = unescape($param);
1226                 $value = unescape($value);
1227                 push(@{$self->{'.url_param'}->{$param}},$value);
1228             }
1229         } else {
1230             $self->{'.url_param'}->{'keywords'} = [$self->parse_keywordlist($ENV{QUERY_STRING})];
1231         }
1232     }
1233     return keys %{$self->{'.url_param'}} unless defined($name);
1234     return () unless $self->{'.url_param'}->{$name};
1235     return wantarray ? @{$self->{'.url_param'}->{$name}}
1236                      : $self->{'.url_param'}->{$name}->[0];
1237 }
1238 END_OF_FUNC
1239
1240 #### Method: Dump
1241 # Returns a string in which all the known parameter/value
1242 # pairs are represented as nested lists, mainly for the purposes
1243 # of debugging.
1244 ####
1245 'Dump' => <<'END_OF_FUNC',
1246 sub Dump {
1247     my($self) = self_or_default(@_);
1248     my($param,$value,@result);
1249     return '<ul></ul>' unless $self->param;
1250     push(@result,"<ul>");
1251     foreach $param ($self->param) {
1252         my($name)=$self->escapeHTML($param);
1253         push(@result,"<li><strong>$param</strong></li>");
1254         push(@result,"<ul>");
1255         foreach $value ($self->param($param)) {
1256             $value = $self->escapeHTML($value);
1257             $value =~ s/\n/<br \/>\n/g;
1258             push(@result,"<li>$value</li>");
1259         }
1260         push(@result,"</ul>");
1261     }
1262     push(@result,"</ul>");
1263     return join("\n",@result);
1264 }
1265 END_OF_FUNC
1266
1267 #### Method as_string
1268 #
1269 # synonym for "dump"
1270 ####
1271 'as_string' => <<'END_OF_FUNC',
1272 sub as_string {
1273     &Dump(@_);
1274 }
1275 END_OF_FUNC
1276
1277 #### Method: save
1278 # Write values out to a filehandle in such a way that they can
1279 # be reinitialized by the filehandle form of the new() method
1280 ####
1281 'save' => <<'END_OF_FUNC',
1282 sub save {
1283     my($self,$filehandle) = self_or_default(@_);
1284     $filehandle = to_filehandle($filehandle);
1285     my($param);
1286     local($,) = '';  # set print field separator back to a sane value
1287     local($\) = '';  # set output line separator to a sane value
1288     foreach $param ($self->param) {
1289         my($escaped_param) = escape($param);
1290         my($value);
1291         foreach $value ($self->param($param)) {
1292             print $filehandle "$escaped_param=",escape("$value"),"\n";
1293         }
1294     }
1295     foreach (keys %{$self->{'.fieldnames'}}) {
1296           print $filehandle ".cgifields=",escape("$_"),"\n";
1297     }
1298     print $filehandle "=\n";    # end of record
1299 }
1300 END_OF_FUNC
1301
1302
1303 #### Method: save_parameters
1304 # An alias for save() that is a better name for exportation.
1305 # Only intended to be used with the function (non-OO) interface.
1306 ####
1307 'save_parameters' => <<'END_OF_FUNC',
1308 sub save_parameters {
1309     my $fh = shift;
1310     return save(to_filehandle($fh));
1311 }
1312 END_OF_FUNC
1313
1314 #### Method: restore_parameters
1315 # A way to restore CGI parameters from an initializer.
1316 # Only intended to be used with the function (non-OO) interface.
1317 ####
1318 'restore_parameters' => <<'END_OF_FUNC',
1319 sub restore_parameters {
1320     $Q = $CGI::DefaultClass->new(@_);
1321 }
1322 END_OF_FUNC
1323
1324 #### Method: multipart_init
1325 # Return a Content-Type: style header for server-push
1326 # This has to be NPH on most web servers, and it is advisable to set $| = 1
1327 #
1328 # Many thanks to Ed Jordan <ed@fidalgo.net> for this
1329 # contribution, updated by Andrew Benham (adsb@bigfoot.com)
1330 ####
1331 'multipart_init' => <<'END_OF_FUNC',
1332 sub multipart_init {
1333     my($self,@p) = self_or_default(@_);
1334     my($boundary,@other) = rearrange([BOUNDARY],@p);
1335     $boundary = $boundary || '------- =_aaaaaaaaaa0';
1336     $self->{'separator'} = "$CRLF--$boundary$CRLF";
1337     $self->{'final_separator'} = "$CRLF--$boundary--$CRLF";
1338     $type = SERVER_PUSH($boundary);
1339     return $self->header(
1340         -nph => 0,
1341         -type => $type,
1342         (map { split "=", $_, 2 } @other),
1343     ) . "WARNING: YOUR BROWSER DOESN'T SUPPORT THIS SERVER-PUSH TECHNOLOGY." . $self->multipart_end;
1344 }
1345 END_OF_FUNC
1346
1347
1348 #### Method: multipart_start
1349 # Return a Content-Type: style header for server-push, start of section
1350 #
1351 # Many thanks to Ed Jordan <ed@fidalgo.net> for this
1352 # contribution, updated by Andrew Benham (adsb@bigfoot.com)
1353 ####
1354 'multipart_start' => <<'END_OF_FUNC',
1355 sub multipart_start {
1356     my(@header);
1357     my($self,@p) = self_or_default(@_);
1358     my($type,@other) = rearrange([TYPE],@p);
1359     $type = $type || 'text/html';
1360     push(@header,"Content-Type: $type");
1361
1362     # rearrange() was designed for the HTML portion, so we
1363     # need to fix it up a little.
1364     foreach (@other) {
1365         # Don't use \s because of perl bug 21951
1366         next unless my($header,$value) = /([^ \r\n\t=]+)=\"?(.+?)\"?$/;
1367         ($_ = $header) =~ s/^(\w)(.*)/$1 . lc ($2) . ': '.$self->unescapeHTML($value)/e;
1368     }
1369     push(@header,@other);
1370     my $header = join($CRLF,@header)."${CRLF}${CRLF}";
1371     return $header;
1372 }
1373 END_OF_FUNC
1374
1375
1376 #### Method: multipart_end
1377 # Return a MIME boundary separator for server-push, end of section
1378 #
1379 # Many thanks to Ed Jordan <ed@fidalgo.net> for this
1380 # contribution
1381 ####
1382 'multipart_end' => <<'END_OF_FUNC',
1383 sub multipart_end {
1384     my($self,@p) = self_or_default(@_);
1385     return $self->{'separator'};
1386 }
1387 END_OF_FUNC
1388
1389
1390 #### Method: multipart_final
1391 # Return a MIME boundary separator for server-push, end of all sections
1392 #
1393 # Contributed by Andrew Benham (adsb@bigfoot.com)
1394 ####
1395 'multipart_final' => <<'END_OF_FUNC',
1396 sub multipart_final {
1397     my($self,@p) = self_or_default(@_);
1398     return $self->{'final_separator'} . "WARNING: YOUR BROWSER DOESN'T SUPPORT THIS SERVER-PUSH TECHNOLOGY." . $CRLF;
1399 }
1400 END_OF_FUNC
1401
1402
1403 #### Method: header
1404 # Return a Content-Type: style header
1405 #
1406 ####
1407 'header' => <<'END_OF_FUNC',
1408 sub header {
1409     my($self,@p) = self_or_default(@_);
1410     my(@header);
1411
1412     return "" if $self->{'.header_printed'}++ and $HEADERS_ONCE;
1413
1414     my($type,$status,$cookie,$target,$expires,$nph,$charset,$attachment,$p3p,@other) =
1415         rearrange([['TYPE','CONTENT_TYPE','CONTENT-TYPE'],
1416                             'STATUS',['COOKIE','COOKIES'],'TARGET',
1417                             'EXPIRES','NPH','CHARSET',
1418                             'ATTACHMENT','P3P'],@p);
1419
1420     $nph     ||= $NPH;
1421
1422     $type ||= 'text/html' unless defined($type);
1423
1424     if (defined $charset) {
1425       $self->charset($charset);
1426     } else {
1427       $charset = $self->charset if $type =~ /^text\//;
1428     }
1429
1430     # rearrange() was designed for the HTML portion, so we
1431     # need to fix it up a little.
1432     foreach (@other) {
1433         # Don't use \s because of perl bug 21951
1434         next unless my($header,$value) = /([^ \r\n\t=]+)=\"?(.+?)\"?$/;
1435         ($_ = $header) =~ s/^(\w)(.*)/"\u$1\L$2" . ': '.$self->unescapeHTML($value)/e;
1436     }
1437
1438     $type .= "; charset=$charset"
1439       if     $type ne ''
1440          and $type !~ /\bcharset\b/
1441          and defined $charset
1442          and $charset ne '';
1443
1444     # Maybe future compatibility.  Maybe not.
1445     my $protocol = $ENV{SERVER_PROTOCOL} || 'HTTP/1.0';
1446     push(@header,$protocol . ' ' . ($status || '200 OK')) if $nph;
1447     push(@header,"Server: " . &server_software()) if $nph;
1448
1449     push(@header,"Status: $status") if $status;
1450     push(@header,"Window-Target: $target") if $target;
1451     if ($p3p) {
1452        $p3p = join ' ',@$p3p if ref($p3p) eq 'ARRAY';
1453        push(@header,qq(P3P: policyref="/w3c/p3p.xml", CP="$p3p"));
1454     }
1455     # push all the cookies -- there may be several
1456     if ($cookie) {
1457         my(@cookie) = ref($cookie) && ref($cookie) eq 'ARRAY' ? @{$cookie} : $cookie;
1458         foreach (@cookie) {
1459             my $cs = UNIVERSAL::isa($_,'CGI::Cookie') ? $_->as_string : $_;
1460             push(@header,"Set-Cookie: $cs") if $cs ne '';
1461         }
1462     }
1463     # if the user indicates an expiration time, then we need
1464     # both an Expires and a Date header (so that the browser is
1465     # uses OUR clock)
1466     push(@header,"Expires: " . expires($expires,'http'))
1467         if $expires;
1468     push(@header,"Date: " . expires(0,'http')) if $expires || $cookie || $nph;
1469     push(@header,"Pragma: no-cache") if $self->cache();
1470     push(@header,"Content-Disposition: attachment; filename=\"$attachment\"") if $attachment;
1471     push(@header,map {ucfirst $_} @other);
1472     push(@header,"Content-Type: $type") if $type ne '';
1473     my $header = join($CRLF,@header)."${CRLF}${CRLF}";
1474     if ($MOD_PERL and not $nph) {
1475         $self->r->send_cgi_header($header);
1476         return '';
1477     }
1478     return $header;
1479 }
1480 END_OF_FUNC
1481
1482
1483 #### Method: cache
1484 # Control whether header() will produce the no-cache
1485 # Pragma directive.
1486 ####
1487 'cache' => <<'END_OF_FUNC',
1488 sub cache {
1489     my($self,$new_value) = self_or_default(@_);
1490     $new_value = '' unless $new_value;
1491     if ($new_value ne '') {
1492         $self->{'cache'} = $new_value;
1493     }
1494     return $self->{'cache'};
1495 }
1496 END_OF_FUNC
1497
1498
1499 #### Method: redirect
1500 # Return a Location: style header
1501 #
1502 ####
1503 'redirect' => <<'END_OF_FUNC',
1504 sub redirect {
1505     my($self,@p) = self_or_default(@_);
1506     my($url,$target,$status,$cookie,$nph,@other) =
1507          rearrange([[LOCATION,URI,URL],TARGET,STATUS,['COOKIE','COOKIES'],NPH],@p);
1508     $status = '302 Found' unless defined $status;
1509     $url ||= $self->self_url;
1510     my(@o);
1511     foreach (@other) { tr/\"//d; push(@o,split("=",$_,2)); }
1512     unshift(@o,
1513          '-Status'  => $status,
1514          '-Location'=> $url,
1515          '-nph'     => $nph);
1516     unshift(@o,'-Target'=>$target) if $target;
1517     unshift(@o,'-Type'=>'');
1518     my @unescaped;
1519     unshift(@unescaped,'-Cookie'=>$cookie) if $cookie;
1520     return $self->header((map {$self->unescapeHTML($_)} @o),@unescaped);
1521 }
1522 END_OF_FUNC
1523
1524
1525 #### Method: start_html
1526 # Canned HTML header
1527 #
1528 # Parameters:
1529 # $title -> (optional) The title for this HTML document (-title)
1530 # $author -> (optional) e-mail address of the author (-author)
1531 # $base -> (optional) if set to true, will enter the BASE address of this document
1532 #          for resolving relative references (-base)
1533 # $xbase -> (optional) alternative base at some remote location (-xbase)
1534 # $target -> (optional) target window to load all links into (-target)
1535 # $script -> (option) Javascript code (-script)
1536 # $no_script -> (option) Javascript <noscript> tag (-noscript)
1537 # $meta -> (optional) Meta information tags
1538 # $head -> (optional) any other elements you'd like to incorporate into the <head> tag
1539 #           (a scalar or array ref)
1540 # $style -> (optional) reference to an external style sheet
1541 # @other -> (optional) any other named parameters you'd like to incorporate into
1542 #           the <body> tag.
1543 ####
1544 'start_html' => <<'END_OF_FUNC',
1545 sub start_html {
1546     my($self,@p) = &self_or_default(@_);
1547     my($title,$author,$base,$xbase,$script,$noscript,
1548         $target,$meta,$head,$style,$dtd,$lang,$encoding,$declare_xml,@other) =
1549         rearrange([TITLE,AUTHOR,BASE,XBASE,SCRIPT,NOSCRIPT,TARGET,
1550                    META,HEAD,STYLE,DTD,LANG,ENCODING,DECLARE_XML],@p);
1551
1552     $self->element_id(0);
1553     $self->element_tab(0);
1554
1555     $encoding = lc($self->charset) unless defined $encoding;
1556
1557     # Need to sort out the DTD before it's okay to call escapeHTML().
1558     my(@result,$xml_dtd);
1559     if ($dtd) {
1560         if (defined(ref($dtd)) and (ref($dtd) eq 'ARRAY')) {
1561             $dtd = $DEFAULT_DTD unless $dtd->[0] =~ m|^-//|;
1562         } else {
1563             $dtd = $DEFAULT_DTD unless $dtd =~ m|^-//|;
1564         }
1565     } else {
1566         $dtd = $XHTML ? XHTML_DTD : $DEFAULT_DTD;
1567     }
1568
1569     $xml_dtd++ if ref($dtd) eq 'ARRAY' && $dtd->[0] =~ /\bXHTML\b/i;
1570     $xml_dtd++ if ref($dtd) eq '' && $dtd =~ /\bXHTML\b/i;
1571     push @result,qq(<?xml version="1.0" encoding="$encoding"?>) if $xml_dtd && $declare_xml;
1572
1573     if (ref($dtd) && ref($dtd) eq 'ARRAY') {
1574         push(@result,qq(<!DOCTYPE html\n\tPUBLIC "$dtd->[0]"\n\t "$dtd->[1]">));
1575         $DTD_PUBLIC_IDENTIFIER = $dtd->[0];
1576     } else {
1577         push(@result,qq(<!DOCTYPE html\n\tPUBLIC "$dtd">));
1578         $DTD_PUBLIC_IDENTIFIER = $dtd;
1579     }
1580
1581     # Now that we know whether we're using the HTML 3.2 DTD or not, it's okay to
1582     # call escapeHTML().  Strangely enough, the title needs to be escaped as
1583     # HTML while the author needs to be escaped as a URL.
1584     $title = $self->escapeHTML($title || 'Untitled Document');
1585     $author = $self->escape($author);
1586
1587     if ($DTD_PUBLIC_IDENTIFIER =~ /[^X]HTML (2\.0|3\.2)/i) {
1588         $lang = "" unless defined $lang;
1589         $XHTML = 0;
1590     }
1591     else {
1592         $lang = 'en-US' unless defined $lang;
1593     }
1594
1595     my $lang_bits = $lang ne '' ? qq( lang="$lang" xml:lang="$lang") : '';
1596     my $meta_bits = qq(<meta http-equiv="Content-Type" content="text/html; charset=$encoding" />)
1597                     if $XHTML && $encoding && !$declare_xml;
1598
1599     push(@result,$XHTML ? qq(<html xmlns="http://www.w3.org/1999/xhtml"$lang_bits>\n<head>\n<title>$title</title>)
1600                         : ($lang ? qq(<html lang="$lang">) : "<html>")
1601                           . "<head><title>$title</title>");
1602         if (defined $author) {
1603     push(@result,$XHTML ? "<link rev=\"made\" href=\"mailto:$author\" />"
1604                         : "<link rev=\"made\" href=\"mailto:$author\">");
1605         }
1606
1607     if ($base || $xbase || $target) {
1608         my $href = $xbase || $self->url('-path'=>1);
1609         my $t = $target ? qq/ target="$target"/ : '';
1610         push(@result,$XHTML ? qq(<base href="$href"$t />) : qq(<base href="$href"$t>));
1611     }
1612
1613     if ($meta && ref($meta) && (ref($meta) eq 'HASH')) {
1614         foreach (keys %$meta) { push(@result,$XHTML ? qq(<meta name="$_" content="$meta->{$_}" />)
1615                         : qq(<meta name="$_" content="$meta->{$_}">)); }
1616     }
1617
1618     push(@result,ref($head) ? @$head : $head) if $head;
1619
1620     # handle the infrequently-used -style and -script parameters
1621     push(@result,$self->_style($style))   if defined $style;
1622     push(@result,$self->_script($script)) if defined $script;
1623     push(@result,$meta_bits)              if defined $meta_bits;
1624
1625     # handle -noscript parameter
1626     push(@result,<<END) if $noscript;
1627 <noscript>
1628 $noscript
1629 </noscript>
1630 END
1631     ;
1632     my($other) = @other ? " @other" : '';
1633     push(@result,"</head>\n<body$other>\n");
1634     return join("\n",@result);
1635 }
1636 END_OF_FUNC
1637
1638 ### Method: _style
1639 # internal method for generating a CSS style section
1640 ####
1641 '_style' => <<'END_OF_FUNC',
1642 sub _style {
1643     my ($self,$style) = @_;
1644     my (@result);
1645     my $type = 'text/css';
1646
1647     my $cdata_start = $XHTML ? "\n<!--/* <![CDATA[ */" : "\n<!-- ";
1648     my $cdata_end   = $XHTML ? "\n/* ]]> */-->\n" : " -->\n";
1649
1650     my @s = ref($style) eq 'ARRAY' ? @$style : $style;
1651
1652     for my $s (@s) {
1653       if (ref($s)) {
1654        my($src,$code,$verbatim,$stype,$foo,@other) =
1655            rearrange([qw(SRC CODE VERBATIM TYPE FOO)],
1656                       ('-foo'=>'bar',
1657                        ref($s) eq 'ARRAY' ? @$s : %$s));
1658        $type  = $stype if $stype;
1659        my $other = @other ? join ' ',@other : '';
1660
1661        if (ref($src) eq "ARRAY") # Check to see if the $src variable is an array reference
1662        { # If it is, push a LINK tag for each one
1663            foreach $src (@$src)
1664          {
1665            push(@result,$XHTML ? qq(<link rel="stylesheet" type="$type" href="$src" $other/>)
1666                              : qq(<link rel="stylesheet" type="$type" href="$src"$other>)) if $src;
1667          }
1668        }
1669        else
1670        { # Otherwise, push the single -src, if it exists.
1671          push(@result,$XHTML ? qq(<link rel="stylesheet" type="$type" href="$src" $other/>)
1672                              : qq(<link rel="stylesheet" type="$type" href="$src"$other>)
1673               ) if $src;
1674         }
1675      if ($verbatim) {
1676            my @v = ref($verbatim) eq 'ARRAY' ? @$verbatim : $verbatim;
1677            push(@result, "<style type=\"text/css\">\n$_\n</style>") foreach @v;
1678       }
1679       my @c = ref($code) eq 'ARRAY' ? @$code : $code if $code;
1680       push(@result,style({'type'=>$type},"$cdata_start\n$_\n$cdata_end")) foreach @c;
1681
1682       } else {
1683            my $src = $s;
1684            push(@result,$XHTML ? qq(<link rel="stylesheet" type="$type" href="$src" $other/>)
1685                                : qq(<link rel="stylesheet" type="$type" href="$src"$other>));
1686       }
1687     }
1688     @result;
1689 }
1690 END_OF_FUNC
1691
1692 '_script' => <<'END_OF_FUNC',
1693 sub _script {
1694     my ($self,$script) = @_;
1695     my (@result);
1696
1697     my (@scripts) = ref($script) eq 'ARRAY' ? @$script : ($script);
1698     foreach $script (@scripts) {
1699         my($src,$code,$language);
1700         if (ref($script)) { # script is a hash
1701             ($src,$code,$language, $type) =
1702                 rearrange([SRC,CODE,LANGUAGE,TYPE],
1703                                  '-foo'=>'bar', # a trick to allow the '-' to be omitted
1704                                  ref($script) eq 'ARRAY' ? @$script : %$script);
1705             # User may not have specified language
1706             $language ||= 'JavaScript';
1707             unless (defined $type) {
1708                 $type = lc $language;
1709                 # strip '1.2' from 'javascript1.2'
1710                 $type =~ s/^(\D+).*$/text\/$1/;
1711             }
1712         } else {
1713             ($src,$code,$language, $type) = ('',$script,'JavaScript', 'text/javascript');
1714         }
1715
1716     my $comment = '//';  # javascript by default
1717     $comment = '#' if $type=~/perl|tcl/i;
1718     $comment = "'" if $type=~/vbscript/i;
1719
1720     my ($cdata_start,$cdata_end);
1721     if ($XHTML) {
1722        $cdata_start    = "$comment<![CDATA[\n";
1723        $cdata_end     .= "\n$comment]]>";
1724     } else {
1725        $cdata_start  =  "\n<!-- Hide script\n";
1726        $cdata_end    = $comment;
1727        $cdata_end   .= " End script hiding -->\n";
1728    }
1729      my(@satts);
1730      push(@satts,'src'=>$src) if $src;
1731      push(@satts,'language'=>$language) unless defined $type;
1732      push(@satts,'type'=>$type);
1733      $code = $cdata_start . $code . $cdata_end if defined $code;
1734      push(@result,$self->script({@satts},$code || ''));
1735     }
1736     @result;
1737 }
1738 END_OF_FUNC
1739
1740 #### Method: end_html
1741 # End an HTML document.
1742 # Trivial method for completeness.  Just returns "</body>"
1743 ####
1744 'end_html' => <<'END_OF_FUNC',
1745 sub end_html {
1746     return "\n</body>\n</html>";
1747 }
1748 END_OF_FUNC
1749
1750
1751 ################################
1752 # METHODS USED IN BUILDING FORMS
1753 ################################
1754
1755 #### Method: isindex
1756 # Just prints out the isindex tag.
1757 # Parameters:
1758 #  $action -> optional URL of script to run
1759 # Returns:
1760 #   A string containing a <isindex> tag
1761 'isindex' => <<'END_OF_FUNC',
1762 sub isindex {
1763     my($self,@p) = self_or_default(@_);
1764     my($action,@other) = rearrange([ACTION],@p);
1765     $action = qq/ action="$action"/ if $action;
1766     my($other) = @other ? " @other" : '';
1767     return $XHTML ? "<isindex$action$other />" : "<isindex$action$other>";
1768 }
1769 END_OF_FUNC
1770
1771
1772 #### Method: startform
1773 # Start a form
1774 # Parameters:
1775 #   $method -> optional submission method to use (GET or POST)
1776 #   $action -> optional URL of script to run
1777 #   $enctype ->encoding to use (URL_ENCODED or MULTIPART)
1778 'startform' => <<'END_OF_FUNC',
1779 sub startform {
1780     my($self,@p) = self_or_default(@_);
1781
1782     my($method,$action,$enctype,@other) =
1783         rearrange([METHOD,ACTION,ENCTYPE],@p);
1784
1785     $method  = $self->escapeHTML(lc($method) || 'post');
1786     $enctype = $self->escapeHTML($enctype || &URL_ENCODED);
1787     if (defined $action) {
1788        $action = $self->escapeHTML($action);
1789     }
1790     else {
1791        $action = $self->escapeHTML($self->request_uri);
1792     }
1793     $action = qq(action="$action");
1794     my($other) = @other ? " @other" : '';
1795     $self->{'.parametersToAdd'}={};
1796     return qq/<form method="$method" $action enctype="$enctype"$other>\n/;
1797 }
1798 END_OF_FUNC
1799
1800
1801 #### Method: start_form
1802 # synonym for startform
1803 'start_form' => <<'END_OF_FUNC',
1804 sub start_form {
1805     $XHTML ? &start_multipart_form : &startform;
1806 }
1807 END_OF_FUNC
1808
1809 'end_multipart_form' => <<'END_OF_FUNC',
1810 sub end_multipart_form {
1811     &endform;
1812 }
1813 END_OF_FUNC
1814
1815 #### Method: start_multipart_form
1816 # synonym for startform
1817 'start_multipart_form' => <<'END_OF_FUNC',
1818 sub start_multipart_form {
1819     my($self,@p) = self_or_default(@_);
1820     if (defined($p[0]) && substr($p[0],0,1) eq '-') {
1821         my(%p) = @p;
1822         $p{'-enctype'}=&MULTIPART;
1823         return $self->startform(%p);
1824     } else {
1825         my($method,$action,@other) =
1826             rearrange([METHOD,ACTION],@p);
1827         return $self->startform($method,$action,&MULTIPART,@other);
1828     }
1829 }
1830 END_OF_FUNC
1831
1832
1833 #### Method: endform
1834 # End a form
1835 'endform' => <<'END_OF_FUNC',
1836 sub endform {
1837     my($self,@p) = self_or_default(@_);
1838     if ( $NOSTICKY ) {
1839     return wantarray ? ("</form>") : "\n</form>";
1840     } else {
1841       if (my @fields = $self->get_fields) {
1842          return wantarray ? ("<div>",@fields,"</div>","</form>")
1843                           : "<div>".(join '',@fields)."</div>\n</form>";
1844       } else {
1845          return "</form>";
1846       }
1847     }
1848 }
1849 END_OF_FUNC
1850
1851
1852 '_textfield' => <<'END_OF_FUNC',
1853 sub _textfield {
1854     my($self,$tag,@p) = self_or_default(@_);
1855     my($name,$default,$size,$maxlength,$override,$tabindex,@other) =
1856         rearrange([NAME,[DEFAULT,VALUE,VALUES],SIZE,MAXLENGTH,[OVERRIDE,FORCE],TABINDEX],@p);
1857
1858     my $current = $override ? $default :
1859         (defined($self->param($name)) ? $self->param($name) : $default);
1860
1861     $current = defined($current) ? $self->escapeHTML($current,1) : '';
1862     $name = defined($name) ? $self->escapeHTML($name) : '';
1863     my($s) = defined($size) ? qq/ size="$size"/ : '';
1864     my($m) = defined($maxlength) ? qq/ maxlength="$maxlength"/ : '';
1865     my($other) = @other ? " @other" : '';
1866     # this entered at cristy's request to fix problems with file upload fields
1867     # and WebTV -- not sure it won't break stuff
1868     my($value) = $current ne '' ? qq(value="$current") : '';
1869     $tabindex = $self->element_tab($tabindex);
1870     return $XHTML ? qq(<input type="$tag" name="$name" $tabindex$value$s$m$other />)
1871                   : qq(<input type="$tag" name="$name" $value$s$m$other>);
1872 }
1873 END_OF_FUNC
1874
1875 #### Method: textfield
1876 # Parameters:
1877 #   $name -> Name of the text field
1878 #   $default -> Optional default value of the field if not
1879 #                already defined.
1880 #   $size ->  Optional width of field in characaters.
1881 #   $maxlength -> Optional maximum number of characters.
1882 # Returns:
1883 #   A string containing a <input type="text"> field
1884 #
1885 'textfield' => <<'END_OF_FUNC',
1886 sub textfield {
1887     my($self,@p) = self_or_default(@_);
1888     $self->_textfield('text',@p);
1889 }
1890 END_OF_FUNC
1891
1892
1893 #### Method: filefield
1894 # Parameters:
1895 #   $name -> Name of the file upload field
1896 #   $size ->  Optional width of field in characaters.
1897 #   $maxlength -> Optional maximum number of characters.
1898 # Returns:
1899 #   A string containing a <input type="file"> field
1900 #
1901 'filefield' => <<'END_OF_FUNC',
1902 sub filefield {
1903     my($self,@p) = self_or_default(@_);
1904     $self->_textfield('file',@p);
1905 }
1906 END_OF_FUNC
1907
1908
1909 #### Method: password
1910 # Create a "secret password" entry field
1911 # Parameters:
1912 #   $name -> Name of the field
1913 #   $default -> Optional default value of the field if not
1914 #                already defined.
1915 #   $size ->  Optional width of field in characters.
1916 #   $maxlength -> Optional maximum characters that can be entered.
1917 # Returns:
1918 #   A string containing a <input type="password"> field
1919 #
1920 'password_field' => <<'END_OF_FUNC',
1921 sub password_field {
1922     my ($self,@p) = self_or_default(@_);
1923     $self->_textfield('password',@p);
1924 }
1925 END_OF_FUNC
1926
1927 #### Method: textarea
1928 # Parameters:
1929 #   $name -> Name of the text field
1930 #   $default -> Optional default value of the field if not
1931 #                already defined.
1932 #   $rows ->  Optional number of rows in text area
1933 #   $columns -> Optional number of columns in text area
1934 # Returns:
1935 #   A string containing a <textarea></textarea> tag
1936 #
1937 'textarea' => <<'END_OF_FUNC',
1938 sub textarea {
1939     my($self,@p) = self_or_default(@_);
1940     my($name,$default,$rows,$cols,$override,$tabindex,@other) =
1941         rearrange([NAME,[DEFAULT,VALUE],ROWS,[COLS,COLUMNS],[OVERRIDE,FORCE],TABINDEX],@p);
1942
1943     my($current)= $override ? $default :
1944         (defined($self->param($name)) ? $self->param($name) : $default);
1945
1946     $name = defined($name) ? $self->escapeHTML($name) : '';
1947     $current = defined($current) ? $self->escapeHTML($current) : '';
1948     my($r) = $rows ? qq/ rows="$rows"/ : '';
1949     my($c) = $cols ? qq/ cols="$cols"/ : '';
1950     my($other) = @other ? " @other" : '';
1951     $tabindex = $self->element_tab($tabindex);
1952     return qq{<textarea name="$name" $tabindex$r$c$other>$current</textarea>};
1953 }
1954 END_OF_FUNC
1955
1956
1957 #### Method: button
1958 # Create a javascript button.
1959 # Parameters:
1960 #   $name ->  (optional) Name for the button. (-name)
1961 #   $value -> (optional) Value of the button when selected (and visible name) (-value)
1962 #   $onclick -> (optional) Text of the JavaScript to run when the button is
1963 #                clicked.
1964 # Returns:
1965 #   A string containing a <input type="button"> tag
1966 ####
1967 'button' => <<'END_OF_FUNC',
1968 sub button {
1969     my($self,@p) = self_or_default(@_);
1970
1971     my($label,$value,$script,$tabindex,@other) = rearrange([NAME,[VALUE,LABEL],
1972                                                             [ONCLICK,SCRIPT],TABINDEX],@p);
1973
1974     $label=$self->escapeHTML($label);
1975     $value=$self->escapeHTML($value,1);
1976     $script=$self->escapeHTML($script);
1977
1978     my($name) = '';
1979     $name = qq/ name="$label"/ if $label;
1980     $value = $value || $label;
1981     my($val) = '';
1982     $val = qq/ value="$value"/ if $value;
1983     $script = qq/ onclick="$script"/ if $script;
1984     my($other) = @other ? " @other" : '';
1985     $tabindex = $self->element_tab($tabindex);
1986     return $XHTML ? qq(<input type="button" $tabindex$name$val$script$other />)
1987                   : qq(<input type="button"$name$val$script$other>);
1988 }
1989 END_OF_FUNC
1990
1991
1992 #### Method: submit
1993 # Create a "submit query" button.
1994 # Parameters:
1995 #   $name ->  (optional) Name for the button.
1996 #   $value -> (optional) Value of the button when selected (also doubles as label).
1997 #   $label -> (optional) Label printed on the button(also doubles as the value).
1998 # Returns:
1999 #   A string containing a <input type="submit"> tag
2000 ####
2001 'submit' => <<'END_OF_FUNC',
2002 sub submit {
2003     my($self,@p) = self_or_default(@_);
2004
2005     my($label,$value,$tabindex,@other) = rearrange([NAME,[VALUE,LABEL],TABINDEX],@p);
2006
2007     $label=$self->escapeHTML($label);
2008     $value=$self->escapeHTML($value,1);
2009
2010     my $name = $NOSTICKY ? '' : 'name=".submit" ';
2011     $name = qq/name="$label" / if defined($label);
2012     $value = defined($value) ? $value : $label;
2013     my $val = '';
2014     $val = qq/value="$value" / if defined($value);
2015     $tabindex = $self->element_tab($tabindex);
2016     my($other) = @other ? "@other " : '';
2017     return $XHTML ? qq(<input type="submit" $tabindex$name$val$other/>)
2018                   : qq(<input type="submit" $name$val$other>);
2019 }
2020 END_OF_FUNC
2021
2022
2023 #### Method: reset
2024 # Create a "reset" button.
2025 # Parameters:
2026 #   $name -> (optional) Name for the button.
2027 # Returns:
2028 #   A string containing a <input type="reset"> tag
2029 ####
2030 'reset' => <<'END_OF_FUNC',
2031 sub reset {
2032     my($self,@p) = self_or_default(@_);
2033     my($label,$value,$tabindex,@other) = rearrange(['NAME',['VALUE','LABEL'],TABINDEX],@p);
2034     $label=$self->escapeHTML($label);
2035     $value=$self->escapeHTML($value,1);
2036     my ($name) = ' name=".reset"';
2037     $name = qq/ name="$label"/ if defined($label);
2038     $value = defined($value) ? $value : $label;
2039     my($val) = '';
2040     $val = qq/ value="$value"/ if defined($value);
2041     my($other) = @other ? " @other" : '';
2042     $tabindex = $self->element_tab($tabindex);
2043     return $XHTML ? qq(<input type="reset" $tabindex$name$val$other />)
2044                   : qq(<input type="reset"$name$val$other>);
2045 }
2046 END_OF_FUNC
2047
2048
2049 #### Method: defaults
2050 # Create a "defaults" button.
2051 # Parameters:
2052 #   $name -> (optional) Name for the button.
2053 # Returns:
2054 #   A string containing a <input type="submit" name=".defaults"> tag
2055 #
2056 # Note: this button has a special meaning to the initialization script,
2057 # and tells it to ERASE the current query string so that your defaults
2058 # are used again!
2059 ####
2060 'defaults' => <<'END_OF_FUNC',
2061 sub defaults {
2062     my($self,@p) = self_or_default(@_);
2063
2064     my($label,$tabindex,@other) = rearrange([[NAME,VALUE],TABINDEX],@p);
2065
2066     $label=$self->escapeHTML($label,1);
2067     $label = $label || "Defaults";
2068     my($value) = qq/ value="$label"/;
2069     my($other) = @other ? " @other" : '';
2070     $tabindex = $self->element_tab($tabindex);
2071     return $XHTML ? qq(<input type="submit" name=".defaults" $tabindex$value$other />)
2072                   : qq/<input type="submit" NAME=".defaults"$value$other>/;
2073 }
2074 END_OF_FUNC
2075
2076
2077 #### Method: comment
2078 # Create an HTML <!-- comment -->
2079 # Parameters: a string
2080 'comment' => <<'END_OF_FUNC',
2081 sub comment {
2082     my($self,@p) = self_or_CGI(@_);
2083     return "<!-- @p -->";
2084 }
2085 END_OF_FUNC
2086
2087 #### Method: checkbox
2088 # Create a checkbox that is not logically linked to any others.
2089 # The field value is "on" when the button is checked.
2090 # Parameters:
2091 #   $name -> Name of the checkbox
2092 #   $checked -> (optional) turned on by default if true
2093 #   $value -> (optional) value of the checkbox, 'on' by default
2094 #   $label -> (optional) a user-readable label printed next to the box.
2095 #             Otherwise the checkbox name is used.
2096 # Returns:
2097 #   A string containing a <input type="checkbox"> field
2098 ####
2099 'checkbox' => <<'END_OF_FUNC',
2100 sub checkbox {
2101     my($self,@p) = self_or_default(@_);
2102
2103     my($name,$checked,$value,$label,$override,$tabindex,@other) =
2104         rearrange([NAME,[CHECKED,SELECTED,ON],VALUE,LABEL,[OVERRIDE,FORCE],TABINDEX],@p);
2105
2106     $value = defined $value ? $value : 'on';
2107
2108     if (!$override && ($self->{'.fieldnames'}->{$name} ||
2109                        defined $self->param($name))) {
2110         $checked = grep($_ eq $value,$self->param($name)) ? $self->_checked(1) : '';
2111     } else {
2112         $checked = $self->_checked($checked);
2113     }
2114     my($the_label) = defined $label ? $label : $name;
2115     $name = $self->escapeHTML($name);
2116     $value = $self->escapeHTML($value,1);
2117     $the_label = $self->escapeHTML($the_label);
2118     my($other) = @other ? "@other " : '';
2119     $tabindex = $self->element_tab($tabindex);
2120     $self->register_parameter($name);
2121     return $XHTML ? CGI::label(qq{<input type="checkbox" name="$name" value="$value" $tabindex$checked$other/>$the_label})
2122                   : qq{<input type="checkbox" name="$name" value="$value"$checked$other>$the_label};
2123 }
2124 END_OF_FUNC
2125
2126
2127
2128 # Escape HTML -- used internally
2129 'escapeHTML' => <<'END_OF_FUNC',
2130 sub escapeHTML {
2131          # hack to work around  earlier hacks
2132          push @_,$_[0] if @_==1 && $_[0] eq 'CGI';
2133          my ($self,$toencode,$newlinestoo) = CGI::self_or_default(@_);
2134          return undef unless defined($toencode);
2135          return $toencode if ref($self) && !$self->{'escape'};
2136          $toencode =~ s{&}{&amp;}gso;
2137          $toencode =~ s{<}{&lt;}gso;
2138          $toencode =~ s{>}{&gt;}gso;
2139          if ($DTD_PUBLIC_IDENTIFIER =~ /[^X]HTML 3\.2/i) {
2140              # $quot; was accidentally omitted from the HTML 3.2 DTD -- see
2141              # <http://validator.w3.org/docs/errors.html#bad-entity> /
2142              # <http://lists.w3.org/Archives/Public/www-html/1997Mar/0003.html>.
2143              $toencode =~ s{"}{&#34;}gso;
2144          }
2145          else {
2146              $toencode =~ s{"}{&quot;}gso;
2147          }
2148          my $latin = uc $self->{'.charset'} eq 'ISO-8859-1' ||
2149                      uc $self->{'.charset'} eq 'WINDOWS-1252';
2150          if ($latin) {  # bug in some browsers
2151                 $toencode =~ s{'}{&#39;}gso;
2152                 $toencode =~ s{\x8b}{&#8249;}gso;
2153                 $toencode =~ s{\x9b}{&#8250;}gso;
2154                 if (defined $newlinestoo && $newlinestoo) {
2155                      $toencode =~ s{\012}{&#10;}gso;
2156                      $toencode =~ s{\015}{&#13;}gso;
2157                 }
2158          }
2159          return $toencode;
2160 }
2161 END_OF_FUNC
2162
2163 # unescape HTML -- used internally
2164 'unescapeHTML' => <<'END_OF_FUNC',
2165 sub unescapeHTML {
2166     # hack to work around  earlier hacks
2167     push @_,$_[0] if @_==1 && $_[0] eq 'CGI';
2168     my ($self,$string) = CGI::self_or_default(@_);
2169     return undef unless defined($string);
2170     my $latin = defined $self->{'.charset'} ? $self->{'.charset'} =~ /^(ISO-8859-1|WINDOWS-1252)$/i
2171                                             : 1;
2172     # thanks to Randal Schwartz for the correct solution to this one
2173     $string=~ s[&(.*?);]{
2174         local $_ = $1;
2175         /^amp$/i        ? "&" :
2176         /^quot$/i       ? '"' :
2177         /^gt$/i         ? ">" :
2178         /^lt$/i         ? "<" :
2179         /^#(\d+)$/ && $latin         ? chr($1) :
2180         /^#x([0-9a-f]+)$/i && $latin ? chr(hex($1)) :
2181         $_
2182         }gex;
2183     return $string;
2184 }
2185 END_OF_FUNC
2186
2187 # Internal procedure - don't use
2188 '_tableize' => <<'END_OF_FUNC',
2189 sub _tableize {
2190     my($rows,$columns,$rowheaders,$colheaders,@elements) = @_;
2191     my @rowheaders = $rowheaders ? @$rowheaders : ();
2192     my @colheaders = $colheaders ? @$colheaders : ();
2193     my($result);
2194
2195     if (defined($columns)) {
2196         $rows = int(0.99 + @elements/$columns) unless defined($rows);
2197     }
2198     if (defined($rows)) {
2199         $columns = int(0.99 + @elements/$rows) unless defined($columns);
2200     }
2201
2202     # rearrange into a pretty table
2203     $result = "<table>";
2204     my($row,$column);
2205     unshift(@colheaders,'') if @colheaders && @rowheaders;
2206     $result .= "<tr>" if @colheaders;
2207     foreach (@colheaders) {
2208         $result .= "<th>$_</th>";
2209     }
2210     for ($row=0;$row<$rows;$row++) {
2211         $result .= "<tr>";
2212         $result .= "<th>$rowheaders[$row]</th>" if @rowheaders;
2213         for ($column=0;$column<$columns;$column++) {
2214             $result .= "<td>" . $elements[$column*$rows + $row] . "</td>"
2215                 if defined($elements[$column*$rows + $row]);
2216         }
2217         $result .= "</tr>";
2218     }
2219     $result .= "</table>";
2220     return $result;
2221 }
2222 END_OF_FUNC
2223
2224
2225 #### Method: radio_group
2226 # Create a list of logically-linked radio buttons.
2227 # Parameters:
2228 #   $name -> Common name for all the buttons.
2229 #   $values -> A pointer to a regular array containing the
2230 #             values for each button in the group.
2231 #   $default -> (optional) Value of the button to turn on by default.  Pass '-'
2232 #               to turn _nothing_ on.
2233 #   $linebreak -> (optional) Set to true to place linebreaks
2234 #             between the buttons.
2235 #   $labels -> (optional)
2236 #             A pointer to an associative array of labels to print next to each checkbox
2237 #             in the form $label{'value'}="Long explanatory label".
2238 #             Otherwise the provided values are used as the labels.
2239 # Returns:
2240 #   An ARRAY containing a series of <input type="radio"> fields
2241 ####
2242 'radio_group' => <<'END_OF_FUNC',
2243 sub radio_group {
2244     my($self,@p) = self_or_default(@_);
2245    $self->_box_group('radio',@p);
2246 }
2247 END_OF_FUNC
2248
2249 #### Method: checkbox_group
2250 # Create a list of logically-linked checkboxes.
2251 # Parameters:
2252 #   $name -> Common name for all the check boxes
2253 #   $values -> A pointer to a regular array containing the
2254 #             values for each checkbox in the group.
2255 #   $defaults -> (optional)
2256 #             1. If a pointer to a regular array of checkbox values,
2257 #             then this will be used to decide which
2258 #             checkboxes to turn on by default.
2259 #             2. If a scalar, will be assumed to hold the
2260 #             value of a single checkbox in the group to turn on.
2261 #   $linebreak -> (optional) Set to true to place linebreaks
2262 #             between the buttons.
2263 #   $labels -> (optional)
2264 #             A pointer to an associative array of labels to print next to each checkbox
2265 #             in the form $label{'value'}="Long explanatory label".
2266 #             Otherwise the provided values are used as the labels.
2267 # Returns:
2268 #   An ARRAY containing a series of <input type="checkbox"> fields
2269 ####
2270
2271 'checkbox_group' => <<'END_OF_FUNC',
2272 sub checkbox_group {
2273     my($self,@p) = self_or_default(@_);
2274    $self->_box_group('checkbox',@p);
2275 }
2276 END_OF_FUNC
2277
2278 '_box_group' => <<'END_OF_FUNC',
2279 sub _box_group {
2280     my $self     = shift;
2281     my $box_type = shift;
2282
2283     my($name,$values,$defaults,$linebreak,$labels,$attributes,
2284        $rows,$columns,$rowheaders,$colheaders,
2285        $override,$nolabels,$tabindex,@other) =
2286        rearrange([      NAME,[VALUES,VALUE],[DEFAULT,DEFAULTS],LINEBREAK,LABELS,ATTRIBUTES,
2287                         ROWS,[COLUMNS,COLS],ROWHEADERS,COLHEADERS,
2288                         [OVERRIDE,FORCE],NOLABELS,TABINDEX
2289                  ],@_);
2290     my($result,$checked);
2291
2292
2293     my(@elements,@values);
2294     @values = $self->_set_values_and_labels($values,\$labels,$name);
2295     my %checked = $self->previous_or_default($name,$defaults,$override);
2296
2297     # If no check array is specified, check the first by default
2298     $checked{$values[0]}++ if $box_type eq 'radio' && !%checked;
2299
2300     $name=$self->escapeHTML($name);
2301
2302     my %tabs = ();
2303     if ($TABINDEX && $tabindex) {
2304       if (!ref $tabindex) {
2305           $self->element_tab($tabindex);
2306       } elsif (ref $tabindex eq 'ARRAY') {
2307           %tabs = map {$_=>$self->element_tab} @$tabindex;
2308       } elsif (ref $tabindex eq 'HASH') {
2309           %tabs = %$tabindex;
2310       }
2311     }
2312     %tabs = map {$_=>$self->element_tab} @values unless %tabs;
2313
2314     my $other = @other ? "@other " : '';
2315     my $radio_checked;
2316     foreach (@values) {
2317         my $checkit = $self->_checked($box_type eq 'radio' ? ($checked{$_} && !$radio_checked++)
2318                                                            : $checked{$_});
2319         my($break);
2320         if ($linebreak) {
2321           $break = $XHTML ? "<br />" : "<br>";
2322         }
2323         else {
2324           $break = '';
2325         }
2326         my($label)='';
2327         unless (defined($nolabels) && $nolabels) {
2328             $label = $_;
2329             $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2330             $label = $self->escapeHTML($label,1);
2331         }
2332         my $attribs = $self->_set_attributes($_, $attributes);
2333         my $tab     = $tabs{$_};
2334         $_=$self->escapeHTML($_);
2335         if ($XHTML) {
2336            push @elements,
2337               CGI::label(
2338                    qq(<input type="$box_type" name="$name" value="$_" $checkit$other$tab$attribs/>$label)).${break};
2339         } else {
2340            push(@elements,qq/<input type="$box_type" name="$name" value="$_"$checkit$other$tab$attribs>${label}${break}/);
2341         }
2342     }
2343     $self->register_parameter($name);
2344     return wantarray ? @elements : "@elements"
2345            unless defined($columns) || defined($rows);
2346     return _tableize($rows,$columns,$rowheaders,$colheaders,@elements);
2347 }
2348 END_OF_FUNC
2349
2350
2351 #### Method: popup_menu
2352 # Create a popup menu.
2353 # Parameters:
2354 #   $name -> Name for all the menu
2355 #   $values -> A pointer to a regular array containing the
2356 #             text of each menu item.
2357 #   $default -> (optional) Default item to display
2358 #   $labels -> (optional)
2359 #             A pointer to an associative array of labels to print next to each checkbox
2360 #             in the form $label{'value'}="Long explanatory label".
2361 #             Otherwise the provided values are used as the labels.
2362 # Returns:
2363 #   A string containing the definition of a popup menu.
2364 ####
2365 'popup_menu' => <<'END_OF_FUNC',
2366 sub popup_menu {
2367     my($self,@p) = self_or_default(@_);
2368
2369     my($name,$values,$default,$labels,$attributes,$override,$tabindex,@other) =
2370        rearrange([NAME,[VALUES,VALUE],[DEFAULT,DEFAULTS],LABELS,
2371        ATTRIBUTES,[OVERRIDE,FORCE],TABINDEX],@p);
2372     my($result,$selected);
2373
2374     if (!$override && defined($self->param($name))) {
2375         $selected = $self->param($name);
2376     } else {
2377         $selected = $default;
2378     }
2379     $name=$self->escapeHTML($name);
2380     my($other) = @other ? " @other" : '';
2381
2382     my(@values);
2383     @values = $self->_set_values_and_labels($values,\$labels,$name);
2384     $tabindex = $self->element_tab($tabindex);
2385     $result = qq/<select name="$name" $tabindex$other>\n/;
2386     foreach (@values) {
2387         if (/<optgroup/) {
2388             foreach (split(/\n/)) {
2389                 my $selectit = $XHTML ? 'selected="selected"' : 'selected';
2390                 s/(value="$selected")/$selectit $1/ if defined $selected;
2391                 $result .= "$_\n";
2392             }
2393         }
2394         else {
2395             my $attribs = $self->_set_attributes($_, $attributes);
2396         my($selectit) = defined($selected) ? $self->_selected($selected eq $_) : '';
2397         my($label) = $_;
2398         $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2399         my($value) = $self->escapeHTML($_);
2400         $label=$self->escapeHTML($label,1);
2401             $result .= "<option $selectit${attribs}value=\"$value\">$label</option>\n";
2402         }
2403     }
2404
2405     $result .= "</select>";
2406     return $result;
2407 }
2408 END_OF_FUNC
2409
2410
2411 #### Method: optgroup
2412 # Create a optgroup.
2413 # Parameters:
2414 #   $name -> Label for the group
2415 #   $values -> A pointer to a regular array containing the
2416 #              values for each option line in the group.
2417 #   $labels -> (optional)
2418 #              A pointer to an associative array of labels to print next to each item
2419 #              in the form $label{'value'}="Long explanatory label".
2420 #              Otherwise the provided values are used as the labels.
2421 #   $labeled -> (optional)
2422 #               A true value indicates the value should be used as the label attribute
2423 #               in the option elements.
2424 #               The label attribute specifies the option label presented to the user.
2425 #               This defaults to the content of the <option> element, but the label
2426 #               attribute allows authors to more easily use optgroup without sacrificing
2427 #               compatibility with browsers that do not support option groups.
2428 #   $novals -> (optional)
2429 #              A true value indicates to suppress the val attribute in the option elements
2430 # Returns:
2431 #   A string containing the definition of an option group.
2432 ####
2433 'optgroup' => <<'END_OF_FUNC',
2434 sub optgroup {
2435     my($self,@p) = self_or_default(@_);
2436     my($name,$values,$attributes,$labeled,$noval,$labels,@other)
2437         = rearrange([NAME,[VALUES,VALUE],ATTRIBUTES,LABELED,NOVALS,LABELS],@p);
2438
2439     my($result,@values);
2440     @values = $self->_set_values_and_labels($values,\$labels,$name,$labeled,$novals);
2441     my($other) = @other ? " @other" : '';
2442
2443     $name=$self->escapeHTML($name);
2444     $result = qq/<optgroup label="$name"$other>\n/;
2445     foreach (@values) {
2446         if (/<optgroup/) {
2447             foreach (split(/\n/)) {
2448                 my $selectit = $XHTML ? 'selected="selected"' : 'selected';
2449                 s/(value="$selected")/$selectit $1/ if defined $selected;
2450                 $result .= "$_\n";
2451             }
2452         }
2453         else {
2454             my $attribs = $self->_set_attributes($_, $attributes);
2455             my($label) = $_;
2456             $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2457             $label=$self->escapeHTML($label);
2458             my($value)=$self->escapeHTML($_,1);
2459             $result .= $labeled ? $novals ? "<option$attribs label=\"$value\">$label</option>\n"
2460                                           : "<option$attribs label=\"$value\" value=\"$value\">$label</option>\n"
2461                                 : $novals ? "<option$attribs>$label</option>\n"
2462                                           : "<option$attribs value=\"$value\">$label</option>\n";
2463         }
2464     }
2465     $result .= "</optgroup>";
2466     return $result;
2467 }
2468 END_OF_FUNC
2469
2470
2471 #### Method: scrolling_list
2472 # Create a scrolling list.
2473 # Parameters:
2474 #   $name -> name for the list
2475 #   $values -> A pointer to a regular array containing the
2476 #             values for each option line in the list.
2477 #   $defaults -> (optional)
2478 #             1. If a pointer to a regular array of options,
2479 #             then this will be used to decide which
2480 #             lines to turn on by default.
2481 #             2. Otherwise holds the value of the single line to turn on.
2482 #   $size -> (optional) Size of the list.
2483 #   $multiple -> (optional) If set, allow multiple selections.
2484 #   $labels -> (optional)
2485 #             A pointer to an associative array of labels to print next to each checkbox
2486 #             in the form $label{'value'}="Long explanatory label".
2487 #             Otherwise the provided values are used as the labels.
2488 # Returns:
2489 #   A string containing the definition of a scrolling list.
2490 ####
2491 'scrolling_list' => <<'END_OF_FUNC',
2492 sub scrolling_list {
2493     my($self,@p) = self_or_default(@_);
2494     my($name,$values,$defaults,$size,$multiple,$labels,$attributes,$override,$tabindex,@other)
2495         = rearrange([NAME,[VALUES,VALUE],[DEFAULTS,DEFAULT],
2496           SIZE,MULTIPLE,LABELS,ATTRIBUTES,[OVERRIDE,FORCE],TABINDEX],@p);
2497
2498     my($result,@values);
2499     @values = $self->_set_values_and_labels($values,\$labels,$name);
2500
2501     $size = $size || scalar(@values);
2502
2503     my(%selected) = $self->previous_or_default($name,$defaults,$override);
2504     my($is_multiple) = $multiple ? qq/ multiple="multiple"/ : '';
2505     my($has_size) = $size ? qq/ size="$size"/: '';
2506     my($other) = @other ? " @other" : '';
2507
2508     $name=$self->escapeHTML($name);
2509     $tabindex = $self->element_tab($tabindex);
2510     $result = qq/<select name="$name" $tabindex$has_size$is_multiple$other>\n/;
2511     foreach (@values) {
2512         my($selectit) = $self->_selected($selected{$_});
2513         my($label) = $_;
2514         $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2515         $label=$self->escapeHTML($label);
2516         my($value)=$self->escapeHTML($_,1);
2517         my $attribs = $self->_set_attributes($_, $attributes);
2518         $result .= "<option ${selectit}${attribs}value=\"$value\">$label</option>\n";
2519     }
2520     $result .= "</select>";
2521     $self->register_parameter($name);
2522     return $result;
2523 }
2524 END_OF_FUNC
2525
2526
2527 #### Method: hidden
2528 # Parameters:
2529 #   $name -> Name of the hidden field
2530 #   @default -> (optional) Initial values of field (may be an array)
2531 #      or
2532 #   $default->[initial values of field]
2533 # Returns:
2534 #   A string containing a <input type="hidden" name="name" value="value">
2535 ####
2536 'hidden' => <<'END_OF_FUNC',
2537 sub hidden {
2538     my($self,@p) = self_or_default(@_);
2539
2540     # this is the one place where we departed from our standard
2541     # calling scheme, so we have to special-case (darn)
2542     my(@result,@value);
2543     my($name,$default,$override,@other) =
2544         rearrange([NAME,[DEFAULT,VALUE,VALUES],[OVERRIDE,FORCE]],@p);
2545
2546     my $do_override = 0;
2547     if ( ref($p[0]) || substr($p[0],0,1) eq '-') {
2548         @value = ref($default) ? @{$default} : $default;
2549         $do_override = $override;
2550     } else {
2551         foreach ($default,$override,@other) {
2552             push(@value,$_) if defined($_);
2553         }
2554     }
2555
2556     # use previous values if override is not set
2557     my @prev = $self->param($name);
2558     @value = @prev if !$do_override && @prev;
2559
2560     $name=$self->escapeHTML($name);
2561     foreach (@value) {
2562         $_ = defined($_) ? $self->escapeHTML($_,1) : '';
2563         push @result,$XHTML ? qq(<input type="hidden" name="$name" value="$_" @other />)
2564                             : qq(<input type="hidden" name="$name" value="$_" @other>);
2565     }
2566     return wantarray ? @result : join('',@result);
2567 }
2568 END_OF_FUNC
2569
2570
2571 #### Method: image_button
2572 # Parameters:
2573 #   $name -> Name of the button
2574 #   $src ->  URL of the image source
2575 #   $align -> Alignment style (TOP, BOTTOM or MIDDLE)
2576 # Returns:
2577 #   A string containing a <input type="image" name="name" src="url" align="alignment">
2578 ####
2579 'image_button' => <<'END_OF_FUNC',
2580 sub image_button {
2581     my($self,@p) = self_or_default(@_);
2582
2583     my($name,$src,$alignment,@other) =
2584         rearrange([NAME,SRC,ALIGN],@p);
2585
2586     my($align) = $alignment ? " align=\U\"$alignment\"" : '';
2587     my($other) = @other ? " @other" : '';
2588     $name=$self->escapeHTML($name);
2589     return $XHTML ? qq(<input type="image" name="$name" src="$src"$align$other />)
2590                   : qq/<input type="image" name="$name" src="$src"$align$other>/;
2591 }
2592 END_OF_FUNC
2593
2594
2595 #### Method: self_url
2596 # Returns a URL containing the current script and all its
2597 # param/value pairs arranged as a query.  You can use this
2598 # to create a link that, when selected, will reinvoke the
2599 # script with all its state information preserved.
2600 ####
2601 'self_url' => <<'END_OF_FUNC',
2602 sub self_url {
2603     my($self,@p) = self_or_default(@_);
2604     return $self->url('-path_info'=>1,'-query'=>1,'-full'=>1,@p);
2605 }
2606 END_OF_FUNC
2607
2608
2609 # This is provided as a synonym to self_url() for people unfortunate
2610 # enough to have incorporated it into their programs already!
2611 'state' => <<'END_OF_FUNC',
2612 sub state {
2613     &self_url;
2614 }
2615 END_OF_FUNC
2616
2617
2618 #### Method: url
2619 # Like self_url, but doesn't return the query string part of
2620 # the URL.
2621 ####
2622 'url' => <<'END_OF_FUNC',
2623 sub url {
2624     my($self,@p) = self_or_default(@_);
2625     my ($relative,$absolute,$full,$path_info,$query,$base,$rewrite) =
2626         rearrange(['RELATIVE','ABSOLUTE','FULL',['PATH','PATH_INFO'],['QUERY','QUERY_STRING'],'BASE','REWRITE'],@p);
2627     my $url  = '';
2628     $full++      if $base || !($relative || $absolute);
2629     $rewrite++   unless defined $rewrite;
2630
2631     my $path        =  $self->path_info;
2632     my $script_name =  $self->script_name;
2633     my $request_uri = $self->request_uri || '';
2634     my $query_str   =  $self->query_string;
2635
2636     my $rewrite_in_use = $request_uri && $request_uri !~ /^$script_name/;
2637     undef $path if $rewrite_in_use && $rewrite;  # path not valid when rewriting active
2638
2639     my $uri         =  $rewrite && $request_uri ? $request_uri : $script_name;
2640     $uri            =~ s/\?.*$//;                                 # remove query string
2641     $uri            =~ s/$path$//      if defined $path;          # remove path
2642
2643     if ($full) {
2644         my $protocol = $self->protocol();
2645         $url = "$protocol://";
2646         my $vh = http('x_forwarded_host') || http('host');
2647         if ($vh) {
2648             $url .= $vh;
2649         } else {
2650             $url .= server_name();
2651             my $port = $self->server_port;
2652             $url .= ":" . $port
2653                 unless (lc($protocol) eq 'http'  && $port == 80)
2654                     || (lc($protocol) eq 'https' && $port == 443);
2655         }
2656         return $url if $base;
2657         $url .= $uri;
2658     } elsif ($relative) {
2659         ($url) = $script_name =~ m!([^/]+)$!;
2660     } elsif ($absolute) {
2661         $url = $uri;
2662     }
2663
2664     $url .= $path         if $path_info and defined $path;
2665     $url .= "?$query_str" if $query     and $query_str ne '';
2666     $url =~ s/([^a-zA-Z0-9_.%;&?\/\\:+=~-])/sprintf("%%%02X",ord($1))/eg;
2667     return $url;
2668 }
2669
2670 END_OF_FUNC
2671
2672 #### Method: cookie
2673 # Set or read a cookie from the specified name.
2674 # Cookie can then be passed to header().
2675 # Usual rules apply to the stickiness of -value.
2676 #  Parameters:
2677 #   -name -> name for this cookie (optional)
2678 #   -value -> value of this cookie (scalar, array or hash)
2679 #   -path -> paths for which this cookie is valid (optional)
2680 #   -domain -> internet domain in which this cookie is valid (optional)
2681 #   -secure -> if true, cookie only passed through secure channel (optional)
2682 #   -expires -> expiry date in format Wdy, DD-Mon-YYYY HH:MM:SS GMT (optional)
2683 ####
2684 'cookie' => <<'END_OF_FUNC',
2685 sub cookie {
2686     my($self,@p) = self_or_default(@_);
2687     my($name,$value,$path,$domain,$secure,$expires) =
2688         rearrange([NAME,[VALUE,VALUES],PATH,DOMAIN,SECURE,EXPIRES],@p);
2689
2690     require CGI::Cookie;
2691
2692     # if no value is supplied, then we retrieve the
2693     # value of the cookie, if any.  For efficiency, we cache the parsed
2694     # cookies in our state variables.
2695     unless ( defined($value) ) {
2696         $self->{'.cookies'} = CGI::Cookie->fetch
2697             unless $self->{'.cookies'};
2698
2699         # If no name is supplied, then retrieve the names of all our cookies.
2700         return () unless $self->{'.cookies'};
2701         return keys %{$self->{'.cookies'}} unless $name;
2702         return () unless $self->{'.cookies'}->{$name};
2703         return $self->{'.cookies'}->{$name}->value if defined($name) && $name ne '';
2704     }
2705
2706     # If we get here, we're creating a new cookie
2707     return undef unless defined($name) && $name ne '';  # this is an error
2708
2709     my @param;
2710     push(@param,'-name'=>$name);
2711     push(@param,'-value'=>$value);
2712     push(@param,'-domain'=>$domain) if $domain;
2713     push(@param,'-path'=>$path) if $path;
2714     push(@param,'-expires'=>$expires) if $expires;
2715     push(@param,'-secure'=>$secure) if $secure;
2716
2717     return new CGI::Cookie(@param);
2718 }
2719 END_OF_FUNC
2720
2721 'parse_keywordlist' => <<'END_OF_FUNC',
2722 sub parse_keywordlist {
2723     my($self,$tosplit) = @_;
2724     $tosplit = unescape($tosplit); # unescape the keywords
2725     $tosplit=~tr/+/ /;          # pluses to spaces
2726     my(@keywords) = split(/\s+/,$tosplit);
2727     return @keywords;
2728 }
2729 END_OF_FUNC
2730
2731 'param_fetch' => <<'END_OF_FUNC',
2732 sub param_fetch {
2733     my($self,@p) = self_or_default(@_);
2734     my($name) = rearrange([NAME],@p);
2735     unless (exists($self->{$name})) {
2736         $self->add_parameter($name);
2737         $self->{$name} = [];
2738     }
2739
2740     return $self->{$name};
2741 }
2742 END_OF_FUNC
2743
2744 ###############################################
2745 # OTHER INFORMATION PROVIDED BY THE ENVIRONMENT
2746 ###############################################
2747
2748 #### Method: path_info
2749 # Return the extra virtual path information provided
2750 # after the URL (if any)
2751 ####
2752 'path_info' => <<'END_OF_FUNC',
2753 sub path_info {
2754     my ($self,$info) = self_or_default(@_);
2755     if (defined($info)) {
2756         $info = "/$info" if $info ne '' &&  substr($info,0,1) ne '/';
2757         $self->{'.path_info'} = $info;
2758     } elsif (! defined($self->{'.path_info'}) ) {
2759         my (undef,$path_info) = $self->_name_and_path_from_env;
2760         $self->{'.path_info'} = $path_info || '';
2761         # hack to fix broken path info in IIS
2762         $self->{'.path_info'} =~ s/^\Q$ENV{'SCRIPT_NAME'}\E// if $IIS;
2763
2764     }
2765     return $self->{'.path_info'};
2766 }
2767 END_OF_FUNC
2768
2769 # WE USE THIS TO COMPENSATE FOR A BUG IN APACHE 2 PRESENT AT LEAST UP THROUGH 2.0.54
2770 '_name_and_path_from_env' => <<'END_OF_FUNC',
2771 sub _name_and_path_from_env {
2772    my $self = shift;
2773    my $raw_script_name = $ENV{SCRIPT_NAME} || '';
2774    my $raw_path_info   = $ENV{PATH_INFO}   || '';
2775    my $uri             = $ENV{REQUEST_URI} || '';
2776
2777    if ($raw_script_name =~ m/$raw_path_info$/) {
2778      $raw_script_name =~ s/$raw_path_info$//;
2779    }
2780
2781    my @uri_double_slashes  = $uri =~ m^(/{2,}?)^g;
2782    my @path_double_slashes = "$raw_script_name $raw_path_info" =~ m^(/{2,}?)^g;
2783
2784    my $apache_bug      = @uri_double_slashes != @path_double_slashes;
2785    return ($raw_script_name,$raw_path_info) unless $apache_bug;
2786
2787    my $path_info_search = $raw_path_info;
2788    # these characters will not (necessarily) be escaped
2789    $path_info_search    =~ s/([^a-zA-Z0-9$()':_.,+*\/;?=&-])/uc sprintf("%%%02x",ord($1))/eg;
2790    $path_info_search    = quotemeta($path_info_search);
2791    $path_info_search    =~ s!/!/+!g;
2792    if ($uri =~ m/^(.+)($path_info_search)/) {
2793        return ($1,$2);
2794    } else {
2795        return ($raw_script_name,$raw_path_info);
2796    }
2797 }
2798 END_OF_FUNC
2799
2800
2801 #### Method: request_method
2802 # Returns 'POST', 'GET', 'PUT' or 'HEAD'
2803 ####
2804 'request_method' => <<'END_OF_FUNC',
2805 sub request_method {
2806     return $ENV{'REQUEST_METHOD'};
2807 }
2808 END_OF_FUNC
2809
2810 #### Method: content_type
2811 # Returns the content_type string
2812 ####
2813 'content_type' => <<'END_OF_FUNC',
2814 sub content_type {
2815     return $ENV{'CONTENT_TYPE'};
2816 }
2817 END_OF_FUNC
2818
2819 #### Method: path_translated
2820 # Return the physical path information provided
2821 # by the URL (if any)
2822 ####
2823 'path_translated' => <<'END_OF_FUNC',
2824 sub path_translated {
2825     return $ENV{'PATH_TRANSLATED'};
2826 }
2827 END_OF_FUNC
2828
2829
2830 #### Method: request_uri
2831 # Return the literal request URI
2832 ####
2833 'request_uri' => <<'END_OF_FUNC',
2834 sub request_uri {
2835     return $ENV{'REQUEST_URI'};
2836 }
2837 END_OF_FUNC
2838
2839
2840 #### Method: query_string
2841 # Synthesize a query string from our current
2842 # parameters
2843 ####
2844 'query_string' => <<'END_OF_FUNC',
2845 sub query_string {
2846     my($self) = self_or_default(@_);
2847     my($param,$value,@pairs);
2848     foreach $param ($self->param) {
2849         my($eparam) = escape($param);
2850         foreach $value ($self->param($param)) {
2851             $value = escape($value);
2852             next unless defined $value;
2853             push(@pairs,"$eparam=$value");
2854         }
2855     }
2856     foreach (keys %{$self->{'.fieldnames'}}) {
2857       push(@pairs,".cgifields=".escape("$_"));
2858     }
2859     return join($USE_PARAM_SEMICOLONS ? ';' : '&',@pairs);
2860 }
2861 END_OF_FUNC
2862
2863
2864 #### Method: accept
2865 # Without parameters, returns an array of the
2866 # MIME types the browser accepts.
2867 # With a single parameter equal to a MIME
2868 # type, will return undef if the browser won't
2869 # accept it, 1 if the browser accepts it but
2870 # doesn't give a preference, or a floating point
2871 # value between 0.0 and 1.0 if the browser
2872 # declares a quantitative score for it.
2873 # This handles MIME type globs correctly.
2874 ####
2875 'Accept' => <<'END_OF_FUNC',
2876 sub Accept {
2877     my($self,$search) = self_or_CGI(@_);
2878     my(%prefs,$type,$pref,$pat);
2879
2880     my(@accept) = split(',',$self->http('accept'));
2881
2882     foreach (@accept) {
2883         ($pref) = /q=(\d\.\d+|\d+)/;
2884         ($type) = m#(\S+/[^;]+)#;
2885         next unless $type;
2886         $prefs{$type}=$pref || 1;
2887     }
2888
2889     return keys %prefs unless $search;
2890
2891     # if a search type is provided, we may need to
2892     # perform a pattern matching operation.
2893     # The MIME types use a glob mechanism, which
2894     # is easily translated into a perl pattern match
2895
2896     # First return the preference for directly supported
2897     # types:
2898     return $prefs{$search} if $prefs{$search};
2899
2900     # Didn't get it, so try pattern matching.
2901     foreach (keys %prefs) {
2902         next unless /\*/;       # not a pattern match
2903         ($pat = $_) =~ s/([^\w*])/\\$1/g; # escape meta characters
2904         $pat =~ s/\*/.*/g; # turn it into a pattern
2905         return $prefs{$_} if $search=~/$pat/;
2906     }
2907 }
2908 END_OF_FUNC
2909
2910
2911 #### Method: user_agent
2912 # If called with no parameters, returns the user agent.
2913 # If called with one parameter, does a pattern match (case
2914 # insensitive) on the user agent.
2915 ####
2916 'user_agent' => <<'END_OF_FUNC',
2917 sub user_agent {
2918     my($self,$match)=self_or_CGI(@_);
2919     return $self->http('user_agent') unless $match;
2920     return $self->http('user_agent') =~ /$match/i;
2921 }
2922 END_OF_FUNC
2923
2924
2925 #### Method: raw_cookie
2926 # Returns the magic cookies for the session.
2927 # The cookies are not parsed or altered in any way, i.e.
2928 # cookies are returned exactly as given in the HTTP
2929 # headers.  If a cookie name is given, only that cookie's
2930 # value is returned, otherwise the entire raw cookie
2931 # is returned.
2932 ####
2933 'raw_cookie' => <<'END_OF_FUNC',
2934 sub raw_cookie {
2935     my($self,$key) = self_or_CGI(@_);
2936
2937     require CGI::Cookie;
2938
2939     if (defined($key)) {
2940         $self->{'.raw_cookies'} = CGI::Cookie->raw_fetch
2941             unless $self->{'.raw_cookies'};
2942
2943         return () unless $self->{'.raw_cookies'};
2944         return () unless $self->{'.raw_cookies'}->{$key};
2945         return $self->{'.raw_cookies'}->{$key};
2946     }
2947     return $self->http('cookie') || $ENV{'COOKIE'} || '';
2948 }
2949 END_OF_FUNC
2950
2951 #### Method: virtual_host
2952 # Return the name of the virtual_host, which
2953 # is not always the same as the server
2954 ######
2955 'virtual_host' => <<'END_OF_FUNC',
2956 sub virtual_host {
2957     my $vh = http('x_forwarded_host') || http('host') || server_name();
2958     $vh =~ s/:\d+$//;           # get rid of port number
2959     return $vh;
2960 }
2961 END_OF_FUNC
2962
2963 #### Method: remote_host
2964 # Return the name of the remote host, or its IP
2965 # address if unavailable.  If this variable isn't
2966 # defined, it returns "localhost" for debugging
2967 # purposes.
2968 ####
2969 'remote_host' => <<'END_OF_FUNC',
2970 sub remote_host {
2971     return $ENV{'REMOTE_HOST'} || $ENV{'REMOTE_ADDR'}
2972     || 'localhost';
2973 }
2974 END_OF_FUNC
2975
2976
2977 #### Method: remote_addr
2978 # Return the IP addr of the remote host.
2979 ####
2980 'remote_addr' => <<'END_OF_FUNC',
2981 sub remote_addr {
2982     return $ENV{'REMOTE_ADDR'} || '127.0.0.1';
2983 }
2984 END_OF_FUNC
2985
2986
2987 #### Method: script_name
2988 # Return the partial URL to this script for
2989 # self-referencing scripts.  Also see
2990 # self_url(), which returns a URL with all state information
2991 # preserved.
2992 ####
2993 'script_name' => <<'END_OF_FUNC',
2994 sub script_name {
2995     my ($self,@p) = self_or_default(@_);
2996     if (@p) {
2997         $self->{'.script_name'} = shift;
2998     } elsif (!exists $self->{'.script_name'}) {
2999         my ($script_name,$path_info) = $self->_name_and_path_from_env();
3000         $self->{'.script_name'} = $script_name;
3001     }
3002     return $self->{'.script_name'};
3003 }
3004 END_OF_FUNC
3005
3006
3007 #### Method: referer
3008 # Return the HTTP_REFERER: useful for generating
3009 # a GO BACK button.
3010 ####
3011 'referer' => <<'END_OF_FUNC',
3012 sub referer {
3013     my($self) = self_or_CGI(@_);
3014     return $self->http('referer');
3015 }
3016 END_OF_FUNC
3017
3018
3019 #### Method: server_name
3020 # Return the name of the server
3021 ####
3022 'server_name' => <<'END_OF_FUNC',
3023 sub server_name {
3024     return $ENV{'SERVER_NAME'} || 'localhost';
3025 }
3026 END_OF_FUNC
3027
3028 #### Method: server_software
3029 # Return the name of the server software
3030 ####
3031 'server_software' => <<'END_OF_FUNC',
3032 sub server_software {
3033     return $ENV{'SERVER_SOFTWARE'} || 'cmdline';
3034 }
3035 END_OF_FUNC
3036
3037 #### Method: virtual_port
3038 # Return the server port, taking virtual hosts into account
3039 ####
3040 'virtual_port' => <<'END_OF_FUNC',
3041 sub virtual_port {
3042     my($self) = self_or_default(@_);
3043     my $vh = $self->http('x_forwarded_host') || $self->http('host');
3044     my $protocol = $self->protocol;
3045     if ($vh) {
3046         return ($vh =~ /:(\d+)$/)[0] || ($protocol eq 'https' ? 443 : 80);
3047     } else {
3048         return $self->server_port();
3049     }
3050 }
3051 END_OF_FUNC
3052
3053 #### Method: server_port
3054 # Return the tcp/ip port the server is running on
3055 ####
3056 'server_port' => <<'END_OF_FUNC',
3057 sub server_port {
3058     return $ENV{'SERVER_PORT'} || 80; # for debugging
3059 }
3060 END_OF_FUNC
3061
3062 #### Method: server_protocol
3063 # Return the protocol (usually HTTP/1.0)
3064 ####
3065 'server_protocol' => <<'END_OF_FUNC',
3066 sub server_protocol {
3067     return $ENV{'SERVER_PROTOCOL'} || 'HTTP/1.0'; # for debugging
3068 }
3069 END_OF_FUNC
3070
3071 #### Method: http
3072 # Return the value of an HTTP variable, or
3073 # the list of variables if none provided
3074 ####
3075 'http' => <<'END_OF_FUNC',
3076 sub http {
3077     my ($self,$parameter) = self_or_CGI(@_);
3078     return $ENV{$parameter} if $parameter=~/^HTTP/;
3079     $parameter =~ tr/-/_/;
3080     return $ENV{"HTTP_\U$parameter\E"} if $parameter;
3081     my(@p);
3082     foreach (keys %ENV) {
3083         push(@p,$_) if /^HTTP/;
3084     }
3085     return @p;
3086 }
3087 END_OF_FUNC
3088
3089 #### Method: https
3090 # Return the value of HTTPS
3091 ####
3092 'https' => <<'END_OF_FUNC',
3093 sub https {
3094     local($^W)=0;
3095     my ($self,$parameter) = self_or_CGI(@_);
3096     return $ENV{HTTPS} unless $parameter;
3097     return $ENV{$parameter} if $parameter=~/^HTTPS/;
3098     $parameter =~ tr/-/_/;
3099     return $ENV{"HTTPS_\U$parameter\E"} if $parameter;
3100     my(@p);
3101     foreach (keys %ENV) {
3102         push(@p,$_) if /^HTTPS/;
3103     }
3104     return @p;
3105 }
3106 END_OF_FUNC
3107
3108 #### Method: protocol
3109 # Return the protocol (http or https currently)
3110 ####
3111 'protocol' => <<'END_OF_FUNC',
3112 sub protocol {
3113     local($^W)=0;
3114     my $self = shift;
3115     return 'https' if uc($self->https()) eq 'ON';
3116     return 'https' if $self->server_port == 443;
3117     my $prot = $self->server_protocol;
3118     my($protocol,$version) = split('/',$prot);
3119     return "\L$protocol\E";
3120 }
3121 END_OF_FUNC
3122
3123 #### Method: remote_ident
3124 # Return the identity of the remote user
3125 # (but only if his host is running identd)
3126 ####
3127 'remote_ident' => <<'END_OF_FUNC',
3128 sub remote_ident {
3129     return $ENV{'REMOTE_IDENT'};
3130 }
3131 END_OF_FUNC
3132
3133
3134 #### Method: auth_type
3135 # Return the type of use verification/authorization in use, if any.
3136 ####
3137 'auth_type' => <<'END_OF_FUNC',
3138 sub auth_type {
3139     return $ENV{'AUTH_TYPE'};
3140 }
3141 END_OF_FUNC
3142
3143
3144 #### Method: remote_user
3145 # Return the authorization name used for user
3146 # verification.
3147 ####
3148 'remote_user' => <<'END_OF_FUNC',
3149 sub remote_user {
3150     return $ENV{'REMOTE_USER'};
3151 }
3152 END_OF_FUNC
3153
3154
3155 #### Method: user_name
3156 # Try to return the remote user's name by hook or by
3157 # crook
3158 ####
3159 'user_name' => <<'END_OF_FUNC',
3160 sub user_name {
3161     my ($self) = self_or_CGI(@_);
3162     return $self->http('from') || $ENV{'REMOTE_IDENT'} || $ENV{'REMOTE_USER'};
3163 }
3164 END_OF_FUNC
3165
3166 #### Method: nosticky
3167 # Set or return the NOSTICKY global flag
3168 ####
3169 'nosticky' => <<'END_OF_FUNC',
3170 sub nosticky {
3171     my ($self,$param) = self_or_CGI(@_);
3172     $CGI::NOSTICKY = $param if defined($param);
3173     return $CGI::NOSTICKY;
3174 }
3175 END_OF_FUNC
3176
3177 #### Method: nph
3178 # Set or return the NPH global flag
3179 ####
3180 'nph' => <<'END_OF_FUNC',
3181 sub nph {
3182     my ($self,$param) = self_or_CGI(@_);
3183     $CGI::NPH = $param if defined($param);
3184     return $CGI::NPH;
3185 }
3186 END_OF_FUNC
3187
3188 #### Method: private_tempfiles
3189 # Set or return the private_tempfiles global flag
3190 ####
3191 'private_tempfiles' => <<'END_OF_FUNC',
3192 sub private_tempfiles {
3193     my ($self,$param) = self_or_CGI(@_);
3194     $CGI::PRIVATE_TEMPFILES = $param if defined($param);
3195     return $CGI::PRIVATE_TEMPFILES;
3196 }
3197 END_OF_FUNC
3198 #### Method: close_upload_files
3199 # Set or return the close_upload_files global flag
3200 ####
3201 'close_upload_files' => <<'END_OF_FUNC',
3202 sub close_upload_files {
3203     my ($self,$param) = self_or_CGI(@_);
3204     $CGI::CLOSE_UPLOAD_FILES = $param if defined($param);
3205     return $CGI::CLOSE_UPLOAD_FILES;
3206 }
3207 END_OF_FUNC
3208
3209
3210 #### Method: default_dtd
3211 # Set or return the default_dtd global
3212 ####
3213 'default_dtd' => <<'END_OF_FUNC',
3214 sub default_dtd {
3215     my ($self,$param,$param2) = self_or_CGI(@_);
3216     if (defined $param2 && defined $param) {
3217         $CGI::DEFAULT_DTD = [ $param, $param2 ];
3218     } elsif (defined $param) {
3219         $CGI::DEFAULT_DTD = $param;
3220     }
3221     return $CGI::DEFAULT_DTD;
3222 }
3223 END_OF_FUNC
3224
3225 # -------------- really private subroutines -----------------
3226 'previous_or_default' => <<'END_OF_FUNC',
3227 sub previous_or_default {
3228     my($self,$name,$defaults,$override) = @_;
3229     my(%selected);
3230
3231     if (!$override && ($self->{'.fieldnames'}->{$name} ||
3232                        defined($self->param($name)) ) ) {
3233         grep($selected{$_}++,$self->param($name));
3234     } elsif (defined($defaults) && ref($defaults) &&
3235              (ref($defaults) eq 'ARRAY')) {
3236         grep($selected{$_}++,@{$defaults});
3237     } else {
3238         $selected{$defaults}++ if defined($defaults);
3239     }
3240
3241     return %selected;
3242 }
3243 END_OF_FUNC
3244
3245 'register_parameter' => <<'END_OF_FUNC',
3246 sub register_parameter {
3247     my($self,$param) = @_;
3248     $self->{'.parametersToAdd'}->{$param}++;
3249 }
3250 END_OF_FUNC
3251
3252 'get_fields' => <<'END_OF_FUNC',
3253 sub get_fields {
3254     my($self) = @_;
3255     return $self->CGI::hidden('-name'=>'.cgifields',
3256                               '-values'=>[keys %{$self->{'.parametersToAdd'}}],
3257                               '-override'=>1);
3258 }
3259 END_OF_FUNC
3260
3261 'read_from_cmdline' => <<'END_OF_FUNC',
3262 sub read_from_cmdline {
3263     my($input,@words);
3264     my($query_string);
3265     my($subpath);
3266     if ($DEBUG && @ARGV) {
3267         @words = @ARGV;
3268     } elsif ($DEBUG > 1) {
3269         require "shellwords.pl";
3270         print STDERR "(offline mode: enter name=value pairs on standard input; press ^D or ^Z when done)\n";
3271         chomp(@lines = <STDIN>); # remove newlines
3272         $input = join(" ",@lines);
3273         @words = &shellwords($input);
3274     }
3275     foreach (@words) {
3276         s/\\=/%3D/g;
3277         s/\\&/%26/g;
3278     }
3279
3280     if ("@words"=~/=/) {
3281         $query_string = join('&',@words);
3282     } else {
3283         $query_string = join('+',@words);
3284     }
3285     if ($query_string =~ /^(.*?)\?(.*)$/)
3286     {
3287         $query_string = $2;
3288         $subpath = $1;
3289     }
3290     return { 'query_string' => $query_string, 'subpath' => $subpath };
3291 }
3292 END_OF_FUNC
3293
3294 #####
3295 # subroutine: read_multipart
3296 #
3297 # Read multipart data and store it into our parameters.
3298 # An interesting feature is that if any of the parts is a file, we
3299 # create a temporary file and open up a filehandle on it so that the
3300 # caller can read from it if necessary.
3301 #####
3302 'read_multipart' => <<'END_OF_FUNC',
3303 sub read_multipart {
3304     my($self,$boundary,$length) = @_;
3305     my($buffer) = $self->new_MultipartBuffer($boundary,$length);
3306     return unless $buffer;
3307     my(%header,$body);
3308     my $filenumber = 0;
3309     while (!$buffer->eof) {
3310         %header = $buffer->readHeader;
3311
3312         unless (%header) {
3313             $self->cgi_error("400 Bad request (malformed multipart POST)");
3314             return;
3315         }
3316
3317         my($param)= $header{'Content-Disposition'}=~/ name="([^"]*)"/;
3318         $param .= $TAINTED;
3319
3320         # Bug:  Netscape doesn't escape quotation marks in file names!!!
3321         my($filename) = $header{'Content-Disposition'}=~/ filename="([^"]*)"/;
3322         # Test for Opera's multiple upload feature
3323         my($multipart) = ( defined( $header{'Content-Type'} ) &&
3324                 $header{'Content-Type'} =~ /multipart\/mixed/ ) ?
3325                 1 : 0;
3326
3327         # add this parameter to our list
3328         $self->add_parameter($param);
3329
3330         # If no filename specified, then just read the data and assign it
3331         # to our parameter list.
3332         if ( ( !defined($filename) || $filename eq '' ) && !$multipart ) {
3333             my($value) = $buffer->readBody;
3334             $value .= $TAINTED;
3335             push(@{$self->{$param}},$value);
3336             next;
3337         }
3338
3339         my ($tmpfile,$tmp,$filehandle);
3340       UPLOADS: {
3341           # If we get here, then we are dealing with a potentially large
3342           # uploaded form.  Save the data to a temporary file, then open
3343           # the file for reading.
3344
3345           # skip the file if uploads disabled
3346           if ($DISABLE_UPLOADS) {
3347               while (defined($data = $buffer->read)) { }
3348               last UPLOADS;
3349           }
3350
3351           # set the filename to some recognizable value
3352           if ( ( !defined($filename) || $filename eq '' ) && $multipart ) {
3353               $filename = "multipart/mixed";
3354           }
3355
3356           # choose a relatively unpredictable tmpfile sequence number
3357           my $seqno = unpack("%16C*",join('',localtime,grep {defined $_} values %ENV));
3358           for (my $cnt=10;$cnt>0;$cnt--) {
3359             next unless $tmpfile = new CGITempFile($seqno);
3360             $tmp = $tmpfile->as_string;
3361             last if defined($filehandle = Fh->new($filename,$tmp,$PRIVATE_TEMPFILES));
3362             $seqno += int rand(100);
3363           }
3364           die "CGI open of tmpfile: $!\n" unless defined $filehandle;
3365           $CGI::DefaultClass->binmode($filehandle) if $CGI::needs_binmode
3366                      && defined fileno($filehandle);
3367
3368           # if this is an multipart/mixed attachment, save the header
3369           # together with the body for later parsing with an external
3370           # MIME parser module
3371           if ( $multipart ) {
3372               foreach ( keys %header ) {
3373                   print $filehandle "$_: $header{$_}${CRLF}";
3374               }
3375               print $filehandle "${CRLF}";
3376           }
3377
3378           my ($data);
3379           local($\) = '';
3380           my $totalbytes;
3381           while (defined($data = $buffer->read)) {
3382               if (defined $self->{'.upload_hook'})
3383                {
3384                   $totalbytes += length($data);
3385                    &{$self->{'.upload_hook'}}($filename ,$data, $totalbytes, $self->{'.upload_data'});
3386               }
3387               print $filehandle $data;
3388           }
3389
3390           # back up to beginning of file
3391           seek($filehandle,0,0);
3392
3393       ## Close the filehandle if requested this allows a multipart MIME
3394       ## upload to contain many files, and we won't die due to too many
3395       ## open file handles. The user can access the files using the hash
3396       ## below.
3397       close $filehandle if $CLOSE_UPLOAD_FILES;
3398           $CGI::DefaultClass->binmode($filehandle) if $CGI::needs_binmode;
3399
3400           # Save some information about the uploaded file where we can get
3401           # at it later.
3402           # Use the typeglob as the key, as this is guaranteed to be
3403           # unique for each filehandle.  Don't use the file descriptor as
3404           # this will be re-used for each filehandle if the
3405           # close_upload_files feature is used.
3406           $self->{'.tmpfiles'}->{$$filehandle}= {
3407               hndl => $filehandle,
3408               name => $tmpfile,
3409               info => {%header},
3410           };
3411           push(@{$self->{$param}},$filehandle);
3412       }
3413     }
3414 }
3415 END_OF_FUNC
3416
3417 'upload' =><<'END_OF_FUNC',
3418 sub upload {
3419     my($self,$param_name) = self_or_default(@_);
3420     my @param = grep(ref && fileno($_), $self->param($param_name));
3421     return unless @param;
3422     return wantarray ? @param : $param[0];
3423 }
3424 END_OF_FUNC
3425
3426 'tmpFileName' => <<'END_OF_FUNC',
3427 sub tmpFileName {
3428     my($self,$filename) = self_or_default(@_);
3429     return $self->{'.tmpfiles'}->{$$filename}->{name} ?
3430         $self->{'.tmpfiles'}->{$$filename}->{name}->as_string
3431             : '';
3432 }
3433 END_OF_FUNC
3434
3435 'uploadInfo' => <<'END_OF_FUNC',
3436 sub uploadInfo {
3437     my($self,$filename) = self_or_default(@_);
3438     return $self->{'.tmpfiles'}->{$$filename}->{info};
3439 }
3440 END_OF_FUNC
3441
3442 # internal routine, don't use
3443 '_set_values_and_labels' => <<'END_OF_FUNC',
3444 sub _set_values_and_labels {
3445     my $self = shift;
3446     my ($v,$l,$n) = @_;
3447     $$l = $v if ref($v) eq 'HASH' && !ref($$l);
3448     return $self->param($n) if !defined($v);
3449     return $v if !ref($v);
3450     return ref($v) eq 'HASH' ? keys %$v : @$v;
3451 }
3452 END_OF_FUNC
3453
3454 # internal routine, don't use
3455 '_set_attributes' => <<'END_OF_FUNC',
3456 sub _set_attributes {
3457     my $self = shift;
3458     my($element, $attributes) = @_;
3459     return '' unless defined($attributes->{$element});
3460     $attribs = ' ';
3461     foreach my $attrib (keys %{$attributes->{$element}}) {
3462         (my $clean_attrib = $attrib) =~ s/^-//;
3463         $attribs .= "@{[lc($clean_attrib)]}=\"$attributes->{$element}{$attrib}\" ";
3464     }
3465     $attribs =~ s/ $//;
3466     return $attribs;
3467 }
3468 END_OF_FUNC
3469
3470 '_compile_all' => <<'END_OF_FUNC',
3471 sub _compile_all {
3472     foreach (@_) {
3473         next if defined(&$_);
3474         $AUTOLOAD = "CGI::$_";
3475         _compile();
3476     }
3477 }
3478 END_OF_FUNC
3479
3480 );
3481 END_OF_AUTOLOAD
3482 ;
3483
3484 #########################################################
3485 # Globals and stubs for other packages that we use.
3486 #########################################################
3487
3488 ################### Fh -- lightweight filehandle ###############
3489 package Fh;
3490 use overload
3491     '""'  => \&asString,
3492     'cmp' => \&compare,
3493     'fallback'=>1;
3494
3495 $FH='fh00000';
3496
3497 *Fh::AUTOLOAD = \&CGI::AUTOLOAD;
3498
3499 sub DESTROY {
3500     my $self = shift;
3501     close $self;
3502 }
3503
3504 $AUTOLOADED_ROUTINES = '';      # prevent -w error
3505 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
3506 %SUBS =  (
3507 'asString' => <<'END_OF_FUNC',
3508 sub asString {
3509     my $self = shift;
3510     # get rid of package name
3511     (my $i = $$self) =~ s/^\*(\w+::fh\d{5})+//;
3512     $i =~ s/%(..)/ chr(hex($1)) /eg;
3513     return $i.$CGI::TAINTED;
3514 # BEGIN DEAD CODE
3515 # This was an extremely clever patch that allowed "use strict refs".
3516 # Unfortunately it relied on another bug that caused leaky file descriptors.
3517 # The underlying bug has been fixed, so this no longer works.  However
3518 # "strict refs" still works for some reason.
3519 #    my $self = shift;
3520 #    return ${*{$self}{SCALAR}};
3521 # END DEAD CODE
3522 }
3523 END_OF_FUNC
3524
3525 'compare' => <<'END_OF_FUNC',
3526 sub compare {
3527     my $self = shift;
3528     my $value = shift;
3529     return "$self" cmp $value;
3530 }
3531 END_OF_FUNC
3532
3533 'new'  => <<'END_OF_FUNC',
3534 sub new {
3535     my($pack,$name,$file,$delete) = @_;
3536     _setup_symbols(@SAVED_SYMBOLS) if @SAVED_SYMBOLS;
3537     require Fcntl unless defined &Fcntl::O_RDWR;
3538     (my $safename = $name) =~ s/([':%])/ sprintf '%%%02X', ord $1 /eg;
3539     my $fv = ++$FH . $safename;
3540     my $ref = \*{"Fh::$fv"};
3541     $file =~ m!^([a-zA-Z0-9_ \'\":/.\$\\-]+)$! || return;
3542     my $safe = $1;
3543     sysopen($ref,$safe,Fcntl::O_RDWR()|Fcntl::O_CREAT()|Fcntl::O_EXCL(),0600) || return;
3544     unlink($safe) if $delete;
3545     CORE::delete $Fh::{$fv};
3546     return bless $ref,$pack;
3547 }
3548 END_OF_FUNC
3549
3550 );
3551 END_OF_AUTOLOAD
3552
3553 ######################## MultipartBuffer ####################
3554 package MultipartBuffer;
3555
3556 use constant DEBUG => 0;
3557
3558 # how many bytes to read at a time.  We use
3559 # a 4K buffer by default.
3560 $INITIAL_FILLUNIT = 1024 * 4;
3561 $TIMEOUT = 240*60;       # 4 hour timeout for big files
3562 $SPIN_LOOP_MAX = 2000;  # bug fix for some Netscape servers
3563 $CRLF=$CGI::CRLF;
3564
3565 #reuse the autoload function
3566 *MultipartBuffer::AUTOLOAD = \&CGI::AUTOLOAD;
3567
3568 # avoid autoloader warnings
3569 sub DESTROY {}
3570
3571 ###############################################################################
3572 ################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
3573 ###############################################################################
3574 $AUTOLOADED_ROUTINES = '';      # prevent -w error
3575 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
3576 %SUBS =  (
3577
3578 'new' => <<'END_OF_FUNC',
3579 sub new {
3580     my($package,$interface,$boundary,$length) = @_;
3581     $FILLUNIT = $INITIAL_FILLUNIT;
3582     $CGI::DefaultClass->binmode($IN); # if $CGI::needs_binmode;  # just do it always
3583
3584     # If the user types garbage into the file upload field,
3585     # then Netscape passes NOTHING to the server (not good).
3586     # We may hang on this read in that case. So we implement
3587     # a read timeout.  If nothing is ready to read
3588     # by then, we return.
3589
3590     # Netscape seems to be a little bit unreliable
3591     # about providing boundary strings.
3592     my $boundary_read = 0;
3593     if ($boundary) {
3594
3595         # Under the MIME spec, the boundary consists of the
3596         # characters "--" PLUS the Boundary string
3597
3598         # BUG: IE 3.01 on the Macintosh uses just the boundary -- not
3599         # the two extra hyphens.  We do a special case here on the user-agent!!!!
3600         $boundary = "--$boundary" unless CGI::user_agent('MSIE\s+3\.0[12];\s*Mac|DreamPassport');
3601
3602     } else { # otherwise we find it ourselves
3603         my($old);
3604         ($old,$/) = ($/,$CRLF); # read a CRLF-delimited line
3605         $boundary = <STDIN>;      # BUG: This won't work correctly under mod_perl
3606         $length -= length($boundary);
3607         chomp($boundary);               # remove the CRLF
3608         $/ = $old;                      # restore old line separator
3609         $boundary_read++;
3610     }
3611
3612     my $self = {LENGTH=>$length,
3613                 CHUNKED=>!defined $length,
3614                 BOUNDARY=>$boundary,
3615                 INTERFACE=>$interface,
3616                 BUFFER=>'',
3617             };
3618
3619     $FILLUNIT = length($boundary)
3620         if length($boundary) > $FILLUNIT;
3621
3622     my $retval = bless $self,ref $package || $package;
3623
3624     # Read the preamble and the topmost (boundary) line plus the CRLF.
3625     unless ($boundary_read) {
3626       while ($self->read(0)) { }
3627     }
3628     die "Malformed multipart POST: data truncated\n" if $self->eof;
3629
3630     return $retval;
3631 }
3632 END_OF_FUNC
3633
3634 'readHeader' => <<'END_OF_FUNC',
3635 sub readHeader {
3636     my($self) = @_;
3637     my($end);
3638     my($ok) = 0;
3639     my($bad) = 0;
3640
3641     local($CRLF) = "\015\012" if $CGI::OS eq 'VMS' || $CGI::EBCDIC;
3642
3643     do {
3644         $self->fillBuffer($FILLUNIT);
3645         $ok++ if ($end = index($self->{BUFFER},"${CRLF}${CRLF}")) >= 0;
3646         $ok++ if $self->{BUFFER} eq '';
3647         $bad++ if !$ok && $self->{LENGTH} <= 0;
3648         # this was a bad idea
3649         # $FILLUNIT *= 2 if length($self->{BUFFER}) >= $FILLUNIT;
3650     } until $ok || $bad;
3651     return () if $bad;
3652
3653     #EBCDIC NOTE: translate header into EBCDIC, but watch out for continuation lines!
3654
3655     my($header) = substr($self->{BUFFER},0,$end+2);
3656     substr($self->{BUFFER},0,$end+4) = '';
3657     my %return;
3658
3659     if ($CGI::EBCDIC) {
3660       warn "untranslated header=$header\n" if DEBUG;
3661       $header = CGI::Util::ascii2ebcdic($header);
3662       warn "translated header=$header\n" if DEBUG;
3663     }
3664
3665     # See RFC 2045 Appendix A and RFC 822 sections 3.4.8
3666     #   (Folding Long Header Fields), 3.4.3 (Comments)
3667     #   and 3.4.5 (Quoted-Strings).
3668
3669     my $token = '[-\w!\#$%&\'*+.^_\`|{}~]';
3670     $header=~s/$CRLF\s+/ /og;           # merge continuation lines
3671
3672     while ($header=~/($token+):\s+([^$CRLF]*)/mgox) {
3673         my ($field_name,$field_value) = ($1,$2);
3674         $field_name =~ s/\b(\w)/uc($1)/eg; #canonicalize
3675         $return{$field_name}=$field_value;
3676     }
3677     return %return;
3678 }
3679 END_OF_FUNC
3680
3681 # This reads and returns the body as a single scalar value.
3682 'readBody' => <<'END_OF_FUNC',
3683 sub readBody {
3684     my($self) = @_;
3685     my($data);
3686     my($returnval)='';
3687
3688     #EBCDIC NOTE: want to translate returnval into EBCDIC HERE
3689
3690     while (defined($data = $self->read)) {
3691         $returnval .= $data;
3692     }
3693
3694     if ($CGI::EBCDIC) {
3695       warn "untranslated body=$returnval\n" if DEBUG;
3696       $returnval = CGI::Util::ascii2ebcdic($returnval);
3697       warn "translated body=$returnval\n"   if DEBUG;
3698     }
3699     return $returnval;
3700 }
3701 END_OF_FUNC
3702
3703 # This will read $bytes or until the boundary is hit, whichever happens
3704 # first.  After the boundary is hit, we return undef.  The next read will
3705 # skip over the boundary and begin reading again;
3706 'read' => <<'END_OF_FUNC',
3707 sub read {
3708     my($self,$bytes) = @_;
3709
3710     # default number of bytes to read
3711     $bytes = $bytes || $FILLUNIT;
3712
3713     # Fill up our internal buffer in such a way that the boundary
3714     # is never split between reads.
3715     $self->fillBuffer($bytes);
3716
3717     my $boundary_start = $CGI::EBCDIC ? CGI::Util::ebcdic2ascii($self->{BOUNDARY})      : $self->{BOUNDARY};
3718     my $boundary_end   = $CGI::EBCDIC ? CGI::Util::ebcdic2ascii($self->{BOUNDARY}.'--') : $self->{BOUNDARY}.'--';
3719
3720     # Find the boundary in the buffer (it may not be there).
3721     my $start = index($self->{BUFFER},$boundary_start);
3722
3723     warn "boundary=$self->{BOUNDARY} length=$self->{LENGTH} start=$start\n" if DEBUG;
3724
3725     # protect against malformed multipart POST operations
3726     die "Malformed multipart POST\n" unless $self->{CHUNKED} || ($start >= 0 || $self->{LENGTH} > 0);
3727
3728     #EBCDIC NOTE: want to translate boundary search into ASCII here.
3729
3730     # If the boundary begins the data, then skip past it
3731     # and return undef.
3732     if ($start == 0) {
3733
3734         # clear us out completely if we've hit the last boundary.
3735         if (index($self->{BUFFER},$boundary_end)==0) {
3736             $self->{BUFFER}='';
3737             $self->{LENGTH}=0;
3738             return undef;
3739         }
3740
3741         # just remove the boundary.
3742         substr($self->{BUFFER},0,length($boundary_start))='';
3743         $self->{BUFFER} =~ s/^\012\015?//;
3744         return undef;
3745     }
3746
3747     my $bytesToReturn;
3748     if ($start > 0) {           # read up to the boundary
3749         $bytesToReturn = $start-2 > $bytes ? $bytes : $start;
3750     } else {    # read the requested number of bytes
3751         # leave enough bytes in the buffer to allow us to read
3752         # the boundary.  Thanks to Kevin Hendrick for finding
3753         # this one.
3754         $bytesToReturn = $bytes - (length($boundary_start)+1);
3755     }
3756
3757     my $returnval=substr($self->{BUFFER},0,$bytesToReturn);
3758     substr($self->{BUFFER},0,$bytesToReturn)='';
3759
3760     # If we hit the boundary, remove the CRLF from the end.
3761     return ($bytesToReturn==$start)
3762            ? substr($returnval,0,-2) : $returnval;
3763 }
3764 END_OF_FUNC
3765
3766
3767 # This fills up our internal buffer in such a way that the
3768 # boundary is never split between reads
3769 'fillBuffer' => <<'END_OF_FUNC',
3770 sub fillBuffer {
3771     my($self,$bytes) = @_;
3772     return unless $self->{CHUNKED} || $self->{LENGTH};
3773
3774     my($boundaryLength) = length($self->{BOUNDARY});
3775     my($bufferLength) = length($self->{BUFFER});
3776     my($bytesToRead) = $bytes - $bufferLength + $boundaryLength + 2;
3777     $bytesToRead = $self->{LENGTH} if !$self->{CHUNKED} && $self->{LENGTH} < $bytesToRead;
3778
3779     # Try to read some data.  We may hang here if the browser is screwed up.
3780     my $bytesRead = $self->{INTERFACE}->read_from_client(\$self->{BUFFER},
3781                                                          $bytesToRead,
3782                                                          $bufferLength);
3783     warn "bytesToRead=$bytesToRead, bufferLength=$bufferLength, buffer=$self->{BUFFER}\n" if DEBUG;
3784     $self->{BUFFER} = '' unless defined $self->{BUFFER};
3785
3786     # An apparent bug in the Apache server causes the read()
3787     # to return zero bytes repeatedly without blocking if the
3788     # remote user aborts during a file transfer.  I don't know how
3789     # they manage this, but the workaround is to abort if we get
3790     # more than SPIN_LOOP_MAX consecutive zero reads.
3791     if ($bytesRead <= 0) {
3792         die  "CGI.pm: Server closed socket during multipart read (client aborted?).\n"
3793             if ($self->{ZERO_LOOP_COUNTER}++ >= $SPIN_LOOP_MAX);
3794     } else {
3795         $self->{ZERO_LOOP_COUNTER}=0;
3796     }
3797
3798     $self->{LENGTH} -= $bytesRead if !$self->{CHUNKED} && $bytesRead;
3799 }
3800 END_OF_FUNC
3801
3802
3803 # Return true when we've finished reading
3804 'eof' => <<'END_OF_FUNC'
3805 sub eof {
3806     my($self) = @_;
3807     return 1 if (length($self->{BUFFER}) == 0)
3808                  && ($self->{LENGTH} <= 0);
3809     undef;
3810 }
3811 END_OF_FUNC
3812
3813 );
3814 END_OF_AUTOLOAD
3815
3816 ####################################################################################
3817 ################################## TEMPORARY FILES #################################
3818 ####################################################################################
3819 package CGITempFile;
3820
3821 sub find_tempdir {
3822   $SL = $CGI::SL;
3823   $MAC = $CGI::OS eq 'MACINTOSH';
3824   my ($vol) = $MAC ? MacPerl::Volumes() =~ /:(.*)/ : "";
3825   unless (defined $TMPDIRECTORY) {
3826     @TEMP=("${SL}usr${SL}tmp","${SL}var${SL}tmp",
3827            "C:${SL}temp","${SL}tmp","${SL}temp",
3828            "${vol}${SL}Temporary Items",
3829            "${SL}WWW_ROOT", "${SL}SYS\$SCRATCH",
3830            "C:${SL}system${SL}temp");
3831     unshift(@TEMP,$ENV{'TMPDIR'}) if defined $ENV{'TMPDIR'};
3832
3833     # this feature was supposed to provide per-user tmpfiles, but
3834     # it is problematic.
3835     #    unshift(@TEMP,(getpwuid($<))[7].'/tmp') if $CGI::OS eq 'UNIX';
3836     # Rob: getpwuid() is unfortunately UNIX specific. On brain dead OS'es this
3837     #    : can generate a 'getpwuid() not implemented' exception, even though
3838     #    : it's never called.  Found under DOS/Win with the DJGPP perl port.
3839     #    : Refer to getpwuid() only at run-time if we're fortunate and have  UNIX.
3840     # unshift(@TEMP,(eval {(getpwuid($>))[7]}).'/tmp') if $CGI::OS eq 'UNIX' and $> != 0;
3841
3842     foreach (@TEMP) {
3843       do {$TMPDIRECTORY = $_; last} if -d $_ && -w _;
3844     }
3845   }
3846   $TMPDIRECTORY  = $MAC ? "" : "." unless $TMPDIRECTORY;
3847 }
3848
3849 find_tempdir();
3850
3851 $MAXTRIES = 5000;
3852
3853 # cute feature, but overload implementation broke it
3854 # %OVERLOAD = ('""'=>'as_string');
3855 *CGITempFile::AUTOLOAD = \&CGI::AUTOLOAD;
3856
3857 sub DESTROY {
3858     my($self) = @_;
3859     $$self =~ m!^([a-zA-Z0-9_ \'\":/.\$\\-]+)$! || return;
3860     my $safe = $1;             # untaint operation
3861     unlink $safe;              # get rid of the file
3862 }
3863
3864 ###############################################################################
3865 ################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
3866 ###############################################################################
3867 $AUTOLOADED_ROUTINES = '';      # prevent -w error
3868 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
3869 %SUBS = (
3870
3871 'new' => <<'END_OF_FUNC',
3872 sub new {
3873     my($package,$sequence) = @_;
3874     my $filename;
3875     find_tempdir() unless -w $TMPDIRECTORY;
3876     for (my $i = 0; $i < $MAXTRIES; $i++) {
3877         last if ! -f ($filename = sprintf("${TMPDIRECTORY}${SL}CGItemp%d",$sequence++));
3878     }
3879     # check that it is a more-or-less valid filename
3880     return unless $filename =~ m!^([a-zA-Z0-9_ \'\":/.\$\\-]+)$!;
3881     # this used to untaint, now it doesn't
3882     # $filename = $1;
3883     return bless \$filename;
3884 }
3885 END_OF_FUNC
3886
3887 'as_string' => <<'END_OF_FUNC'
3888 sub as_string {
3889     my($self) = @_;
3890     return $$self;
3891 }
3892 END_OF_FUNC
3893
3894 );
3895 END_OF_AUTOLOAD
3896
3897 package CGI;
3898
3899 # We get a whole bunch of warnings about "possibly uninitialized variables"
3900 # when running with the -w switch.  Touch them all once to get rid of the
3901 # warnings.  This is ugly and I hate it.
3902 if ($^W) {
3903     $CGI::CGI = '';
3904     $CGI::CGI=<<EOF;
3905     $CGI::VERSION;
3906     $MultipartBuffer::SPIN_LOOP_MAX;
3907     $MultipartBuffer::CRLF;
3908     $MultipartBuffer::TIMEOUT;
3909     $MultipartBuffer::INITIAL_FILLUNIT;
3910 EOF
3911     ;
3912 }
3913
3914 1;
3915
3916 __END__
3917
3918 =head1 NAME
3919
3920 CGI - Simple Common Gateway Interface Class
3921
3922 =head1 SYNOPSIS
3923
3924   # CGI script that creates a fill-out form
3925   # and echoes back its values.
3926
3927   use CGI qw/:standard/;
3928   print header,
3929         start_html('A Simple Example'),
3930         h1('A Simple Example'),
3931         start_form,
3932         "What's your name? ",textfield('name'),p,
3933         "What's the combination?", p,
3934         checkbox_group(-name=>'words',
3935                        -values=>['eenie','meenie','minie','moe'],
3936                        -defaults=>['eenie','minie']), p,
3937         "What's your favorite color? ",
3938         popup_menu(-name=>'color',
3939                    -values=>['red','green','blue','chartreuse']),p,
3940         submit,
3941         end_form,
3942         hr;
3943
3944    if (param()) {
3945        my $name      = param('name');
3946        my $keywords  = join ', ',param('words');
3947        my $color     = param('color');
3948        print "Your name is",em(escapeHTML($name)),p,
3949              "The keywords are: ",em(escapeHTML($keywords)),p,
3950              "Your favorite color is ",em(escapeHTML($color)),
3951              hr;
3952    }
3953
3954 =head1 ABSTRACT
3955
3956 This perl library uses perl5 objects to make it easy to create Web
3957 fill-out forms and parse their contents.  This package defines CGI
3958 objects, entities that contain the values of the current query string
3959 and other state variables.  Using a CGI object's methods, you can
3960 examine keywords and parameters passed to your script, and create
3961 forms whose initial values are taken from the current query (thereby
3962 preserving state information).  The module provides shortcut functions
3963 that produce boilerplate HTML, reducing typing and coding errors. It
3964 also provides functionality for some of the more advanced features of
3965 CGI scripting, including support for file uploads, cookies, cascading
3966 style sheets, server push, and frames.
3967
3968 CGI.pm also provides a simple function-oriented programming style for
3969 those who don't need its object-oriented features.
3970
3971 The current version of CGI.pm is available at
3972
3973   http://www.genome.wi.mit.edu/ftp/pub/software/WWW/cgi_docs.html
3974   ftp://ftp-genome.wi.mit.edu/pub/software/WWW/
3975
3976 =head1 DESCRIPTION
3977
3978 =head2 PROGRAMMING STYLE
3979
3980 There are two styles of programming with CGI.pm, an object-oriented
3981 style and a function-oriented style.  In the object-oriented style you
3982 create one or more CGI objects and then use object methods to create
3983 the various elements of the page.  Each CGI object starts out with the
3984 list of named parameters that were passed to your CGI script by the
3985 server.  You can modify the objects, save them to a file or database
3986 and recreate them.  Because each object corresponds to the "state" of
3987 the CGI script, and because each object's parameter list is
3988 independent of the others, this allows you to save the state of the
3989 script and restore it later.
3990
3991 For example, using the object oriented style, here is how you create
3992 a simple "Hello World" HTML page:
3993
3994    #!/usr/local/bin/perl -w
3995    use CGI;                             # load CGI routines
3996    $q = new CGI;                        # create new CGI object
3997    print $q->header,                    # create the HTTP header
3998          $q->start_html('hello world'), # start the HTML
3999          $q->h1('hello world'),         # level 1 header
4000          $q->end_html;                  # end the HTML
4001
4002 In the function-oriented style, there is one default CGI object that
4003 you rarely deal with directly.  Instead you just call functions to
4004 retrieve CGI parameters, create HTML tags, manage cookies, and so
4005 on.  This provides you with a cleaner programming interface, but
4006 limits you to using one CGI object at a time.  The following example
4007 prints the same page, but uses the function-oriented interface.
4008 The main differences are that we now need to import a set of functions
4009 into our name space (usually the "standard" functions), and we don't
4010 need to create the CGI object.
4011
4012    #!/usr/local/bin/perl
4013    use CGI qw/:standard/;           # load standard CGI routines
4014    print header,                    # create the HTTP header
4015          start_html('hello world'), # start the HTML
4016          h1('hello world'),         # level 1 header
4017          end_html;                  # end the HTML
4018
4019 The examples in this document mainly use the object-oriented style.
4020 See HOW TO IMPORT FUNCTIONS for important information on
4021 function-oriented programming in CGI.pm
4022
4023 =head2 CALLING CGI.PM ROUTINES
4024
4025 Most CGI.pm routines accept several arguments, sometimes as many as 20
4026 optional ones!  To simplify this interface, all routines use a named
4027 argument calling style that looks like this:
4028
4029    print $q->header(-type=>'image/gif',-expires=>'+3d');
4030
4031 Each argument name is preceded by a dash.  Neither case nor order
4032 matters in the argument list.  -type, -Type, and -TYPE are all
4033 acceptable.  In fact, only the first argument needs to begin with a
4034 dash.  If a dash is present in the first argument, CGI.pm assumes
4035 dashes for the subsequent ones.
4036
4037 Several routines are commonly called with just one argument.  In the
4038 case of these routines you can provide the single argument without an
4039 argument name.  header() happens to be one of these routines.  In this
4040 case, the single argument is the document type.
4041
4042    print $q->header('text/html');
4043
4044 Other such routines are documented below.
4045
4046 Sometimes named arguments expect a scalar, sometimes a reference to an
4047 array, and sometimes a reference to a hash.  Often, you can pass any
4048 type of argument and the routine will do whatever is most appropriate.
4049 For example, the param() routine is used to set a CGI parameter to a
4050 single or a multi-valued value.  The two cases are shown below:
4051
4052    $q->param(-name=>'veggie',-value=>'tomato');
4053    $q->param(-name=>'veggie',-value=>['tomato','tomahto','potato','potahto']);
4054
4055 A large number of routines in CGI.pm actually aren't specifically
4056 defined in the module, but are generated automatically as needed.
4057 These are the "HTML shortcuts," routines that generate HTML tags for
4058 use in dynamically-generated pages.  HTML tags have both attributes
4059 (the attribute="value" pairs within the tag itself) and contents (the
4060 part between the opening and closing pairs.)  To distinguish between
4061 attributes and contents, CGI.pm uses the convention of passing HTML
4062 attributes as a hash reference as the first argument, and the
4063 contents, if any, as any subsequent arguments.  It works out like
4064 this:
4065
4066    Code                           Generated HTML
4067    ----                           --------------
4068    h1()                           <h1>
4069    h1('some','contents');         <h1>some contents</h1>
4070    h1({-align=>left});            <h1 align="LEFT">
4071    h1({-align=>left},'contents'); <h1 align="LEFT">contents</h1>
4072
4073 HTML tags are described in more detail later.
4074
4075 Many newcomers to CGI.pm are puzzled by the difference between the
4076 calling conventions for the HTML shortcuts, which require curly braces
4077 around the HTML tag attributes, and the calling conventions for other
4078 routines, which manage to generate attributes without the curly
4079 brackets.  Don't be confused.  As a convenience the curly braces are
4080 optional in all but the HTML shortcuts.  If you like, you can use
4081 curly braces when calling any routine that takes named arguments.  For
4082 example:
4083
4084    print $q->header( {-type=>'image/gif',-expires=>'+3d'} );
4085
4086 If you use the B<-w> switch, you will be warned that some CGI.pm argument
4087 names conflict with built-in Perl functions.  The most frequent of
4088 these is the -values argument, used to create multi-valued menus,
4089 radio button clusters and the like.  To get around this warning, you
4090 have several choices:
4091
4092 =over 4
4093
4094 =item 1.
4095
4096 Use another name for the argument, if one is available.
4097 For example, -value is an alias for -values.
4098
4099 =item 2.
4100
4101 Change the capitalization, e.g. -Values
4102
4103 =item 3.
4104
4105 Put quotes around the argument name, e.g. '-values'
4106
4107 =back
4108
4109 Many routines will do something useful with a named argument that it
4110 doesn't recognize.  For example, you can produce non-standard HTTP
4111 header fields by providing them as named arguments:
4112
4113   print $q->header(-type  =>  'text/html',
4114                    -cost  =>  'Three smackers',
4115                    -annoyance_level => 'high',
4116                    -complaints_to   => 'bit bucket');
4117
4118 This will produce the following nonstandard HTTP header:
4119
4120    HTTP/1.0 200 OK
4121    Cost: Three smackers
4122    Annoyance-level: high
4123    Complaints-to: bit bucket
4124    Content-type: text/html
4125
4126 Notice the way that underscores are translated automatically into
4127 hyphens.  HTML-generating routines perform a different type of
4128 translation.
4129
4130 This feature allows you to keep up with the rapidly changing HTTP and
4131 HTML "standards".
4132
4133 =head2 CREATING A NEW QUERY OBJECT (OBJECT-ORIENTED STYLE):
4134
4135      $query = new CGI;
4136
4137 This will parse the input (from both POST and GET methods) and store
4138 it into a perl5 object called $query.
4139
4140 =head2 CREATING A NEW QUERY OBJECT FROM AN INPUT FILE
4141
4142      $query = new CGI(INPUTFILE);
4143
4144 If you provide a file handle to the new() method, it will read
4145 parameters from the file (or STDIN, or whatever).  The file can be in
4146 any of the forms describing below under debugging (i.e. a series of
4147 newline delimited TAG=VALUE pairs will work).  Conveniently, this type
4148 of file is created by the save() method (see below).  Multiple records
4149 can be saved and restored.
4150
4151 Perl purists will be pleased to know that this syntax accepts
4152 references to file handles, or even references to filehandle globs,
4153 which is the "official" way to pass a filehandle:
4154
4155     $query = new CGI(\*STDIN);
4156
4157 You can also initialize the CGI object with a FileHandle or IO::File
4158 object.
4159
4160 If you are using the function-oriented interface and want to
4161 initialize CGI state from a file handle, the way to do this is with
4162 B<restore_parameters()>.  This will (re)initialize the
4163 default CGI object from the indicated file handle.
4164
4165     open (IN,"test.in") || die;
4166     restore_parameters(IN);
4167     close IN;
4168
4169 You can also initialize the query object from an associative array
4170 reference:
4171
4172     $query = new CGI( {'dinosaur'=>'barney',
4173                        'song'=>'I love you',
4174                        'friends'=>[qw/Jessica George Nancy/]}
4175                     );
4176
4177 or from a properly formatted, URL-escaped query string:
4178
4179     $query = new CGI('dinosaur=barney&color=purple');
4180
4181 or from a previously existing CGI object (currently this clones the
4182 parameter list, but none of the other object-specific fields, such as
4183 autoescaping):
4184
4185     $old_query = new CGI;
4186     $new_query = new CGI($old_query);
4187
4188 To create an empty query, initialize it from an empty string or hash:
4189
4190    $empty_query = new CGI("");
4191
4192        -or-
4193
4194    $empty_query = new CGI({});
4195
4196 =head2 FETCHING A LIST OF KEYWORDS FROM THE QUERY:
4197
4198      @keywords = $query->keywords
4199
4200 If the script was invoked as the result of an <ISINDEX> search, the
4201 parsed keywords can be obtained as an array using the keywords() method.
4202
4203 =head2 FETCHING THE NAMES OF ALL THE PARAMETERS PASSED TO YOUR SCRIPT:
4204
4205      @names = $query->param
4206
4207 If the script was invoked with a parameter list
4208 (e.g. "name1=value1&name2=value2&name3=value3"), the param() method
4209 will return the parameter names as a list.  If the script was invoked
4210 as an <ISINDEX> script and contains a string without ampersands
4211 (e.g. "value1+value2+value3") , there will be a single parameter named
4212 "keywords" containing the "+"-delimited keywords.
4213
4214 NOTE: As of version 1.5, the array of parameter names returned will
4215 be in the same order as they were submitted by the browser.
4216 Usually this order is the same as the order in which the
4217 parameters are defined in the form (however, this isn't part
4218 of the spec, and so isn't guaranteed).
4219
4220 =head2 FETCHING THE VALUE OR VALUES OF A SINGLE NAMED PARAMETER:
4221
4222     @values = $query->param('foo');
4223
4224               -or-
4225
4226     $value = $query->param('foo');
4227
4228 Pass the param() method a single argument to fetch the value of the
4229 named parameter. If the parameter is multivalued (e.g. from multiple
4230 selections in a scrolling list), you can ask to receive an array.  Otherwise
4231 the method will return a single value.
4232
4233 If a value is not given in the query string, as in the queries
4234 "name1=&name2=" or "name1&name2", it will be returned as an empty
4235 string.  This feature is new in 2.63.
4236
4237
4238 If the parameter does not exist at all, then param() will return undef
4239 in a scalar context, and the empty list in a list context.
4240
4241
4242 =head2 SETTING THE VALUE(S) OF A NAMED PARAMETER:
4243
4244     $query->param('foo','an','array','of','values');
4245
4246 This sets the value for the named parameter 'foo' to an array of
4247 values.  This is one way to change the value of a field AFTER
4248 the script has been invoked once before.  (Another way is with
4249 the -override parameter accepted by all methods that generate
4250 form elements.)
4251
4252 param() also recognizes a named parameter style of calling described
4253 in more detail later:
4254
4255     $query->param(-name=>'foo',-values=>['an','array','of','values']);
4256
4257                               -or-
4258
4259     $query->param(-name=>'foo',-value=>'the value');
4260
4261 =head2 APPENDING ADDITIONAL VALUES TO A NAMED PARAMETER:
4262
4263    $query->append(-name=>'foo',-values=>['yet','more','values']);
4264
4265 This adds a value or list of values to the named parameter.  The
4266 values are appended to the end of the parameter if it already exists.
4267 Otherwise the parameter is created.  Note that this method only
4268 recognizes the named argument calling syntax.
4269
4270 =head2 IMPORTING ALL PARAMETERS INTO A NAMESPACE:
4271
4272    $query->import_names('R');
4273
4274 This creates a series of variables in the 'R' namespace.  For example,
4275 $R::foo, @R:foo.  For keyword lists, a variable @R::keywords will appear.
4276 If no namespace is given, this method will assume 'Q'.
4277 WARNING:  don't import anything into 'main'; this is a major security
4278 risk!!!!
4279
4280 NOTE 1: Variable names are transformed as necessary into legal Perl
4281 variable names.  All non-legal characters are transformed into
4282 underscores.  If you need to keep the original names, you should use
4283 the param() method instead to access CGI variables by name.
4284
4285 NOTE 2: In older versions, this method was called B<import()>.  As of version 2.20,
4286 this name has been removed completely to avoid conflict with the built-in
4287 Perl module B<import> operator.
4288
4289 =head2 DELETING A PARAMETER COMPLETELY:
4290
4291     $query->delete('foo','bar','baz');
4292
4293 This completely clears a list of parameters.  It sometimes useful for
4294 resetting parameters that you don't want passed down between script
4295 invocations.
4296
4297 If you are using the function call interface, use "Delete()" instead
4298 to avoid conflicts with Perl's built-in delete operator.
4299
4300 =head2 DELETING ALL PARAMETERS:
4301
4302    $query->delete_all();
4303
4304 This clears the CGI object completely.  It might be useful to ensure
4305 that all the defaults are taken when you create a fill-out form.
4306
4307 Use Delete_all() instead if you are using the function call interface.
4308
4309 =head2 HANDLING NON-URLENCODED ARGUMENTS
4310
4311
4312 If POSTed data is not of type application/x-www-form-urlencoded or
4313 multipart/form-data, then the POSTed data will not be processed, but
4314 instead be returned as-is in a parameter named POSTDATA.  To retrieve
4315 it, use code like this:
4316
4317    my $data = $query->param('POSTDATA');
4318
4319 (If you don't know what the preceding means, don't worry about it.  It
4320 only affects people trying to use CGI for XML processing and other
4321 specialized tasks.)
4322
4323
4324 =head2 DIRECT ACCESS TO THE PARAMETER LIST:
4325
4326    $q->param_fetch('address')->[1] = '1313 Mockingbird Lane';
4327    unshift @{$q->param_fetch(-name=>'address')},'George Munster';
4328
4329 If you need access to the parameter list in a way that isn't covered
4330 by the methods above, you can obtain a direct reference to it by
4331 calling the B<param_fetch()> method with the name of the .  This
4332 will return an array reference to the named parameters, which you then
4333 can manipulate in any way you like.
4334
4335 You can also use a named argument style using the B<-name> argument.
4336
4337 =head2 FETCHING THE PARAMETER LIST AS A HASH:
4338
4339     $params = $q->Vars;
4340     print $params->{'address'};
4341     @foo = split("\0",$params->{'foo'});
4342     %params = $q->Vars;
4343
4344     use CGI ':cgi-lib';
4345     $params = Vars;
4346
4347 Many people want to fetch the entire parameter list as a hash in which
4348 the keys are the names of the CGI parameters, and the values are the
4349 parameters' values.  The Vars() method does this.  Called in a scalar
4350 context, it returns the parameter list as a tied hash reference.
4351 Changing a key changes the value of the parameter in the underlying
4352 CGI parameter list.  Called in a list context, it returns the
4353 parameter list as an ordinary hash.  This allows you to read the
4354 contents of the parameter list, but not to change it.
4355
4356 When using this, the thing you must watch out for are multivalued CGI
4357 parameters.  Because a hash cannot distinguish between scalar and
4358 list context, multivalued parameters will be returned as a packed
4359 string, separated by the "\0" (null) character.  You must split this
4360 packed string in order to get at the individual values.  This is the
4361 convention introduced long ago by Steve Brenner in his cgi-lib.pl
4362 module for Perl version 4.
4363
4364 If you wish to use Vars() as a function, import the I<:cgi-lib> set of
4365 function calls (also see the section on CGI-LIB compatibility).
4366
4367 =head2 SAVING THE STATE OF THE SCRIPT TO A FILE:
4368
4369     $query->save(\*FILEHANDLE)
4370
4371 This will write the current state of the form to the provided
4372 filehandle.  You can read it back in by providing a filehandle
4373 to the new() method.  Note that the filehandle can be a file, a pipe,
4374 or whatever!
4375
4376 The format of the saved file is:
4377
4378         NAME1=VALUE1
4379         NAME1=VALUE1'
4380         NAME2=VALUE2
4381         NAME3=VALUE3
4382         =
4383
4384 Both name and value are URL escaped.  Multi-valued CGI parameters are
4385 represented as repeated names.  A session record is delimited by a
4386 single = symbol.  You can write out multiple records and read them
4387 back in with several calls to B<new>.  You can do this across several
4388 sessions by opening the file in append mode, allowing you to create
4389 primitive guest books, or to keep a history of users' queries.  Here's
4390 a short example of creating multiple session records:
4391
4392    use CGI;
4393
4394    open (OUT,">>test.out") || die;
4395    $records = 5;
4396    foreach (0..$records) {
4397        my $q = new CGI;
4398        $q->param(-name=>'counter',-value=>$_);
4399        $q->save(\*OUT);
4400    }
4401    close OUT;
4402
4403    # reopen for reading
4404    open (IN,"test.out") || die;
4405    while (!eof(IN)) {
4406        my $q = new CGI(\*IN);
4407        print $q->param('counter'),"\n";
4408    }
4409
4410 The file format used for save/restore is identical to that used by the
4411 Whitehead Genome Center's data exchange format "Boulderio", and can be
4412 manipulated and even databased using Boulderio utilities.  See
4413
4414   http://stein.cshl.org/boulder/
4415
4416 for further details.
4417
4418 If you wish to use this method from the function-oriented (non-OO)
4419 interface, the exported name for this method is B<save_parameters()>.
4420
4421 =head2 RETRIEVING CGI ERRORS
4422
4423 Errors can occur while processing user input, particularly when
4424 processing uploaded files.  When these errors occur, CGI will stop
4425 processing and return an empty parameter list.  You can test for
4426 the existence and nature of errors using the I<cgi_error()> function.
4427 The error messages are formatted as HTTP status codes. You can either
4428 incorporate the error text into an HTML page, or use it as the value
4429 of the HTTP status:
4430
4431     my $error = $q->cgi_error;
4432     if ($error) {
4433         print $q->header(-status=>$error),
4434               $q->start_html('Problems'),
4435               $q->h2('Request not processed'),
4436               $q->strong($error);
4437         exit 0;
4438     }
4439
4440 When using the function-oriented interface (see the next section),
4441 errors may only occur the first time you call I<param()>. Be ready
4442 for this!
4443
4444 =head2 USING THE FUNCTION-ORIENTED INTERFACE
4445
4446 To use the function-oriented interface, you must specify which CGI.pm
4447 routines or sets of routines to import into your script's namespace.
4448 There is a small overhead associated with this importation, but it
4449 isn't much.
4450
4451    use CGI <list of methods>;
4452
4453 The listed methods will be imported into the current package; you can
4454 call them directly without creating a CGI object first.  This example
4455 shows how to import the B<param()> and B<header()>
4456 methods, and then use them directly:
4457
4458    use CGI 'param','header';
4459    print header('text/plain');
4460    $zipcode = param('zipcode');
4461
4462 More frequently, you'll import common sets of functions by referring
4463 to the groups by name.  All function sets are preceded with a ":"
4464 character as in ":html3" (for tags defined in the HTML 3 standard).
4465
4466 Here is a list of the function sets you can import:
4467
4468 =over 4
4469
4470 =item B<:cgi>
4471
4472 Import all CGI-handling methods, such as B<param()>, B<path_info()>
4473 and the like.
4474
4475 =item B<:form>
4476
4477 Import all fill-out form generating methods, such as B<textfield()>.
4478
4479 =item B<:html2>
4480
4481 Import all methods that generate HTML 2.0 standard elements.
4482
4483 =item B<:html3>
4484
4485 Import all methods that generate HTML 3.0 elements (such as
4486 <table>, <super> and <sub>).
4487
4488 =item B<:html4>
4489
4490 Import all methods that generate HTML 4 elements (such as
4491 <abbrev>, <acronym> and <thead>).
4492
4493 =item B<:netscape>
4494
4495 Import all methods that generate Netscape-specific HTML extensions.
4496
4497 =item B<:html>
4498
4499 Import all HTML-generating shortcuts (i.e. 'html2' + 'html3' +
4500 'netscape')...
4501
4502 =item B<:standard>
4503
4504 Import "standard" features, 'html2', 'html3', 'html4', 'form' and 'cgi'.
4505
4506 =item B<:all>
4507
4508 Import all the available methods.  For the full list, see the CGI.pm
4509 code, where the variable %EXPORT_TAGS is defined.
4510
4511 =back
4512
4513 If you import a function name that is not part of CGI.pm, the module
4514 will treat it as a new HTML tag and generate the appropriate
4515 subroutine.  You can then use it like any other HTML tag.  This is to
4516 provide for the rapidly-evolving HTML "standard."  For example, say
4517 Microsoft comes out with a new tag called <gradient> (which causes the
4518 user's desktop to be flooded with a rotating gradient fill until his
4519 machine reboots).  You don't need to wait for a new version of CGI.pm
4520 to start using it immediately:
4521
4522    use CGI qw/:standard :html3 gradient/;
4523    print gradient({-start=>'red',-end=>'blue'});
4524
4525 Note that in the interests of execution speed CGI.pm does B<not> use
4526 the standard L<Exporter> syntax for specifying load symbols.  This may
4527 change in the future.
4528
4529 If you import any of the state-maintaining CGI or form-generating
4530 methods, a default CGI object will be created and initialized
4531 automatically the first time you use any of the methods that require
4532 one to be present.  This includes B<param()>, B<textfield()>,
4533 B<submit()> and the like.  (If you need direct access to the CGI
4534 object, you can find it in the global variable B<$CGI::Q>).  By
4535 importing CGI.pm methods, you can create visually elegant scripts:
4536
4537    use CGI qw/:standard/;
4538    print
4539        header,
4540        start_html('Simple Script'),
4541        h1('Simple Script'),
4542        start_form,
4543        "What's your name? ",textfield('name'),p,
4544        "What's the combination?",
4545        checkbox_group(-name=>'words',
4546                       -values=>['eenie','meenie','minie','moe'],
4547                       -defaults=>['eenie','moe']),p,
4548        "What's your favorite color?",
4549        popup_menu(-name=>'color',
4550                   -values=>['red','green','blue','chartreuse']),p,
4551        submit,
4552        end_form,
4553        hr,"\n";
4554
4555     if (param) {
4556        print
4557            "Your name is ",em(param('name')),p,
4558            "The keywords are: ",em(join(", ",param('words'))),p,
4559            "Your favorite color is ",em(param('color')),".\n";
4560     }
4561     print end_html;
4562
4563 =head2 PRAGMAS
4564
4565 In addition to the function sets, there are a number of pragmas that
4566 you can import.  Pragmas, which are always preceded by a hyphen,
4567 change the way that CGI.pm functions in various ways.  Pragmas,
4568 function sets, and individual functions can all be imported in the
4569 same use() line.  For example, the following use statement imports the
4570 standard set of functions and enables debugging mode (pragma
4571 -debug):
4572
4573    use CGI qw/:standard -debug/;
4574
4575 The current list of pragmas is as follows:
4576
4577 =over 4
4578
4579 =item -any
4580
4581 When you I<use CGI -any>, then any method that the query object
4582 doesn't recognize will be interpreted as a new HTML tag.  This allows
4583 you to support the next I<ad hoc> Netscape or Microsoft HTML
4584 extension.  This lets you go wild with new and unsupported tags:
4585
4586    use CGI qw(-any);
4587    $q=new CGI;
4588    print $q->gradient({speed=>'fast',start=>'red',end=>'blue'});
4589
4590 Since using <cite>any</cite> causes any mistyped method name
4591 to be interpreted as an HTML tag, use it with care or not at
4592 all.
4593
4594 =item -compile
4595
4596 This causes the indicated autoloaded methods to be compiled up front,
4597 rather than deferred to later.  This is useful for scripts that run
4598 for an extended period of time under FastCGI or mod_perl, and for
4599 those destined to be crunched by Malcom Beattie's Perl compiler.  Use
4600 it in conjunction with the methods or method families you plan to use.
4601
4602    use CGI qw(-compile :standard :html3);
4603
4604 or even
4605
4606    use CGI qw(-compile :all);
4607
4608 Note that using the -compile pragma in this way will always have
4609 the effect of importing the compiled functions into the current
4610 namespace.  If you want to compile without importing use the
4611 compile() method instead:
4612
4613    use CGI();
4614    CGI->compile();
4615
4616 This is particularly useful in a mod_perl environment, in which you
4617 might want to precompile all CGI routines in a startup script, and
4618 then import the functions individually in each mod_perl script.
4619
4620 =item -nosticky
4621
4622 By default the CGI module implements a state-preserving behavior
4623 called "sticky" fields.  The way this works is that if you are
4624 regenerating a form, the methods that generate the form field values
4625 will interrogate param() to see if similarly-named parameters are
4626 present in the query string. If they find a like-named parameter, they
4627 will use it to set their default values.
4628
4629 Sometimes this isn't what you want.  The B<-nosticky> pragma prevents
4630 this behavior.  You can also selectively change the sticky behavior in
4631 each element that you generate.
4632
4633 =item -tabindex
4634
4635 Automatically add tab index attributes to each form field. With this
4636 option turned off, you can still add tab indexes manually by passing a
4637 -tabindex option to each field-generating method.
4638
4639 =item -no_undef_params
4640
4641 This keeps CGI.pm from including undef params in the parameter list.
4642
4643 =item -no_xhtml
4644
4645 By default, CGI.pm versions 2.69 and higher emit XHTML
4646 (http://www.w3.org/TR/xhtml1/).  The -no_xhtml pragma disables this
4647 feature.  Thanks to Michalis Kabrianis <kabrianis@hellug.gr> for this
4648 feature.
4649
4650 If start_html()'s -dtd parameter specifies an HTML 2.0 or 3.2 DTD,
4651 XHTML will automatically be disabled without needing to use this
4652 pragma.
4653
4654 =item -nph
4655
4656 This makes CGI.pm produce a header appropriate for an NPH (no
4657 parsed header) script.  You may need to do other things as well
4658 to tell the server that the script is NPH.  See the discussion
4659 of NPH scripts below.
4660
4661 =item -newstyle_urls
4662
4663 Separate the name=value pairs in CGI parameter query strings with
4664 semicolons rather than ampersands.  For example:
4665
4666    ?name=fred;age=24;favorite_color=3
4667
4668 Semicolon-delimited query strings are always accepted, but will not be
4669 emitted by self_url() and query_string() unless the -newstyle_urls
4670 pragma is specified.
4671
4672 This became the default in version 2.64.
4673
4674 =item -oldstyle_urls
4675
4676 Separate the name=value pairs in CGI parameter query strings with
4677 ampersands rather than semicolons.  This is no longer the default.
4678
4679 =item -autoload
4680
4681 This overrides the autoloader so that any function in your program
4682 that is not recognized is referred to CGI.pm for possible evaluation.
4683 This allows you to use all the CGI.pm functions without adding them to
4684 your symbol table, which is of concern for mod_perl users who are
4685 worried about memory consumption.  I<Warning:> when
4686 I<-autoload> is in effect, you cannot use "poetry mode"
4687 (functions without the parenthesis).  Use I<hr()> rather
4688 than I<hr>, or add something like I<use subs qw/hr p header/>
4689 to the top of your script.
4690
4691 =item -no_debug
4692
4693 This turns off the command-line processing features.  If you want to
4694 run a CGI.pm script from the command line to produce HTML, and you
4695 don't want it to read CGI parameters from the command line or STDIN,
4696 then use this pragma:
4697
4698    use CGI qw(-no_debug :standard);
4699
4700 =item -debug
4701
4702 This turns on full debugging.  In addition to reading CGI arguments
4703 from the command-line processing, CGI.pm will pause and try to read
4704 arguments from STDIN, producing the message "(offline mode: enter
4705 name=value pairs on standard input)" features.
4706
4707 See the section on debugging for more details.
4708
4709 =item -private_tempfiles
4710
4711 CGI.pm can process uploaded file. Ordinarily it spools the uploaded
4712 file to a temporary directory, then deletes the file when done.
4713 However, this opens the risk of eavesdropping as described in the file
4714 upload section.  Another CGI script author could peek at this data
4715 during the upload, even if it is confidential information. On Unix
4716 systems, the -private_tempfiles pragma will cause the temporary file
4717 to be unlinked as soon as it is opened and before any data is written
4718 into it, reducing, but not eliminating the risk of eavesdropping
4719 (there is still a potential race condition).  To make life harder for
4720 the attacker, the program chooses tempfile names by calculating a 32
4721 bit checksum of the incoming HTTP headers.
4722
4723 To ensure that the temporary file cannot be read by other CGI scripts,
4724 use suEXEC or a CGI wrapper program to run your script.  The temporary
4725 file is created with mode 0600 (neither world nor group readable).
4726
4727 The temporary directory is selected using the following algorithm:
4728
4729     1. if the current user (e.g. "nobody") has a directory named
4730     "tmp" in its home directory, use that (Unix systems only).
4731
4732     2. if the environment variable TMPDIR exists, use the location
4733     indicated.
4734
4735     3. Otherwise try the locations /usr/tmp, /var/tmp, C:\temp,
4736     /tmp, /temp, ::Temporary Items, and \WWW_ROOT.
4737
4738 Each of these locations is checked that it is a directory and is
4739 writable.  If not, the algorithm tries the next choice.
4740
4741 =back
4742
4743 =head2 SPECIAL FORMS FOR IMPORTING HTML-TAG FUNCTIONS
4744
4745 Many of the methods generate HTML tags.  As described below, tag
4746 functions automatically generate both the opening and closing tags.
4747 For example:
4748
4749   print h1('Level 1 Header');
4750
4751 produces
4752
4753   <h1>Level 1 Header</h1>
4754
4755 There will be some times when you want to produce the start and end
4756 tags yourself.  In this case, you can use the form start_I<tag_name>
4757 and end_I<tag_name>, as in:
4758
4759   print start_h1,'Level 1 Header',end_h1;
4760
4761 With a few exceptions (described below), start_I<tag_name> and
4762 end_I<tag_name> functions are not generated automatically when you
4763 I<use CGI>.  However, you can specify the tags you want to generate
4764 I<start/end> functions for by putting an asterisk in front of their
4765 name, or, alternatively, requesting either "start_I<tag_name>" or
4766 "end_I<tag_name>" in the import list.
4767
4768 Example:
4769
4770   use CGI qw/:standard *table start_ul/;
4771
4772 In this example, the following functions are generated in addition to
4773 the standard ones:
4774
4775 =over 4
4776
4777 =item 1. start_table() (generates a <table> tag)
4778
4779 =item 2. end_table() (generates a </table> tag)
4780
4781 =item 3. start_ul() (generates a <ul> tag)
4782
4783 =item 4. end_ul() (generates a </ul> tag)
4784
4785 =back
4786
4787 =head1 GENERATING DYNAMIC DOCUMENTS
4788
4789 Most of CGI.pm's functions deal with creating documents on the fly.
4790 Generally you will produce the HTTP header first, followed by the
4791 document itself.  CGI.pm provides functions for generating HTTP
4792 headers of various types as well as for generating HTML.  For creating
4793 GIF images, see the GD.pm module.
4794
4795 Each of these functions produces a fragment of HTML or HTTP which you
4796 can print out directly so that it displays in the browser window,
4797 append to a string, or save to a file for later use.
4798
4799 =head2 CREATING A STANDARD HTTP HEADER:
4800
4801 Normally the first thing you will do in any CGI script is print out an
4802 HTTP header.  This tells the browser what type of document to expect,
4803 and gives other optional information, such as the language, expiration
4804 date, and whether to cache the document.  The header can also be
4805 manipulated for special purposes, such as server push and pay per view
4806 pages.
4807
4808         print header;
4809
4810              -or-
4811
4812         print header('image/gif');
4813
4814              -or-
4815
4816         print header('text/html','204 No response');
4817
4818              -or-
4819
4820         print header(-type=>'image/gif',
4821                              -nph=>1,
4822                              -status=>'402 Payment required',
4823                              -expires=>'+3d',
4824                              -cookie=>$cookie,
4825                              -charset=>'utf-7',
4826                              -attachment=>'foo.gif',
4827                              -Cost=>'$2.00');
4828
4829 header() returns the Content-type: header.  You can provide your own
4830 MIME type if you choose, otherwise it defaults to text/html.  An
4831 optional second parameter specifies the status code and a human-readable
4832 message.  For example, you can specify 204, "No response" to create a
4833 script that tells the browser to do nothing at all.
4834
4835 The last example shows the named argument style for passing arguments
4836 to the CGI methods using named parameters.  Recognized parameters are
4837 B<-type>, B<-status>, B<-expires>, and B<-cookie>.  Any other named
4838 parameters will be stripped of their initial hyphens and turned into
4839 header fields, allowing you to specify any HTTP header you desire.
4840 Internal underscores will be turned into hyphens:
4841
4842     print header(-Content_length=>3002);
4843
4844 Most browsers will not cache the output from CGI scripts.  Every time
4845 the browser reloads the page, the script is invoked anew.  You can
4846 change this behavior with the B<-expires> parameter.  When you specify
4847 an absolute or relative expiration interval with this parameter, some
4848 browsers and proxy servers will cache the script's output until the
4849 indicated expiration date.  The following forms are all valid for the
4850 -expires field:
4851
4852         +30s                              30 seconds from now
4853         +10m                              ten minutes from now
4854         +1h                               one hour from now
4855         -1d                               yesterday (i.e. "ASAP!")
4856         now                               immediately
4857         +3M                               in three months
4858         +10y                              in ten years time
4859         Thursday, 25-Apr-1999 00:40:33 GMT  at the indicated time & date
4860
4861 The B<-cookie> parameter generates a header that tells the browser to provide
4862 a "magic cookie" during all subsequent transactions with your script.
4863 Netscape cookies have a special format that includes interesting attributes
4864 such as expiration time.  Use the cookie() method to create and retrieve
4865 session cookies.
4866
4867 The B<-nph> parameter, if set to a true value, will issue the correct
4868 headers to work with a NPH (no-parse-header) script.  This is important
4869 to use with certain servers that expect all their scripts to be NPH.
4870
4871 The B<-charset> parameter can be used to control the character set
4872 sent to the browser.  If not provided, defaults to ISO-8859-1.  As a
4873 side effect, this sets the charset() method as well.
4874
4875 The B<-attachment> parameter can be used to turn the page into an
4876 attachment.  Instead of displaying the page, some browsers will prompt
4877 the user to save it to disk.  The value of the argument is the
4878 suggested name for the saved file.  In order for this to work, you may
4879 have to set the B<-type> to "application/octet-stream".
4880
4881 The B<-p3p> parameter will add a P3P tag to the outgoing header.  The
4882 parameter can be an arrayref or a space-delimited string of P3P tags.
4883 For example:
4884
4885    print header(-p3p=>[qw(CAO DSP LAW CURa)]);
4886    print header(-p3p=>'CAO DSP LAW CURa');
4887
4888 In either case, the outgoing header will be formatted as:
4889
4890   P3P: policyref="/w3c/p3p.xml" cp="CAO DSP LAW CURa"
4891
4892 =head2 GENERATING A REDIRECTION HEADER
4893
4894    print redirect('http://somewhere.else/in/movie/land');
4895
4896 Sometimes you don't want to produce a document yourself, but simply
4897 redirect the browser elsewhere, perhaps choosing a URL based on the
4898 time of day or the identity of the user.
4899
4900 The redirect() function redirects the browser to a different URL.  If
4901 you use redirection like this, you should B<not> print out a header as
4902 well.
4903
4904 You should always use full URLs (including the http: or ftp: part) in
4905 redirection requests.  Relative URLs will not work correctly.
4906
4907 You can also use named arguments:
4908
4909     print redirect(-uri=>'http://somewhere.else/in/movie/land',
4910                            -nph=>1,
4911                            -status=>301);
4912
4913 The B<-nph> parameter, if set to a true value, will issue the correct
4914 headers to work with a NPH (no-parse-header) script.  This is important
4915 to use with certain servers, such as Microsoft IIS, which
4916 expect all their scripts to be NPH.
4917
4918 The B<-status> parameter will set the status of the redirect.  HTTP
4919 defines three different possible redirection status codes:
4920
4921      301 Moved Permanently
4922      302 Found
4923      303 See Other
4924
4925 The default if not specified is 302, which means "moved temporarily."
4926 You may change the status to another status code if you wish.  Be
4927 advised that changing the status to anything other than 301, 302 or
4928 303 will probably break redirection.
4929
4930 =head2 CREATING THE HTML DOCUMENT HEADER
4931
4932    print start_html(-title=>'Secrets of the Pyramids',
4933                             -author=>'fred@capricorn.org',
4934                             -base=>'true',
4935                             -target=>'_blank',
4936                             -meta=>{'keywords'=>'pharaoh secret mummy',
4937                                     'copyright'=>'copyright 1996 King Tut'},
4938                             -style=>{'src'=>'/styles/style1.css'},
4939                             -BGCOLOR=>'blue');
4940
4941 After creating the HTTP header, most CGI scripts will start writing
4942 out an HTML document.  The start_html() routine creates the top of the
4943 page, along with a lot of optional information that controls the
4944 page's appearance and behavior.
4945
4946 This method returns a canned HTML header and the opening <body> tag.
4947 All parameters are optional.  In the named parameter form, recognized
4948 parameters are -title, -author, -base, -xbase, -dtd, -lang and -target
4949 (see below for the explanation).  Any additional parameters you
4950 provide, such as the Netscape unofficial BGCOLOR attribute, are added
4951 to the <body> tag.  Additional parameters must be proceeded by a
4952 hyphen.
4953
4954 The argument B<-xbase> allows you to provide an HREF for the <base> tag
4955 different from the current location, as in
4956
4957     -xbase=>"http://home.mcom.com/"
4958
4959 All relative links will be interpreted relative to this tag.
4960
4961 The argument B<-target> allows you to provide a default target frame
4962 for all the links and fill-out forms on the page.  B<This is a
4963 non-standard HTTP feature which only works with Netscape browsers!>
4964 See the Netscape documentation on frames for details of how to
4965 manipulate this.
4966
4967     -target=>"answer_window"
4968
4969 All relative links will be interpreted relative to this tag.
4970 You add arbitrary meta information to the header with the B<-meta>
4971 argument.  This argument expects a reference to an associative array
4972 containing name/value pairs of meta information.  These will be turned
4973 into a series of header <meta> tags that look something like this:
4974
4975     <meta name="keywords" content="pharaoh secret mummy">
4976     <meta name="description" content="copyright 1996 King Tut">
4977
4978 To create an HTTP-EQUIV type of <meta> tag, use B<-head>, described
4979 below.
4980
4981 The B<-style> argument is used to incorporate cascading stylesheets
4982 into your code.  See the section on CASCADING STYLESHEETS for more
4983 information.
4984
4985 The B<-lang> argument is used to incorporate a language attribute into
4986 the <html> tag.  For example:
4987
4988     print $q->start_html(-lang=>'fr-CA');
4989
4990 The default if not specified is "en-US" for US English, unless the
4991 -dtd parameter specifies an HTML 2.0 or 3.2 DTD, in which case the
4992 lang attribute is left off.  You can force the lang attribute to left
4993 off in other cases by passing an empty string (-lang=>'').
4994
4995 The B<-encoding> argument can be used to specify the character set for
4996 XHTML.  It defaults to iso-8859-1 if not specified.
4997
4998 The B<-declare_xml> argument, when used in conjunction with XHTML,
4999 will put a <?xml> declaration at the top of the HTML header. The sole
5000 purpose of this declaration is to declare the character set
5001 encoding. In the absence of -declare_xml, the output HTML will contain
5002 a <meta> tag that specifies the encoding, allowing the HTML to pass
5003 most validators.  The default for -declare_xml is false.
5004
5005 You can place other arbitrary HTML elements to the <head> section with the
5006 B<-head> tag.  For example, to place the rarely-used <link> element in the
5007 head section, use this:
5008
5009     print start_html(-head=>Link({-rel=>'next',
5010                                   -href=>'http://www.capricorn.com/s2.html'}));
5011
5012 To incorporate multiple HTML elements into the <head> section, just pass an
5013 array reference:
5014
5015     print start_html(-head=>[
5016                              Link({-rel=>'next',
5017                                    -href=>'http://www.capricorn.com/s2.html'}),
5018                              Link({-rel=>'previous',
5019                                    -href=>'http://www.capricorn.com/s1.html'})
5020                              ]
5021                      );
5022
5023 And here's how to create an HTTP-EQUIV <meta> tag:
5024
5025       print start_html(-head=>meta({-http_equiv => 'Content-Type',
5026                                     -content    => 'text/html'}))
5027
5028
5029 JAVASCRIPTING: The B<-script>, B<-noScript>, B<-onLoad>,
5030 B<-onMouseOver>, B<-onMouseOut> and B<-onUnload> parameters are used
5031 to add Netscape JavaScript calls to your pages.  B<-script> should
5032 point to a block of text containing JavaScript function definitions.
5033 This block will be placed within a <script> block inside the HTML (not
5034 HTTP) header.  The block is placed in the header in order to give your
5035 page a fighting chance of having all its JavaScript functions in place
5036 even if the user presses the stop button before the page has loaded
5037 completely.  CGI.pm attempts to format the script in such a way that
5038 JavaScript-naive browsers will not choke on the code: unfortunately
5039 there are some browsers, such as Chimera for Unix, that get confused
5040 by it nevertheless.
5041
5042 The B<-onLoad> and B<-onUnload> parameters point to fragments of JavaScript
5043 code to execute when the page is respectively opened and closed by the
5044 browser.  Usually these parameters are calls to functions defined in the
5045 B<-script> field:
5046
5047       $query = new CGI;
5048       print header;
5049       $JSCRIPT=<<END;
5050       // Ask a silly question
5051       function riddle_me_this() {
5052          var r = prompt("What walks on four legs in the morning, " +
5053                        "two legs in the afternoon, " +
5054                        "and three legs in the evening?");
5055          response(r);
5056       }
5057       // Get a silly answer
5058       function response(answer) {
5059          if (answer == "man")
5060             alert("Right you are!");
5061          else
5062             alert("Wrong!  Guess again.");
5063       }
5064       END
5065       print start_html(-title=>'The Riddle of the Sphinx',
5066                                -script=>$JSCRIPT);
5067
5068 Use the B<-noScript> parameter to pass some HTML text that will be displayed on
5069 browsers that do not have JavaScript (or browsers where JavaScript is turned
5070 off).
5071
5072 Netscape 3.0 recognizes several attributes of the <script> tag,
5073 including LANGUAGE and SRC.  The latter is particularly interesting,
5074 as it allows you to keep the JavaScript code in a file or CGI script
5075 rather than cluttering up each page with the source.  To use these
5076 attributes pass a HASH reference in the B<-script> parameter containing
5077 one or more of -language, -src, or -code:
5078
5079     print $q->start_html(-title=>'The Riddle of the Sphinx',
5080                          -script=>{-language=>'JAVASCRIPT',
5081                                    -src=>'/javascript/sphinx.js'}
5082                          );
5083
5084     print $q->(-title=>'The Riddle of the Sphinx',
5085                -script=>{-language=>'PERLSCRIPT',
5086                          -code=>'print "hello world!\n;"'}
5087                );
5088
5089
5090 A final feature allows you to incorporate multiple <script> sections into the
5091 header.  Just pass the list of script sections as an array reference.
5092 this allows you to specify different source files for different dialects
5093 of JavaScript.  Example:
5094
5095      print $q->start_html(-title=>'The Riddle of the Sphinx',
5096                           -script=>[
5097                                     { -language => 'JavaScript1.0',
5098                                       -src      => '/javascript/utilities10.js'
5099                                     },
5100                                     { -language => 'JavaScript1.1',
5101                                       -src      => '/javascript/utilities11.js'
5102                                     },
5103                                     { -language => 'JavaScript1.2',
5104                                       -src      => '/javascript/utilities12.js'
5105                                     },
5106                                     { -language => 'JavaScript28.2',
5107                                       -src      => '/javascript/utilities219.js'
5108                                     }
5109                                  ]
5110                              );
5111
5112 If this looks a bit extreme, take my advice and stick with straight CGI scripting.
5113
5114 See
5115
5116    http://home.netscape.com/eng/mozilla/2.0/handbook/javascript/
5117
5118 for more information about JavaScript.
5119
5120 The old-style positional parameters are as follows:
5121
5122 =over 4
5123
5124 =item B<Parameters:>
5125
5126 =item 1.
5127
5128 The title
5129
5130 =item 2.
5131
5132 The author's e-mail address (will create a <link rev="MADE"> tag if present
5133
5134 =item 3.
5135
5136 A 'true' flag if you want to include a <base> tag in the header.  This
5137 helps resolve relative addresses to absolute ones when the document is moved,
5138 but makes the document hierarchy non-portable.  Use with care!
5139
5140 =item 4, 5, 6...
5141
5142 Any other parameters you want to include in the <body> tag.  This is a good
5143 place to put Netscape extensions, such as colors and wallpaper patterns.
5144
5145 =back
5146
5147 =head2 ENDING THE HTML DOCUMENT:
5148
5149         print end_html
5150
5151 This ends an HTML document by printing the </body></html> tags.
5152
5153 =head2 CREATING A SELF-REFERENCING URL THAT PRESERVES STATE INFORMATION:
5154
5155     $myself = self_url;
5156     print q(<a href="$myself">I'm talking to myself.</a>);
5157
5158 self_url() will return a URL, that, when selected, will reinvoke
5159 this script with all its state information intact.  This is most
5160 useful when you want to jump around within the document using
5161 internal anchors but you don't want to disrupt the current contents
5162 of the form(s).  Something like this will do the trick.
5163
5164      $myself = self_url;
5165      print "<a href=\"$myself#table1\">See table 1</a>";
5166      print "<a href=\"$myself#table2\">See table 2</a>";
5167      print "<a href=\"$myself#yourself\">See for yourself</a>";
5168
5169 If you want more control over what's returned, using the B<url()>
5170 method instead.
5171
5172 You can also retrieve the unprocessed query string with query_string():
5173
5174     $the_string = query_string;
5175
5176 =head2 OBTAINING THE SCRIPT'S URL
5177
5178     $full_url      = url();
5179     $full_url      = url(-full=>1);  #alternative syntax
5180     $relative_url  = url(-relative=>1);
5181     $absolute_url  = url(-absolute=>1);
5182     $url_with_path = url(-path_info=>1);
5183     $url_with_path_and_query = url(-path_info=>1,-query=>1);
5184     $netloc        = url(-base => 1);
5185
5186 B<url()> returns the script's URL in a variety of formats.  Called
5187 without any arguments, it returns the full form of the URL, including
5188 host name and port number
5189
5190     http://your.host.com/path/to/script.cgi
5191
5192 You can modify this format with the following named arguments:
5193
5194 =over 4
5195
5196 =item B<-absolute>
5197
5198 If true, produce an absolute URL, e.g.
5199
5200     /path/to/script.cgi
5201
5202 =item B<-relative>
5203
5204 Produce a relative URL.  This is useful if you want to reinvoke your
5205 script with different parameters. For example:
5206
5207     script.cgi
5208
5209 =item B<-full>
5210
5211 Produce the full URL, exactly as if called without any arguments.
5212 This overrides the -relative and -absolute arguments.
5213
5214 =item B<-path> (B<-path_info>)
5215
5216 Append the additional path information to the URL.  This can be
5217 combined with B<-full>, B<-absolute> or B<-relative>.  B<-path_info>
5218 is provided as a synonym.
5219
5220 =item B<-query> (B<-query_string>)
5221
5222 Append the query string to the URL.  This can be combined with
5223 B<-full>, B<-absolute> or B<-relative>.  B<-query_string> is provided
5224 as a synonym.
5225
5226 =item B<-base>
5227
5228 Generate just the protocol and net location, as in http://www.foo.com:8000
5229
5230 =item B<-rewrite>
5231
5232 If Apache's mod_rewrite is turned on, then the script name and path
5233 info probably won't match the request that the user sent. Set
5234 -rewrite=>1 (default) to return URLs that match what the user sent
5235 (the original request URI). Set -rewrite->0 to return URLs that match
5236 the URL after mod_rewrite's rules have run. Because the additional
5237 path information only makes sense in the context of the rewritten URL,
5238 -rewrite is set to false when you request path info in the URL.
5239
5240 =back
5241
5242 =head2 MIXING POST AND URL PARAMETERS
5243
5244    $color = url_param('color');
5245
5246 It is possible for a script to receive CGI parameters in the URL as
5247 well as in the fill-out form by creating a form that POSTs to a URL
5248 containing a query string (a "?" mark followed by arguments).  The
5249 B<param()> method will always return the contents of the POSTed
5250 fill-out form, ignoring the URL's query string.  To retrieve URL
5251 parameters, call the B<url_param()> method.  Use it in the same way as
5252 B<param()>.  The main difference is that it allows you to read the
5253 parameters, but not set them.
5254
5255
5256 Under no circumstances will the contents of the URL query string
5257 interfere with similarly-named CGI parameters in POSTed forms.  If you
5258 try to mix a URL query string with a form submitted with the GET
5259 method, the results will not be what you expect.
5260
5261 =head1 CREATING STANDARD HTML ELEMENTS:
5262
5263 CGI.pm defines general HTML shortcut methods for most, if not all of
5264 the HTML 3 and HTML 4 tags.  HTML shortcuts are named after a single
5265 HTML element and return a fragment of HTML text that you can then
5266 print or manipulate as you like.  Each shortcut returns a fragment of
5267 HTML code that you can append to a string, save to a file, or, most
5268 commonly, print out so that it displays in the browser window.
5269
5270 This example shows how to use the HTML methods:
5271
5272    print $q->blockquote(
5273                      "Many years ago on the island of",
5274                      $q->a({href=>"http://crete.org/"},"Crete"),
5275                      "there lived a Minotaur named",
5276                      $q->strong("Fred."),
5277                     ),
5278        $q->hr;
5279
5280 This results in the following HTML code (extra newlines have been
5281 added for readability):
5282
5283    <blockquote>
5284    Many years ago on the island of
5285    <a href="http://crete.org/">Crete</a> there lived
5286    a minotaur named <strong>Fred.</strong>
5287    </blockquote>
5288    <hr>
5289
5290 If you find the syntax for calling the HTML shortcuts awkward, you can
5291 import them into your namespace and dispense with the object syntax
5292 completely (see the next section for more details):
5293
5294    use CGI ':standard';
5295    print blockquote(
5296       "Many years ago on the island of",
5297       a({href=>"http://crete.org/"},"Crete"),
5298       "there lived a minotaur named",
5299       strong("Fred."),
5300       ),
5301       hr;
5302
5303 =head2 PROVIDING ARGUMENTS TO HTML SHORTCUTS
5304
5305 The HTML methods will accept zero, one or multiple arguments.  If you
5306 provide no arguments, you get a single tag:
5307
5308    print hr;    #  <hr>
5309
5310 If you provide one or more string arguments, they are concatenated
5311 together with spaces and placed between opening and closing tags:
5312
5313    print h1("Chapter","1"); # <h1>Chapter 1</h1>"
5314
5315 If the first argument is an associative array reference, then the keys
5316 and values of the associative array become the HTML tag's attributes:
5317
5318    print a({-href=>'fred.html',-target=>'_new'},
5319       "Open a new frame");
5320
5321             <a href="fred.html",target="_new">Open a new frame</a>
5322
5323 You may dispense with the dashes in front of the attribute names if
5324 you prefer:
5325
5326    print img {src=>'fred.gif',align=>'LEFT'};
5327
5328            <img align="LEFT" src="fred.gif">
5329
5330 Sometimes an HTML tag attribute has no argument.  For example, ordered
5331 lists can be marked as COMPACT.  The syntax for this is an argument that
5332 that points to an undef string:
5333
5334    print ol({compact=>undef},li('one'),li('two'),li('three'));
5335
5336 Prior to CGI.pm version 2.41, providing an empty ('') string as an
5337 attribute argument was the same as providing undef.  However, this has
5338 changed in order to accommodate those who want to create tags of the form
5339 <img alt="">.  The difference is shown in these two pieces of code:
5340
5341    CODE                   RESULT
5342    img({alt=>undef})      <img alt>
5343    img({alt=>''})         <img alt="">
5344
5345 =head2 THE DISTRIBUTIVE PROPERTY OF HTML SHORTCUTS
5346
5347 One of the cool features of the HTML shortcuts is that they are
5348 distributive.  If you give them an argument consisting of a
5349 B<reference> to a list, the tag will be distributed across each
5350 element of the list.  For example, here's one way to make an ordered
5351 list:
5352
5353    print ul(
5354              li({-type=>'disc'},['Sneezy','Doc','Sleepy','Happy'])
5355            );
5356
5357 This example will result in HTML output that looks like this:
5358
5359    <ul>
5360      <li type="disc">Sneezy</li>
5361      <li type="disc">Doc</li>
5362      <li type="disc">Sleepy</li>
5363      <li type="disc">Happy</li>
5364    </ul>
5365
5366 This is extremely useful for creating tables.  For example:
5367
5368    print table({-border=>undef},
5369            caption('When Should You Eat Your Vegetables?'),
5370            Tr({-align=>CENTER,-valign=>TOP},
5371            [
5372               th(['Vegetable', 'Breakfast','Lunch','Dinner']),
5373               td(['Tomatoes' , 'no', 'yes', 'yes']),
5374               td(['Broccoli' , 'no', 'no',  'yes']),
5375               td(['Onions'   , 'yes','yes', 'yes'])
5376            ]
5377            )
5378         );
5379
5380 =head2 HTML SHORTCUTS AND LIST INTERPOLATION
5381
5382 Consider this bit of code:
5383
5384    print blockquote(em('Hi'),'mom!'));
5385
5386 It will ordinarily return the string that you probably expect, namely:
5387
5388    <blockquote><em>Hi</em> mom!</blockquote>
5389
5390 Note the space between the element "Hi" and the element "mom!".
5391 CGI.pm puts the extra space there using array interpolation, which is
5392 controlled by the magic $" variable.  Sometimes this extra space is
5393 not what you want, for example, when you are trying to align a series
5394 of images.  In this case, you can simply change the value of $" to an
5395 empty string.
5396
5397    {
5398       local($") = '';
5399       print blockquote(em('Hi'),'mom!'));
5400     }
5401
5402 I suggest you put the code in a block as shown here.  Otherwise the
5403 change to $" will affect all subsequent code until you explicitly
5404 reset it.
5405
5406 =head2 NON-STANDARD HTML SHORTCUTS
5407
5408 A few HTML tags don't follow the standard pattern for various
5409 reasons.
5410
5411 B<comment()> generates an HTML comment (<!-- comment -->).  Call it
5412 like
5413
5414     print comment('here is my comment');
5415
5416 Because of conflicts with built-in Perl functions, the following functions
5417 begin with initial caps:
5418
5419     Select
5420     Tr
5421     Link
5422     Delete
5423     Accept
5424     Sub
5425
5426 In addition, start_html(), end_html(), start_form(), end_form(),
5427 start_multipart_form() and all the fill-out form tags are special.
5428 See their respective sections.
5429
5430 =head2 AUTOESCAPING HTML
5431
5432 By default, all HTML that is emitted by the form-generating functions
5433 is passed through a function called escapeHTML():
5434
5435 =over 4
5436
5437 =item $escaped_string = escapeHTML("unescaped string");
5438
5439 Escape HTML formatting characters in a string.
5440
5441 =back
5442
5443 Provided that you have specified a character set of ISO-8859-1 (the
5444 default), the standard HTML escaping rules will be used.  The "<"
5445 character becomes "&lt;", ">" becomes "&gt;", "&" becomes "&amp;", and
5446 the quote character becomes "&quot;".  In addition, the hexadecimal
5447 0x8b and 0x9b characters, which some browsers incorrectly interpret
5448 as the left and right angle-bracket characters, are replaced by their
5449 numeric character entities ("&#8249" and "&#8250;").  If you manually change
5450 the charset, either by calling the charset() method explicitly or by
5451 passing a -charset argument to header(), then B<all> characters will
5452 be replaced by their numeric entities, since CGI.pm has no lookup
5453 table for all the possible encodings.
5454
5455 The automatic escaping does not apply to other shortcuts, such as
5456 h1().  You should call escapeHTML() yourself on untrusted data in
5457 order to protect your pages against nasty tricks that people may enter
5458 into guestbooks, etc..  To change the character set, use charset().
5459 To turn autoescaping off completely, use autoEscape(0):
5460
5461 =over 4
5462
5463 =item $charset = charset([$charset]);
5464
5465 Get or set the current character set.
5466
5467 =item $flag = autoEscape([$flag]);
5468
5469 Get or set the value of the autoescape flag.
5470
5471 =back
5472
5473 =head2 PRETTY-PRINTING HTML
5474
5475 By default, all the HTML produced by these functions comes out as one
5476 long line without carriage returns or indentation. This is yuck, but
5477 it does reduce the size of the documents by 10-20%.  To get
5478 pretty-printed output, please use L<CGI::Pretty>, a subclass
5479 contributed by Brian Paulsen.
5480
5481 =head1 CREATING FILL-OUT FORMS:
5482
5483 I<General note>  The various form-creating methods all return strings
5484 to the caller, containing the tag or tags that will create the requested
5485 form element.  You are responsible for actually printing out these strings.
5486 It's set up this way so that you can place formatting tags
5487 around the form elements.
5488
5489 I<Another note> The default values that you specify for the forms are only
5490 used the B<first> time the script is invoked (when there is no query
5491 string).  On subsequent invocations of the script (when there is a query
5492 string), the former values are used even if they are blank.
5493
5494 If you want to change the value of a field from its previous value, you have two
5495 choices:
5496
5497 (1) call the param() method to set it.
5498
5499 (2) use the -override (alias -force) parameter (a new feature in version 2.15).
5500 This forces the default value to be used, regardless of the previous value:
5501
5502    print textfield(-name=>'field_name',
5503                            -default=>'starting value',
5504                            -override=>1,
5505                            -size=>50,
5506                            -maxlength=>80);
5507
5508 I<Yet another note> By default, the text and labels of form elements are
5509 escaped according to HTML rules.  This means that you can safely use
5510 "<CLICK ME>" as the label for a button.  However, it also interferes with
5511 your ability to incorporate special HTML character sequences, such as &Aacute;,
5512 into your fields.  If you wish to turn off automatic escaping, call the
5513 autoEscape() method with a false value immediately after creating the CGI object:
5514
5515    $query = new CGI;
5516    autoEscape(undef);
5517
5518 I<A Lurking Trap!> Some of the form-element generating methods return
5519 multiple tags.  In a scalar context, the tags will be concatenated
5520 together with spaces, or whatever is the current value of the $"
5521 global.  In a list context, the methods will return a list of
5522 elements, allowing you to modify them if you wish.  Usually you will
5523 not notice this behavior, but beware of this:
5524
5525     printf("%s\n",end_form())
5526
5527 end_form() produces several tags, and only the first of them will be
5528 printed because the format only expects one value.
5529
5530 <p>
5531
5532
5533 =head2 CREATING AN ISINDEX TAG
5534
5535    print isindex(-action=>$action);
5536
5537          -or-
5538
5539    print isindex($action);
5540
5541 Prints out an <isindex> tag.  Not very exciting.  The parameter
5542 -action specifies the URL of the script to process the query.  The
5543 default is to process the query with the current script.
5544
5545 =head2 STARTING AND ENDING A FORM
5546
5547     print start_form(-method=>$method,
5548                     -action=>$action,
5549                     -enctype=>$encoding);
5550       <... various form stuff ...>
5551     print endform;
5552
5553         -or-
5554
5555     print start_form($method,$action,$encoding);
5556       <... various form stuff ...>
5557     print endform;
5558
5559 start_form() will return a <form> tag with the optional method,
5560 action and form encoding that you specify.  The defaults are:
5561
5562     method: POST
5563     action: this script
5564     enctype: application/x-www-form-urlencoded
5565
5566 endform() returns the closing </form> tag.
5567
5568 Start_form()'s enctype argument tells the browser how to package the various
5569 fields of the form before sending the form to the server.  Two
5570 values are possible:
5571
5572 B<Note:> This method was previously named startform(), and startform()
5573 is still recognized as an alias.
5574
5575 =over 4
5576
5577 =item B<application/x-www-form-urlencoded>
5578
5579 This is the older type of encoding used by all browsers prior to
5580 Netscape 2.0.  It is compatible with many CGI scripts and is
5581 suitable for short fields containing text data.  For your
5582 convenience, CGI.pm stores the name of this encoding
5583 type in B<&CGI::URL_ENCODED>.
5584
5585 =item B<multipart/form-data>
5586
5587 This is the newer type of encoding introduced by Netscape 2.0.
5588 It is suitable for forms that contain very large fields or that
5589 are intended for transferring binary data.  Most importantly,
5590 it enables the "file upload" feature of Netscape 2.0 forms.  For
5591 your convenience, CGI.pm stores the name of this encoding type
5592 in B<&CGI::MULTIPART>
5593
5594 Forms that use this type of encoding are not easily interpreted
5595 by CGI scripts unless they use CGI.pm or another library designed
5596 to handle them.
5597
5598 If XHTML is activated (the default), then forms will be automatically
5599 created using this type of encoding.
5600
5601 =back
5602
5603 For compatibility, the start_form() method uses the older form of
5604 encoding by default.  If you want to use the newer form of encoding
5605 by default, you can call B<start_multipart_form()> instead of
5606 B<start_form()>.
5607
5608 JAVASCRIPTING: The B<-name> and B<-onSubmit> parameters are provided
5609 for use with JavaScript.  The -name parameter gives the
5610 form a name so that it can be identified and manipulated by
5611 JavaScript functions.  -onSubmit should point to a JavaScript
5612 function that will be executed just before the form is submitted to your
5613 server.  You can use this opportunity to check the contents of the form
5614 for consistency and completeness.  If you find something wrong, you
5615 can put up an alert box or maybe fix things up yourself.  You can
5616 abort the submission by returning false from this function.
5617
5618 Usually the bulk of JavaScript functions are defined in a <script>
5619 block in the HTML header and -onSubmit points to one of these function
5620 call.  See start_html() for details.
5621
5622 =head2 FORM ELEMENTS
5623
5624 After starting a form, you will typically create one or more
5625 textfields, popup menus, radio groups and other form elements.  Each
5626 of these elements takes a standard set of named arguments.  Some
5627 elements also have optional arguments.  The standard arguments are as
5628 follows:
5629
5630 =over 4
5631
5632 =item B<-name>
5633
5634 The name of the field. After submission this name can be used to
5635 retrieve the field's value using the param() method.
5636
5637 =item B<-value>, B<-values>
5638
5639 The initial value of the field which will be returned to the script
5640 after form submission.  Some form elements, such as text fields, take
5641 a single scalar -value argument. Others, such as popup menus, take a
5642 reference to an array of values. The two arguments are synonyms.
5643
5644 =item B<-tabindex>
5645
5646 A numeric value that sets the order in which the form element receives
5647 focus when the user presses the tab key. Elements with lower values
5648 receive focus first.
5649
5650 =item B<-id>
5651
5652 A string identifier that can be used to identify this element to
5653 JavaScript and DHTML.
5654
5655 =item B<-override>
5656
5657 A boolean, which, if true, forces the element to take on the value
5658 specified by B<-value>, overriding the sticky behavior described
5659 earlier for the B<-no_sticky> pragma.
5660
5661 =item B<-onChange>, B<-onFocus>, B<-onBlur>, B<-onMouseOver>, B<-onMouseOut>, B<-onSelect>
5662
5663 These are used to assign JavaScript event handlers. See the
5664 JavaScripting section for more details.
5665
5666 =back
5667
5668 Other common arguments are described in the next section. In addition
5669 to these, all attributes described in the HTML specifications are
5670 supported.
5671
5672 =head2 CREATING A TEXT FIELD
5673
5674     print textfield(-name=>'field_name',
5675                     -value=>'starting value',
5676                     -size=>50,
5677                     -maxlength=>80);
5678         -or-
5679
5680     print textfield('field_name','starting value',50,80);
5681
5682 textfield() will return a text input field.
5683
5684 =over 4
5685
5686 =item B<Parameters>
5687
5688 =item 1.
5689
5690 The first parameter is the required name for the field (-name).
5691
5692 =item 2.
5693
5694 The optional second parameter is the default starting value for the field
5695 contents (-value, formerly known as -default).
5696
5697 =item 3.
5698
5699 The optional third parameter is the size of the field in
5700       characters (-size).
5701
5702 =item 4.
5703
5704 The optional fourth parameter is the maximum number of characters the
5705       field will accept (-maxlength).
5706
5707 =back
5708
5709 As with all these methods, the field will be initialized with its
5710 previous contents from earlier invocations of the script.
5711 When the form is processed, the value of the text field can be
5712 retrieved with:
5713
5714        $value = param('foo');
5715
5716 If you want to reset it from its initial value after the script has been
5717 called once, you can do so like this:
5718
5719        param('foo',"I'm taking over this value!");
5720
5721 =head2 CREATING A BIG TEXT FIELD
5722
5723    print textarea(-name=>'foo',
5724                           -default=>'starting value',
5725                           -rows=>10,
5726                           -columns=>50);
5727
5728         -or
5729
5730    print textarea('foo','starting value',10,50);
5731
5732 textarea() is just like textfield, but it allows you to specify
5733 rows and columns for a multiline text entry box.  You can provide
5734 a starting value for the field, which can be long and contain
5735 multiple lines.
5736
5737 =head2 CREATING A PASSWORD FIELD
5738
5739    print password_field(-name=>'secret',
5740                                 -value=>'starting value',
5741                                 -size=>50,
5742                                 -maxlength=>80);
5743         -or-
5744
5745    print password_field('secret','starting value',50,80);
5746
5747 password_field() is identical to textfield(), except that its contents
5748 will be starred out on the web page.
5749
5750 =head2 CREATING A FILE UPLOAD FIELD
5751
5752     print filefield(-name=>'uploaded_file',
5753                             -default=>'starting value',
5754                             -size=>50,
5755                             -maxlength=>80);
5756         -or-
5757
5758     print filefield('uploaded_file','starting value',50,80);
5759
5760 filefield() will return a file upload field for Netscape 2.0 browsers.
5761 In order to take full advantage of this I<you must use the new
5762 multipart encoding scheme> for the form.  You can do this either
5763 by calling B<start_form()> with an encoding type of B<&CGI::MULTIPART>,
5764 or by calling the new method B<start_multipart_form()> instead of
5765 vanilla B<start_form()>.
5766
5767 =over 4
5768
5769 =item B<Parameters>
5770
5771 =item 1.
5772
5773 The first parameter is the required name for the field (-name).
5774
5775 =item 2.
5776
5777 The optional second parameter is the starting value for the field contents
5778 to be used as the default file name (-default).
5779
5780 For security reasons, browsers don't pay any attention to this field,
5781 and so the starting value will always be blank.  Worse, the field
5782 loses its "sticky" behavior and forgets its previous contents.  The
5783 starting value field is called for in the HTML specification, however,
5784 and possibly some browser will eventually provide support for it.
5785
5786 =item 3.
5787
5788 The optional third parameter is the size of the field in
5789 characters (-size).
5790
5791 =item 4.
5792
5793 The optional fourth parameter is the maximum number of characters the
5794 field will accept (-maxlength).
5795
5796 =back
5797
5798 When the form is processed, you can retrieve the entered filename
5799 by calling param():
5800
5801        $filename = param('uploaded_file');
5802
5803 Different browsers will return slightly different things for the
5804 name.  Some browsers return the filename only.  Others return the full
5805 path to the file, using the path conventions of the user's machine.
5806 Regardless, the name returned is always the name of the file on the
5807 I<user's> machine, and is unrelated to the name of the temporary file
5808 that CGI.pm creates during upload spooling (see below).
5809
5810 The filename returned is also a file handle.  You can read the contents
5811 of the file using standard Perl file reading calls:
5812
5813         # Read a text file and print it out
5814         while (<$filename>) {
5815            print;
5816         }
5817
5818         # Copy a binary file to somewhere safe
5819         open (OUTFILE,">>/usr/local/web/users/feedback");
5820         while ($bytesread=read($filename,$buffer,1024)) {
5821            print OUTFILE $buffer;
5822         }
5823
5824 However, there are problems with the dual nature of the upload fields.
5825 If you C<use strict>, then Perl will complain when you try to use a
5826 string as a filehandle.  You can get around this by placing the file
5827 reading code in a block containing the C<no strict> pragma.  More
5828 seriously, it is possible for the remote user to type garbage into the
5829 upload field, in which case what you get from param() is not a
5830 filehandle at all, but a string.
5831
5832 To be safe, use the I<upload()> function (new in version 2.47).  When
5833 called with the name of an upload field, I<upload()> returns a
5834 filehandle, or undef if the parameter is not a valid filehandle.
5835
5836      $fh = upload('uploaded_file');
5837      while (<$fh>) {
5838            print;
5839      }
5840
5841 In an list context, upload() will return an array of filehandles.
5842 This makes it possible to create forms that use the same name for
5843 multiple upload fields.
5844
5845 This is the recommended idiom.
5846
5847 When a file is uploaded the browser usually sends along some
5848 information along with it in the format of headers.  The information
5849 usually includes the MIME content type.  Future browsers may send
5850 other information as well (such as modification date and size). To
5851 retrieve this information, call uploadInfo().  It returns a reference to
5852 an associative array containing all the document headers.
5853
5854        $filename = param('uploaded_file');
5855        $type = uploadInfo($filename)->{'Content-Type'};
5856        unless ($type eq 'text/html') {
5857           die "HTML FILES ONLY!";
5858        }
5859
5860 If you are using a machine that recognizes "text" and "binary" data
5861 modes, be sure to understand when and how to use them (see the Camel book).
5862 Otherwise you may find that binary files are corrupted during file
5863 uploads.
5864
5865 There are occasionally problems involving parsing the uploaded file.
5866 This usually happens when the user presses "Stop" before the upload is
5867 finished.  In this case, CGI.pm will return undef for the name of the
5868 uploaded file and set I<cgi_error()> to the string "400 Bad request
5869 (malformed multipart POST)".  This error message is designed so that
5870 you can incorporate it into a status code to be sent to the browser.
5871 Example:
5872
5873    $file = upload('uploaded_file');
5874    if (!$file && cgi_error) {
5875       print header(-status=>cgi_error);
5876       exit 0;
5877    }
5878
5879 You are free to create a custom HTML page to complain about the error,
5880 if you wish.
5881
5882 You can set up a callback that will be called whenever a file upload
5883 is being read during the form processing. This is much like the
5884 UPLOAD_HOOK facility available in Apache::Request, with the exception
5885 that the first argument to the callback is an Apache::Upload object,
5886 here it's the remote filename.
5887
5888  $q = CGI->new(\&hook,$data);
5889
5890  sub hook
5891  {
5892         my ($filename, $buffer, $bytes_read, $data) = @_;
5893         print  "Read $bytes_read bytes of $filename\n";
5894  }
5895
5896 If using the function-oriented interface, call the CGI::upload_hook()
5897 method before calling param() or any other CGI functions:
5898
5899   CGI::upload_hook(\&hook,$data);
5900
5901 This method is not exported by default.  You will have to import it
5902 explicitly if you wish to use it without the CGI:: prefix.
5903
5904 If you are using CGI.pm on a Windows platform and find that binary
5905 files get slightly larger when uploaded but that text files remain the
5906 same, then you have forgotten to activate binary mode on the output
5907 filehandle.  Be sure to call binmode() on any handle that you create
5908 to write the uploaded file to disk.
5909
5910 JAVASCRIPTING: The B<-onChange>, B<-onFocus>, B<-onBlur>,
5911 B<-onMouseOver>, B<-onMouseOut> and B<-onSelect> parameters are
5912 recognized.  See textfield() for details.
5913
5914 =head2 CREATING A POPUP MENU
5915
5916    print popup_menu('menu_name',
5917                             ['eenie','meenie','minie'],
5918                             'meenie');
5919
5920       -or-
5921
5922    %labels = ('eenie'=>'your first choice',
5923               'meenie'=>'your second choice',
5924               'minie'=>'your third choice');
5925    %attributes = ('eenie'=>{'class'=>'class of first choice'});
5926    print popup_menu('menu_name',
5927                             ['eenie','meenie','minie'],
5928           'meenie',\%labels,\%attributes);
5929
5930         -or (named parameter style)-
5931
5932    print popup_menu(-name=>'menu_name',
5933                             -values=>['eenie','meenie','minie'],
5934                             -default=>'meenie',
5935           -labels=>\%labels,
5936           -attributes=>\%attributes);
5937
5938 popup_menu() creates a menu.
5939
5940 =over 4
5941
5942 =item 1.
5943
5944 The required first argument is the menu's name (-name).
5945
5946 =item 2.
5947
5948 The required second argument (-values) is an array B<reference>
5949 containing the list of menu items in the menu.  You can pass the
5950 method an anonymous array, as shown in the example, or a reference to
5951 a named array, such as "\@foo".
5952
5953 =item 3.
5954
5955 The optional third parameter (-default) is the name of the default
5956 menu choice.  If not specified, the first item will be the default.
5957 The values of the previous choice will be maintained across queries.
5958
5959 =item 4.
5960
5961 The optional fourth parameter (-labels) is provided for people who
5962 want to use different values for the user-visible label inside the
5963 popup menu and the value returned to your script.  It's a pointer to an
5964 associative array relating menu values to user-visible labels.  If you
5965 leave this parameter blank, the menu values will be displayed by
5966 default.  (You can also leave a label undefined if you want to).
5967
5968 =item 5.
5969
5970 The optional fifth parameter (-attributes) is provided to assign
5971 any of the common HTML attributes to an individual menu item. It's
5972 a pointer to an associative array relating menu values to another
5973 associative array with the attribute's name as the key and the
5974 attribute's value as the value.
5975
5976 =back
5977
5978 When the form is processed, the selected value of the popup menu can
5979 be retrieved using:
5980
5981       $popup_menu_value = param('menu_name');
5982
5983 =head2 CREATING AN OPTION GROUP
5984
5985 Named parameter style
5986
5987   print popup_menu(-name=>'menu_name',
5988                   -values=>[qw/eenie meenie minie/,
5989                             optgroup(-name=>'optgroup_name',
5990                                              -values => ['moe','catch'],
5991                                              -attributes=>{'catch'=>{'class'=>'red'}})],
5992                   -labels=>{'eenie'=>'one',
5993                             'meenie'=>'two',
5994                             'minie'=>'three'},
5995                   -default=>'meenie');
5996
5997   Old style
5998   print popup_menu('menu_name',
5999                   ['eenie','meenie','minie',
6000                    optgroup('optgroup_name', ['moe', 'catch'],
6001                                    {'catch'=>{'class'=>'red'}})],'meenie',
6002                   {'eenie'=>'one','meenie'=>'two','minie'=>'three'});
6003
6004 optgroup() creates an option group within a popup menu.
6005
6006 =over 4
6007
6008 =item 1.
6009
6010 The required first argument (B<-name>) is the label attribute of the
6011 optgroup and is B<not> inserted in the parameter list of the query.
6012
6013 =item 2.
6014
6015 The required second argument (B<-values>)  is an array reference
6016 containing the list of menu items in the menu.  You can pass the
6017 method an anonymous array, as shown in the example, or a reference
6018 to a named array, such as \@foo.  If you pass a HASH reference,
6019 the keys will be used for the menu values, and the values will be
6020 used for the menu labels (see -labels below).
6021
6022 =item 3.
6023
6024 The optional third parameter (B<-labels>) allows you to pass a reference
6025 to an associative array containing user-visible labels for one or more
6026 of the menu items.  You can use this when you want the user to see one
6027 menu string, but have the browser return your program a different one.
6028 If you don't specify this, the value string will be used instead
6029 ("eenie", "meenie" and "minie" in this example).  This is equivalent
6030 to using a hash reference for the -values parameter.
6031
6032 =item 4.
6033
6034 An optional fourth parameter (B<-labeled>) can be set to a true value
6035 and indicates that the values should be used as the label attribute
6036 for each option element within the optgroup.
6037
6038 =item 5.
6039
6040 An optional fifth parameter (-novals) can be set to a true value and
6041 indicates to suppress the val attribute in each option element within
6042 the optgroup.
6043
6044 See the discussion on optgroup at W3C
6045 (http://www.w3.org/TR/REC-html40/interact/forms.html#edef-OPTGROUP)
6046 for details.
6047
6048 =item 6.
6049
6050 An optional sixth parameter (-attributes) is provided to assign
6051 any of the common HTML attributes to an individual menu item. It's
6052 a pointer to an associative array relating menu values to another
6053 associative array with the attribute's name as the key and the
6054 attribute's value as the value.
6055
6056 =back
6057
6058 =head2 CREATING A SCROLLING LIST
6059
6060    print scrolling_list('list_name',
6061                                 ['eenie','meenie','minie','moe'],
6062         ['eenie','moe'],5,'true',{'moe'=>{'class'=>'red'}});
6063       -or-
6064
6065    print scrolling_list('list_name',
6066                                 ['eenie','meenie','minie','moe'],
6067                                 ['eenie','moe'],5,'true',
6068         \%labels,%attributes);
6069
6070         -or-
6071
6072    print scrolling_list(-name=>'list_name',
6073                                 -values=>['eenie','meenie','minie','moe'],
6074                                 -default=>['eenie','moe'],
6075                                 -size=>5,
6076                                 -multiple=>'true',
6077         -labels=>\%labels,
6078         -attributes=>\%attributes);
6079
6080 scrolling_list() creates a scrolling list.
6081
6082 =over 4
6083
6084 =item B<Parameters:>
6085
6086 =item 1.
6087
6088 The first and second arguments are the list name (-name) and values
6089 (-values).  As in the popup menu, the second argument should be an
6090 array reference.
6091
6092 =item 2.
6093
6094 The optional third argument (-default) can be either a reference to a
6095 list containing the values to be selected by default, or can be a
6096 single value to select.  If this argument is missing or undefined,
6097 then nothing is selected when the list first appears.  In the named
6098 parameter version, you can use the synonym "-defaults" for this
6099 parameter.
6100
6101 =item 3.
6102
6103 The optional fourth argument is the size of the list (-size).
6104
6105 =item 4.
6106
6107 The optional fifth argument can be set to true to allow multiple
6108 simultaneous selections (-multiple).  Otherwise only one selection
6109 will be allowed at a time.
6110
6111 =item 5.
6112
6113 The optional sixth argument is a pointer to an associative array
6114 containing long user-visible labels for the list items (-labels).
6115 If not provided, the values will be displayed.
6116
6117 =item 6.
6118
6119 The optional sixth parameter (-attributes) is provided to assign
6120 any of the common HTML attributes to an individual menu item. It's
6121 a pointer to an associative array relating menu values to another
6122 associative array with the attribute's name as the key and the
6123 attribute's value as the value.
6124
6125 When this form is processed, all selected list items will be returned as
6126 a list under the parameter name 'list_name'.  The values of the
6127 selected items can be retrieved with:
6128
6129       @selected = param('list_name');
6130
6131 =back
6132
6133 =head2 CREATING A GROUP OF RELATED CHECKBOXES
6134
6135    print checkbox_group(-name=>'group_name',
6136                                 -values=>['eenie','meenie','minie','moe'],
6137                                 -default=>['eenie','moe'],
6138                                 -linebreak=>'true',
6139         -labels=>\%labels,
6140         -attributes=>\%attributes);
6141
6142    print checkbox_group('group_name',
6143                                 ['eenie','meenie','minie','moe'],
6144         ['eenie','moe'],'true',\%labels,
6145         {'moe'=>{'class'=>'red'}});
6146
6147    HTML3-COMPATIBLE BROWSERS ONLY:
6148
6149    print checkbox_group(-name=>'group_name',
6150                                 -values=>['eenie','meenie','minie','moe'],
6151                                 -rows=2,-columns=>2);
6152
6153
6154 checkbox_group() creates a list of checkboxes that are related
6155 by the same name.
6156
6157 =over 4
6158
6159 =item B<Parameters:>
6160
6161 =item 1.
6162
6163 The first and second arguments are the checkbox name and values,
6164 respectively (-name and -values).  As in the popup menu, the second
6165 argument should be an array reference.  These values are used for the
6166 user-readable labels printed next to the checkboxes as well as for the
6167 values passed to your script in the query string.
6168
6169 =item 2.
6170
6171 The optional third argument (-default) can be either a reference to a
6172 list containing the values to be checked by default, or can be a
6173 single value to checked.  If this argument is missing or undefined,
6174 then nothing is selected when the list first appears.
6175
6176 =item 3.
6177
6178 The optional fourth argument (-linebreak) can be set to true to place
6179 line breaks between the checkboxes so that they appear as a vertical
6180 list.  Otherwise, they will be strung together on a horizontal line.
6181
6182 =back
6183
6184
6185 The optional b<-labels> argument is a pointer to an associative array
6186 relating the checkbox values to the user-visible labels that will be
6187 printed next to them.  If not provided, the values will be used as the
6188 default.
6189
6190
6191 Modern browsers can take advantage of the optional parameters
6192 B<-rows>, and B<-columns>.  These parameters cause checkbox_group() to
6193 return an HTML3 compatible table containing the checkbox group
6194 formatted with the specified number of rows and columns.  You can
6195 provide just the -columns parameter if you wish; checkbox_group will
6196 calculate the correct number of rows for you.
6197
6198
6199 The optional B<-attributes> argument is provided to assign any of the
6200 common HTML attributes to an individual menu item. It's a pointer to
6201 an associative array relating menu values to another associative array
6202 with the attribute's name as the key and the attribute's value as the
6203 value.
6204
6205 The optional B<-tabindex> argument can be used to control the order in which
6206 radio buttons receive focus when the user presses the tab button.  If
6207 passed a scalar numeric value, the first element in the group will
6208 receive this tab index and subsequent elements will be incremented by
6209 one.  If given a reference to an array of radio button values, then
6210 the indexes will be jiggered so that the order specified in the array
6211 will correspond to the tab order.  You can also pass a reference to a
6212 hash in which the hash keys are the radio button values and the values
6213 are the tab indexes of each button.  Examples:
6214
6215   -tabindex => 100    #  this group starts at index 100 and counts up
6216   -tabindex => ['moe','minie','eenie','meenie']  # tab in this order
6217   -tabindex => {meenie=>100,moe=>101,minie=>102,eenie=>200} # tab in this order
6218
6219 When the form is processed, all checked boxes will be returned as
6220 a list under the parameter name 'group_name'.  The values of the
6221 "on" checkboxes can be retrieved with:
6222
6223       @turned_on = param('group_name');
6224
6225 The value returned by checkbox_group() is actually an array of button
6226 elements.  You can capture them and use them within tables, lists,
6227 or in other creative ways:
6228
6229     @h = checkbox_group(-name=>'group_name',-values=>\@values);
6230     &use_in_creative_way(@h);
6231
6232 =head2 CREATING A STANDALONE CHECKBOX
6233
6234     print checkbox(-name=>'checkbox_name',
6235                            -checked=>1,
6236                            -value=>'ON',
6237                            -label=>'CLICK ME');
6238
6239         -or-
6240
6241     print checkbox('checkbox_name','checked','ON','CLICK ME');
6242
6243 checkbox() is used to create an isolated checkbox that isn't logically
6244 related to any others.
6245
6246 =over 4
6247
6248 =item B<Parameters:>
6249
6250 =item 1.
6251
6252 The first parameter is the required name for the checkbox (-name).  It
6253 will also be used for the user-readable label printed next to the
6254 checkbox.
6255
6256 =item 2.
6257
6258 The optional second parameter (-checked) specifies that the checkbox
6259 is turned on by default.  Synonyms are -selected and -on.
6260
6261 =item 3.
6262
6263 The optional third parameter (-value) specifies the value of the
6264 checkbox when it is checked.  If not provided, the word "on" is
6265 assumed.
6266
6267 =item 4.
6268
6269 The optional fourth parameter (-label) is the user-readable label to
6270 be attached to the checkbox.  If not provided, the checkbox name is
6271 used.
6272
6273 =back
6274
6275 The value of the checkbox can be retrieved using:
6276
6277     $turned_on = param('checkbox_name');
6278
6279 =head2 CREATING A RADIO BUTTON GROUP
6280
6281    print radio_group(-name=>'group_name',
6282                              -values=>['eenie','meenie','minie'],
6283                              -default=>'meenie',
6284                              -linebreak=>'true',
6285            -labels=>\%labels,
6286            -attributes=>\%attributes);
6287
6288         -or-
6289
6290    print radio_group('group_name',['eenie','meenie','minie'],
6291             'meenie','true',\%labels,\%attributes);
6292
6293
6294    HTML3-COMPATIBLE BROWSERS ONLY:
6295
6296    print radio_group(-name=>'group_name',
6297                              -values=>['eenie','meenie','minie','moe'],
6298                              -rows=2,-columns=>2);
6299
6300 radio_group() creates a set of logically-related radio buttons
6301 (turning one member of the group on turns the others off)
6302
6303 =over 4
6304
6305 =item B<Parameters:>
6306
6307 =item 1.
6308
6309 The first argument is the name of the group and is required (-name).
6310
6311 =item 2.
6312
6313 The second argument (-values) is the list of values for the radio
6314 buttons.  The values and the labels that appear on the page are
6315 identical.  Pass an array I<reference> in the second argument, either
6316 using an anonymous array, as shown, or by referencing a named array as
6317 in "\@foo".
6318
6319 =item 3.
6320
6321 The optional third parameter (-default) is the name of the default
6322 button to turn on. If not specified, the first item will be the
6323 default.  You can provide a nonexistent button name, such as "-" to
6324 start up with no buttons selected.
6325
6326 =item 4.
6327
6328 The optional fourth parameter (-linebreak) can be set to 'true' to put
6329 line breaks between the buttons, creating a vertical list.
6330
6331 =item 5.
6332
6333 The optional fifth parameter (-labels) is a pointer to an associative
6334 array relating the radio button values to user-visible labels to be
6335 used in the display.  If not provided, the values themselves are
6336 displayed.
6337
6338 =back
6339
6340
6341 All modern browsers can take advantage of the optional parameters
6342 B<-rows>, and B<-columns>.  These parameters cause radio_group() to
6343 return an HTML3 compatible table containing the radio group formatted
6344 with the specified number of rows and columns.  You can provide just
6345 the -columns parameter if you wish; radio_group will calculate the
6346 correct number of rows for you.
6347
6348 To include row and column headings in the returned table, you
6349 can use the B<-rowheader> and B<-colheader> parameters.  Both
6350 of these accept a pointer to an array of headings to use.
6351 The headings are just decorative.  They don't reorganize the
6352 interpretation of the radio buttons -- they're still a single named
6353 unit.
6354
6355 The optional B<-tabindex> argument can be used to control the order in which
6356 radio buttons receive focus when the user presses the tab button.  If
6357 passed a scalar numeric value, the first element in the group will
6358 receive this tab index and subsequent elements will be incremented by
6359 one.  If given a reference to an array of radio button values, then
6360 the indexes will be jiggered so that the order specified in the array
6361 will correspond to the tab order.  You can also pass a reference to a
6362 hash in which the hash keys are the radio button values and the values
6363 are the tab indexes of each button.  Examples:
6364
6365   -tabindex => 100    #  this group starts at index 100 and counts up
6366   -tabindex => ['moe','minie','eenie','meenie']  # tab in this order
6367   -tabindex => {meenie=>100,moe=>101,minie=>102,eenie=>200} # tab in this order
6368
6369
6370 The optional B<-attributes> argument is provided to assign any of the
6371 common HTML attributes to an individual menu item. It's a pointer to
6372 an associative array relating menu values to another associative array
6373 with the attribute's name as the key and the attribute's value as the
6374 value.
6375
6376 When the form is processed, the selected radio button can
6377 be retrieved using:
6378
6379       $which_radio_button = param('group_name');
6380
6381 The value returned by radio_group() is actually an array of button
6382 elements.  You can capture them and use them within tables, lists,
6383 or in other creative ways:
6384
6385     @h = radio_group(-name=>'group_name',-values=>\@values);
6386     &use_in_creative_way(@h);
6387
6388 =head2 CREATING A SUBMIT BUTTON
6389
6390    print submit(-name=>'button_name',
6391                         -value=>'value');
6392
6393         -or-
6394
6395    print submit('button_name','value');
6396
6397 submit() will create the query submission button.  Every form
6398 should have one of these.
6399
6400 =over 4
6401
6402 =item B<Parameters:>
6403
6404 =item 1.
6405
6406 The first argument (-name) is optional.  You can give the button a
6407 name if you have several submission buttons in your form and you want
6408 to distinguish between them.
6409
6410 =item 2.
6411
6412 The second argument (-value) is also optional.  This gives the button
6413 a value that will be passed to your script in the query string. The
6414 name will also be used as the user-visible label.
6415
6416 =item 3.
6417
6418 You can use -label as an alias for -value.  I always get confused
6419 about which of -name and -value changes the user-visible label on the
6420 button.
6421
6422 =back
6423
6424 You can figure out which button was pressed by using different
6425 values for each one:
6426
6427      $which_one = param('button_name');
6428
6429 =head2 CREATING A RESET BUTTON
6430
6431    print reset
6432
6433 reset() creates the "reset" button.  Note that it restores the
6434 form to its value from the last time the script was called,
6435 NOT necessarily to the defaults.
6436
6437 Note that this conflicts with the Perl reset() built-in.  Use
6438 CORE::reset() to get the original reset function.
6439
6440 =head2 CREATING A DEFAULT BUTTON
6441
6442    print defaults('button_label')
6443
6444 defaults() creates a button that, when invoked, will cause the
6445 form to be completely reset to its defaults, wiping out all the
6446 changes the user ever made.
6447
6448 =head2 CREATING A HIDDEN FIELD
6449
6450         print hidden(-name=>'hidden_name',
6451                              -default=>['value1','value2'...]);
6452
6453                 -or-
6454
6455         print hidden('hidden_name','value1','value2'...);
6456
6457 hidden() produces a text field that can't be seen by the user.  It
6458 is useful for passing state variable information from one invocation
6459 of the script to the next.
6460
6461 =over 4
6462
6463 =item B<Parameters:>
6464
6465 =item 1.
6466
6467 The first argument is required and specifies the name of this
6468 field (-name).
6469
6470 =item 2.
6471
6472 The second argument is also required and specifies its value
6473 (-default).  In the named parameter style of calling, you can provide
6474 a single value here or a reference to a whole list
6475
6476 =back
6477
6478 Fetch the value of a hidden field this way:
6479
6480      $hidden_value = param('hidden_name');
6481
6482 Note, that just like all the other form elements, the value of a
6483 hidden field is "sticky".  If you want to replace a hidden field with
6484 some other values after the script has been called once you'll have to
6485 do it manually:
6486
6487      param('hidden_name','new','values','here');
6488
6489 =head2 CREATING A CLICKABLE IMAGE BUTTON
6490
6491      print image_button(-name=>'button_name',
6492                                 -src=>'/source/URL',
6493                                 -align=>'MIDDLE');
6494
6495         -or-
6496
6497      print image_button('button_name','/source/URL','MIDDLE');
6498
6499 image_button() produces a clickable image.  When it's clicked on the
6500 position of the click is returned to your script as "button_name.x"
6501 and "button_name.y", where "button_name" is the name you've assigned
6502 to it.
6503
6504 =over 4
6505
6506 =item B<Parameters:>
6507
6508 =item 1.
6509
6510 The first argument (-name) is required and specifies the name of this
6511 field.
6512
6513 =item 2.
6514
6515 The second argument (-src) is also required and specifies the URL
6516
6517 =item 3.
6518 The third option (-align, optional) is an alignment type, and may be
6519 TOP, BOTTOM or MIDDLE
6520
6521 =back
6522
6523 Fetch the value of the button this way:
6524      $x = param('button_name.x');
6525      $y = param('button_name.y');
6526
6527 =head2 CREATING A JAVASCRIPT ACTION BUTTON
6528
6529      print button(-name=>'button_name',
6530                           -value=>'user visible label',
6531                           -onClick=>"do_something()");
6532
6533         -or-
6534
6535      print button('button_name',"do_something()");
6536
6537 button() produces a button that is compatible with Netscape 2.0's
6538 JavaScript.  When it's pressed the fragment of JavaScript code
6539 pointed to by the B<-onClick> parameter will be executed.  On
6540 non-Netscape browsers this form element will probably not even
6541 display.
6542
6543 =head1 HTTP COOKIES
6544
6545 Netscape browsers versions 1.1 and higher, and all versions of
6546 Internet Explorer, support a so-called "cookie" designed to help
6547 maintain state within a browser session.  CGI.pm has several methods
6548 that support cookies.
6549
6550 A cookie is a name=value pair much like the named parameters in a CGI
6551 query string.  CGI scripts create one or more cookies and send
6552 them to the browser in the HTTP header.  The browser maintains a list
6553 of cookies that belong to a particular Web server, and returns them
6554 to the CGI script during subsequent interactions.
6555
6556 In addition to the required name=value pair, each cookie has several
6557 optional attributes:
6558
6559 =over 4
6560
6561 =item 1. an expiration time
6562
6563 This is a time/date string (in a special GMT format) that indicates
6564 when a cookie expires.  The cookie will be saved and returned to your
6565 script until this expiration date is reached if the user exits
6566 the browser and restarts it.  If an expiration date isn't specified, the cookie
6567 will remain active until the user quits the browser.
6568
6569 =item 2. a domain
6570
6571 This is a partial or complete domain name for which the cookie is
6572 valid.  The browser will return the cookie to any host that matches
6573 the partial domain name.  For example, if you specify a domain name
6574 of ".capricorn.com", then the browser will return the cookie to
6575 Web servers running on any of the machines "www.capricorn.com",
6576 "www2.capricorn.com", "feckless.capricorn.com", etc.  Domain names
6577 must contain at least two periods to prevent attempts to match
6578 on top level domains like ".edu".  If no domain is specified, then
6579 the browser will only return the cookie to servers on the host the
6580 cookie originated from.
6581
6582 =item 3. a path
6583
6584 If you provide a cookie path attribute, the browser will check it
6585 against your script's URL before returning the cookie.  For example,
6586 if you specify the path "/cgi-bin", then the cookie will be returned
6587 to each of the scripts "/cgi-bin/tally.pl", "/cgi-bin/order.pl",
6588 and "/cgi-bin/customer_service/complain.pl", but not to the script
6589 "/cgi-private/site_admin.pl".  By default, path is set to "/", which
6590 causes the cookie to be sent to any CGI script on your site.
6591
6592 =item 4. a "secure" flag
6593
6594 If the "secure" attribute is set, the cookie will only be sent to your
6595 script if the CGI request is occurring on a secure channel, such as SSL.
6596
6597 =back
6598
6599 The interface to HTTP cookies is the B<cookie()> method:
6600
6601     $cookie = cookie(-name=>'sessionID',
6602                              -value=>'xyzzy',
6603                              -expires=>'+1h',
6604                              -path=>'/cgi-bin/database',
6605                              -domain=>'.capricorn.org',
6606                              -secure=>1);
6607     print header(-cookie=>$cookie);
6608
6609 B<cookie()> creates a new cookie.  Its parameters include:
6610
6611 =over 4
6612
6613 =item B<-name>
6614
6615 The name of the cookie (required).  This can be any string at all.
6616 Although browsers limit their cookie names to non-whitespace
6617 alphanumeric characters, CGI.pm removes this restriction by escaping
6618 and unescaping cookies behind the scenes.
6619
6620 =item B<-value>
6621
6622 The value of the cookie.  This can be any scalar value,
6623 array reference, or even associative array reference.  For example,
6624 you can store an entire associative array into a cookie this way:
6625
6626         $cookie=cookie(-name=>'family information',
6627                                -value=>\%childrens_ages);
6628
6629 =item B<-path>
6630
6631 The optional partial path for which this cookie will be valid, as described
6632 above.
6633
6634 =item B<-domain>
6635
6636 The optional partial domain for which this cookie will be valid, as described
6637 above.
6638
6639 =item B<-expires>
6640
6641 The optional expiration date for this cookie.  The format is as described
6642 in the section on the B<header()> method:
6643
6644         "+1h"  one hour from now
6645
6646 =item B<-secure>
6647
6648 If set to true, this cookie will only be used within a secure
6649 SSL session.
6650
6651 =back
6652
6653 The cookie created by cookie() must be incorporated into the HTTP
6654 header within the string returned by the header() method:
6655
6656         print header(-cookie=>$my_cookie);
6657
6658 To create multiple cookies, give header() an array reference:
6659
6660         $cookie1 = cookie(-name=>'riddle_name',
6661                                   -value=>"The Sphynx's Question");
6662         $cookie2 = cookie(-name=>'answers',
6663                                   -value=>\%answers);
6664         print header(-cookie=>[$cookie1,$cookie2]);
6665
6666 To retrieve a cookie, request it by name by calling cookie() method
6667 without the B<-value> parameter:
6668
6669         use CGI;
6670         $query = new CGI;
6671         $riddle = cookie('riddle_name');
6672         %answers = cookie('answers');
6673
6674 Cookies created with a single scalar value, such as the "riddle_name"
6675 cookie, will be returned in that form.  Cookies with array and hash
6676 values can also be retrieved.
6677
6678 The cookie and CGI namespaces are separate.  If you have a parameter
6679 named 'answers' and a cookie named 'answers', the values retrieved by
6680 param() and cookie() are independent of each other.  However, it's
6681 simple to turn a CGI parameter into a cookie, and vice-versa:
6682
6683    # turn a CGI parameter into a cookie
6684    $c=cookie(-name=>'answers',-value=>[param('answers')]);
6685    # vice-versa
6686    param(-name=>'answers',-value=>[cookie('answers')]);
6687
6688 If you call cookie() without any parameters, it will return a list of
6689 the names of all cookies passed to your script:
6690
6691   @cookies = cookie();
6692
6693 See the B<cookie.cgi> example script for some ideas on how to use
6694 cookies effectively.
6695
6696 =head1 WORKING WITH FRAMES
6697
6698 It's possible for CGI.pm scripts to write into several browser panels
6699 and windows using the HTML 4 frame mechanism.  There are three
6700 techniques for defining new frames programmatically:
6701
6702 =over 4
6703
6704 =item 1. Create a <Frameset> document
6705
6706 After writing out the HTTP header, instead of creating a standard
6707 HTML document using the start_html() call, create a <frameset>
6708 document that defines the frames on the page.  Specify your script(s)
6709 (with appropriate parameters) as the SRC for each of the frames.
6710
6711 There is no specific support for creating <frameset> sections
6712 in CGI.pm, but the HTML is very simple to write.  See the frame
6713 documentation in Netscape's home pages for details
6714
6715   http://home.netscape.com/assist/net_sites/frames.html
6716
6717 =item 2. Specify the destination for the document in the HTTP header
6718
6719 You may provide a B<-target> parameter to the header() method:
6720
6721     print header(-target=>'ResultsWindow');
6722
6723 This will tell the browser to load the output of your script into the
6724 frame named "ResultsWindow".  If a frame of that name doesn't already
6725 exist, the browser will pop up a new window and load your script's
6726 document into that.  There are a number of magic names that you can
6727 use for targets.  See the frame documents on Netscape's home pages for
6728 details.
6729
6730 =item 3. Specify the destination for the document in the <form> tag
6731
6732 You can specify the frame to load in the FORM tag itself.  With
6733 CGI.pm it looks like this:
6734
6735     print start_form(-target=>'ResultsWindow');
6736
6737 When your script is reinvoked by the form, its output will be loaded
6738 into the frame named "ResultsWindow".  If one doesn't already exist
6739 a new window will be created.
6740
6741 =back
6742
6743 The script "frameset.cgi" in the examples directory shows one way to
6744 create pages in which the fill-out form and the response live in
6745 side-by-side frames.
6746
6747 =head1 SUPPORT FOR JAVASCRIPT
6748
6749 Netscape versions 2.0 and higher incorporate an interpreted language
6750 called JavaScript. Internet Explorer, 3.0 and higher, supports a
6751 closely-related dialect called JScript. JavaScript isn't the same as
6752 Java, and certainly isn't at all the same as Perl, which is a great
6753 pity. JavaScript allows you to programmatically change the contents of
6754 fill-out forms, create new windows, and pop up dialog box from within
6755 Netscape itself. From the point of view of CGI scripting, JavaScript
6756 is quite useful for validating fill-out forms prior to submitting
6757 them.
6758
6759 You'll need to know JavaScript in order to use it. There are many good
6760 sources in bookstores and on the web.
6761
6762 The usual way to use JavaScript is to define a set of functions in a
6763 <SCRIPT> block inside the HTML header and then to register event
6764 handlers in the various elements of the page. Events include such
6765 things as the mouse passing over a form element, a button being
6766 clicked, the contents of a text field changing, or a form being
6767 submitted. When an event occurs that involves an element that has
6768 registered an event handler, its associated JavaScript code gets
6769 called.
6770
6771 The elements that can register event handlers include the <BODY> of an
6772 HTML document, hypertext links, all the various elements of a fill-out
6773 form, and the form itself. There are a large number of events, and
6774 each applies only to the elements for which it is relevant. Here is a
6775 partial list:
6776
6777 =over 4
6778
6779 =item B<onLoad>
6780
6781 The browser is loading the current document. Valid in:
6782
6783      + The HTML <BODY> section only.
6784
6785 =item B<onUnload>
6786
6787 The browser is closing the current page or frame. Valid for:
6788
6789      + The HTML <BODY> section only.
6790
6791 =item B<onSubmit>
6792
6793 The user has pressed the submit button of a form. This event happens
6794 just before the form is submitted, and your function can return a
6795 value of false in order to abort the submission.  Valid for:
6796
6797      + Forms only.
6798
6799 =item B<onClick>
6800
6801 The mouse has clicked on an item in a fill-out form. Valid for:
6802
6803      + Buttons (including submit, reset, and image buttons)
6804      + Checkboxes
6805      + Radio buttons
6806
6807 =item B<onChange>
6808
6809 The user has changed the contents of a field. Valid for:
6810
6811      + Text fields
6812      + Text areas
6813      + Password fields
6814      + File fields
6815      + Popup Menus
6816      + Scrolling lists
6817
6818 =item B<onFocus>
6819
6820 The user has selected a field to work with. Valid for:
6821
6822      + Text fields
6823      + Text areas
6824      + Password fields
6825      + File fields
6826      + Popup Menus
6827      + Scrolling lists
6828
6829 =item B<onBlur>
6830
6831 The user has deselected a field (gone to work somewhere else).  Valid
6832 for:
6833
6834      + Text fields
6835      + Text areas
6836      + Password fields
6837      + File fields
6838      + Popup Menus
6839      + Scrolling lists
6840
6841 =item B<onSelect>
6842
6843 The user has changed the part of a text field that is selected.  Valid
6844 for:
6845
6846      + Text fields
6847      + Text areas
6848      + Password fields
6849      + File fields
6850
6851 =item B<onMouseOver>
6852
6853 The mouse has moved over an element.
6854
6855      + Text fields
6856      + Text areas
6857      + Password fields
6858      + File fields
6859      + Popup Menus
6860      + Scrolling lists
6861
6862 =item B<onMouseOut>
6863
6864 The mouse has moved off an element.
6865
6866      + Text fields
6867      + Text areas
6868      + Password fields
6869      + File fields
6870      + Popup Menus
6871      + Scrolling lists
6872
6873 =back
6874
6875 In order to register a JavaScript event handler with an HTML element,
6876 just use the event name as a parameter when you call the corresponding
6877 CGI method. For example, to have your validateAge() JavaScript code
6878 executed every time the textfield named "age" changes, generate the
6879 field like this:
6880
6881  print textfield(-name=>'age',-onChange=>"validateAge(this)");
6882
6883 This example assumes that you've already declared the validateAge()
6884 function by incorporating it into a <SCRIPT> block. The CGI.pm
6885 start_html() method provides a convenient way to create this section.
6886
6887 Similarly, you can create a form that checks itself over for
6888 consistency and alerts the user if some essential value is missing by
6889 creating it this way:
6890   print startform(-onSubmit=>"validateMe(this)");
6891
6892 See the javascript.cgi script for a demonstration of how this all
6893 works.
6894
6895
6896 =head1 LIMITED SUPPORT FOR CASCADING STYLE SHEETS
6897
6898 CGI.pm has limited support for HTML3's cascading style sheets (css).
6899 To incorporate a stylesheet into your document, pass the
6900 start_html() method a B<-style> parameter.  The value of this
6901 parameter may be a scalar, in which case it is treated as the source
6902 URL for the stylesheet, or it may be a hash reference.  In the latter
6903 case you should provide the hash with one or more of B<-src> or
6904 B<-code>.  B<-src> points to a URL where an externally-defined
6905 stylesheet can be found.  B<-code> points to a scalar value to be
6906 incorporated into a <style> section.  Style definitions in B<-code>
6907 override similarly-named ones in B<-src>, hence the name "cascading."
6908
6909 You may also specify the type of the stylesheet by adding the optional
6910 B<-type> parameter to the hash pointed to by B<-style>.  If not
6911 specified, the style defaults to 'text/css'.
6912
6913 To refer to a style within the body of your document, add the
6914 B<-class> parameter to any HTML element:
6915
6916     print h1({-class=>'Fancy'},'Welcome to the Party');
6917
6918 Or define styles on the fly with the B<-style> parameter:
6919
6920     print h1({-style=>'Color: red;'},'Welcome to Hell');
6921
6922 You may also use the new B<span()> element to apply a style to a
6923 section of text:
6924
6925     print span({-style=>'Color: red;'},
6926                h1('Welcome to Hell'),
6927                "Where did that handbasket get to?"
6928                );
6929
6930 Note that you must import the ":html3" definitions to have the
6931 B<span()> method available.  Here's a quick and dirty example of using
6932 CSS's.  See the CSS specification at
6933 http://www.w3.org/pub/WWW/TR/Wd-css-1.html for more information.
6934
6935     use CGI qw/:standard :html3/;
6936
6937     #here's a stylesheet incorporated directly into the page
6938     $newStyle=<<END;
6939     <!--
6940     P.Tip {
6941         margin-right: 50pt;
6942         margin-left: 50pt;
6943         color: red;
6944     }
6945     P.Alert {
6946         font-size: 30pt;
6947         font-family: sans-serif;
6948       color: red;
6949     }
6950     -->
6951     END
6952     print header();
6953     print start_html( -title=>'CGI with Style',
6954                       -style=>{-src=>'http://www.capricorn.com/style/st1.css',
6955                                -code=>$newStyle}
6956                      );
6957     print h1('CGI with Style'),
6958           p({-class=>'Tip'},
6959             "Better read the cascading style sheet spec before playing with this!"),
6960           span({-style=>'color: magenta'},
6961                "Look Mom, no hands!",
6962                p(),
6963                "Whooo wee!"
6964                );
6965     print end_html;
6966
6967 Pass an array reference to B<-code> or B<-src> in order to incorporate
6968 multiple stylesheets into your document.
6969
6970 Should you wish to incorporate a verbatim stylesheet that includes
6971 arbitrary formatting in the header, you may pass a -verbatim tag to
6972 the -style hash, as follows:
6973
6974 print start_html (-STYLE  =>  {-verbatim => '@import
6975 url("/server-common/css/'.$cssFile.'");',
6976                       -src      =>  '/server-common/css/core.css'});
6977 </blockquote></pre>
6978
6979
6980 This will generate an HTML header that contains this:
6981
6982  <link rel="stylesheet" type="text/css"  href="/server-common/css/core.css">
6983    <style type="text/css">
6984    @import url("/server-common/css/main.css");
6985    </style>
6986
6987 Any additional arguments passed in the -style value will be
6988 incorporated into the <link> tag.  For example:
6989
6990  start_html(-style=>{-src=>['/styles/print.css','/styles/layout.css'],
6991                           -media => 'all'});
6992
6993 This will give:
6994
6995  <link rel="stylesheet" type="text/css" href="/styles/print.css" media="all"/>
6996  <link rel="stylesheet" type="text/css" href="/styles/layout.css" media="all"/>
6997
6998 <p>
6999
7000 To make more complicated <link> tags, use the Link() function
7001 and pass it to start_html() in the -head argument, as in:
7002
7003   @h = (Link({-rel=>'stylesheet',-type=>'text/css',-src=>'/ss/ss.css',-media=>'all'}),
7004         Link({-rel=>'stylesheet',-type=>'text/css',-src=>'/ss/fred.css',-media=>'paper'}));
7005   print start_html({-head=>\@h})
7006
7007 =head1 DEBUGGING
7008
7009 If you are running the script from the command line or in the perl
7010 debugger, you can pass the script a list of keywords or
7011 parameter=value pairs on the command line or from standard input (you
7012 don't have to worry about tricking your script into reading from
7013 environment variables).  You can pass keywords like this:
7014
7015     your_script.pl keyword1 keyword2 keyword3
7016
7017 or this:
7018
7019    your_script.pl keyword1+keyword2+keyword3
7020
7021 or this:
7022
7023     your_script.pl name1=value1 name2=value2
7024
7025 or this:
7026
7027     your_script.pl name1=value1&name2=value2
7028
7029 To turn off this feature, use the -no_debug pragma.
7030
7031 To test the POST method, you may enable full debugging with the -debug
7032 pragma.  This will allow you to feed newline-delimited name=value
7033 pairs to the script on standard input.
7034
7035 When debugging, you can use quotes and backslashes to escape
7036 characters in the familiar shell manner, letting you place
7037 spaces and other funny characters in your parameter=value
7038 pairs:
7039
7040    your_script.pl "name1='I am a long value'" "name2=two\ words"
7041
7042 Finally, you can set the path info for the script by prefixing the first
7043 name/value parameter with the path followed by a question mark (?):
7044
7045     your_script.pl /your/path/here?name1=value1&name2=value2
7046
7047 =head2 DUMPING OUT ALL THE NAME/VALUE PAIRS
7048
7049 The Dump() method produces a string consisting of all the query's
7050 name/value pairs formatted nicely as a nested list.  This is useful
7051 for debugging purposes:
7052
7053     print Dump
7054
7055
7056 Produces something that looks like:
7057
7058     <ul>
7059     <li>name1
7060         <ul>
7061         <li>value1
7062         <li>value2
7063         </ul>
7064     <li>name2
7065         <ul>
7066         <li>value1
7067         </ul>
7068     </ul>
7069
7070 As a shortcut, you can interpolate the entire CGI object into a string
7071 and it will be replaced with the a nice HTML dump shown above:
7072
7073     $query=new CGI;
7074     print "<h2>Current Values</h2> $query\n";
7075
7076 =head1 FETCHING ENVIRONMENT VARIABLES
7077
7078 Some of the more useful environment variables can be fetched
7079 through this interface.  The methods are as follows:
7080
7081 =over 4
7082
7083 =item B<Accept()>
7084
7085 Return a list of MIME types that the remote browser accepts. If you
7086 give this method a single argument corresponding to a MIME type, as in
7087 Accept('text/html'), it will return a floating point value
7088 corresponding to the browser's preference for this type from 0.0
7089 (don't want) to 1.0.  Glob types (e.g. text/*) in the browser's accept
7090 list are handled correctly.
7091
7092 Note that the capitalization changed between version 2.43 and 2.44 in
7093 order to avoid conflict with Perl's accept() function.
7094
7095 =item B<raw_cookie()>
7096
7097 Returns the HTTP_COOKIE variable, an HTTP extension implemented by
7098 Netscape browsers version 1.1 and higher, and all versions of Internet
7099 Explorer.  Cookies have a special format, and this method call just
7100 returns the raw form (?cookie dough).  See cookie() for ways of
7101 setting and retrieving cooked cookies.
7102
7103 Called with no parameters, raw_cookie() returns the packed cookie
7104 structure.  You can separate it into individual cookies by splitting
7105 on the character sequence "; ".  Called with the name of a cookie,
7106 retrieves the B<unescaped> form of the cookie.  You can use the
7107 regular cookie() method to get the names, or use the raw_fetch()
7108 method from the CGI::Cookie module.
7109
7110 =item B<user_agent()>
7111
7112 Returns the HTTP_USER_AGENT variable.  If you give
7113 this method a single argument, it will attempt to
7114 pattern match on it, allowing you to do something
7115 like user_agent(netscape);
7116
7117 =item B<path_info()>
7118
7119 Returns additional path information from the script URL.
7120 E.G. fetching /cgi-bin/your_script/additional/stuff will result in
7121 path_info() returning "/additional/stuff".
7122
7123 NOTE: The Microsoft Internet Information Server
7124 is broken with respect to additional path information.  If
7125 you use the Perl DLL library, the IIS server will attempt to
7126 execute the additional path information as a Perl script.
7127 If you use the ordinary file associations mapping, the
7128 path information will be present in the environment,
7129 but incorrect.  The best thing to do is to avoid using additional
7130 path information in CGI scripts destined for use with IIS.
7131
7132 =item B<path_translated()>
7133
7134 As per path_info() but returns the additional
7135 path information translated into a physical path, e.g.
7136 "/usr/local/etc/httpd/htdocs/additional/stuff".
7137
7138 The Microsoft IIS is broken with respect to the translated
7139 path as well.
7140
7141 =item B<remote_host()>
7142
7143 Returns either the remote host name or IP address.
7144 if the former is unavailable.
7145
7146 =item B<script_name()>
7147 Return the script name as a partial URL, for self-refering
7148 scripts.
7149
7150 =item B<referer()>
7151
7152 Return the URL of the page the browser was viewing
7153 prior to fetching your script.  Not available for all
7154 browsers.
7155
7156 =item B<auth_type ()>
7157
7158 Return the authorization/verification method in use for this
7159 script, if any.
7160
7161 =item B<server_name ()>
7162
7163 Returns the name of the server, usually the machine's host
7164 name.
7165
7166 =item B<virtual_host ()>
7167
7168 When using virtual hosts, returns the name of the host that
7169 the browser attempted to contact
7170
7171 =item B<server_port ()>
7172
7173 Return the port that the server is listening on.
7174
7175 =item B<virtual_port ()>
7176
7177 Like server_port() except that it takes virtual hosts into account.
7178 Use this when running with virtual hosts.
7179
7180 =item B<server_software ()>
7181
7182 Returns the server software and version number.
7183
7184 =item B<remote_user ()>
7185
7186 Return the authorization/verification name used for user
7187 verification, if this script is protected.
7188
7189 =item B<user_name ()>
7190
7191 Attempt to obtain the remote user's name, using a variety of different
7192 techniques.  This only works with older browsers such as Mosaic.
7193 Newer browsers do not report the user name for privacy reasons!
7194
7195 =item B<request_method()>
7196
7197 Returns the method used to access your script, usually
7198 one of 'POST', 'GET' or 'HEAD'.
7199
7200 =item B<content_type()>
7201
7202 Returns the content_type of data submitted in a POST, generally
7203 multipart/form-data or application/x-www-form-urlencoded
7204
7205 =item B<http()>
7206
7207 Called with no arguments returns the list of HTTP environment
7208 variables, including such things as HTTP_USER_AGENT,
7209 HTTP_ACCEPT_LANGUAGE, and HTTP_ACCEPT_CHARSET, corresponding to the
7210 like-named HTTP header fields in the request.  Called with the name of
7211 an HTTP header field, returns its value.  Capitalization and the use
7212 of hyphens versus underscores are not significant.
7213
7214 For example, all three of these examples are equivalent:
7215
7216    $requested_language = http('Accept-language');
7217    $requested_language = http('Accept_language');
7218    $requested_language = http('HTTP_ACCEPT_LANGUAGE');
7219
7220 =item B<https()>
7221
7222 The same as I<http()>, but operates on the HTTPS environment variables
7223 present when the SSL protocol is in effect.  Can be used to determine
7224 whether SSL is turned on.
7225
7226 =back
7227
7228 =head1 USING NPH SCRIPTS
7229
7230 NPH, or "no-parsed-header", scripts bypass the server completely by
7231 sending the complete HTTP header directly to the browser.  This has
7232 slight performance benefits, but is of most use for taking advantage
7233 of HTTP extensions that are not directly supported by your server,
7234 such as server push and PICS headers.
7235
7236 Servers use a variety of conventions for designating CGI scripts as
7237 NPH.  Many Unix servers look at the beginning of the script's name for
7238 the prefix "nph-".  The Macintosh WebSTAR server and Microsoft's
7239 Internet Information Server, in contrast, try to decide whether a
7240 program is an NPH script by examining the first line of script output.
7241
7242
7243 CGI.pm supports NPH scripts with a special NPH mode.  When in this
7244 mode, CGI.pm will output the necessary extra header information when
7245 the header() and redirect() methods are
7246 called.
7247
7248 The Microsoft Internet Information Server requires NPH mode.  As of
7249 version 2.30, CGI.pm will automatically detect when the script is
7250 running under IIS and put itself into this mode.  You do not need to
7251 do this manually, although it won't hurt anything if you do.  However,
7252 note that if you have applied Service Pack 6, much of the
7253 functionality of NPH scripts, including the ability to redirect while
7254 setting a cookie, b<do not work at all> on IIS without a special patch
7255 from Microsoft.  See
7256 http://support.microsoft.com/support/kb/articles/Q280/3/41.ASP:
7257 Non-Parsed Headers Stripped From CGI Applications That Have nph-
7258 Prefix in Name.
7259
7260 =over 4
7261
7262 =item In the B<use> statement
7263
7264 Simply add the "-nph" pragmato the list of symbols to be imported into
7265 your script:
7266
7267       use CGI qw(:standard -nph)
7268
7269 =item By calling the B<nph()> method:
7270
7271 Call B<nph()> with a non-zero parameter at any point after using CGI.pm in your program.
7272
7273       CGI->nph(1)
7274
7275 =item By using B<-nph> parameters
7276
7277 in the B<header()> and B<redirect()>  statements:
7278
7279       print header(-nph=>1);
7280
7281 =back
7282
7283 =head1 Server Push
7284
7285 CGI.pm provides four simple functions for producing multipart
7286 documents of the type needed to implement server push.  These
7287 functions were graciously provided by Ed Jordan <ed@fidalgo.net>.  To
7288 import these into your namespace, you must import the ":push" set.
7289 You are also advised to put the script into NPH mode and to set $| to
7290 1 to avoid buffering problems.
7291
7292 Here is a simple script that demonstrates server push:
7293
7294   #!/usr/local/bin/perl
7295   use CGI qw/:push -nph/;
7296   $| = 1;
7297   print multipart_init(-boundary=>'----here we go!');
7298   foreach (0 .. 4) {
7299       print multipart_start(-type=>'text/plain'),
7300             "The current time is ",scalar(localtime),"\n";
7301       if ($_ < 4) {
7302               print multipart_end;
7303       } else {
7304               print multipart_final;
7305       }
7306       sleep 1;
7307   }
7308
7309 This script initializes server push by calling B<multipart_init()>.
7310 It then enters a loop in which it begins a new multipart section by
7311 calling B<multipart_start()>, prints the current local time,
7312 and ends a multipart section with B<multipart_end()>.  It then sleeps
7313 a second, and begins again. On the final iteration, it ends the
7314 multipart section with B<multipart_final()> rather than with
7315 B<multipart_end()>.
7316
7317 =over 4
7318
7319 =item multipart_init()
7320
7321   multipart_init(-boundary=>$boundary);
7322
7323 Initialize the multipart system.  The -boundary argument specifies
7324 what MIME boundary string to use to separate parts of the document.
7325 If not provided, CGI.pm chooses a reasonable boundary for you.
7326
7327 =item multipart_start()
7328
7329   multipart_start(-type=>$type)
7330
7331 Start a new part of the multipart document using the specified MIME
7332 type.  If not specified, text/html is assumed.
7333
7334 =item multipart_end()
7335
7336   multipart_end()
7337
7338 End a part.  You must remember to call multipart_end() once for each
7339 multipart_start(), except at the end of the last part of the multipart
7340 document when multipart_final() should be called instead of multipart_end().
7341
7342 =item multipart_final()
7343
7344   multipart_final()
7345
7346 End all parts.  You should call multipart_final() rather than
7347 multipart_end() at the end of the last part of the multipart document.
7348
7349 =back
7350
7351 Users interested in server push applications should also have a look
7352 at the CGI::Push module.
7353
7354 Only Netscape Navigator supports server push.  Internet Explorer
7355 browsers do not.
7356
7357 =head1 Avoiding Denial of Service Attacks
7358
7359 A potential problem with CGI.pm is that, by default, it attempts to
7360 process form POSTings no matter how large they are.  A wily hacker
7361 could attack your site by sending a CGI script a huge POST of many
7362 megabytes.  CGI.pm will attempt to read the entire POST into a
7363 variable, growing hugely in size until it runs out of memory.  While
7364 the script attempts to allocate the memory the system may slow down
7365 dramatically.  This is a form of denial of service attack.
7366
7367 Another possible attack is for the remote user to force CGI.pm to
7368 accept a huge file upload.  CGI.pm will accept the upload and store it
7369 in a temporary directory even if your script doesn't expect to receive
7370 an uploaded file.  CGI.pm will delete the file automatically when it
7371 terminates, but in the meantime the remote user may have filled up the
7372 server's disk space, causing problems for other programs.
7373
7374 The best way to avoid denial of service attacks is to limit the amount
7375 of memory, CPU time and disk space that CGI scripts can use.  Some Web
7376 servers come with built-in facilities to accomplish this. In other
7377 cases, you can use the shell I<limit> or I<ulimit>
7378 commands to put ceilings on CGI resource usage.
7379
7380
7381 CGI.pm also has some simple built-in protections against denial of
7382 service attacks, but you must activate them before you can use them.
7383 These take the form of two global variables in the CGI name space:
7384
7385 =over 4
7386
7387 =item B<$CGI::POST_MAX>
7388
7389 If set to a non-negative integer, this variable puts a ceiling
7390 on the size of POSTings, in bytes.  If CGI.pm detects a POST
7391 that is greater than the ceiling, it will immediately exit with an error
7392 message.  This value will affect both ordinary POSTs and
7393 multipart POSTs, meaning that it limits the maximum size of file
7394 uploads as well.  You should set this to a reasonably high
7395 value, such as 1 megabyte.
7396
7397 =item B<$CGI::DISABLE_UPLOADS>
7398
7399 If set to a non-zero value, this will disable file uploads
7400 completely.  Other fill-out form values will work as usual.
7401
7402 =back
7403
7404 You can use these variables in either of two ways.
7405
7406 =over 4
7407
7408 =item B<1. On a script-by-script basis>
7409
7410 Set the variable at the top of the script, right after the "use" statement:
7411
7412     use CGI qw/:standard/;
7413     use CGI::Carp 'fatalsToBrowser';
7414     $CGI::POST_MAX=1024 * 100;  # max 100K posts
7415     $CGI::DISABLE_UPLOADS = 1;  # no uploads
7416
7417 =item B<2. Globally for all scripts>
7418
7419 Open up CGI.pm, find the definitions for $POST_MAX and
7420 $DISABLE_UPLOADS, and set them to the desired values.  You'll
7421 find them towards the top of the file in a subroutine named
7422 initialize_globals().
7423
7424 =back
7425
7426 An attempt to send a POST larger than $POST_MAX bytes will cause
7427 I<param()> to return an empty CGI parameter list.  You can test for
7428 this event by checking I<cgi_error()>, either after you create the CGI
7429 object or, if you are using the function-oriented interface, call
7430 <param()> for the first time.  If the POST was intercepted, then
7431 cgi_error() will return the message "413 POST too large".
7432
7433 This error message is actually defined by the HTTP protocol, and is
7434 designed to be returned to the browser as the CGI script's status
7435  code.  For example:
7436
7437    $uploaded_file = param('upload');
7438    if (!$uploaded_file && cgi_error()) {
7439       print header(-status=>cgi_error());
7440       exit 0;
7441    }
7442
7443 However it isn't clear that any browser currently knows what to do
7444 with this status code.  It might be better just to create an
7445 HTML page that warns the user of the problem.
7446
7447 =head1 COMPATIBILITY WITH CGI-LIB.PL
7448
7449 To make it easier to port existing programs that use cgi-lib.pl the
7450 compatibility routine "ReadParse" is provided.  Porting is simple:
7451
7452 OLD VERSION
7453     require "cgi-lib.pl";
7454     &ReadParse;
7455     print "The value of the antique is $in{antique}.\n";
7456
7457 NEW VERSION
7458     use CGI;
7459     CGI::ReadParse();
7460     print "The value of the antique is $in{antique}.\n";
7461
7462 CGI.pm's ReadParse() routine creates a tied variable named %in,
7463 which can be accessed to obtain the query variables.  Like
7464 ReadParse, you can also provide your own variable.  Infrequently
7465 used features of ReadParse, such as the creation of @in and $in
7466 variables, are not supported.
7467
7468 Once you use ReadParse, you can retrieve the query object itself
7469 this way:
7470
7471     $q = $in{CGI};
7472     print textfield(-name=>'wow',
7473                         -value=>'does this really work?');
7474
7475 This allows you to start using the more interesting features
7476 of CGI.pm without rewriting your old scripts from scratch.
7477
7478 =head1 AUTHOR INFORMATION
7479
7480 Copyright 1995-1998, Lincoln D. Stein.  All rights reserved.
7481
7482 This library is free software; you can redistribute it and/or modify
7483 it under the same terms as Perl itself.
7484
7485 Address bug reports and comments to: lstein@cshl.org.  When sending
7486 bug reports, please provide the version of CGI.pm, the version of
7487 Perl, the name and version of your Web server, and the name and
7488 version of the operating system you are using.  If the problem is even
7489 remotely browser dependent, please provide information about the
7490 affected browers as well.
7491
7492 =head1 CREDITS
7493
7494 Thanks very much to:
7495
7496 =over 4
7497
7498 =item Matt Heffron (heffron@falstaff.css.beckman.com)
7499
7500 =item James Taylor (james.taylor@srs.gov)
7501
7502 =item Scott Anguish <sanguish@digifix.com>
7503
7504 =item Mike Jewell (mlj3u@virginia.edu)
7505
7506 =item Timothy Shimmin (tes@kbs.citri.edu.au)
7507
7508 =item Joergen Haegg (jh@axis.se)
7509
7510 =item Laurent Delfosse (delfosse@delfosse.com)
7511
7512 =item Richard Resnick (applepi1@aol.com)
7513
7514 =item Craig Bishop (csb@barwonwater.vic.gov.au)
7515
7516 =item Tony Curtis (tc@vcpc.univie.ac.at)
7517
7518 =item Tim Bunce (Tim.Bunce@ig.co.uk)
7519
7520 =item Tom Christiansen (tchrist@convex.com)
7521
7522 =item Andreas Koenig (k@franz.ww.TU-Berlin.DE)
7523
7524 =item Tim MacKenzie (Tim.MacKenzie@fulcrum.com.au)
7525
7526 =item Kevin B. Hendricks (kbhend@dogwood.tyler.wm.edu)
7527
7528 =item Stephen Dahmen (joyfire@inxpress.net)
7529
7530 =item Ed Jordan (ed@fidalgo.net)
7531
7532 =item David Alan Pisoni (david@cnation.com)
7533
7534 =item Doug MacEachern (dougm@opengroup.org)
7535
7536 =item Robin Houston (robin@oneworld.org)
7537
7538 =item ...and many many more...
7539
7540 for suggestions and bug fixes.
7541
7542 =back
7543
7544 =head1 A COMPLETE EXAMPLE OF A SIMPLE FORM-BASED SCRIPT
7545
7546
7547         #!/usr/local/bin/perl
7548
7549         use CGI ':standard';
7550
7551         print header;
7552         print start_html("Example CGI.pm Form");
7553         print "<h1> Example CGI.pm Form</h1>\n";
7554         print_prompt();
7555         do_work();
7556         print_tail();
7557         print end_html;
7558
7559         sub print_prompt {
7560            print start_form;
7561            print "<em>What's your name?</em><br>";
7562            print textfield('name');
7563            print checkbox('Not my real name');
7564
7565            print "<p><em>Where can you find English Sparrows?</em><br>";
7566            print checkbox_group(
7567                                  -name=>'Sparrow locations',
7568                                  -values=>[England,France,Spain,Asia,Hoboken],
7569                                  -linebreak=>'yes',
7570                                  -defaults=>[England,Asia]);
7571
7572            print "<p><em>How far can they fly?</em><br>",
7573                 radio_group(
7574                         -name=>'how far',
7575                         -values=>['10 ft','1 mile','10 miles','real far'],
7576                         -default=>'1 mile');
7577
7578            print "<p><em>What's your favorite color?</em>  ";
7579            print popup_menu(-name=>'Color',
7580                                     -values=>['black','brown','red','yellow'],
7581                                     -default=>'red');
7582
7583            print hidden('Reference','Monty Python and the Holy Grail');
7584
7585            print "<p><em>What have you got there?</em><br>";
7586            print scrolling_list(
7587                          -name=>'possessions',
7588                          -values=>['A Coconut','A Grail','An Icon',
7589                                    'A Sword','A Ticket'],
7590                          -size=>5,
7591                          -multiple=>'true');
7592
7593            print "<p><em>Any parting comments?</em><br>";
7594            print textarea(-name=>'Comments',
7595                                   -rows=>10,
7596                                   -columns=>50);
7597
7598            print "<p>",reset;
7599            print submit('Action','Shout');
7600            print submit('Action','Scream');
7601            print endform;
7602            print "<hr>\n";
7603         }
7604
7605         sub do_work {
7606            my(@values,$key);
7607
7608            print "<h2>Here are the current settings in this form</h2>";
7609
7610            foreach $key (param) {
7611               print "<strong>$key</strong> -> ";
7612               @values = param($key);
7613               print join(", ",@values),"<br>\n";
7614           }
7615         }
7616
7617         sub print_tail {
7618            print <<END;
7619         <hr>
7620         <address>Lincoln D. Stein</address><br>
7621         <a href="/">Home Page</a>
7622         END
7623         }
7624
7625 =head1 BUGS
7626
7627 Please report them.
7628
7629 =head1 SEE ALSO
7630
7631 L<CGI::Carp>, L<CGI::Fast>, L<CGI::Pretty>
7632
7633 =cut
7634