lib/AutoSplit.pm

   1 package AutoSplit;
   2
   3 use 5.005_64;
   4 use Exporter ();
   5 use Config qw(%Config);
   6 use Carp qw(carp);
   7 use File::Basename ();
   8 use File::Path qw(mkpath);
   9 use File::Spec::Functions qw(curdir catfile);
  10 use strict;
  11 our($VERSION, @ISA, @EXPORT, @EXPORT_OK, $Verbose, $Keep, $Maxlen,
  12     $CheckForAutoloader, $CheckModTime);
  13
  14 $VERSION = "1.0305";
  15 @ISA = qw(Exporter);
  16 @EXPORT = qw(&autosplit &autosplit_lib_modules);
  17 @EXPORT_OK = qw($Verbose $Keep $Maxlen $CheckForAutoloader $CheckModTime);
  18
  19 =head1 NAME
  20
  21 AutoSplit - split a package for autoloading
  22
  23 =head1 SYNOPSIS
  24
  25  autosplit($file, $dir, $keep, $check, $modtime);
  26
  27  autosplit_lib_modules(@modules);
  28
  29 =head1 DESCRIPTION
  30
  31 This function will split up your program into files that the AutoLoader
  32 module can handle. It is used by both the standard perl libraries and by
  33 the MakeMaker utility, to automatically configure libraries for autoloading.
  34
  35 The C<autosplit> interface splits the specified file into a hierarchy
  36 rooted at the directory C<$dir>. It creates directories as needed to reflect
  37 class hierarchy, and creates the file F<autosplit.ix>. This file acts as
  38 both forward declaration of all package routines, and as timestamp for the
  39 last update of the hierarchy.
  40
  41 The remaining three arguments to C<autosplit> govern other options to
  42 the autosplitter.
  43
  44 =over 2
  45
  46 =item $keep
  47
  48 If the third argument, I<$keep>, is false, then any
  49 pre-existing C<*.al> files in the autoload directory are removed if
  50 they are no longer part of the module (obsoleted functions).
  51 $keep defaults to 0.
  52
  53 =item $check
  54
  55 The
  56 fourth argument, I<$check>, instructs C<autosplit> to check the module
  57 currently being split to ensure that it does include a C<use>
  58 specification for the AutoLoader module, and skips the module if
  59 AutoLoader is not detected.
  60 $check defaults to 1.
  61
  62 =item $modtime
  63
  64 Lastly, the I<$modtime> argument specifies
  65 that C<autosplit> is to check the modification time of the module
  66 against that of the C<autosplit.ix> file, and only split the module if
  67 it is newer.
  68 $modtime defaults to 1.
  69
  70 =back
  71
  72 Typical use of AutoSplit in the perl MakeMaker utility is via the command-line
  73 with:
  74
  75  perl -e 'use AutoSplit; autosplit($ARGV[0], $ARGV[1], 0, 1, 1)'
  76
  77 Defined as a Make macro, it is invoked with file and directory arguments;
  78 C<autosplit> will split the specified file into the specified directory and
  79 delete obsolete C<.al> files, after checking first that the module does use
  80 the AutoLoader, and ensuring that the module is not already currently split
  81 in its current form (the modtime test).
  82
  83 The C<autosplit_lib_modules> form is used in the building of perl. It takes
  84 as input a list of files (modules) that are assumed to reside in a directory
  85 B<lib> relative to the current directory. Each file is sent to the
  86 autosplitter one at a time, to be split into the directory B<lib/auto>.
  87
  88 In both usages of the autosplitter, only subroutines defined following the
  89 perl I<__END__> token are split out into separate files. Some
  90 routines may be placed prior to this marker to force their immediate loading
  91 and parsing.
  92
  93 =head2 Multiple packages
  94
  95 As of version 1.01 of the AutoSplit module it is possible to have
  96 multiple packages within a single file. Both of the following cases
  97 are supported:
  98
  99    package NAME;
 100    __END__
 101    sub AAA { ... }
 102    package NAME::option1;
 103    sub BBB { ... }
 104    package NAME::option2;
 105    sub BBB { ... }
 106
 107    package NAME;
 108    __END__
 109    sub AAA { ... }
 110    sub NAME::option1::BBB { ... }
 111    sub NAME::option2::BBB { ... }
 112
 113 =head1 DIAGNOSTICS
 114
 115 C<AutoSplit> will inform the user if it is necessary to create the
 116 top-level directory specified in the invocation. It is preferred that
 117 the script or installation process that invokes C<AutoSplit> have
 118 created the full directory path ahead of time. This warning may
 119 indicate that the module is being split into an incorrect path.
 120
 121 C<AutoSplit> will warn the user of all subroutines whose name causes
 122 potential file naming conflicts on machines with drastically limited
 123 (8 characters or less) file name length. Since the subroutine name is
 124 used as the file name, these warnings can aid in portability to such
 125 systems.
 126
 127 Warnings are issued and the file skipped if C<AutoSplit> cannot locate
 128 either the I<__END__> marker or a "package Name;"-style specification.
 129
 130 C<AutoSplit> will also emit general diagnostics for inability to
 131 create directories or files.
 132
 133 =cut
 134
 135 # for portability warn about names longer than $maxlen
 136 $Maxlen  = 8;   # 8 for dos, 11 (14-".al") for SYSVR3
 137 $Verbose = 1;   # 0=none, 1=minimal, 2=list .al files
 138 $Keep    = 0;
 139 $CheckForAutoloader = 1;
 140 $CheckModTime = 1;
 141
 142 my $IndexFile = "autosplit.ix"; # file also serves as timestamp
 143 my $maxflen = 255;
 144 $maxflen = 14 if $Config{'d_flexfnam'} ne 'define';
 145 if (defined (&Dos::UseLFN)) {
 146      $maxflen = Dos::UseLFN() ? 255 : 11;
 147 }
 148 my $Is_VMS = ($^O eq 'VMS');
 149
 150 # allow checking for valid ': attrlist' attachments
 151 my $nested;
 152 $nested = qr{ \( (?: (?> [^()]+ ) | (??{ $nested }) )* \) }x;
 153 my $one_attr = qr{ (?> (?! \d) \w+ (?:$nested)? ) (?:\s*\:\s*|\s+(?!\:)) }x;
 154 my $attr_list = qr{ \s* : \s* (?: $one_attr )* }x;
 155
 156
 157
 158 sub autosplit{
 159     my($file, $autodir,  $keep, $ckal, $ckmt) = @_;
 160     # $file    - the perl source file to be split (after __END__)
 161     # $autodir - the ".../auto" dir below which to write split subs
 162     # Handle optional flags:
 163     $keep = $Keep unless defined $keep;
 164     $ckal = $CheckForAutoloader unless defined $ckal;
 165     $ckmt = $CheckModTime unless defined $ckmt;
 166     autosplit_file($file, $autodir, $keep, $ckal, $ckmt);
 167 }
 168
 169
 170 # This function is used during perl building/installation
 171 # ./miniperl -e 'use AutoSplit; autosplit_lib_modules(@ARGV)' ...
 172
 173 sub autosplit_lib_modules{
 174     my(@modules) = @_; # list of Module names
 175
 176     while(defined($_ = shift @modules)){
 177         while (m#(.*?[^:])::([^:].*)#) { # in case specified as ABC::XYZ
 178             $_ = catfile($1, $2);
 179         }
 180         s|\\|/|g;               # bug in ksh OS/2
 181         my($lib) = catfile(curdir(), "lib");
 182         s#^$lib\W+##s; # incase specified as lib/*.pm
 183         if ($Is_VMS && /[:>\]]/) { # may need to convert VMS-style filespecs
 184             my ($dir,$name) = (/(.*])(.*)/s);
 185             $dir =~ s/.*lib[\.\]]//s;
 186             $dir =~ s#[\.\]]#/#g;
 187             $_ = $dir . $name;
 188         }
 189         autosplit_file(catfile($lib, $_), catfile($lib, "auto"),
 190                        $Keep, $CheckForAutoloader, $CheckModTime);
 191     }
 192     0;
 193 }
 194
 195
 196 # private functions
 197
 198 sub autosplit_file {
 199     my($filename, $autodir, $keep, $check_for_autoloader, $check_mod_time)
 200         = @_;
 201     my(@outfiles);
 202     local($_);
 203     local($/) = "\n";
 204
 205     # where to write output files
 206     $autodir ||= catfile(curdir(), "lib", "auto");
 207     if ($Is_VMS) {
 208         ($autodir = VMS::Filespec::unixpath($autodir)) =~ s|/\z||;
 209         $filename = VMS::Filespec::unixify($filename); # may have dirs
 210     }
 211     unless (-d $autodir){
 212         mkpath($autodir,0,0755);
 213         # We should never need to create the auto dir
 214         # here. installperl (or similar) should have done
 215         # it. Expecting it to exist is a valuable sanity check against
 216         # autosplitting into some random directory by mistake.
 217         print "Warning: AutoSplit had to create top-level " .
 218             "$autodir unexpectedly.\n";
 219     }
 220
 221     # allow just a package name to be used
 222     $filename .= ".pm" unless ($filename =~ m/\.pm\z/);
 223
 224     open(IN, "<$filename") or die "AutoSplit: Can't open $filename: $!\n";
 225     my($pm_mod_time) = (stat($filename))[9];
 226     my($autoloader_seen) = 0;
 227     my($in_pod) = 0;
 228     my($def_package,$last_package,$this_package,$fnr);
 229     while (<IN>) {
 230         # Skip pod text.
 231         $fnr++;
 232         $in_pod = 1 if /^=\w/;
 233         $in_pod = 0 if /^=cut/;
 234         next if ($in_pod || /^=cut/);
 235
 236         # record last package name seen
 237         $def_package = $1 if (m/^\s*package\s+([\w:]+)\s*;/);
 238         ++$autoloader_seen if m/^\s*(use|require)\s+AutoLoader\b/;
 239         ++$autoloader_seen if m/\bISA\s*=.*\bAutoLoader\b/;
 240         last if /^__END__/;
 241     }
 242     if ($check_for_autoloader && !$autoloader_seen){
 243         print "AutoSplit skipped $filename: no AutoLoader used\n"
 244             if ($Verbose>=2);
 245         return 0;
 246     }
 247     $_ or die "Can't find __END__ in $filename\n";
 248
 249     $def_package or die "Can't find 'package Name;' in $filename\n";
 250
 251     my($modpname) = _modpname($def_package);
 252
 253     # this _has_ to match so we have a reasonable timestamp file
 254     die "Package $def_package ($modpname.pm) does not ".
 255         "match filename $filename"
 256             unless ($filename =~ m/\Q$modpname.pm\E$/ or
 257                     ($^O eq 'dos') or ($^O eq 'MSWin32') or
 258                     $Is_VMS && $filename =~ m/$modpname.pm/i);
 259
 260     my($al_idx_file) = "$autodir/$modpname/$IndexFile";
 261
 262     if ($check_mod_time){
 263         my($al_ts_time) = (stat("$al_idx_file"))[9] || 1;
 264         if ($al_ts_time >= $pm_mod_time){
 265             print "AutoSplit skipped ($al_idx_file newer than $filename)\n"
 266                 if ($Verbose >= 2);
 267             return undef;       # one undef, not a list
 268         }
 269     }
 270
 271     my($modnamedir) = catfile($autodir, $modpname);
 272     print "AutoSplitting $filename ($modnamedir)\n"
 273         if $Verbose;
 274
 275     unless (-d "$modnamedir"){
 276         mkpath("$modnamedir",0,0777);
 277     }
 278
 279     # We must try to deal with some SVR3 systems with a limit of 14
 280     # characters for file names. Sadly we *cannot* simply truncate all
 281     # file names to 14 characters on these systems because we *must*
 282     # create filenames which exactly match the names used by AutoLoader.pm.
 283     # This is a problem because some systems silently truncate the file
 284     # names while others treat long file names as an error.
 285
 286     my $Is83 = $maxflen==11;  # plain, case INSENSITIVE dos filenames
 287
 288     my(@subnames, $subname, %proto, %package);
 289     my @cache = ();
 290     my $caching = 1;
 291     $last_package = '';
 292     while (<IN>) {
 293         $fnr++;
 294         $in_pod = 1 if /^=\w/;
 295         $in_pod = 0 if /^=cut/;
 296         next if ($in_pod || /^=cut/);
 297         # the following (tempting) old coding gives big troubles if a
 298         # cut is forgotten at EOF:
 299         # next if /^=\w/ .. /^=cut/;
 300         if (/^package\s+([\w:]+)\s*;/) {
 301             $this_package = $def_package = $1;
 302         }
 303         if (/^sub\s+([\w:]+)(\s*(?:\(.*?\))?(?:$attr_list)?)/) {
 304             print OUT "# end of $last_package\::$subname\n1;\n"
 305                 if $last_package;
 306             $subname = $1;
 307             my $proto = $2 || '';
 308             if ($subname =~ s/(.*):://){
 309                 $this_package = $1;
 310             } else {
 311                 $this_package = $def_package;
 312             }
 313             my $fq_subname = "$this_package\::$subname";
 314             $package{$fq_subname} = $this_package;
 315             $proto{$fq_subname} = $proto;
 316             push(@subnames, $fq_subname);
 317             my($lname, $sname) = ($subname, substr($subname,0,$maxflen-3));
 318             $modpname = _modpname($this_package);
 319             my($modnamedir) = catfile($autodir, $modpname);
 320             mkpath("$modnamedir",0,0777);
 321             my($lpath) = catfile($modnamedir, "$lname.al");
 322             my($spath) = catfile($modnamedir, "$sname.al");
 323             my $path;
 324             if (!$Is83 and open(OUT, ">$lpath")){
 325                 $path=$lpath;
 326                 print "  writing $lpath\n" if ($Verbose>=2);
 327             } else {
 328                 open(OUT, ">$spath") or die "Can't create $spath: $!\n";
 329                 $path=$spath;
 330                 print "  writing $spath (with truncated name)\n"
 331                         if ($Verbose>=1);
 332             }
 333             push(@outfiles, $path);
 334             print OUT <<EOT;
 335 # NOTE: Derived from $filename.
 336 # Changes made here will be lost when autosplit again.
 337 # See AutoSplit.pm.
 338 package $this_package;
 339
 340 #line $fnr "$filename (autosplit into $path)"
 341 EOT
 342             print OUT @cache;
 343             @cache = ();
 344             $caching = 0;
 345         }
 346         if($caching) {
 347             push(@cache, $_) if @cache || /\S/;
 348         } else {
 349             print OUT $_;
 350         }
 351         if(/^\}/) {
 352             if($caching) {
 353                 print OUT @cache;
 354                 @cache = ();
 355             }
 356             print OUT "\n";
 357             $caching = 1;
 358         }
 359         $last_package = $this_package if defined $this_package;
 360     }
 361     if ($subname) {
 362         print OUT @cache,"1;\n# end of $last_package\::$subname\n";
 363         close(OUT);
 364     }
 365     close(IN);
 366
 367     if (!$keep){  # don't keep any obsolete *.al files in the directory
 368         my(%outfiles);
 369         # @outfiles{@outfiles} = @outfiles;
 370         # perl downcases all filenames on VMS (which upcases all filenames) so
 371         # we'd better downcase the sub name list too, or subs with upper case
 372         # letters in them will get their .al files deleted right after they're
 373         # created. (The mixed case sub name won't match the all-lowercase
 374         # filename, and so be cleaned up as a scrap file)
 375         if ($Is_VMS or $Is83) {
 376             %outfiles = map {lc($_) => lc($_) } @outfiles;
 377         } else {
 378             @outfiles{@outfiles} = @outfiles;
 379         }
 380         my(%outdirs,@outdirs);
 381         for (@outfiles) {
 382             $outdirs{File::Basename::dirname($_)}||=1;
 383         }
 384         for my $dir (keys %outdirs) {
 385             opendir(OUTDIR,$dir);
 386             foreach (sort readdir(OUTDIR)){
 387                 next unless /\.al\z/;
 388                 my($file) = catfile($dir, $_);
 389                 $file = lc $file if $Is83 or $Is_VMS;
 390                 next if $outfiles{$file};
 391                 print "  deleting $file\n" if ($Verbose>=2);
 392                 my($deleted,$thistime);  # catch all versions on VMS
 393                 do { $deleted += ($thistime = unlink $file) } while ($thistime);
 394                 carp "Unable to delete $file: $!" unless $deleted;
 395             }
 396             closedir(OUTDIR);
 397         }
 398     }
 399
 400     open(TS,">$al_idx_file") or
 401         carp "AutoSplit: unable to create timestamp file ($al_idx_file): $!";
 402     print TS "# Index created by AutoSplit for $filename\n";
 403     print TS "#    (file acts as timestamp)\n";
 404     $last_package = '';
 405     for my $fqs (@subnames) {
 406         my($subname) = $fqs;
 407         $subname =~ s/.*:://;
 408         print TS "package $package{$fqs};\n"
 409             unless $last_package eq $package{$fqs};
 410         print TS "sub $subname $proto{$fqs};\n";
 411         $last_package = $package{$fqs};
 412     }
 413     print TS "1;\n";
 414     close(TS);
 415
 416     _check_unique($filename, $Maxlen, 1, @outfiles);
 417
 418     @outfiles;
 419 }
 420
 421 sub _modpname ($) {
 422     my($package) = @_;
 423     my $modpname = $package;
 424     if ($^O eq 'MSWin32') {
 425         $modpname =~ s#::#\\#g;
 426     } else {
 427         while ($modpname =~ m#(.*?[^:])::([^:].*)#) {
 428             $modpname = catfile($1, $2);
 429         }
 430     }
 431     $modpname;
 432 }
 433
 434 sub _check_unique {
 435     my($filename, $maxlen, $warn, @outfiles) = @_;
 436     my(%notuniq) = ();
 437     my(%shorts)  = ();
 438     my(@toolong) = grep(
 439                         length(File::Basename::basename($_))
 440                         > $maxlen,
 441                         @outfiles
 442                        );
 443
 444     foreach (@toolong){
 445         my($dir) = File::Basename::dirname($_);
 446         my($file) = File::Basename::basename($_);
 447         my($trunc) = substr($file,0,$maxlen);
 448         $notuniq{$dir}{$trunc} = 1 if $shorts{$dir}{$trunc};
 449         $shorts{$dir}{$trunc} = $shorts{$dir}{$trunc} ?
 450             "$shorts{$dir}{$trunc}, $file" : $file;
 451     }
 452     if (%notuniq && $warn){
 453         print "$filename: some names are not unique when " .
 454             "truncated to $maxlen characters:\n";
 455         foreach my $dir (sort keys %notuniq){
 456             print " directory $dir:\n";
 457             foreach my $trunc (sort keys %{$notuniq{$dir}}) {
 458                 print "  $shorts{$dir}{$trunc} truncate to $trunc\n";
 459             }
 460         }
 461     }
 462 }
 463
 464 1;
 465 __END__
 466
 467 # test functions so AutoSplit.pm can be applied to itself:
 468 sub test1 ($)   { "test 1\n"; }
 469 sub test2 ($$)  { "test 2\n"; }
 470 sub test3 ($$$) { "test 3\n"; }
 471 sub testtesttesttest4_1  { "test 4\n"; }
 472 sub testtesttesttest4_2  { "duplicate test 4\n"; }
 473 sub Just::Another::test5 { "another test 5\n"; }
 474 sub test6       { return join ":", __FILE__,__LINE__; }
 475 package Yet::Another::AutoSplit;
 476 sub testtesttesttest4_1 ($)  { "another test 4\n"; }
 477 sub testtesttesttest4_2 ($$) { "another duplicate test 4\n"; }
 478 package Yet::More::Attributes;
 479 sub test_a1 ($) : locked :locked { 1; }
 480 sub test_a2 : locked { 1; }