lib/AutoLoader.pm

   1 package AutoLoader;
   2
   3 use 5.005_64;
   4 our(@EXPORT, @EXPORT_OK, $VERSION);
   5
   6 my $is_dosish;
   7 my $is_epoc;
   8 my $is_vms;
   9
  10 BEGIN {
  11     require Exporter;
  12     @EXPORT = @EXPORT = ();
  13     @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
  14     $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32';
  15     $is_epoc = $^O eq 'epoc';
  16     $is_vms = $^O eq 'VMS';
  17     $VERSION = '5.57';
  18 }
  19
  20 AUTOLOAD {
  21     my $sub = $AUTOLOAD;
  22     my $filename;
  23     # Braces used to preserve $1 et al.
  24     {
  25         # Try to find the autoloaded file from the package-qualified
  26         # name of the sub. e.g., if the sub needed is
  27         # Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
  28         # something like '/usr/lib/perl5/Getopt/Long.pm', and the
  29         # autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
  30         #
  31         # However, if @INC is a relative path, this might not work.  If,
  32         # for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
  33         # 'lib/Getopt/Long.pm', and we want to require
  34         # 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
  35         # In this case, we simple prepend the 'auto/' and let the
  36         # C<require> take care of the searching for us.
  37
  38         my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
  39         $pkg =~ s#::#/#g;
  40         if (defined($filename = $INC{"$pkg.pm"})) {
  41             $filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
  42
  43             # if the file exists, then make sure that it is a
  44             # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
  45             # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
  46             # (and failing) to find the 'lib/auto/foo/bar.al' because it
  47             # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
  48
  49             if (-r $filename) {
  50                 unless ($filename =~ m|^/|s) {
  51                     if ($is_dosish) {
  52                         unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
  53                              $filename = "./$filename";
  54                         }
  55                     }
  56                     elsif ($is_epoc) {
  57                         unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
  58                              $filename = "./$filename";
  59                         }
  60                     }elsif ($is_vms) {
  61                         # XXX todo by VMSmiths
  62                         $filename = "./$filename";
  63                     }
  64                     else {
  65                         $filename = "./$filename";
  66                     }
  67                 }
  68             }
  69             else {
  70                 $filename = undef;
  71             }
  72         }
  73         unless (defined $filename) {
  74             # let C<require> do the searching
  75             $filename = "auto/$sub.al";
  76             $filename =~ s#::#/#g;
  77         }
  78     }
  79     my $save = $@;
  80     eval { local $SIG{__DIE__}; require $filename };
  81     if ($@) {
  82         if (substr($sub,-9) eq '::DESTROY') {
  83             *$sub = sub {};
  84         } else {
  85             # The load might just have failed because the filename was too
  86             # long for some old SVR3 systems which treat long names as errors.
  87             # If we can succesfully truncate a long name then it's worth a go.
  88             # There is a slight risk that we could pick up the wrong file here
  89             # but autosplit should have warned about that when splitting.
  90             if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
  91                 eval { local $SIG{__DIE__}; require $filename };
  92             }
  93             if ($@){
  94                 $@ =~ s/ at .*\n//;
  95                 my $error = $@;
  96                 require Carp;
  97                 Carp::croak($error);
  98             }
  99         }
 100     }
 101     $@ = $save;
 102     goto &$sub;
 103 }
 104
 105 sub import {
 106     my $pkg = shift;
 107     my $callpkg = caller;
 108
 109     #
 110     # Export symbols, but not by accident of inheritance.
 111     #
 112
 113     if ($pkg eq 'AutoLoader') {
 114       local $Exporter::ExportLevel = 1;
 115       Exporter::import $pkg, @_;
 116     }
 117
 118     #
 119     # Try to find the autosplit index file.  Eg., if the call package
 120     # is POSIX, then $INC{POSIX.pm} is something like
 121     # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
 122     # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
 123     #
 124     # However, if @INC is a relative path, this might not work.  If,
 125     # for example, @INC = ('lib'), then
 126     # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
 127     # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
 128     #
 129
 130     (my $calldir = $callpkg) =~ s#::#/#g;
 131     my $path = $INC{$calldir . '.pm'};
 132     if (defined($path)) {
 133         # Try absolute path name.
 134         $path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
 135         eval { require $path; };
 136         # If that failed, try relative path with normal @INC searching.
 137         if ($@) {
 138             $path ="auto/$calldir/autosplit.ix";
 139             eval { require $path; };
 140         }
 141         if ($@) {
 142             my $error = $@;
 143             require Carp;
 144             Carp::carp($error);
 145         }
 146     }
 147 }
 148
 149 sub unimport {
 150   my $callpkg = caller;
 151   eval "package $callpkg; sub AUTOLOAD;";
 152 }
 153
 154 1;
 155
 156 __END__
 157
 158 =head1 NAME
 159
 160 AutoLoader - load subroutines only on demand
 161
 162 =head1 SYNOPSIS
 163
 164     package Foo;
 165     use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine
 166
 167     package Bar;
 168     use AutoLoader;              # don't import AUTOLOAD, define our own
 169     sub AUTOLOAD {
 170         ...
 171         $AutoLoader::AUTOLOAD = "...";
 172         goto &AutoLoader::AUTOLOAD;
 173     }
 174
 175 =head1 DESCRIPTION
 176
 177 The B<AutoLoader> module works with the B<AutoSplit> module and the
 178 C<__END__> token to defer the loading of some subroutines until they are
 179 used rather than loading them all at once.
 180
 181 To use B<AutoLoader>, the author of a module has to place the
 182 definitions of subroutines to be autoloaded after an C<__END__> token.
 183 (See L<perldata>.)  The B<AutoSplit> module can then be run manually to
 184 extract the definitions into individual files F<auto/funcname.al>.
 185
 186 B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
 187 subroutine in is called in a client module of B<AutoLoader>,
 188 B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
 189 file with a name related to the location of the file from which the
 190 client module was read.  As an example, if F<POSIX.pm> is located in
 191 F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
 192 subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
 193 the C<.al> file has the same name as the subroutine, sans package.  If
 194 such a file exists, AUTOLOAD will read and evaluate it,
 195 thus (presumably) defining the needed subroutine.  AUTOLOAD will then
 196 C<goto> the newly defined subroutine.
 197
 198 Once this process completes for a given function, it is defined, so
 199 future calls to the subroutine will bypass the AUTOLOAD mechanism.
 200
 201 =head2 Subroutine Stubs
 202
 203 In order for object method lookup and/or prototype checking to operate
 204 correctly even when methods have not yet been defined it is necessary to
 205 "forward declare" each subroutine (as in C<sub NAME;>).  See
 206 L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
 207 stubs", which are place holders with no code.
 208
 209 The AutoSplit and B<AutoLoader> modules automate the creation of forward
 210 declarations.  The AutoSplit module creates an 'index' file containing
 211 forward declarations of all the AutoSplit subroutines.  When the
 212 AutoLoader module is 'use'd it loads these declarations into its callers
 213 package.
 214
 215 Because of this mechanism it is important that B<AutoLoader> is always
 216 C<use>d and not C<require>d.
 217
 218 =head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
 219
 220 In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
 221 explicitly import it:
 222
 223     use AutoLoader 'AUTOLOAD';
 224
 225 =head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
 226
 227 Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
 228 They typically need to check for some special cases (such as constants)
 229 and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
 230
 231 Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
 232 Instead, they should define their own AUTOLOAD subroutines along these
 233 lines:
 234
 235     use AutoLoader;
 236     use Carp;
 237
 238     sub AUTOLOAD {
 239         my $sub = $AUTOLOAD;
 240         (my $constname = $sub) =~ s/.*:://;
 241         my $val = constant($constname, @_ ? $_[0] : 0);
 242         if ($! != 0) {
 243             if ($! =~ /Invalid/ || $!{EINVAL}) {
 244                 $AutoLoader::AUTOLOAD = $sub;
 245                 goto &AutoLoader::AUTOLOAD;
 246             }
 247             else {
 248                 croak "Your vendor has not defined constant $constname";
 249             }
 250         }
 251         *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
 252         goto &$sub;
 253     }
 254
 255 If any module's own AUTOLOAD subroutine has no need to fallback to the
 256 AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
 257 subroutines), then that module should not use B<AutoLoader> at all.
 258
 259 =head2 Package Lexicals
 260
 261 Package lexicals declared with C<my> in the main block of a package
 262 using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
 263 the fact that the given scope ends at the C<__END__> marker.  A module
 264 using such variables as package globals will not work properly under the
 265 B<AutoLoader>.
 266
 267 The C<vars> pragma (see L<perlmod/"vars">) may be used in such
 268 situations as an alternative to explicitly qualifying all globals with
 269 the package namespace.  Variables pre-declared with this pragma will be
 270 visible to any autoloaded routines (but will not be invisible outside
 271 the package, unfortunately).
 272
 273 =head2 Not Using AutoLoader
 274
 275 You can stop using AutoLoader by simply
 276
 277         no AutoLoader;
 278
 279 =head2 B<AutoLoader> vs. B<SelfLoader>
 280
 281 The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
 282 loading of subroutines.
 283
 284 B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
 285 While this avoids the use of a hierarchy of disk files and the
 286 associated open/close for each routine loaded, B<SelfLoader> suffers a
 287 startup speed disadvantage in the one-time parsing of the lines after
 288 C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
 289 handle multiple packages in a file.
 290
 291 B<AutoLoader> only reads code as it is requested, and in many cases
 292 should be faster, but requires a mechanism like B<AutoSplit> be used to
 293 create the individual files.  L<ExtUtils::MakeMaker> will invoke
 294 B<AutoSplit> automatically if B<AutoLoader> is used in a module source
 295 file.
 296
 297 =head1 CAVEATS
 298
 299 AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
 300 old modules which use B<AutoLoader> should be changed to the new calling
 301 style.  Typically this just means changing a require to a use, adding
 302 the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
 303 from C<@ISA>.
 304
 305 On systems with restrictions on file name length, the file corresponding
 306 to a subroutine may have a shorter name that the routine itself.  This
 307 can lead to conflicting file names.  The I<AutoSplit> package warns of
 308 these potential conflicts when used to split a module.
 309
 310 AutoLoader may fail to find the autosplit files (or even find the wrong
 311 ones) in cases where C<@INC> contains relative paths, B<and> the program
 312 does C<chdir>.
 313
 314 =head1 SEE ALSO
 315
 316 L<SelfLoader> - an autoloader that doesn't use external files.
 317
 318 =cut