lib/AutoLoader.pm

   1 package AutoLoader;
   2
   3 use 5.005_64;
   4 our(@EXPORT, @EXPORT_OK, $VERSION);
   5
   6 my $is_dosish;
   7 my $is_epoc;
   8 my $is_vms;
   9 my $is_macos;
  10
  11 BEGIN {
  12     require Exporter;
  13     @EXPORT = @EXPORT = ();
  14     @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
  15     $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32';
  16     $is_epoc = $^O eq 'epoc';
  17     $is_vms = $^O eq 'VMS';
  18     $is_macos = $^O eq 'MacOS';
  19     $VERSION = '5.58';
  20 }
  21
  22 AUTOLOAD {
  23     my $sub = $AUTOLOAD;
  24     my $filename;
  25     # Braces used to preserve $1 et al.
  26     {
  27         # Try to find the autoloaded file from the package-qualified
  28         # name of the sub. e.g., if the sub needed is
  29         # Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
  30         # something like '/usr/lib/perl5/Getopt/Long.pm', and the
  31         # autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
  32         #
  33         # However, if @INC is a relative path, this might not work.  If,
  34         # for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
  35         # 'lib/Getopt/Long.pm', and we want to require
  36         # 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
  37         # In this case, we simple prepend the 'auto/' and let the
  38         # C<require> take care of the searching for us.
  39
  40         my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
  41         $pkg =~ s#::#/#g;
  42         if (defined($filename = $INC{"$pkg.pm"})) {
  43             if ($is_macos) {
  44                 $pkg =~ tr#/#:#;
  45                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto:$pkg:$func.al#s;
  46             } else {
  47                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
  48             }
  49
  50             # if the file exists, then make sure that it is a
  51             # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
  52             # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
  53             # (and failing) to find the 'lib/auto/foo/bar.al' because it
  54             # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
  55
  56             if (-r $filename) {
  57                 unless ($filename =~ m|^/|s) {
  58                     if ($is_dosish) {
  59                         unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
  60                              $filename = "./$filename";
  61                         }
  62                     }
  63                     elsif ($is_epoc) {
  64                         unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
  65                              $filename = "./$filename";
  66                         }
  67                     }elsif ($is_vms) {
  68                         # XXX todo by VMSmiths
  69                         $filename = "./$filename";
  70                     }
  71                     elsif (!$is_macos) {
  72                         $filename = "./$filename";
  73                     }
  74                 }
  75             }
  76             else {
  77                 $filename = undef;
  78             }
  79         }
  80         unless (defined $filename) {
  81             # let C<require> do the searching
  82             $filename = "auto/$sub.al";
  83             $filename =~ s#::#/#g;
  84         }
  85     }
  86     my $save = $@;
  87     eval { local $SIG{__DIE__}; require $filename };
  88     if ($@) {
  89         if (substr($sub,-9) eq '::DESTROY') {
  90             *$sub = sub {};
  91         } else {
  92             # The load might just have failed because the filename was too
  93             # long for some old SVR3 systems which treat long names as errors.
  94             # If we can succesfully truncate a long name then it's worth a go.
  95             # There is a slight risk that we could pick up the wrong file here
  96             # but autosplit should have warned about that when splitting.
  97             if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
  98                 eval { local $SIG{__DIE__}; require $filename };
  99             }
 100             if ($@){
 101                 $@ =~ s/ at .*\n//;
 102                 my $error = $@;
 103                 require Carp;
 104                 Carp::croak($error);
 105             }
 106         }
 107     }
 108     $@ = $save;
 109     goto &$sub;
 110 }
 111
 112 sub import {
 113     my $pkg = shift;
 114     my $callpkg = caller;
 115
 116     #
 117     # Export symbols, but not by accident of inheritance.
 118     #
 119
 120     if ($pkg eq 'AutoLoader') {
 121       local $Exporter::ExportLevel = 1;
 122       Exporter::import $pkg, @_;
 123     }
 124
 125     #
 126     # Try to find the autosplit index file.  Eg., if the call package
 127     # is POSIX, then $INC{POSIX.pm} is something like
 128     # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
 129     # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
 130     #
 131     # However, if @INC is a relative path, this might not work.  If,
 132     # for example, @INC = ('lib'), then
 133     # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
 134     # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
 135     #
 136
 137     (my $calldir = $callpkg) =~ s#::#/#g;
 138     my $path = $INC{$calldir . '.pm'};
 139     if (defined($path)) {
 140         # Try absolute path name.
 141         $path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
 142         eval { require $path; };
 143         # If that failed, try relative path with normal @INC searching.
 144         if ($@) {
 145             $path ="auto/$calldir/autosplit.ix";
 146             eval { require $path; };
 147         }
 148         if ($@) {
 149             my $error = $@;
 150             require Carp;
 151             Carp::carp($error);
 152         }
 153     }
 154 }
 155
 156 sub unimport {
 157   my $callpkg = caller;
 158   eval "package $callpkg; sub AUTOLOAD;";
 159 }
 160
 161 1;
 162
 163 __END__
 164
 165 =head1 NAME
 166
 167 AutoLoader - load subroutines only on demand
 168
 169 =head1 SYNOPSIS
 170
 171     package Foo;
 172     use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine
 173
 174     package Bar;
 175     use AutoLoader;              # don't import AUTOLOAD, define our own
 176     sub AUTOLOAD {
 177         ...
 178         $AutoLoader::AUTOLOAD = "...";
 179         goto &AutoLoader::AUTOLOAD;
 180     }
 181
 182 =head1 DESCRIPTION
 183
 184 The B<AutoLoader> module works with the B<AutoSplit> module and the
 185 C<__END__> token to defer the loading of some subroutines until they are
 186 used rather than loading them all at once.
 187
 188 To use B<AutoLoader>, the author of a module has to place the
 189 definitions of subroutines to be autoloaded after an C<__END__> token.
 190 (See L<perldata>.)  The B<AutoSplit> module can then be run manually to
 191 extract the definitions into individual files F<auto/funcname.al>.
 192
 193 B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
 194 subroutine in is called in a client module of B<AutoLoader>,
 195 B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
 196 file with a name related to the location of the file from which the
 197 client module was read.  As an example, if F<POSIX.pm> is located in
 198 F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
 199 subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
 200 the C<.al> file has the same name as the subroutine, sans package.  If
 201 such a file exists, AUTOLOAD will read and evaluate it,
 202 thus (presumably) defining the needed subroutine.  AUTOLOAD will then
 203 C<goto> the newly defined subroutine.
 204
 205 Once this process completes for a given function, it is defined, so
 206 future calls to the subroutine will bypass the AUTOLOAD mechanism.
 207
 208 =head2 Subroutine Stubs
 209
 210 In order for object method lookup and/or prototype checking to operate
 211 correctly even when methods have not yet been defined it is necessary to
 212 "forward declare" each subroutine (as in C<sub NAME;>).  See
 213 L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
 214 stubs", which are place holders with no code.
 215
 216 The AutoSplit and B<AutoLoader> modules automate the creation of forward
 217 declarations.  The AutoSplit module creates an 'index' file containing
 218 forward declarations of all the AutoSplit subroutines.  When the
 219 AutoLoader module is 'use'd it loads these declarations into its callers
 220 package.
 221
 222 Because of this mechanism it is important that B<AutoLoader> is always
 223 C<use>d and not C<require>d.
 224
 225 =head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
 226
 227 In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
 228 explicitly import it:
 229
 230     use AutoLoader 'AUTOLOAD';
 231
 232 =head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
 233
 234 Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
 235 They typically need to check for some special cases (such as constants)
 236 and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
 237
 238 Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
 239 Instead, they should define their own AUTOLOAD subroutines along these
 240 lines:
 241
 242     use AutoLoader;
 243     use Carp;
 244
 245     sub AUTOLOAD {
 246         my $sub = $AUTOLOAD;
 247         (my $constname = $sub) =~ s/.*:://;
 248         my $val = constant($constname, @_ ? $_[0] : 0);
 249         if ($! != 0) {
 250             if ($! =~ /Invalid/ || $!{EINVAL}) {
 251                 $AutoLoader::AUTOLOAD = $sub;
 252                 goto &AutoLoader::AUTOLOAD;
 253             }
 254             else {
 255                 croak "Your vendor has not defined constant $constname";
 256             }
 257         }
 258         *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
 259         goto &$sub;
 260     }
 261
 262 If any module's own AUTOLOAD subroutine has no need to fallback to the
 263 AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
 264 subroutines), then that module should not use B<AutoLoader> at all.
 265
 266 =head2 Package Lexicals
 267
 268 Package lexicals declared with C<my> in the main block of a package
 269 using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
 270 the fact that the given scope ends at the C<__END__> marker.  A module
 271 using such variables as package globals will not work properly under the
 272 B<AutoLoader>.
 273
 274 The C<vars> pragma (see L<perlmod/"vars">) may be used in such
 275 situations as an alternative to explicitly qualifying all globals with
 276 the package namespace.  Variables pre-declared with this pragma will be
 277 visible to any autoloaded routines (but will not be invisible outside
 278 the package, unfortunately).
 279
 280 =head2 Not Using AutoLoader
 281
 282 You can stop using AutoLoader by simply
 283
 284         no AutoLoader;
 285
 286 =head2 B<AutoLoader> vs. B<SelfLoader>
 287
 288 The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
 289 loading of subroutines.
 290
 291 B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
 292 While this avoids the use of a hierarchy of disk files and the
 293 associated open/close for each routine loaded, B<SelfLoader> suffers a
 294 startup speed disadvantage in the one-time parsing of the lines after
 295 C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
 296 handle multiple packages in a file.
 297
 298 B<AutoLoader> only reads code as it is requested, and in many cases
 299 should be faster, but requires a mechanism like B<AutoSplit> be used to
 300 create the individual files.  L<ExtUtils::MakeMaker> will invoke
 301 B<AutoSplit> automatically if B<AutoLoader> is used in a module source
 302 file.
 303
 304 =head1 CAVEATS
 305
 306 AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
 307 old modules which use B<AutoLoader> should be changed to the new calling
 308 style.  Typically this just means changing a require to a use, adding
 309 the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
 310 from C<@ISA>.
 311
 312 On systems with restrictions on file name length, the file corresponding
 313 to a subroutine may have a shorter name that the routine itself.  This
 314 can lead to conflicting file names.  The I<AutoSplit> package warns of
 315 these potential conflicts when used to split a module.
 316
 317 AutoLoader may fail to find the autosplit files (or even find the wrong
 318 ones) in cases where C<@INC> contains relative paths, B<and> the program
 319 does C<chdir>.
 320
 321 =head1 SEE ALSO
 322
 323 L<SelfLoader> - an autoloader that doesn't use external files.
 324
 325 =cut