lib/AutoLoader.pm

   1 package AutoLoader;
   2
   3 use 5.005_64;
   4 our(@EXPORT, @EXPORT_OK, $VERSION);
   5
   6 my $is_dosish;
   7 my $is_epoc;
   8 my $is_vms;
   9 my $is_macos;
  10
  11 BEGIN {
  12     require Exporter;
  13     @EXPORT = @EXPORT = ();
  14     @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
  15     $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32' || $^O eq 'NetWare';
  16     $is_epoc = $^O eq 'epoc';
  17     $is_vms = $^O eq 'VMS';
  18     $is_macos = $^O eq 'MacOS';
  19     $VERSION = '5.58';
  20 }
  21
  22 AUTOLOAD {
  23     my $sub = $AUTOLOAD;
  24     my $filename;
  25     # Braces used to preserve $1 et al.
  26     {
  27         # Try to find the autoloaded file from the package-qualified
  28         # name of the sub. e.g., if the sub needed is
  29         # Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
  30         # something like '/usr/lib/perl5/Getopt/Long.pm', and the
  31         # autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
  32         #
  33         # However, if @INC is a relative path, this might not work.  If,
  34         # for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
  35         # 'lib/Getopt/Long.pm', and we want to require
  36         # 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
  37         # In this case, we simple prepend the 'auto/' and let the
  38         # C<require> take care of the searching for us.
  39
  40         my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
  41         $pkg =~ s#::#/#g;
  42         if (defined($filename = $INC{"$pkg.pm"})) {
  43             if ($is_macos) {
  44                 $pkg =~ tr#/#:#;
  45                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto:$pkg:$func.al#s;
  46             } else {
  47                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
  48             }
  49
  50             # if the file exists, then make sure that it is a
  51             # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
  52             # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
  53             # (and failing) to find the 'lib/auto/foo/bar.al' because it
  54             # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
  55
  56             if (-r $filename) {
  57                 unless ($filename =~ m|^/|s) {
  58                     if ($is_dosish) {
  59                         unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
  60                              if ($^O ne 'NetWare') {
  61                                         $filename = "./$filename";
  62                                 } else {
  63                                         $filename = "$filename";
  64                                 }
  65                         }
  66                     }
  67                     elsif ($is_epoc) {
  68                         unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
  69                              $filename = "./$filename";
  70                         }
  71                     }elsif ($is_vms) {
  72                         # XXX todo by VMSmiths
  73                         $filename = "./$filename";
  74                     }
  75                     elsif (!$is_macos) {
  76                         $filename = "./$filename";
  77                     }
  78                 }
  79             }
  80             else {
  81                 $filename = undef;
  82             }
  83         }
  84         unless (defined $filename) {
  85             # let C<require> do the searching
  86             $filename = "auto/$sub.al";
  87             $filename =~ s#::#/#g;
  88         }
  89     }
  90     my $save = $@;
  91     eval { local $SIG{__DIE__}; require $filename };
  92     if ($@) {
  93         if (substr($sub,-9) eq '::DESTROY') {
  94             *$sub = sub {};
  95         } else {
  96             # The load might just have failed because the filename was too
  97             # long for some old SVR3 systems which treat long names as errors.
  98             # If we can succesfully truncate a long name then it's worth a go.
  99             # There is a slight risk that we could pick up the wrong file here
 100             # but autosplit should have warned about that when splitting.
 101             if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
 102                 eval { local $SIG{__DIE__}; require $filename };
 103             }
 104             if ($@){
 105                 $@ =~ s/ at .*\n//;
 106                 my $error = $@;
 107                 require Carp;
 108                 Carp::croak($error);
 109             }
 110         }
 111     }
 112     $@ = $save;
 113     goto &$sub;
 114 }
 115
 116 sub import {
 117     my $pkg = shift;
 118     my $callpkg = caller;
 119
 120     #
 121     # Export symbols, but not by accident of inheritance.
 122     #
 123
 124     if ($pkg eq 'AutoLoader') {
 125       local $Exporter::ExportLevel = 1;
 126       Exporter::import $pkg, @_;
 127     }
 128
 129     #
 130     # Try to find the autosplit index file.  Eg., if the call package
 131     # is POSIX, then $INC{POSIX.pm} is something like
 132     # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
 133     # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
 134     #
 135     # However, if @INC is a relative path, this might not work.  If,
 136     # for example, @INC = ('lib'), then
 137     # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
 138     # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
 139     #
 140
 141     (my $calldir = $callpkg) =~ s#::#/#g;
 142     my $path = $INC{$calldir . '.pm'};
 143     if (defined($path)) {
 144         # Try absolute path name.
 145         $path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
 146         eval { require $path; };
 147         # If that failed, try relative path with normal @INC searching.
 148         if ($@) {
 149             $path ="auto/$calldir/autosplit.ix";
 150             eval { require $path; };
 151         }
 152         if ($@) {
 153             my $error = $@;
 154             require Carp;
 155             Carp::carp($error);
 156         }
 157     }
 158 }
 159
 160 sub unimport {
 161   my $callpkg = caller;
 162   eval "package $callpkg; sub AUTOLOAD;";
 163 }
 164
 165 1;
 166
 167 __END__
 168
 169 =head1 NAME
 170
 171 AutoLoader - load subroutines only on demand
 172
 173 =head1 SYNOPSIS
 174
 175     package Foo;
 176     use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine
 177
 178     package Bar;
 179     use AutoLoader;              # don't import AUTOLOAD, define our own
 180     sub AUTOLOAD {
 181         ...
 182         $AutoLoader::AUTOLOAD = "...";
 183         goto &AutoLoader::AUTOLOAD;
 184     }
 185
 186 =head1 DESCRIPTION
 187
 188 The B<AutoLoader> module works with the B<AutoSplit> module and the
 189 C<__END__> token to defer the loading of some subroutines until they are
 190 used rather than loading them all at once.
 191
 192 To use B<AutoLoader>, the author of a module has to place the
 193 definitions of subroutines to be autoloaded after an C<__END__> token.
 194 (See L<perldata>.)  The B<AutoSplit> module can then be run manually to
 195 extract the definitions into individual files F<auto/funcname.al>.
 196
 197 B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
 198 subroutine in is called in a client module of B<AutoLoader>,
 199 B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
 200 file with a name related to the location of the file from which the
 201 client module was read.  As an example, if F<POSIX.pm> is located in
 202 F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
 203 subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
 204 the C<.al> file has the same name as the subroutine, sans package.  If
 205 such a file exists, AUTOLOAD will read and evaluate it,
 206 thus (presumably) defining the needed subroutine.  AUTOLOAD will then
 207 C<goto> the newly defined subroutine.
 208
 209 Once this process completes for a given function, it is defined, so
 210 future calls to the subroutine will bypass the AUTOLOAD mechanism.
 211
 212 =head2 Subroutine Stubs
 213
 214 In order for object method lookup and/or prototype checking to operate
 215 correctly even when methods have not yet been defined it is necessary to
 216 "forward declare" each subroutine (as in C<sub NAME;>).  See
 217 L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
 218 stubs", which are place holders with no code.
 219
 220 The AutoSplit and B<AutoLoader> modules automate the creation of forward
 221 declarations.  The AutoSplit module creates an 'index' file containing
 222 forward declarations of all the AutoSplit subroutines.  When the
 223 AutoLoader module is 'use'd it loads these declarations into its callers
 224 package.
 225
 226 Because of this mechanism it is important that B<AutoLoader> is always
 227 C<use>d and not C<require>d.
 228
 229 =head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
 230
 231 In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
 232 explicitly import it:
 233
 234     use AutoLoader 'AUTOLOAD';
 235
 236 =head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
 237
 238 Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
 239 They typically need to check for some special cases (such as constants)
 240 and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
 241
 242 Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
 243 Instead, they should define their own AUTOLOAD subroutines along these
 244 lines:
 245
 246     use AutoLoader;
 247     use Carp;
 248
 249     sub AUTOLOAD {
 250         my $sub = $AUTOLOAD;
 251         (my $constname = $sub) =~ s/.*:://;
 252         my $val = constant($constname, @_ ? $_[0] : 0);
 253         if ($! != 0) {
 254             if ($! =~ /Invalid/ || $!{EINVAL}) {
 255                 $AutoLoader::AUTOLOAD = $sub;
 256                 goto &AutoLoader::AUTOLOAD;
 257             }
 258             else {
 259                 croak "Your vendor has not defined constant $constname";
 260             }
 261         }
 262         *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
 263         goto &$sub;
 264     }
 265
 266 If any module's own AUTOLOAD subroutine has no need to fallback to the
 267 AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
 268 subroutines), then that module should not use B<AutoLoader> at all.
 269
 270 =head2 Package Lexicals
 271
 272 Package lexicals declared with C<my> in the main block of a package
 273 using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
 274 the fact that the given scope ends at the C<__END__> marker.  A module
 275 using such variables as package globals will not work properly under the
 276 B<AutoLoader>.
 277
 278 The C<vars> pragma (see L<perlmod/"vars">) may be used in such
 279 situations as an alternative to explicitly qualifying all globals with
 280 the package namespace.  Variables pre-declared with this pragma will be
 281 visible to any autoloaded routines (but will not be invisible outside
 282 the package, unfortunately).
 283
 284 =head2 Not Using AutoLoader
 285
 286 You can stop using AutoLoader by simply
 287
 288         no AutoLoader;
 289
 290 =head2 B<AutoLoader> vs. B<SelfLoader>
 291
 292 The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
 293 loading of subroutines.
 294
 295 B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
 296 While this avoids the use of a hierarchy of disk files and the
 297 associated open/close for each routine loaded, B<SelfLoader> suffers a
 298 startup speed disadvantage in the one-time parsing of the lines after
 299 C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
 300 handle multiple packages in a file.
 301
 302 B<AutoLoader> only reads code as it is requested, and in many cases
 303 should be faster, but requires a mechanism like B<AutoSplit> be used to
 304 create the individual files.  L<ExtUtils::MakeMaker> will invoke
 305 B<AutoSplit> automatically if B<AutoLoader> is used in a module source
 306 file.
 307
 308 =head1 CAVEATS
 309
 310 AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
 311 old modules which use B<AutoLoader> should be changed to the new calling
 312 style.  Typically this just means changing a require to a use, adding
 313 the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
 314 from C<@ISA>.
 315
 316 On systems with restrictions on file name length, the file corresponding
 317 to a subroutine may have a shorter name that the routine itself.  This
 318 can lead to conflicting file names.  The I<AutoSplit> package warns of
 319 these potential conflicts when used to split a module.
 320
 321 AutoLoader may fail to find the autosplit files (or even find the wrong
 322 ones) in cases where C<@INC> contains relative paths, B<and> the program
 323 does C<chdir>.
 324
 325 =head1 SEE ALSO
 326
 327 L<SelfLoader> - an autoloader that doesn't use external files.
 328
 329 =cut