lib/AutoLoader.pm

   1 package AutoLoader;
   2
   3 use strict;
   4 use 5.006_001;
   5
   6 our($VERSION, $AUTOLOAD);
   7
   8 my $is_dosish;
   9 my $is_epoc;
  10 my $is_vms;
  11 my $is_macos;
  12
  13 BEGIN {
  14     $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32' || $^O eq 'NetWare';
  15     $is_epoc = $^O eq 'epoc';
  16     $is_vms = $^O eq 'VMS';
  17     $is_macos = $^O eq 'MacOS';
  18     $VERSION = '5.60';
  19 }
  20
  21 AUTOLOAD {
  22     my $sub = $AUTOLOAD;
  23     my $filename;
  24     # Braces used to preserve $1 et al.
  25     {
  26         # Try to find the autoloaded file from the package-qualified
  27         # name of the sub. e.g., if the sub needed is
  28         # Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
  29         # something like '/usr/lib/perl5/Getopt/Long.pm', and the
  30         # autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
  31         #
  32         # However, if @INC is a relative path, this might not work.  If,
  33         # for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
  34         # 'lib/Getopt/Long.pm', and we want to require
  35         # 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
  36         # In this case, we simple prepend the 'auto/' and let the
  37         # C<require> take care of the searching for us.
  38
  39         my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
  40         $pkg =~ s#::#/#g;
  41         if (defined($filename = $INC{"$pkg.pm"})) {
  42             if ($is_macos) {
  43                 $pkg =~ tr#/#:#;
  44                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto:$pkg:$func.al#s;
  45             } else {
  46                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
  47             }
  48
  49             # if the file exists, then make sure that it is a
  50             # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
  51             # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
  52             # (and failing) to find the 'lib/auto/foo/bar.al' because it
  53             # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
  54
  55             if (-r $filename) {
  56                 unless ($filename =~ m|^/|s) {
  57                     if ($is_dosish) {
  58                         unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
  59                              if ($^O ne 'NetWare') {
  60                                         $filename = "./$filename";
  61                                 } else {
  62                                         $filename = "$filename";
  63                                 }
  64                         }
  65                     }
  66                     elsif ($is_epoc) {
  67                         unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
  68                              $filename = "./$filename";
  69                         }
  70                     }
  71                     elsif ($is_vms) {
  72                         # XXX todo by VMSmiths
  73                         $filename = "./$filename";
  74                     }
  75                     elsif (!$is_macos) {
  76                         $filename = "./$filename";
  77                     }
  78                 }
  79             }
  80             else {
  81                 $filename = undef;
  82             }
  83         }
  84         unless (defined $filename) {
  85             # let C<require> do the searching
  86             $filename = "auto/$sub.al";
  87             $filename =~ s#::#/#g;
  88         }
  89     }
  90     my $save = $@;
  91     local $!; # Do not munge the value.
  92     eval { local $SIG{__DIE__}; require $filename };
  93     if ($@) {
  94         if (substr($sub,-9) eq '::DESTROY') {
  95                 no strict 'refs';
  96             *$sub = sub {};
  97         } else {
  98             # The load might just have failed because the filename was too
  99             # long for some old SVR3 systems which treat long names as errors.
 100             # If we can succesfully truncate a long name then it's worth a go.
 101             # There is a slight risk that we could pick up the wrong file here
 102             # but autosplit should have warned about that when splitting.
 103             if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
 104                 eval { local $SIG{__DIE__}; require $filename };
 105             }
 106             if ($@){
 107                 $@ =~ s/ at .*\n//;
 108                 my $error = $@;
 109                 require Carp;
 110                 Carp::croak($error);
 111             }
 112         }
 113     }
 114     $@ = $save;
 115     goto &$sub;
 116 }
 117
 118 sub import {
 119     my $pkg = shift;
 120     my $callpkg = caller;
 121
 122     #
 123     # Export symbols, but not by accident of inheritance.
 124     #
 125
 126     if ($pkg eq 'AutoLoader') {
 127       no strict 'refs';
 128       *{ $callpkg . '::AUTOLOAD' } = \&AUTOLOAD
 129         if @_ and $_[0] =~ /^&?AUTOLOAD$/;
 130     }
 131
 132     #
 133     # Try to find the autosplit index file.  Eg., if the call package
 134     # is POSIX, then $INC{POSIX.pm} is something like
 135     # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
 136     # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
 137     #
 138     # However, if @INC is a relative path, this might not work.  If,
 139     # for example, @INC = ('lib'), then
 140     # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
 141     # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
 142     #
 143
 144     (my $calldir = $callpkg) =~ s#::#/#g;
 145     my $path = $INC{$calldir . '.pm'};
 146     if (defined($path)) {
 147         # Try absolute path name.
 148         if ($is_macos) {
 149             (my $malldir = $calldir) =~ tr#/#:#;
 150             $path =~ s#^(.*)$malldir\.pm\z#$1auto:$malldir:autosplit.ix#s;
 151         } else {
 152             $path =~ s#^(.*)$calldir\.pm\z#$1auto/$calldir/autosplit.ix#;
 153         }
 154
 155         eval { require $path; };
 156         # If that failed, try relative path with normal @INC searching.
 157         if ($@) {
 158             $path ="auto/$calldir/autosplit.ix";
 159             eval { require $path; };
 160         }
 161         if ($@) {
 162             my $error = $@;
 163             require Carp;
 164             Carp::carp($error);
 165         }
 166     }
 167 }
 168
 169 sub unimport {
 170     my $callpkg = caller;
 171
 172     no strict 'refs';
 173     my $symname = $callpkg . '::AUTOLOAD';
 174     undef *{ $symname } if \&{ $symname } == \&AUTOLOAD;
 175     *{ $symname } = \&{ $symname };
 176 }
 177
 178 1;
 179
 180 __END__
 181
 182 =head1 NAME
 183
 184 AutoLoader - load subroutines only on demand
 185
 186 =head1 SYNOPSIS
 187
 188     package Foo;
 189     use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine
 190
 191     package Bar;
 192     use AutoLoader;              # don't import AUTOLOAD, define our own
 193     sub AUTOLOAD {
 194         ...
 195         $AutoLoader::AUTOLOAD = "...";
 196         goto &AutoLoader::AUTOLOAD;
 197     }
 198
 199 =head1 DESCRIPTION
 200
 201 The B<AutoLoader> module works with the B<AutoSplit> module and the
 202 C<__END__> token to defer the loading of some subroutines until they are
 203 used rather than loading them all at once.
 204
 205 To use B<AutoLoader>, the author of a module has to place the
 206 definitions of subroutines to be autoloaded after an C<__END__> token.
 207 (See L<perldata>.)  The B<AutoSplit> module can then be run manually to
 208 extract the definitions into individual files F<auto/funcname.al>.
 209
 210 B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
 211 subroutine in is called in a client module of B<AutoLoader>,
 212 B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
 213 file with a name related to the location of the file from which the
 214 client module was read.  As an example, if F<POSIX.pm> is located in
 215 F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
 216 subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
 217 the C<.al> file has the same name as the subroutine, sans package.  If
 218 such a file exists, AUTOLOAD will read and evaluate it,
 219 thus (presumably) defining the needed subroutine.  AUTOLOAD will then
 220 C<goto> the newly defined subroutine.
 221
 222 Once this process completes for a given function, it is defined, so
 223 future calls to the subroutine will bypass the AUTOLOAD mechanism.
 224
 225 =head2 Subroutine Stubs
 226
 227 In order for object method lookup and/or prototype checking to operate
 228 correctly even when methods have not yet been defined it is necessary to
 229 "forward declare" each subroutine (as in C<sub NAME;>).  See
 230 L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
 231 stubs", which are place holders with no code.
 232
 233 The AutoSplit and B<AutoLoader> modules automate the creation of forward
 234 declarations.  The AutoSplit module creates an 'index' file containing
 235 forward declarations of all the AutoSplit subroutines.  When the
 236 AutoLoader module is 'use'd it loads these declarations into its callers
 237 package.
 238
 239 Because of this mechanism it is important that B<AutoLoader> is always
 240 C<use>d and not C<require>d.
 241
 242 =head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
 243
 244 In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
 245 explicitly import it:
 246
 247     use AutoLoader 'AUTOLOAD';
 248
 249 =head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
 250
 251 Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
 252 They typically need to check for some special cases (such as constants)
 253 and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
 254
 255 Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
 256 Instead, they should define their own AUTOLOAD subroutines along these
 257 lines:
 258
 259     use AutoLoader;
 260     use Carp;
 261
 262     sub AUTOLOAD {
 263         my $sub = $AUTOLOAD;
 264         (my $constname = $sub) =~ s/.*:://;
 265         my $val = constant($constname, @_ ? $_[0] : 0);
 266         if ($! != 0) {
 267             if ($! =~ /Invalid/ || $!{EINVAL}) {
 268                 $AutoLoader::AUTOLOAD = $sub;
 269                 goto &AutoLoader::AUTOLOAD;
 270             }
 271             else {
 272                 croak "Your vendor has not defined constant $constname";
 273             }
 274         }
 275         *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
 276         goto &$sub;
 277     }
 278
 279 If any module's own AUTOLOAD subroutine has no need to fallback to the
 280 AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
 281 subroutines), then that module should not use B<AutoLoader> at all.
 282
 283 =head2 Package Lexicals
 284
 285 Package lexicals declared with C<my> in the main block of a package
 286 using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
 287 the fact that the given scope ends at the C<__END__> marker.  A module
 288 using such variables as package globals will not work properly under the
 289 B<AutoLoader>.
 290
 291 The C<vars> pragma (see L<perlmod/"vars">) may be used in such
 292 situations as an alternative to explicitly qualifying all globals with
 293 the package namespace.  Variables pre-declared with this pragma will be
 294 visible to any autoloaded routines (but will not be invisible outside
 295 the package, unfortunately).
 296
 297 =head2 Not Using AutoLoader
 298
 299 You can stop using AutoLoader by simply
 300
 301         no AutoLoader;
 302
 303 =head2 B<AutoLoader> vs. B<SelfLoader>
 304
 305 The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
 306 loading of subroutines.
 307
 308 B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
 309 While this avoids the use of a hierarchy of disk files and the
 310 associated open/close for each routine loaded, B<SelfLoader> suffers a
 311 startup speed disadvantage in the one-time parsing of the lines after
 312 C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
 313 handle multiple packages in a file.
 314
 315 B<AutoLoader> only reads code as it is requested, and in many cases
 316 should be faster, but requires a mechanism like B<AutoSplit> be used to
 317 create the individual files.  L<ExtUtils::MakeMaker> will invoke
 318 B<AutoSplit> automatically if B<AutoLoader> is used in a module source
 319 file.
 320
 321 =head1 CAVEATS
 322
 323 AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
 324 old modules which use B<AutoLoader> should be changed to the new calling
 325 style.  Typically this just means changing a require to a use, adding
 326 the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
 327 from C<@ISA>.
 328
 329 On systems with restrictions on file name length, the file corresponding
 330 to a subroutine may have a shorter name that the routine itself.  This
 331 can lead to conflicting file names.  The I<AutoSplit> package warns of
 332 these potential conflicts when used to split a module.
 333
 334 AutoLoader may fail to find the autosplit files (or even find the wrong
 335 ones) in cases where C<@INC> contains relative paths, B<and> the program
 336 does C<chdir>.
 337
 338 =head1 SEE ALSO
 339
 340 L<SelfLoader> - an autoloader that doesn't use external files.
 341
 342 =cut