lib/AutoLoader.pm

   1 package AutoLoader;
   2
   3 use 5.005_64;
   4 our(@EXPORT, @EXPORT_OK, $VERSION);
   5
   6 my $is_dosish;
   7 my $is_epoc;
   8 my $is_vms;
   9 my $is_macos;
  10
  11 BEGIN {
  12     require Exporter;
  13     @EXPORT = @EXPORT = ();
  14     @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
  15     $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32' || $^O eq 'NetWare';
  16     $is_epoc = $^O eq 'epoc';
  17     $is_vms = $^O eq 'VMS';
  18     $is_macos = $^O eq 'MacOS';
  19     $VERSION = '5.58';
  20 }
  21
  22 AUTOLOAD {
  23     my $sub = $AUTOLOAD;
  24     my $filename;
  25     # Braces used to preserve $1 et al.
  26     {
  27         # Try to find the autoloaded file from the package-qualified
  28         # name of the sub. e.g., if the sub needed is
  29         # Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
  30         # something like '/usr/lib/perl5/Getopt/Long.pm', and the
  31         # autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
  32         #
  33         # However, if @INC is a relative path, this might not work.  If,
  34         # for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
  35         # 'lib/Getopt/Long.pm', and we want to require
  36         # 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
  37         # In this case, we simple prepend the 'auto/' and let the
  38         # C<require> take care of the searching for us.
  39
  40         my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
  41         $pkg =~ s#::#/#g;
  42         if (defined($filename = $INC{"$pkg.pm"})) {
  43             if ($is_macos) {
  44                 $pkg =~ tr#/#:#;
  45                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto:$pkg:$func.al#s;
  46             } else {
  47                 $filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
  48             }
  49
  50             # if the file exists, then make sure that it is a
  51             # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
  52             # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
  53             # (and failing) to find the 'lib/auto/foo/bar.al' because it
  54             # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
  55
  56             if (-r $filename) {
  57                 unless ($filename =~ m|^/|s) {
  58                     if ($is_dosish) {
  59                         unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
  60                              if ($^O ne 'NetWare') {
  61                                         $filename = "./$filename";
  62                                 } else {
  63                                         $filename = "$filename";
  64                                 }
  65                         }
  66                     }
  67                     elsif ($is_epoc) {
  68                         unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
  69                              $filename = "./$filename";
  70                         }
  71                     }elsif ($is_vms) {
  72                         # XXX todo by VMSmiths
  73                         $filename = "./$filename";
  74                     }
  75                     elsif (!$is_macos) {
  76                         $filename = "./$filename";
  77                     }
  78                 }
  79             }
  80             else {
  81                 $filename = undef;
  82             }
  83         }
  84         unless (defined $filename) {
  85             # let C<require> do the searching
  86             $filename = "auto/$sub.al";
  87             $filename =~ s#::#/#g;
  88         }
  89     }
  90     my $save = $@;
  91     local $!; # Do not munge the value.
  92     eval { local $SIG{__DIE__}; require $filename };
  93     if ($@) {
  94         if (substr($sub,-9) eq '::DESTROY') {
  95             *$sub = sub {};
  96         } else {
  97             # The load might just have failed because the filename was too
  98             # long for some old SVR3 systems which treat long names as errors.
  99             # If we can succesfully truncate a long name then it's worth a go.
 100             # There is a slight risk that we could pick up the wrong file here
 101             # but autosplit should have warned about that when splitting.
 102             if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
 103                 eval { local $SIG{__DIE__}; require $filename };
 104             }
 105             if ($@){
 106                 $@ =~ s/ at .*\n//;
 107                 my $error = $@;
 108                 require Carp;
 109                 Carp::croak($error);
 110             }
 111         }
 112     }
 113     $@ = $save;
 114     goto &$sub;
 115 }
 116
 117 sub import {
 118     my $pkg = shift;
 119     my $callpkg = caller;
 120
 121     #
 122     # Export symbols, but not by accident of inheritance.
 123     #
 124
 125     if ($pkg eq 'AutoLoader') {
 126       local $Exporter::ExportLevel = 1;
 127       Exporter::import $pkg, @_;
 128     }
 129
 130     #
 131     # Try to find the autosplit index file.  Eg., if the call package
 132     # is POSIX, then $INC{POSIX.pm} is something like
 133     # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
 134     # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
 135     #
 136     # However, if @INC is a relative path, this might not work.  If,
 137     # for example, @INC = ('lib'), then
 138     # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
 139     # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
 140     #
 141
 142     (my $calldir = $callpkg) =~ s#::#/#g;
 143     my $path = $INC{$calldir . '.pm'};
 144     if (defined($path)) {
 145         # Try absolute path name.
 146         $path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
 147         eval { require $path; };
 148         # If that failed, try relative path with normal @INC searching.
 149         if ($@) {
 150             $path ="auto/$calldir/autosplit.ix";
 151             eval { require $path; };
 152         }
 153         if ($@) {
 154             my $error = $@;
 155             require Carp;
 156             Carp::carp($error);
 157         }
 158     }
 159 }
 160
 161 sub unimport {
 162   my $callpkg = caller;
 163   eval "package $callpkg; sub AUTOLOAD;";
 164 }
 165
 166 1;
 167
 168 __END__
 169
 170 =head1 NAME
 171
 172 AutoLoader - load subroutines only on demand
 173
 174 =head1 SYNOPSIS
 175
 176     package Foo;
 177     use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine
 178
 179     package Bar;
 180     use AutoLoader;              # don't import AUTOLOAD, define our own
 181     sub AUTOLOAD {
 182         ...
 183         $AutoLoader::AUTOLOAD = "...";
 184         goto &AutoLoader::AUTOLOAD;
 185     }
 186
 187 =head1 DESCRIPTION
 188
 189 The B<AutoLoader> module works with the B<AutoSplit> module and the
 190 C<__END__> token to defer the loading of some subroutines until they are
 191 used rather than loading them all at once.
 192
 193 To use B<AutoLoader>, the author of a module has to place the
 194 definitions of subroutines to be autoloaded after an C<__END__> token.
 195 (See L<perldata>.)  The B<AutoSplit> module can then be run manually to
 196 extract the definitions into individual files F<auto/funcname.al>.
 197
 198 B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
 199 subroutine in is called in a client module of B<AutoLoader>,
 200 B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
 201 file with a name related to the location of the file from which the
 202 client module was read.  As an example, if F<POSIX.pm> is located in
 203 F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
 204 subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
 205 the C<.al> file has the same name as the subroutine, sans package.  If
 206 such a file exists, AUTOLOAD will read and evaluate it,
 207 thus (presumably) defining the needed subroutine.  AUTOLOAD will then
 208 C<goto> the newly defined subroutine.
 209
 210 Once this process completes for a given function, it is defined, so
 211 future calls to the subroutine will bypass the AUTOLOAD mechanism.
 212
 213 =head2 Subroutine Stubs
 214
 215 In order for object method lookup and/or prototype checking to operate
 216 correctly even when methods have not yet been defined it is necessary to
 217 "forward declare" each subroutine (as in C<sub NAME;>).  See
 218 L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
 219 stubs", which are place holders with no code.
 220
 221 The AutoSplit and B<AutoLoader> modules automate the creation of forward
 222 declarations.  The AutoSplit module creates an 'index' file containing
 223 forward declarations of all the AutoSplit subroutines.  When the
 224 AutoLoader module is 'use'd it loads these declarations into its callers
 225 package.
 226
 227 Because of this mechanism it is important that B<AutoLoader> is always
 228 C<use>d and not C<require>d.
 229
 230 =head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
 231
 232 In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
 233 explicitly import it:
 234
 235     use AutoLoader 'AUTOLOAD';
 236
 237 =head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
 238
 239 Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
 240 They typically need to check for some special cases (such as constants)
 241 and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
 242
 243 Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
 244 Instead, they should define their own AUTOLOAD subroutines along these
 245 lines:
 246
 247     use AutoLoader;
 248     use Carp;
 249
 250     sub AUTOLOAD {
 251         my $sub = $AUTOLOAD;
 252         (my $constname = $sub) =~ s/.*:://;
 253         my $val = constant($constname, @_ ? $_[0] : 0);
 254         if ($! != 0) {
 255             if ($! =~ /Invalid/ || $!{EINVAL}) {
 256                 $AutoLoader::AUTOLOAD = $sub;
 257                 goto &AutoLoader::AUTOLOAD;
 258             }
 259             else {
 260                 croak "Your vendor has not defined constant $constname";
 261             }
 262         }
 263         *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
 264         goto &$sub;
 265     }
 266
 267 If any module's own AUTOLOAD subroutine has no need to fallback to the
 268 AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
 269 subroutines), then that module should not use B<AutoLoader> at all.
 270
 271 =head2 Package Lexicals
 272
 273 Package lexicals declared with C<my> in the main block of a package
 274 using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
 275 the fact that the given scope ends at the C<__END__> marker.  A module
 276 using such variables as package globals will not work properly under the
 277 B<AutoLoader>.
 278
 279 The C<vars> pragma (see L<perlmod/"vars">) may be used in such
 280 situations as an alternative to explicitly qualifying all globals with
 281 the package namespace.  Variables pre-declared with this pragma will be
 282 visible to any autoloaded routines (but will not be invisible outside
 283 the package, unfortunately).
 284
 285 =head2 Not Using AutoLoader
 286
 287 You can stop using AutoLoader by simply
 288
 289         no AutoLoader;
 290
 291 =head2 B<AutoLoader> vs. B<SelfLoader>
 292
 293 The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
 294 loading of subroutines.
 295
 296 B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
 297 While this avoids the use of a hierarchy of disk files and the
 298 associated open/close for each routine loaded, B<SelfLoader> suffers a
 299 startup speed disadvantage in the one-time parsing of the lines after
 300 C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
 301 handle multiple packages in a file.
 302
 303 B<AutoLoader> only reads code as it is requested, and in many cases
 304 should be faster, but requires a mechanism like B<AutoSplit> be used to
 305 create the individual files.  L<ExtUtils::MakeMaker> will invoke
 306 B<AutoSplit> automatically if B<AutoLoader> is used in a module source
 307 file.
 308
 309 =head1 CAVEATS
 310
 311 AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
 312 old modules which use B<AutoLoader> should be changed to the new calling
 313 style.  Typically this just means changing a require to a use, adding
 314 the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
 315 from C<@ISA>.
 316
 317 On systems with restrictions on file name length, the file corresponding
 318 to a subroutine may have a shorter name that the routine itself.  This
 319 can lead to conflicting file names.  The I<AutoSplit> package warns of
 320 these potential conflicts when used to split a module.
 321
 322 AutoLoader may fail to find the autosplit files (or even find the wrong
 323 ones) in cases where C<@INC> contains relative paths, B<and> the program
 324 does C<chdir>.
 325
 326 =head1 SEE ALSO
 327
 328 L<SelfLoader> - an autoloader that doesn't use external files.
 329
 330 =cut