1 ### the gnu tar specification:
2 ### http://www.gnu.org/software/tar/manual/tar.html
4 ### and the pax format spec, which tar derives from:
5 ### http://www.opengroup.org/onlinepubs/007904975/utilities/pax.html
11 use vars qw[$DEBUG $error $VERSION $WARN $FOLLOW_SYMLINK $CHOWN $CHMOD
12 $DO_NOT_USE_PREFIX $HAS_PERLIO $HAS_IO_STRING];
20 $DO_NOT_USE_PREFIX = 0;
24 $HAS_PERLIO = $Config::Config{useperlio};
26 ### try and load IO::String anyway, so you can dynamically
27 ### switch between perlio and IO::String
32 $HAS_IO_STRING = $@ ? 0 : 1;
38 use Carp qw(carp croak);
40 use File::Spec::Unix ();
43 use Archive::Tar::File;
44 use Archive::Tar::Constant;
48 Archive::Tar - module for manipulations of tar archives
53 my $tar = Archive::Tar->new;
55 $tar->read('origin.tgz',1);
58 $tar->add_files('file/foo.pl', 'docs/README');
59 $tar->add_data('file/baz.txt', 'This is the contents now');
61 $tar->rename('oldname', 'new/file/name');
63 $tar->write('files.tar');
67 Archive::Tar provides an object oriented mechanism for handling tar
68 files. It provides class methods for quick and easy files handling
69 while also allowing for the creation of tar file objects for custom
70 manipulation. If you have the IO::Zlib module installed,
71 Archive::Tar will also support compressed or gzipped tar files.
73 An object of class Archive::Tar represents a .tar(.gz) archive full
78 =head2 Archive::Tar->new( [$file, $compressed] )
80 Returns a new Tar object. If given any arguments, C<new()> calls the
81 C<read()> method automatically, passing on the arguments provided to
84 If C<new()> is invoked with arguments and the C<read()> method fails
85 for any reason, C<new()> returns undef.
94 ### install get/set accessors for this object.
95 for my $key ( keys %$tmpl ) {
97 *{__PACKAGE__."::$key"} = sub {
99 $self->{$key} = $_[0] if @_;
100 return $self->{$key};
106 $class = ref $class if ref $class;
108 ### copying $tmpl here since a shallow copy makes it use the
109 ### same aref, causing for files to remain in memory always.
110 my $obj = bless { _data => [ ], _file => 'Unknown' }, $class;
113 unless ( $obj->read( @_ ) ) {
114 $obj->_error(qq[No data could be read from file]);
122 =head2 $tar->read ( $filename|$handle, $compressed, {opt => 'val'} )
124 Read the given tar file into memory.
125 The first argument can either be the name of a file or a reference to
126 an already open filehandle (or an IO::Zlib object if it's compressed)
127 The second argument indicates whether the file referenced by the first
128 argument is compressed.
130 The C<read> will I<replace> any previous content in C<$tar>!
132 The second argument may be considered optional if IO::Zlib is
133 installed, since it will transparently Do The Right Thing.
134 Archive::Tar will warn if you try to pass a compressed file if
135 IO::Zlib is not available and simply return.
137 Note that you can currently B<not> pass a C<gzip> compressed
138 filehandle, which is not opened with C<IO::Zlib>, nor a string
139 containing the full archive information (either compressed or
140 uncompressed). These are worth while features, but not currently
141 implemented. See the C<TODO> section.
143 The third argument can be a hash reference with options. Note that
144 all options are case-sensitive.
150 Do not read more than C<limit> files. This is useful if you have
151 very big archives, and are only interested in the first few files.
155 If set to true, immediately extract entries when reading them. This
156 gives you the same memory break as the C<extract_archive> function.
157 Note however that entries will not be read into memory, but written
162 All files are stored internally as C<Archive::Tar::File> objects.
163 Please consult the L<Archive::Tar::File> documentation for details.
165 Returns the number of files read in scalar context, and a list of
166 C<Archive::Tar::File> objects in list context.
173 my $gzip = shift || 0;
174 my $opts = shift || {};
176 unless( defined $file ) {
177 $self->_error( qq[No file to read from!] );
180 $self->_file( $file );
183 my $handle = $self->_get_handle($file, $gzip, READ_ONLY->( ZLIB ) )
186 my $data = $self->_read_tar( $handle, $opts ) or return;
188 $self->_data( $data );
190 return wantarray ? @$data : scalar @$data;
195 my $file = shift; return unless defined $file;
196 return $file if ref $file;
198 my $gzip = shift || 0;
199 my $mode = shift || READ_ONLY->( ZLIB ); # default to read only
203 ### only default to ZLIB if we're not trying to /write/ to a handle ###
204 if( ZLIB and $gzip || MODE_READ->( $mode ) ) {
206 ### IO::Zlib will Do The Right Thing, even when passed
212 $self->_error(qq[Compression not available - Install IO::Zlib!]);
221 unless( $fh->open( $file, $mode ) ) {
222 $self->_error( qq[Could not create filehandle for '$file': $!!] );
233 my $handle = shift or return;
234 my $opts = shift || {};
236 my $count = $opts->{limit} || 0;
237 my $extract = $opts->{extract} || 0;
239 ### set a cap on the amount of files to extract ###
241 $limit = 1 if $count > 0;
246 my $real_name; # to set the name of a file when
247 # we're encountering @longlink
251 while( $handle->read( $chunk, HEAD ) ) {
252 ### IO::Zlib doesn't support this yet
253 my $offset = eval { tell $handle } || 'unknown';
256 my $gzip = GZIP_MAGIC_NUM;
257 if( $chunk =~ /$gzip/ ) {
258 $self->_error( qq[Cannot read compressed format in tar-mode] );
263 ### if we can't read in all bytes... ###
264 last if length $chunk != HEAD;
266 ### Apparently this should really be two blocks of 512 zeroes,
267 ### but GNU tar sometimes gets it wrong. See comment in the
268 ### source code (tar.c) to GNU cpio.
269 next if $chunk eq TAR_END;
271 ### according to the posix spec, the last 12 bytes of the header are
272 ### null bytes, to pad it to a 512 byte block. That means if these
273 ### bytes are NOT null bytes, it's a corrrupt header. See:
274 ### www.koders.com/c/fidCE473AD3D9F835D690259D60AD5654591D91D5BA.aspx
276 { my $nulls = join '', "\0" x 12;
277 unless( $nulls eq substr( $chunk, 500, 12 ) ) {
278 $self->_error( qq[Invalid header block at offset $offset] );
283 ### pass the realname, so we can set it 'proper' right away
284 ### some of the heuristics are done on the name, so important
287 { my %extra_args = ();
288 $extra_args{'name'} = $$real_name if defined $real_name;
290 unless( $entry = Archive::Tar::File->new( chunk => $chunk,
293 $self->_error( qq[Couldn't read chunk at offset $offset] );
299 ### http://www.gnu.org/manual/tar/html_node/tar_139.html
300 next if $entry->is_label;
302 if( length $entry->type and ($entry->is_file || $entry->is_longlink) ) {
304 if ( $entry->is_file && !$entry->validate ) {
305 ### sometimes the chunk is rather fux0r3d and a whole 512
306 ### bytes ends up in the ->name area.
307 ### clean it up, if need be
308 my $name = $entry->name;
309 $name = substr($name, 0, 100) if length $name > 100;
312 $self->_error( $name . qq[: checksum error] );
316 my $block = BLOCK_SIZE->( $entry->size );
318 $data = $entry->get_content_by_ref;
320 ### just read everything into memory
321 ### can't do lazy loading since IO::Zlib doesn't support 'seek'
322 ### this is because Compress::Zlib doesn't support it =/
323 ### this reads in the whole data in one read() call.
324 if( $handle->read( $$data, $block ) < $block ) {
325 $self->_error( qq[Read error on tarfile (missing data) '].
326 $entry->full_path ."' at offset $offset" );
330 ### throw away trailing garbage ###
331 substr ($$data, $entry->size) = "" if defined $$data;
333 ### part II of the @LongLink munging -- need to do /after/
334 ### the checksum check.
335 if( $entry->is_longlink ) {
336 ### weird thing in tarfiles -- if the file is actually a
337 ### @LongLink, the data part seems to have a trailing ^@
338 ### (unprintable) char. to display, pipe output through less.
339 ### but that doesn't *always* happen.. so check if the last
340 ### character is a control character, and if so remove it
341 ### at any rate, we better remove that character here, or tests
342 ### like 'eq' and hashlook ups based on names will SO not work
343 ### remove it by calculating the proper size, and then
344 ### tossing out everything that's longer than that size.
346 ### count number of nulls
347 my $nulls = $$data =~ tr/\0/\0/;
349 ### cut data + size by that many bytes
350 $entry->size( $entry->size - $nulls );
351 substr ($$data, $entry->size) = "";
355 ### clean up of the entries.. posix tar /apparently/ has some
356 ### weird 'feature' that allows for filenames > 255 characters
357 ### they'll put a header in with as name '././@LongLink' and the
358 ### contents will be the name of the /next/ file in the archive
359 ### pretty crappy and kludgy if you ask me
361 ### set the name for the next entry if this is a @LongLink;
362 ### this is one ugly hack =/ but needed for direct extraction
363 if( $entry->is_longlink ) {
366 } elsif ( defined $real_name ) {
367 $entry->name( $$real_name );
372 $self->_extract_file( $entry ) if $extract
373 && !$entry->is_longlink
374 && !$entry->is_unknown
375 && !$entry->is_label;
377 ### Guard against tarfiles with garbage at the end
378 last LOOP if $entry->name eq '';
380 ### push only the name on the rv if we're extracting
381 ### -- for extract_archive
382 push @$tarfile, ($extract ? $entry->name : $entry);
385 $count-- unless $entry->is_longlink || $entry->is_dir;
386 last LOOP unless $count;
395 =head2 $tar->contains_file( $filename )
397 Check if the archive contains a certain file.
398 It will return true if the file is in the archive, false otherwise.
400 Note however, that this function does an exact match using C<eq>
401 on the full path. So it cannot compensate for case-insensitive file-
402 systems or compare 2 paths to see if they would point to the same
409 my $full = shift or return;
411 ### don't warn if the entry isn't there.. that's what this function
412 ### is for after all.
414 return 1 if $self->_find_entry($full);
418 =head2 $tar->extract( [@filenames] )
420 Write files whose names are equivalent to any of the names in
421 C<@filenames> to disk, creating subdirectories as necessary. This
422 might not work too well under VMS.
423 Under MacPerl, the file's modification time will be converted to the
424 MacOS zero of time, and appropriate conversions will be done to the
425 path. However, the length of each element of the path is not
426 inspected to see whether it's longer than MacOS currently allows (32
429 If C<extract> is called without a list of file names, the entire
430 contents of the archive are extracted.
432 Returns a list of filenames extracted.
441 # use the speed optimization for all extracted files
442 local($self->{cwd}) = cwd() unless $self->{cwd};
444 ### you requested the extraction of only certian files
446 for my $file ( @args ) {
448 ### it's already an object?
449 if( UNIVERSAL::isa( $file, 'Archive::Tar::File' ) ) {
457 for my $entry ( @{$self->_data} ) {
458 next unless $file eq $entry->full_path;
460 ### we found the file you're looking for
466 return $self->_error(
467 qq[Could not find '$file' in archive] );
472 ### just grab all the file items
474 @files = $self->get_files;
477 ### nothing found? that's an error
478 unless( scalar @files ) {
479 $self->_error( qq[No files found for ] . $self->_file );
484 for my $entry ( @files ) {
485 unless( $self->_extract_file( $entry ) ) {
486 $self->_error(q[Could not extract ']. $entry->full_path .q['] );
494 =head2 $tar->extract_file( $file, [$extract_path] )
496 Write an entry, whose name is equivalent to the file name provided to
497 disk. Optionally takes a second parameter, which is the full (unix)
498 path (including filename) the entry will be written to.
502 $tar->extract_file( 'name/in/archive', 'name/i/want/to/give/it' );
504 $tar->extract_file( $at_file_object, 'name/i/want/to/give/it' );
506 Returns true on success, false on failure.
512 my $file = shift or return;
515 my $entry = $self->_find_entry( $file )
516 or $self->_error( qq[Could not find an entry for '$file'] ), return;
518 return $self->_extract_file( $entry, $alt );
523 my $entry = shift or return;
526 ### you wanted an alternate extraction location ###
527 my $name = defined $alt ? $alt : $entry->full_path;
529 ### splitpath takes a bool at the end to indicate
530 ### that it's splitting a dir
531 my ($vol,$dirs,$file);
532 if ( defined $alt ) { # It's a local-OS path
533 ($vol,$dirs,$file) = File::Spec->splitpath( $alt,
536 ($vol,$dirs,$file) = File::Spec::Unix->splitpath( $name,
541 ### is $name an absolute path? ###
542 if( File::Spec->file_name_is_absolute( $dirs ) ) {
545 ### it's a relative path ###
547 my $cwd = (defined $self->{cwd} ? $self->{cwd} : cwd());
548 my @dirs = File::Spec::Unix->splitdir( $dirs );
549 my @cwd = File::Spec->splitdir( $cwd );
550 $dir = File::Spec->catdir( @cwd, @dirs );
552 # catdir() returns undef if the path is longer than 255 chars on VMS
553 unless ( defined $dir ) {
554 $^W && $self->_error( qq[Could not compose a path for '$dirs'\n] );
560 if( -e $dir && !-d _ ) {
561 $^W && $self->_error( qq['$dir' exists, but it's not a directory!\n] );
566 eval { File::Path::mkpath( $dir, 0, 0777 ) };
568 $self->_error( qq[Could not create directory '$dir': $@] );
572 ### XXX chown here? that might not be the same as in the archive
573 ### as we're only chown'ing to the owner of the file we're extracting
574 ### not to the owner of the directory itself, which may or may not
575 ### be another entry in the archive
576 ### Answer: no, gnu tar doesn't do it either, it'd be the wrong
578 #if( $CHOWN && CAN_CHOWN ) {
579 # chown $entry->uid, $entry->gid, $dir or
580 # $self->_error( qq[Could not set uid/gid on '$dir'] );
584 ### we're done if we just needed to create a dir ###
585 return 1 if $entry->is_dir;
587 my $full = File::Spec->catfile( $dir, $file );
589 if( $entry->is_unknown ) {
590 $self->_error( qq[Unknown file type for file '$full'] );
594 if( length $entry->type && $entry->is_file ) {
595 my $fh = IO::File->new;
596 $fh->open( '>' . $full ) or (
597 $self->_error( qq[Could not open file '$full': $!] ),
603 syswrite $fh, $entry->data or (
604 $self->_error( qq[Could not write data to '$full'] ),
610 $self->_error( qq[Could not close file '$full'] ),
615 $self->_make_special_file( $entry, $full ) or return;
618 utime time, $entry->mtime - TIME_OFFSET, $full or
619 $self->_error( qq[Could not update timestamp] );
621 if( $CHOWN && CAN_CHOWN ) {
622 chown $entry->uid, $entry->gid, $full or
623 $self->_error( qq[Could not set uid/gid on '$full'] );
626 ### only chmod if we're allowed to, but never chmod symlinks, since they'll
627 ### change the perms on the file they're linking too...
628 if( $CHMOD and not -l $full ) {
629 chmod $entry->mode, $full or
630 $self->_error( qq[Could not chown '$full' to ] . $entry->mode );
636 sub _make_special_file {
638 my $entry = shift or return;
639 my $file = shift; return unless defined $file;
643 if( $entry->is_symlink ) {
646 symlink( $entry->linkname, $file ) or $fail++;
649 $self->_extract_special_file_as_plain_file( $entry, $file )
653 $err = qq[Making symbolink link from '] . $entry->linkname .
654 qq[' to '$file' failed] if $fail;
656 } elsif ( $entry->is_hardlink ) {
659 link( $entry->linkname, $file ) or $fail++;
662 $self->_extract_special_file_as_plain_file( $entry, $file )
666 $err = qq[Making hard link from '] . $entry->linkname .
667 qq[' to '$file' failed] if $fail;
669 } elsif ( $entry->is_fifo ) {
670 ON_UNIX && !system('mknod', $file, 'p') or
671 $err = qq[Making fifo ']. $entry->name .qq[' failed];
673 } elsif ( $entry->is_blockdev or $entry->is_chardev ) {
674 my $mode = $entry->is_blockdev ? 'b' : 'c';
676 ON_UNIX && !system('mknod', $file, $mode,
677 $entry->devmajor, $entry->devminor) or
678 $err = qq[Making block device ']. $entry->name .qq[' (maj=] .
679 $entry->devmajor . qq[ min=] . $entry->devminor .
682 } elsif ( $entry->is_socket ) {
683 ### the original doesn't do anything special for sockets.... ###
687 return $err ? $self->_error( $err ) : 1;
690 ### don't know how to make symlinks, let's just extract the file as
692 sub _extract_special_file_as_plain_file {
694 my $entry = shift or return;
695 my $file = shift; return unless defined $file;
699 my $orig = $self->_find_entry( $entry->linkname );
702 $err = qq[Could not find file '] . $entry->linkname .
707 ### clone the entry, make it appear as a normal file ###
708 my $clone = $entry->clone;
709 $clone->_downgrade_to_plainfile;
710 $self->_extract_file( $clone, $file ) or last TRY;
715 return $self->_error($err);
718 =head2 $tar->list_files( [\@properties] )
720 Returns a list of the names of all the files in the archive.
722 If C<list_files()> is passed an array reference as its first argument
723 it returns a list of hash references containing the requested
724 properties of each file. The following list of properties is
725 supported: name, size, mtime (last modified date), mode, uid, gid,
726 linkname, uname, gname, devmajor, devminor, prefix.
728 Passing an array reference containing only one element, 'name', is
729 special cased to return a list of names rather than a list of hash
730 references, making it equivalent to calling C<list_files> without
737 my $aref = shift || [ ];
739 unless( $self->_data ) {
740 $self->read() or return;
743 if( @$aref == 0 or ( @$aref == 1 and $aref->[0] eq 'name' ) ) {
744 return map { $_->full_path } @{$self->_data};
748 #for my $obj ( @{$self->_data} ) {
749 # push @rv, { map { $_ => $obj->$_() } @$aref };
753 ### this does the same as the above.. just needs a +{ }
754 ### to make sure perl doesn't confuse it for a block
755 return map { my $o=$_;
756 +{ map { $_ => $o->$_() } @$aref }
765 unless( defined $file ) {
766 $self->_error( qq[No file specified] );
770 ### it's an object already
771 return $file if UNIVERSAL::isa( $file, 'Archive::Tar::File' );
773 for my $entry ( @{$self->_data} ) {
774 my $path = $entry->full_path;
775 return $entry if $path eq $file;
778 $self->_error( qq[No such file in archive: '$file'] );
782 =head2 $tar->get_files( [@filenames] )
784 Returns the C<Archive::Tar::File> objects matching the filenames
785 provided. If no filename list was passed, all C<Archive::Tar::File>
786 objects in the current Tar object are returned.
788 Please refer to the C<Archive::Tar::File> documentation on how to
789 handle these objects.
796 return @{ $self->_data } unless @_;
799 for my $file ( @_ ) {
800 push @list, grep { defined } $self->_find_entry( $file );
806 =head2 $tar->get_content( $file )
808 Return the content of the named file.
814 my $entry = $self->_find_entry( shift ) or return;
819 =head2 $tar->replace_content( $file, $content )
821 Make the string $content be the content for the file named $file.
825 sub replace_content {
827 my $entry = $self->_find_entry( shift ) or return;
829 return $entry->replace_content( shift );
832 =head2 $tar->rename( $file, $new_name )
834 Rename the file of the in-memory archive to $new_name.
836 Note that you must specify a Unix path for $new_name, since per tar
837 standard, all files in the archive must be Unix paths.
839 Returns true on success and false on failure.
845 my $file = shift; return unless defined $file;
846 my $new = shift; return unless defined $new;
848 my $entry = $self->_find_entry( $file ) or return;
850 return $entry->rename( $new );
853 =head2 $tar->remove (@filenamelist)
855 Removes any entries with names matching any of the given filenames
856 from the in-memory archive. Returns a list of C<Archive::Tar::File>
865 my %seen = map { $_->full_path => $_ } @{$self->_data};
866 delete $seen{ $_ } for @list;
868 $self->_data( [values %seen] );
875 C<clear> clears the current in-memory archive. This effectively gives
876 you a 'blank' object, ready to be filled again. Note that C<clear>
877 only has effect on the object, not the underlying tarfile.
882 my $self = shift or return;
891 =head2 $tar->write ( [$file, $compressed, $prefix] )
893 Write the in-memory archive to disk. The first argument can either
894 be the name of a file or a reference to an already open filehandle (a
895 GLOB reference). If the second argument is true, the module will use
896 IO::Zlib to write the file in a compressed format. If IO::Zlib is
897 not available, the C<write> method will fail and return.
899 Note that when you pass in a filehandle, the compression argument
900 is ignored, as all files are printed verbatim to your filehandle.
901 If you wish to enable compression with filehandles, use an
902 C<IO::Zlib> filehandle instead.
904 Specific levels of compression can be chosen by passing the values 2
905 through 9 as the second parameter.
907 The third argument is an optional prefix. All files will be tucked
908 away in the directory you specify as prefix. So if you have files
909 'a' and 'b' in your archive, and you specify 'foo' as prefix, they
910 will be written to the archive as 'foo/a' and 'foo/b'.
912 If no arguments are given, C<write> returns the entire formatted
913 archive as a string, which could be useful if you'd like to stuff the
914 archive into a socket or a pipe to gzip or something.
920 my $file = shift; $file = '' unless defined $file;
921 my $gzip = shift || 0;
922 my $ext_prefix = shift; $ext_prefix = '' unless defined $ext_prefix;
925 ### only need a handle if we have a file to print to ###
926 my $handle = length($file)
927 ? ( $self->_get_handle($file, $gzip, WRITE_ONLY->($gzip) )
929 : $HAS_PERLIO ? do { open my $h, '>', \$dummy; $h }
930 : $HAS_IO_STRING ? IO::String->new
931 : __PACKAGE__->no_string_support();
935 for my $entry ( @{$self->_data} ) {
936 ### entries to be written to the tarfile ###
939 ### only now will we change the object to reflect the current state
940 ### of the name and prefix fields -- this needs to be limited to
942 my $clone = $entry->clone;
945 ### so, if you don't want use to use the prefix, we'll stuff
946 ### everything in the name field instead
947 if( $DO_NOT_USE_PREFIX ) {
949 ### you might have an extended prefix, if so, set it in the clone
950 ### XXX is ::Unix right?
951 $clone->name( length $ext_prefix
952 ? File::Spec::Unix->catdir( $ext_prefix,
954 : $clone->full_path );
955 $clone->prefix( '' );
957 ### otherwise, we'll have to set it properly -- prefix part in the
958 ### prefix and name part in the name field.
961 ### split them here, not before!
962 my ($prefix,$name) = $clone->_prefix_and_file( $clone->full_path );
964 ### you might have an extended prefix, if so, set it in the clone
965 ### XXX is ::Unix right?
966 $prefix = File::Spec::Unix->catdir( $ext_prefix, $prefix )
967 if length $ext_prefix;
969 $clone->prefix( $prefix );
970 $clone->name( $name );
973 ### names are too long, and will get truncated if we don't add a
974 ### '@LongLink' file...
975 my $make_longlink = ( length($clone->name) > NAME_LENGTH or
976 length($clone->prefix) > PREFIX_LENGTH
979 ### perhaps we need to make a longlink file?
980 if( $make_longlink ) {
981 my $longlink = Archive::Tar::File->new(
982 data => LONGLINK_NAME,
987 unless( $longlink ) {
988 $self->_error( qq[Could not create 'LongLink' entry for ] .
989 qq[oversize file '] . $clone->full_path ."'" );
993 push @write_me, $longlink;
996 push @write_me, $clone;
998 ### write the one, optionally 2 a::t::file objects to the handle
999 for my $clone (@write_me) {
1001 ### if the file is a symlink, there are 2 options:
1002 ### either we leave the symlink intact, but then we don't write any
1003 ### data OR we follow the symlink, which means we actually make a
1004 ### copy. if we do the latter, we have to change the TYPE of the
1006 my $link_ok = $clone->is_symlink && $Archive::Tar::FOLLOW_SYMLINK;
1007 my $data_ok = !$clone->is_symlink && $clone->has_content;
1009 ### downgrade to a 'normal' file if it's a symlink we're going to
1010 ### treat as a regular file
1011 $clone->_downgrade_to_plainfile if $link_ok;
1013 ### get the header for this block
1014 my $header = $self->_format_tar_entry( $clone );
1016 $self->_error(q[Could not format header for: ] .
1017 $clone->full_path );
1021 unless( print $handle $header ) {
1022 $self->_error(q[Could not write header for: ] .
1027 if( $link_ok or $data_ok ) {
1028 unless( print $handle $clone->data ) {
1029 $self->_error(q[Could not write data for: ] .
1034 ### pad the end of the clone if required ###
1035 print $handle TAR_PAD->( $clone->size ) if $clone->size % BLOCK
1038 } ### done writing these entries
1041 ### write the end markers ###
1042 print $handle TAR_END x 2 or
1043 return $self->_error( qq[Could not write tar end markers] );
1045 ### did you want it written to a file, or returned as a string? ###
1046 my $rv = length($file) ? 1
1047 : $HAS_PERLIO ? $dummy
1048 : do { seek $handle, 0, 0; local $/; <$handle> };
1050 ### make sure to close the handle;
1056 sub _format_tar_entry {
1058 my $entry = shift or return;
1059 my $ext_prefix = shift; $ext_prefix = '' unless defined $ext_prefix;
1060 my $no_prefix = shift || 0;
1062 my $file = $entry->name;
1063 my $prefix = $entry->prefix; $prefix = '' unless defined $prefix;
1065 ### remove the prefix from the file name
1066 ### not sure if this is still neeeded --kane
1067 ### no it's not -- Archive::Tar::File->_new_from_file will take care of
1068 ### this for us. Even worse, this would break if we tried to add a file
1070 #if( length $prefix ) {
1071 # $file =~ s/^$match//;
1074 $prefix = File::Spec::Unix->catdir($ext_prefix, $prefix)
1075 if length $ext_prefix;
1077 ### not sure why this is... ###
1078 my $l = PREFIX_LENGTH; # is ambiguous otherwise...
1079 substr ($prefix, 0, -$l) = "" if length $prefix >= PREFIX_LENGTH;
1081 my $f1 = "%06o"; my $f2 = "%11o";
1083 ### this might be optimizable with a 'changed' flag in the file objects ###
1088 (map { sprintf( $f1, $entry->$_() ) } qw[mode uid gid]),
1089 (map { sprintf( $f2, $entry->$_() ) } qw[size mtime]),
1091 "", # checksum field - space padded a bit down
1093 (map { $entry->$_() } qw[type linkname magic]),
1095 $entry->version || TAR_VERSION,
1097 (map { $entry->$_() } qw[uname gname]),
1098 (map { sprintf( $f1, $entry->$_() ) } qw[devmajor devminor]),
1100 ($no_prefix ? '' : $prefix)
1103 ### add the checksum ###
1104 substr($tar,148,7) = sprintf("%6o\0", unpack("%16C*",$tar));
1109 =head2 $tar->add_files( @filenamelist )
1111 Takes a list of filenames and adds them to the in-memory archive.
1113 The path to the file is automatically converted to a Unix like
1114 equivalent for use in the archive, and, if on MacOS, the file's
1115 modification time is converted from the MacOS epoch to the Unix epoch.
1116 So tar archives created on MacOS with B<Archive::Tar> can be read
1117 both with I<tar> on Unix and applications like I<suntar> or
1118 I<Stuffit Expander> on MacOS.
1120 Be aware that the file's type/creator and resource fork will be lost,
1121 which is usually what you want in cross-platform archives.
1123 Returns a list of C<Archive::Tar::File> objects that were just added.
1129 my @files = @_ or return;
1132 for my $file ( @files ) {
1133 unless( -e $file || -l $file ) {
1134 $self->_error( qq[No such file: '$file'] );
1138 my $obj = Archive::Tar::File->new( file => $file );
1140 $self->_error( qq[Unable to add file: '$file'] );
1147 push @{$self->{_data}}, @rv;
1152 =head2 $tar->add_data ( $filename, $data, [$opthashref] )
1154 Takes a filename, a scalar full of data and optionally a reference to
1155 a hash with specific options.
1157 Will add a file to the in-memory archive, with name C<$filename> and
1158 content C<$data>. Specific properties can be set using C<$opthashref>.
1159 The following list of properties is supported: name, size, mtime
1160 (last modified date), mode, uid, gid, linkname, uname, gname,
1161 devmajor, devminor, prefix, type. (On MacOS, the file's path and
1162 modification times are converted to Unix equivalents.)
1164 Valid values for the file type are the following constants defined in
1165 Archive::Tar::Constants:
1177 Hard and symbolic ("soft") links; linkname should specify target.
1183 Character and block devices. devmajor and devminor should specify the major
1184 and minor device numbers.
1200 Returns the C<Archive::Tar::File> object that was just added, or
1201 C<undef> on failure.
1207 my ($file, $data, $opt) = @_;
1209 my $obj = Archive::Tar::File->new( data => $file, $data, $opt );
1211 $self->_error( qq[Unable to add file: '$file'] );
1215 push @{$self->{_data}}, $obj;
1220 =head2 $tar->error( [$BOOL] )
1222 Returns the current errorstring (usually, the last error reported).
1223 If a true value was specified, it will give the C<Carp::longmess>
1224 equivalent of the error, in effect giving you a stacktrace.
1226 For backwards compatibility, this error is also available as
1227 C<$Archive::Tar::error> although it is much recommended you use the
1228 method call instead.
1238 my $msg = $error = shift;
1239 $longmess = Carp::longmess($error);
1241 ### set Archive::Tar::WARN to 0 to disable printing
1244 carp $DEBUG ? $longmess : $msg;
1252 return shift() ? $longmess : $error;
1256 =head2 $tar->setcwd( $cwd );
1258 C<Archive::Tar> needs to know the current directory, and it will run
1259 C<Cwd::cwd()> I<every> time it extracts a I<relative> entry from the
1260 tarfile and saves it in the file system. (As of version 1.30, however,
1261 C<Archive::Tar> will use the speed optimization described below
1262 automatically, so it's only relevant if you're using C<extract_file()>).
1264 Since C<Archive::Tar> doesn't change the current directory internally
1265 while it is extracting the items in a tarball, all calls to C<Cwd::cwd()>
1266 can be avoided if we can guarantee that the current directory doesn't
1267 get changed externally.
1269 To use this performance boost, set the current directory via
1272 $tar->setcwd( cwd() );
1274 once before calling a function like C<extract_file> and
1275 C<Archive::Tar> will use the current directory setting from then on
1276 and won't call C<Cwd::cwd()> internally.
1278 To switch back to the default behaviour, use
1280 $tar->setcwd( undef );
1282 and C<Archive::Tar> will call C<Cwd::cwd()> internally again.
1284 If you're using C<Archive::Tar>'s C<exract()> method, C<setcwd()> will
1293 $self->{cwd} = $cwd;
1296 =head2 $bool = $tar->has_io_string
1298 Returns true if we currently have C<IO::String> support loaded.
1300 Either C<IO::String> or C<perlio> support is needed to support writing
1301 stringified archives. Currently, C<perlio> is the preferred method, if
1304 See the C<GLOBAL VARIABLES> section to see how to change this preference.
1308 sub has_io_string { return $HAS_IO_STRING; }
1310 =head2 $bool = $tar->has_perlio
1312 Returns true if we currently have C<perlio> support loaded.
1314 This requires C<perl-5.8> or higher, compiled with C<perlio>
1316 Either C<IO::String> or C<perlio> support is needed to support writing
1317 stringified archives. Currently, C<perlio> is the preferred method, if
1320 See the C<GLOBAL VARIABLES> section to see how to change this preference.
1324 sub has_perlio { return $HAS_PERLIO; }
1327 =head1 Class Methods
1329 =head2 Archive::Tar->create_archive($file, $compression, @filelist)
1331 Creates a tar file from the list of files provided. The first
1332 argument can either be the name of the tar file to create or a
1333 reference to an open file handle (e.g. a GLOB reference).
1335 The second argument specifies the level of compression to be used, if
1336 any. Compression of tar files requires the installation of the
1337 IO::Zlib module. Specific levels of compression may be
1338 requested by passing a value between 2 and 9 as the second argument.
1339 Any other value evaluating as true will result in the default
1340 compression level being used.
1342 Note that when you pass in a filehandle, the compression argument
1343 is ignored, as all files are printed verbatim to your filehandle.
1344 If you wish to enable compression with filehandles, use an
1345 C<IO::Zlib> filehandle instead.
1347 The remaining arguments list the files to be included in the tar file.
1348 These files must all exist. Any files which don't exist or can't be
1349 read are silently ignored.
1351 If the archive creation fails for any reason, C<create_archive> will
1352 return false. Please use the C<error> method to find the cause of the
1355 Note that this method does not write C<on the fly> as it were; it
1356 still reads all the files into memory before writing out the archive.
1357 Consult the FAQ below if this is a problem.
1361 sub create_archive {
1364 my $file = shift; return unless defined $file;
1365 my $gzip = shift || 0;
1369 return $class->_error( qq[Cowardly refusing to create empty archive!] );
1372 my $tar = $class->new;
1373 $tar->add_files( @files );
1374 return $tar->write( $file, $gzip );
1377 =head2 Archive::Tar->list_archive ($file, $compressed, [\@properties])
1379 Returns a list of the names of all the files in the archive. The
1380 first argument can either be the name of the tar file to list or a
1381 reference to an open file handle (e.g. a GLOB reference).
1383 If C<list_archive()> is passed an array reference as its third
1384 argument it returns a list of hash references containing the requested
1385 properties of each file. The following list of properties is
1386 supported: full_path, name, size, mtime (last modified date), mode,
1387 uid, gid, linkname, uname, gname, devmajor, devminor, prefix.
1389 See C<Archive::Tar::File> for details about supported properties.
1391 Passing an array reference containing only one element, 'name', is
1392 special cased to return a list of names rather than a list of hash
1399 my $file = shift; return unless defined $file;
1400 my $gzip = shift || 0;
1402 my $tar = $class->new($file, $gzip);
1405 return $tar->list_files( @_ );
1408 =head2 Archive::Tar->extract_archive ($file, $gzip)
1410 Extracts the contents of the tar file. The first argument can either
1411 be the name of the tar file to create or a reference to an open file
1412 handle (e.g. a GLOB reference). All relative paths in the tar file will
1413 be created underneath the current working directory.
1415 C<extract_archive> will return a list of files it extracted.
1416 If the archive extraction fails for any reason, C<extract_archive>
1417 will return false. Please use the C<error> method to find the cause
1422 sub extract_archive {
1424 my $file = shift; return unless defined $file;
1425 my $gzip = shift || 0;
1427 my $tar = $class->new( ) or return;
1429 return $tar->read( $file, $gzip, { extract => 1 } );
1432 =head2 Archive::Tar->can_handle_compressed_files
1434 A simple checking routine, which will return true if C<Archive::Tar>
1435 is able to uncompress compressed archives on the fly with C<IO::Zlib>,
1436 or false if C<IO::Zlib> is not installed.
1438 You can use this as a shortcut to determine whether C<Archive::Tar>
1439 will do what you think before passing compressed archives to its
1444 sub can_handle_compressed_files { return ZLIB ? 1 : 0 }
1446 sub no_string_support {
1447 croak("You have to install IO::String to support writing archives to strings");
1454 =head1 GLOBAL VARIABLES
1456 =head2 $Archive::Tar::FOLLOW_SYMLINK
1458 Set this variable to C<1> to make C<Archive::Tar> effectively make a
1459 copy of the file when extracting. Default is C<0>, which
1460 means the symlink stays intact. Of course, you will have to pack the
1461 file linked to as well.
1463 This option is checked when you write out the tarfile using C<write>
1464 or C<create_archive>.
1466 This works just like C</bin/tar>'s C<-h> option.
1468 =head2 $Archive::Tar::CHOWN
1470 By default, C<Archive::Tar> will try to C<chown> your files if it is
1471 able to. In some cases, this may not be desired. In that case, set
1472 this variable to C<0> to disable C<chown>-ing, even if it were
1475 The default is C<1>.
1477 =head2 $Archive::Tar::CHMOD
1479 By default, C<Archive::Tar> will try to C<chmod> your files to
1480 whatever mode was specified for the particular file in the archive.
1481 In some cases, this may not be desired. In that case, set this
1482 variable to C<0> to disable C<chmod>-ing.
1484 The default is C<1>.
1486 =head2 $Archive::Tar::DO_NOT_USE_PREFIX
1488 By default, C<Archive::Tar> will try to put paths that are over
1489 100 characters in the C<prefix> field of your tar header, as
1490 defined per POSIX-standard. However, some (older) tar programs
1491 do not implement this spec. To retain compatibility with these older
1492 or non-POSIX compliant versions, you can set the C<$DO_NOT_USE_PREFIX>
1493 variable to a true value, and C<Archive::Tar> will use an alternate
1494 way of dealing with paths over 100 characters by using the
1495 C<GNU Extended Header> feature.
1497 Note that clients who do not support the C<GNU Extended Header>
1498 feature will not be able to read these archives. Such clients include
1499 tars on C<Solaris>, C<Irix> and C<AIX>.
1501 The default is C<0>.
1503 =head2 $Archive::Tar::DEBUG
1505 Set this variable to C<1> to always get the C<Carp::longmess> output
1506 of the warnings, instead of the regular C<carp>. This is the same
1507 message you would get by doing:
1513 =head2 $Archive::Tar::WARN
1515 Set this variable to C<0> if you do not want any warnings printed.
1516 Personally I recommend against doing this, but people asked for the
1517 option. Also, be advised that this is of course not threadsafe.
1521 =head2 $Archive::Tar::error
1523 Holds the last reported error. Kept for historical reasons, but its
1524 use is very much discouraged. Use the C<error()> method instead:
1526 warn $tar->error unless $tar->extract;
1528 =head2 $Archive::Tar::HAS_PERLIO
1530 This variable holds a boolean indicating if we currently have
1531 C<perlio> support loaded. This will be enabled for any perl
1532 greater than C<5.8> compiled with C<perlio>.
1534 If you feel strongly about disabling it, set this variable to
1535 C<false>. Note that you will then need C<IO::String> installed
1536 to support writing stringified archives.
1538 Don't change this variable unless you B<really> know what you're
1541 =head2 $Archive::Tar::HAS_IO_STRING
1543 This variable holds a boolean indicating if we currently have
1544 C<IO::String> support loaded. This will be enabled for any perl
1545 that has a loadable C<IO::String> module.
1547 If you feel strongly about disabling it, set this variable to
1548 C<false>. Note that you will then need C<perlio> support from
1549 your perl to be able to write stringified archives.
1551 Don't change this variable unless you B<really> know what you're
1558 =item What's the minimum perl version required to run Archive::Tar?
1560 You will need perl version 5.005_03 or newer.
1562 =item Isn't Archive::Tar slow?
1564 Yes it is. It's pure perl, so it's a lot slower then your C</bin/tar>
1565 However, it's very portable. If speed is an issue, consider using
1566 C</bin/tar> instead.
1568 =item Isn't Archive::Tar heavier on memory than /bin/tar?
1570 Yes it is, see previous answer. Since C<Compress::Zlib> and therefore
1571 C<IO::Zlib> doesn't support C<seek> on their filehandles, there is little
1572 choice but to read the archive into memory.
1573 This is ok if you want to do in-memory manipulation of the archive.
1574 If you just want to extract, use the C<extract_archive> class method
1575 instead. It will optimize and write to disk immediately.
1577 =item Can't you lazy-load data instead?
1579 No, not easily. See previous question.
1581 =item How much memory will an X kb tar file need?
1583 Probably more than X kb, since it will all be read into memory. If
1584 this is a problem, and you don't need to do in memory manipulation
1585 of the archive, consider using C</bin/tar> instead.
1587 =item What do you do with unsupported filetypes in an archive?
1589 C<Unix> has a few filetypes that aren't supported on other platforms,
1590 like C<Win32>. If we encounter a C<hardlink> or C<symlink> we'll just
1591 try to make a copy of the original file, rather than throwing an error.
1593 This does require you to read the entire archive in to memory first,
1594 since otherwise we wouldn't know what data to fill the copy with.
1595 (This means that you cannot use the class methods on archives that
1596 have incompatible filetypes and still expect things to work).
1598 For other filetypes, like C<chardevs> and C<blockdevs> we'll warn that
1599 the extraction of this particular item didn't work.
1601 =item I'm using WinZip, or some other non-POSIX client, and files are not being extracted properly!
1603 By default, C<Archive::Tar> is in a completely POSIX-compatible
1604 mode, which uses the POSIX-specification of C<tar> to store files.
1605 For paths greather than 100 characters, this is done using the
1606 C<POSIX header prefix>. Non-POSIX-compatible clients may not support
1607 this part of the specification, and may only support the C<GNU Extended
1608 Header> functionality. To facilitate those clients, you can set the
1609 C<$Archive::Tar::DO_NOT_USE_PREFIX> variable to C<true>. See the
1610 C<GLOBAL VARIABLES> section for details on this variable.
1612 Note that GNU tar earlier than version 1.14 does not cope well with
1613 the C<POSIX header prefix>. If you use such a version, consider setting
1614 the C<$Archive::Tar::DO_NOT_USE_PREFIX> variable to C<true>.
1616 =item How do I extract only files that have property X from an archive?
1618 Sometimes, you might not wish to extract a complete archive, just
1619 the files that are relevant to you, based on some criteria.
1621 You can do this by filtering a list of C<Archive::Tar::File> objects
1622 based on your criteria. For example, to extract only files that have
1623 the string C<foo> in their title, you would use:
1626 grep { $_->full_path =~ /foo/ } $tar->get_files
1629 This way, you can filter on any attribute of the files in the archive.
1630 Consult the C<Archive::Tar::File> documentation on how to use these
1633 =item How do I access .tar.Z files?
1635 The C<Archive::Tar> module can optionally use C<Compress::Zlib> (via
1636 the C<IO::Zlib> module) to access tar files that have been compressed
1637 with C<gzip>. Unfortunately tar files compressed with the Unix C<compress>
1638 utility cannot be read by C<Compress::Zlib> and so cannot be directly
1639 accesses by C<Archive::Tar>.
1641 If the C<uncompress> or C<gunzip> programs are available, you can use
1642 one of these workarounds to read C<.tar.Z> files from C<Archive::Tar>
1644 Firstly with C<uncompress>
1648 open F, "uncompress -c $filename |";
1649 my $tar = Archive::Tar->new(*F);
1652 and this with C<gunzip>
1656 open F, "gunzip -c $filename |";
1657 my $tar = Archive::Tar->new(*F);
1660 Similarly, if the C<compress> program is available, you can use this to
1661 write a C<.tar.Z> file
1666 my $fh = new IO::File "| compress -c >$filename";
1667 my $tar = Archive::Tar->new();
1679 =item Check if passed in handles are open for read/write
1681 Currently I don't know of any portable pure perl way to do this.
1682 Suggestions welcome.
1684 =item Allow archives to be passed in as string
1686 Currently, we only allow opened filehandles or filenames, but
1687 not strings. The internals would need some reworking to facilitate
1688 stringified archives.
1690 =item Facilitate processing an opened filehandle of a compressed archive
1692 Currently, we only support this if the filehandle is an IO::Zlib object.
1693 Environments, like apache, will present you with an opened filehandle
1694 to an uploaded file, which might be a compressed archive.
1702 =item The GNU tar specification
1704 C<http://www.gnu.org/software/tar/manual/tar.html>
1706 =item The PAX format specication
1708 The specifcation which tar derives from; C< http://www.opengroup.org/onlinepubs/007904975/utilities/pax.html>
1710 =item A comparison of GNU and POSIX tar standards; C<http://www.delorie.com/gnu/docs/tar/tar_114.html>
1712 =item GNU tar intends to switch to POSIX compatibility
1714 GNU Tar authors have expressed their intention to become completely
1715 POSIX-compatible; C<http://www.gnu.org/software/tar/manual/html_node/Formats.html>
1717 =item A Comparison between various tar implementations
1719 Lists known issues and incompatibilities; C<http://gd.tuwien.ac.at/utils/archivers/star/README.otherbugs>
1725 This module by Jos Boumans E<lt>kane@cpan.orgE<gt>.
1727 Please reports bugs to E<lt>bug-archive-tar@rt.cpan.orgE<gt>.
1729 =head1 ACKNOWLEDGEMENTS
1731 Thanks to Sean Burke, Chris Nandor, Chip Salzenberg, Tim Heaney and
1732 especially Andrew Savige for their help and suggestions.
1736 This module is copyright (c) 2002 - 2007 Jos Boumans
1737 E<lt>kane@cpan.orgE<gt>. All rights reserved.
1739 This library is free software; you may redistribute and/or modify
1740 it under the same terms as Perl itself.