1 ### the gnu tar specification:
2 ### http://www.gnu.org/software/tar/manual/tar.html
4 ### and the pax format spec, which tar derives from:
5 ### http://www.opengroup.org/onlinepubs/007904975/utilities/pax.html
11 use vars qw[$DEBUG $error $VERSION $WARN $FOLLOW_SYMLINK $CHOWN $CHMOD
12 $DO_NOT_USE_PREFIX $HAS_PERLIO $HAS_IO_STRING];
20 $DO_NOT_USE_PREFIX = 0;
24 $HAS_PERLIO = $Config::Config{useperlio};
26 ### try and load IO::String anyway, so you can dynamically
27 ### switch between perlio and IO::String
32 $HAS_IO_STRING = $@ ? 0 : 1;
38 use Carp qw(carp croak);
40 use File::Spec::Unix ();
43 use Archive::Tar::File;
44 use Archive::Tar::Constant;
48 Archive::Tar - module for manipulations of tar archives
53 my $tar = Archive::Tar->new;
55 $tar->read('origin.tgz',1);
58 $tar->add_files('file/foo.pl', 'docs/README');
59 $tar->add_data('file/baz.txt', 'This is the contents now');
61 $tar->rename('oldname', 'new/file/name');
63 $tar->write('files.tar');
67 Archive::Tar provides an object oriented mechanism for handling tar
68 files. It provides class methods for quick and easy files handling
69 while also allowing for the creation of tar file objects for custom
70 manipulation. If you have the IO::Zlib module installed,
71 Archive::Tar will also support compressed or gzipped tar files.
73 An object of class Archive::Tar represents a .tar(.gz) archive full
78 =head2 Archive::Tar->new( [$file, $compressed] )
80 Returns a new Tar object. If given any arguments, C<new()> calls the
81 C<read()> method automatically, passing on the arguments provided to
84 If C<new()> is invoked with arguments and the C<read()> method fails
85 for any reason, C<new()> returns undef.
94 ### install get/set accessors for this object.
95 for my $key ( keys %$tmpl ) {
97 *{__PACKAGE__."::$key"} = sub {
99 $self->{$key} = $_[0] if @_;
100 return $self->{$key};
106 $class = ref $class if ref $class;
108 ### copying $tmpl here since a shallow copy makes it use the
109 ### same aref, causing for files to remain in memory always.
110 my $obj = bless { _data => [ ], _file => 'Unknown' }, $class;
113 unless ( $obj->read( @_ ) ) {
114 $obj->_error(qq[No data could be read from file]);
122 =head2 $tar->read ( $filename|$handle, $compressed, {opt => 'val'} )
124 Read the given tar file into memory.
125 The first argument can either be the name of a file or a reference to
126 an already open filehandle (or an IO::Zlib object if it's compressed)
127 The second argument indicates whether the file referenced by the first
128 argument is compressed.
130 The C<read> will I<replace> any previous content in C<$tar>!
132 The second argument may be considered optional if IO::Zlib is
133 installed, since it will transparently Do The Right Thing.
134 Archive::Tar will warn if you try to pass a compressed file if
135 IO::Zlib is not available and simply return.
137 Note that you can currently B<not> pass a C<gzip> compressed
138 filehandle, which is not opened with C<IO::Zlib>, nor a string
139 containing the full archive information (either compressed or
140 uncompressed). These are worth while features, but not currently
141 implemented. See the C<TODO> section.
143 The third argument can be a hash reference with options. Note that
144 all options are case-sensitive.
150 Do not read more than C<limit> files. This is useful if you have
151 very big archives, and are only interested in the first few files.
155 If set to true, immediately extract entries when reading them. This
156 gives you the same memory break as the C<extract_archive> function.
157 Note however that entries will not be read into memory, but written
162 All files are stored internally as C<Archive::Tar::File> objects.
163 Please consult the L<Archive::Tar::File> documentation for details.
165 Returns the number of files read in scalar context, and a list of
166 C<Archive::Tar::File> objects in list context.
173 my $gzip = shift || 0;
174 my $opts = shift || {};
176 unless( defined $file ) {
177 $self->_error( qq[No file to read from!] );
180 $self->_file( $file );
183 my $handle = $self->_get_handle($file, $gzip, READ_ONLY->( ZLIB ) )
186 my $data = $self->_read_tar( $handle, $opts ) or return;
188 $self->_data( $data );
190 return wantarray ? @$data : scalar @$data;
195 my $file = shift; return unless defined $file;
196 return $file if ref $file;
198 my $gzip = shift || 0;
199 my $mode = shift || READ_ONLY->( ZLIB ); # default to read only
203 ### only default to ZLIB if we're not trying to /write/ to a handle ###
204 if( ZLIB and $gzip || MODE_READ->( $mode ) ) {
206 ### IO::Zlib will Do The Right Thing, even when passed
212 $self->_error(qq[Compression not available - Install IO::Zlib!]);
221 unless( $fh->open( $file, $mode ) ) {
222 $self->_error( qq[Could not create filehandle for '$file': $!!] );
233 my $handle = shift or return;
234 my $opts = shift || {};
236 my $count = $opts->{limit} || 0;
237 my $extract = $opts->{extract} || 0;
239 ### set a cap on the amount of files to extract ###
241 $limit = 1 if $count > 0;
246 my $real_name; # to set the name of a file when
247 # we're encountering @longlink
251 while( $handle->read( $chunk, HEAD ) ) {
252 ### IO::Zlib doesn't support this yet
253 my $offset = eval { tell $handle } || 'unknown';
256 my $gzip = GZIP_MAGIC_NUM;
257 if( $chunk =~ /$gzip/ ) {
258 $self->_error( qq[Cannot read compressed format in tar-mode] );
263 ### if we can't read in all bytes... ###
264 last if length $chunk != HEAD;
266 ### Apparently this should really be two blocks of 512 zeroes,
267 ### but GNU tar sometimes gets it wrong. See comment in the
268 ### source code (tar.c) to GNU cpio.
269 next if $chunk eq TAR_END;
271 ### according to the posix spec, the last 12 bytes of the header are
272 ### null bytes, to pad it to a 512 byte block. That means if these
273 ### bytes are NOT null bytes, it's a corrrupt header. See:
274 ### www.koders.com/c/fidCE473AD3D9F835D690259D60AD5654591D91D5BA.aspx
276 { my $nulls = join '', "\0" x 12;
277 unless( $nulls eq substr( $chunk, 500, 12 ) ) {
278 $self->_error( qq[Invalid header block at offset $offset] );
283 ### pass the realname, so we can set it 'proper' right away
284 ### some of the heuristics are done on the name, so important
287 { my %extra_args = ();
288 $extra_args{'name'} = $$real_name if defined $real_name;
290 unless( $entry = Archive::Tar::File->new( chunk => $chunk,
293 $self->_error( qq[Couldn't read chunk at offset $offset] );
299 ### http://www.gnu.org/manual/tar/html_node/tar_139.html
300 next if $entry->is_label;
302 if( length $entry->type and ($entry->is_file || $entry->is_longlink) ) {
304 if ( $entry->is_file && !$entry->validate ) {
305 ### sometimes the chunk is rather fux0r3d and a whole 512
306 ### bytes ends p in the ->name area.
307 ### clean it up, if need be
308 my $name = $entry->name;
309 $name = substr($name, 0, 100) if length $name > 100;
312 $self->_error( $name . qq[: checksum error] );
316 my $block = BLOCK_SIZE->( $entry->size );
318 $data = $entry->get_content_by_ref;
320 ### just read everything into memory
321 ### can't do lazy loading since IO::Zlib doesn't support 'seek'
322 ### this is because Compress::Zlib doesn't support it =/
323 ### this reads in the whole data in one read() call.
324 if( $handle->read( $$data, $block ) < $block ) {
325 $self->_error( qq[Read error on tarfile (missing data) '].
326 $entry->full_path ."' at offset $offset" );
330 ### throw away trailing garbage ###
331 substr ($$data, $entry->size) = "" if defined $$data;
333 ### part II of the @LongLink munging -- need to do /after/
334 ### the checksum check.
335 if( $entry->is_longlink ) {
336 ### weird thing in tarfiles -- if the file is actually a
337 ### @LongLink, the data part seems to have a trailing ^@
338 ### (unprintable) char. to display, pipe output through less.
339 ### but that doesn't *always* happen.. so check if the last
340 ### character is a control character, and if so remove it
341 ### at any rate, we better remove that character here, or tests
342 ### like 'eq' and hashlook ups based on names will SO not work
343 ### remove it by calculating the proper size, and then
344 ### tossing out everything that's longer than that size.
346 ### count number of nulls
347 my $nulls = $$data =~ tr/\0/\0/;
349 ### cut data + size by that many bytes
350 $entry->size( $entry->size - $nulls );
351 substr ($$data, $entry->size) = "";
355 ### clean up of the entries.. posix tar /apparently/ has some
356 ### weird 'feature' that allows for filenames > 255 characters
357 ### they'll put a header in with as name '././@LongLink' and the
358 ### contents will be the name of the /next/ file in the archive
359 ### pretty crappy and kludgy if you ask me
361 ### set the name for the next entry if this is a @LongLink;
362 ### this is one ugly hack =/ but needed for direct extraction
363 if( $entry->is_longlink ) {
366 } elsif ( defined $real_name ) {
367 $entry->name( $$real_name );
372 $self->_extract_file( $entry ) if $extract
373 && !$entry->is_longlink
374 && !$entry->is_unknown
375 && !$entry->is_label;
377 ### Guard against tarfiles with garbage at the end
378 last LOOP if $entry->name eq '';
380 ### push only the name on the rv if we're extracting
381 ### -- for extract_archive
382 push @$tarfile, ($extract ? $entry->name : $entry);
385 $count-- unless $entry->is_longlink || $entry->is_dir;
386 last LOOP unless $count;
395 =head2 $tar->contains_file( $filename )
397 Check if the archive contains a certain file.
398 It will return true if the file is in the archive, false otherwise.
400 Note however, that this function does an exact match using C<eq>
401 on the full path. So it cannot compensate for case-insensitive file-
402 systems or compare 2 paths to see if they would point to the same
409 my $full = shift or return;
411 return 1 if $self->_find_entry($full);
415 =head2 $tar->extract( [@filenames] )
417 Write files whose names are equivalent to any of the names in
418 C<@filenames> to disk, creating subdirectories as necessary. This
419 might not work too well under VMS.
420 Under MacPerl, the file's modification time will be converted to the
421 MacOS zero of time, and appropriate conversions will be done to the
422 path. However, the length of each element of the path is not
423 inspected to see whether it's longer than MacOS currently allows (32
426 If C<extract> is called without a list of file names, the entire
427 contents of the archive are extracted.
429 Returns a list of filenames extracted.
438 # use the speed optimization for all extracted files
439 local($self->{cwd}) = cwd() unless $self->{cwd};
441 ### you requested the extraction of only certian files
443 for my $file ( @args ) {
445 ### it's already an object?
446 if( UNIVERSAL::isa( $file, 'Archive::Tar::File' ) ) {
454 for my $entry ( @{$self->_data} ) {
455 next unless $file eq $entry->full_path;
457 ### we found the file you're looking for
463 return $self->_error(
464 qq[Could not find '$file' in archive] );
469 ### just grab all the file items
471 @files = $self->get_files;
474 ### nothing found? that's an error
475 unless( scalar @files ) {
476 $self->_error( qq[No files found for ] . $self->_file );
481 for my $entry ( @files ) {
482 unless( $self->_extract_file( $entry ) ) {
483 $self->_error(q[Could not extract ']. $entry->full_path .q['] );
491 =head2 $tar->extract_file( $file, [$extract_path] )
493 Write an entry, whose name is equivalent to the file name provided to
494 disk. Optionally takes a second parameter, which is the full (unix)
495 path (including filename) the entry will be written to.
499 $tar->extract_file( 'name/in/archive', 'name/i/want/to/give/it' );
501 $tar->extract_file( $at_file_object, 'name/i/want/to/give/it' );
503 Returns true on success, false on failure.
509 my $file = shift or return;
512 my $entry = $self->_find_entry( $file )
513 or $self->_error( qq[Could not find an entry for '$file'] ), return;
515 return $self->_extract_file( $entry, $alt );
520 my $entry = shift or return;
523 ### you wanted an alternate extraction location ###
524 my $name = defined $alt ? $alt : $entry->full_path;
526 ### splitpath takes a bool at the end to indicate
527 ### that it's splitting a dir
528 my ($vol,$dirs,$file);
529 if ( defined $alt ) { # It's a local-OS path
530 ($vol,$dirs,$file) = File::Spec->splitpath( $alt,
533 ($vol,$dirs,$file) = File::Spec::Unix->splitpath( $name,
538 ### is $name an absolute path? ###
539 if( File::Spec->file_name_is_absolute( $dirs ) ) {
542 ### it's a relative path ###
544 my $cwd = (defined $self->{cwd} ? $self->{cwd} : cwd());
545 my @dirs = File::Spec::Unix->splitdir( $dirs );
546 my @cwd = File::Spec->splitdir( $cwd );
547 $dir = File::Spec->catdir( @cwd, @dirs );
549 # catdir() returns undef if the path is longer than 255 chars on VMS
550 unless ( defined $dir ) {
551 $^W && $self->_error( qq[Could not compose a path for '$dirs'\n] );
557 if( -e $dir && !-d _ ) {
558 $^W && $self->_error( qq['$dir' exists, but it's not a directory!\n] );
563 eval { File::Path::mkpath( $dir, 0, 0777 ) };
565 $self->_error( qq[Could not create directory '$dir': $@] );
570 ### we're done if we just needed to create a dir ###
571 return 1 if $entry->is_dir;
573 my $full = File::Spec->catfile( $dir, $file );
575 if( $entry->is_unknown ) {
576 $self->_error( qq[Unknown file type for file '$full'] );
580 if( length $entry->type && $entry->is_file ) {
581 my $fh = IO::File->new;
582 $fh->open( '>' . $full ) or (
583 $self->_error( qq[Could not open file '$full': $!] ),
589 syswrite $fh, $entry->data or (
590 $self->_error( qq[Could not write data to '$full'] ),
596 $self->_error( qq[Could not close file '$full'] ),
601 $self->_make_special_file( $entry, $full ) or return;
604 utime time, $entry->mtime - TIME_OFFSET, $full or
605 $self->_error( qq[Could not update timestamp] );
607 if( $CHOWN && CAN_CHOWN ) {
608 chown $entry->uid, $entry->gid, $full or
609 $self->_error( qq[Could not set uid/gid on '$full'] );
612 ### only chmod if we're allowed to, but never chmod symlinks, since they'll
613 ### change the perms on the file they're linking too...
614 if( $CHMOD and not -l $full ) {
615 chmod $entry->mode, $full or
616 $self->_error( qq[Could not chown '$full' to ] . $entry->mode );
622 sub _make_special_file {
624 my $entry = shift or return;
625 my $file = shift; return unless defined $file;
629 if( $entry->is_symlink ) {
632 symlink( $entry->linkname, $file ) or $fail++;
635 $self->_extract_special_file_as_plain_file( $entry, $file )
639 $err = qq[Making symbolink link from '] . $entry->linkname .
640 qq[' to '$file' failed] if $fail;
642 } elsif ( $entry->is_hardlink ) {
645 link( $entry->linkname, $file ) or $fail++;
648 $self->_extract_special_file_as_plain_file( $entry, $file )
652 $err = qq[Making hard link from '] . $entry->linkname .
653 qq[' to '$file' failed] if $fail;
655 } elsif ( $entry->is_fifo ) {
656 ON_UNIX && !system('mknod', $file, 'p') or
657 $err = qq[Making fifo ']. $entry->name .qq[' failed];
659 } elsif ( $entry->is_blockdev or $entry->is_chardev ) {
660 my $mode = $entry->is_blockdev ? 'b' : 'c';
662 ON_UNIX && !system('mknod', $file, $mode,
663 $entry->devmajor, $entry->devminor) or
664 $err = qq[Making block device ']. $entry->name .qq[' (maj=] .
665 $entry->devmajor . qq[ min=] . $entry->devminor .
668 } elsif ( $entry->is_socket ) {
669 ### the original doesn't do anything special for sockets.... ###
673 return $err ? $self->_error( $err ) : 1;
676 ### don't know how to make symlinks, let's just extract the file as
678 sub _extract_special_file_as_plain_file {
680 my $entry = shift or return;
681 my $file = shift; return unless defined $file;
685 my $orig = $self->_find_entry( $entry->linkname );
688 $err = qq[Could not find file '] . $entry->linkname .
693 ### clone the entry, make it appear as a normal file ###
694 my $clone = $entry->clone;
695 $clone->_downgrade_to_plainfile;
696 $self->_extract_file( $clone, $file ) or last TRY;
701 return $self->_error($err);
704 =head2 $tar->list_files( [\@properties] )
706 Returns a list of the names of all the files in the archive.
708 If C<list_files()> is passed an array reference as its first argument
709 it returns a list of hash references containing the requested
710 properties of each file. The following list of properties is
711 supported: name, size, mtime (last modified date), mode, uid, gid,
712 linkname, uname, gname, devmajor, devminor, prefix.
714 Passing an array reference containing only one element, 'name', is
715 special cased to return a list of names rather than a list of hash
716 references, making it equivalent to calling C<list_files> without
723 my $aref = shift || [ ];
725 unless( $self->_data ) {
726 $self->read() or return;
729 if( @$aref == 0 or ( @$aref == 1 and $aref->[0] eq 'name' ) ) {
730 return map { $_->full_path } @{$self->_data};
734 #for my $obj ( @{$self->_data} ) {
735 # push @rv, { map { $_ => $obj->$_() } @$aref };
739 ### this does the same as the above.. just needs a +{ }
740 ### to make sure perl doesn't confuse it for a block
741 return map { my $o=$_;
742 +{ map { $_ => $o->$_() } @$aref }
751 unless( defined $file ) {
752 $self->_error( qq[No file specified] );
756 ### it's an object already
757 return $file if UNIVERSAL::isa( $file, 'Archive::Tar::File' );
759 for my $entry ( @{$self->_data} ) {
760 my $path = $entry->full_path;
761 return $entry if $path eq $file;
764 $self->_error( qq[No such file in archive: '$file'] );
768 =head2 $tar->get_files( [@filenames] )
770 Returns the C<Archive::Tar::File> objects matching the filenames
771 provided. If no filename list was passed, all C<Archive::Tar::File>
772 objects in the current Tar object are returned.
774 Please refer to the C<Archive::Tar::File> documentation on how to
775 handle these objects.
782 return @{ $self->_data } unless @_;
785 for my $file ( @_ ) {
786 push @list, grep { defined } $self->_find_entry( $file );
792 =head2 $tar->get_content( $file )
794 Return the content of the named file.
800 my $entry = $self->_find_entry( shift ) or return;
805 =head2 $tar->replace_content( $file, $content )
807 Make the string $content be the content for the file named $file.
811 sub replace_content {
813 my $entry = $self->_find_entry( shift ) or return;
815 return $entry->replace_content( shift );
818 =head2 $tar->rename( $file, $new_name )
820 Rename the file of the in-memory archive to $new_name.
822 Note that you must specify a Unix path for $new_name, since per tar
823 standard, all files in the archive must be Unix paths.
825 Returns true on success and false on failure.
831 my $file = shift; return unless defined $file;
832 my $new = shift; return unless defined $new;
834 my $entry = $self->_find_entry( $file ) or return;
836 return $entry->rename( $new );
839 =head2 $tar->remove (@filenamelist)
841 Removes any entries with names matching any of the given filenames
842 from the in-memory archive. Returns a list of C<Archive::Tar::File>
851 my %seen = map { $_->full_path => $_ } @{$self->_data};
852 delete $seen{ $_ } for @list;
854 $self->_data( [values %seen] );
861 C<clear> clears the current in-memory archive. This effectively gives
862 you a 'blank' object, ready to be filled again. Note that C<clear>
863 only has effect on the object, not the underlying tarfile.
868 my $self = shift or return;
877 =head2 $tar->write ( [$file, $compressed, $prefix] )
879 Write the in-memory archive to disk. The first argument can either
880 be the name of a file or a reference to an already open filehandle (a
881 GLOB reference). If the second argument is true, the module will use
882 IO::Zlib to write the file in a compressed format. If IO::Zlib is
883 not available, the C<write> method will fail and return.
885 Note that when you pass in a filehandle, the compression argument
886 is ignored, as all files are printed verbatim to your filehandle.
887 If you wish to enable compression with filehandles, use an
888 C<IO::Zlib> filehandle instead.
890 Specific levels of compression can be chosen by passing the values 2
891 through 9 as the second parameter.
893 The third argument is an optional prefix. All files will be tucked
894 away in the directory you specify as prefix. So if you have files
895 'a' and 'b' in your archive, and you specify 'foo' as prefix, they
896 will be written to the archive as 'foo/a' and 'foo/b'.
898 If no arguments are given, C<write> returns the entire formatted
899 archive as a string, which could be useful if you'd like to stuff the
900 archive into a socket or a pipe to gzip or something.
906 my $file = shift; $file = '' unless defined $file;
907 my $gzip = shift || 0;
908 my $ext_prefix = shift; $ext_prefix = '' unless defined $ext_prefix;
911 ### only need a handle if we have a file to print to ###
912 my $handle = length($file)
913 ? ( $self->_get_handle($file, $gzip, WRITE_ONLY->($gzip) )
915 : $HAS_PERLIO ? do { open my $h, '>', \$dummy; $h }
916 : $HAS_IO_STRING ? IO::String->new
917 : __PACKAGE__->no_string_support();
921 for my $entry ( @{$self->_data} ) {
922 ### entries to be written to the tarfile ###
925 ### only now will we change the object to reflect the current state
926 ### of the name and prefix fields -- this needs to be limited to
928 my $clone = $entry->clone;
931 ### so, if you don't want use to use the prefix, we'll stuff
932 ### everything in the name field instead
933 if( $DO_NOT_USE_PREFIX ) {
935 ### you might have an extended prefix, if so, set it in the clone
936 ### XXX is ::Unix right?
937 $clone->name( length $ext_prefix
938 ? File::Spec::Unix->catdir( $ext_prefix,
940 : $clone->full_path );
941 $clone->prefix( '' );
943 ### otherwise, we'll have to set it properly -- prefix part in the
944 ### prefix and name part in the name field.
947 ### split them here, not before!
948 my ($prefix,$name) = $clone->_prefix_and_file( $clone->full_path );
950 ### you might have an extended prefix, if so, set it in the clone
951 ### XXX is ::Unix right?
952 $prefix = File::Spec::Unix->catdir( $ext_prefix, $prefix )
953 if length $ext_prefix;
955 $clone->prefix( $prefix );
956 $clone->name( $name );
959 ### names are too long, and will get truncated if we don't add a
960 ### '@LongLink' file...
961 my $make_longlink = ( length($clone->name) > NAME_LENGTH or
962 length($clone->prefix) > PREFIX_LENGTH
965 ### perhaps we need to make a longlink file?
966 if( $make_longlink ) {
967 my $longlink = Archive::Tar::File->new(
968 data => LONGLINK_NAME,
973 unless( $longlink ) {
974 $self->_error( qq[Could not create 'LongLink' entry for ] .
975 qq[oversize file '] . $clone->full_path ."'" );
979 push @write_me, $longlink;
982 push @write_me, $clone;
984 ### write the one, optionally 2 a::t::file objects to the handle
985 for my $clone (@write_me) {
987 ### if the file is a symlink, there are 2 options:
988 ### either we leave the symlink intact, but then we don't write any
989 ### data OR we follow the symlink, which means we actually make a
990 ### copy. if we do the latter, we have to change the TYPE of the
992 my $link_ok = $clone->is_symlink && $Archive::Tar::FOLLOW_SYMLINK;
993 my $data_ok = !$clone->is_symlink && $clone->has_content;
995 ### downgrade to a 'normal' file if it's a symlink we're going to
996 ### treat as a regular file
997 $clone->_downgrade_to_plainfile if $link_ok;
999 ### get the header for this block
1000 my $header = $self->_format_tar_entry( $clone );
1002 $self->_error(q[Could not format header for: ] .
1003 $clone->full_path );
1007 unless( print $handle $header ) {
1008 $self->_error(q[Could not write header for: ] .
1013 if( $link_ok or $data_ok ) {
1014 unless( print $handle $clone->data ) {
1015 $self->_error(q[Could not write data for: ] .
1020 ### pad the end of the clone if required ###
1021 print $handle TAR_PAD->( $clone->size ) if $clone->size % BLOCK
1024 } ### done writing these entries
1027 ### write the end markers ###
1028 print $handle TAR_END x 2 or
1029 return $self->_error( qq[Could not write tar end markers] );
1031 ### did you want it written to a file, or returned as a string? ###
1032 my $rv = length($file) ? 1
1033 : $HAS_PERLIO ? $dummy
1034 : do { seek $handle, 0, 0; local $/; <$handle> };
1036 ### make sure to close the handle;
1042 sub _format_tar_entry {
1044 my $entry = shift or return;
1045 my $ext_prefix = shift; $ext_prefix = '' unless defined $ext_prefix;
1046 my $no_prefix = shift || 0;
1048 my $file = $entry->name;
1049 my $prefix = $entry->prefix; $prefix = '' unless defined $prefix;
1051 ### remove the prefix from the file name
1052 ### not sure if this is still neeeded --kane
1053 ### no it's not -- Archive::Tar::File->_new_from_file will take care of
1054 ### this for us. Even worse, this would break if we tried to add a file
1056 #if( length $prefix ) {
1057 # $file =~ s/^$match//;
1060 $prefix = File::Spec::Unix->catdir($ext_prefix, $prefix)
1061 if length $ext_prefix;
1063 ### not sure why this is... ###
1064 my $l = PREFIX_LENGTH; # is ambiguous otherwise...
1065 substr ($prefix, 0, -$l) = "" if length $prefix >= PREFIX_LENGTH;
1067 my $f1 = "%06o"; my $f2 = "%11o";
1069 ### this might be optimizable with a 'changed' flag in the file objects ###
1074 (map { sprintf( $f1, $entry->$_() ) } qw[mode uid gid]),
1075 (map { sprintf( $f2, $entry->$_() ) } qw[size mtime]),
1077 "", # checksum field - space padded a bit down
1079 (map { $entry->$_() } qw[type linkname magic]),
1081 $entry->version || TAR_VERSION,
1083 (map { $entry->$_() } qw[uname gname]),
1084 (map { sprintf( $f1, $entry->$_() ) } qw[devmajor devminor]),
1086 ($no_prefix ? '' : $prefix)
1089 ### add the checksum ###
1090 substr($tar,148,7) = sprintf("%6o\0", unpack("%16C*",$tar));
1095 =head2 $tar->add_files( @filenamelist )
1097 Takes a list of filenames and adds them to the in-memory archive.
1099 The path to the file is automatically converted to a Unix like
1100 equivalent for use in the archive, and, if on MacOS, the file's
1101 modification time is converted from the MacOS epoch to the Unix epoch.
1102 So tar archives created on MacOS with B<Archive::Tar> can be read
1103 both with I<tar> on Unix and applications like I<suntar> or
1104 I<Stuffit Expander> on MacOS.
1106 Be aware that the file's type/creator and resource fork will be lost,
1107 which is usually what you want in cross-platform archives.
1109 Returns a list of C<Archive::Tar::File> objects that were just added.
1115 my @files = @_ or return;
1118 for my $file ( @files ) {
1119 unless( -e $file ) {
1120 $self->_error( qq[No such file: '$file'] );
1124 my $obj = Archive::Tar::File->new( file => $file );
1126 $self->_error( qq[Unable to add file: '$file'] );
1133 push @{$self->{_data}}, @rv;
1138 =head2 $tar->add_data ( $filename, $data, [$opthashref] )
1140 Takes a filename, a scalar full of data and optionally a reference to
1141 a hash with specific options.
1143 Will add a file to the in-memory archive, with name C<$filename> and
1144 content C<$data>. Specific properties can be set using C<$opthashref>.
1145 The following list of properties is supported: name, size, mtime
1146 (last modified date), mode, uid, gid, linkname, uname, gname,
1147 devmajor, devminor, prefix, type. (On MacOS, the file's path and
1148 modification times are converted to Unix equivalents.)
1150 Valid values for the file type are the following constants defined in
1151 Archive::Tar::Constants:
1163 Hard and symbolic ("soft") links; linkname should specify target.
1169 Character and block devices. devmajor and devminor should specify the major
1170 and minor device numbers.
1186 Returns the C<Archive::Tar::File> object that was just added, or
1187 C<undef> on failure.
1193 my ($file, $data, $opt) = @_;
1195 my $obj = Archive::Tar::File->new( data => $file, $data, $opt );
1197 $self->_error( qq[Unable to add file: '$file'] );
1201 push @{$self->{_data}}, $obj;
1206 =head2 $tar->error( [$BOOL] )
1208 Returns the current errorstring (usually, the last error reported).
1209 If a true value was specified, it will give the C<Carp::longmess>
1210 equivalent of the error, in effect giving you a stacktrace.
1212 For backwards compatibility, this error is also available as
1213 C<$Archive::Tar::error> although it is much recommended you use the
1214 method call instead.
1224 my $msg = $error = shift;
1225 $longmess = Carp::longmess($error);
1227 ### set Archive::Tar::WARN to 0 to disable printing
1230 carp $DEBUG ? $longmess : $msg;
1238 return shift() ? $longmess : $error;
1242 =head2 $tar->setcwd( $cwd );
1244 C<Archive::Tar> needs to know the current directory, and it will run
1245 C<Cwd::cwd()> I<every> time it extracts a I<relative> entry from the
1246 tarfile and saves it in the file system. (As of version 1.30, however,
1247 C<Archive::Tar> will use the speed optimization described below
1248 automatically, so it's only relevant if you're using C<extract_file()>).
1250 Since C<Archive::Tar> doesn't change the current directory internally
1251 while it is extracting the items in a tarball, all calls to C<Cwd::cwd()>
1252 can be avoided if we can guarantee that the current directory doesn't
1253 get changed externally.
1255 To use this performance boost, set the current directory via
1258 $tar->setcwd( cwd() );
1260 once before calling a function like C<extract_file> and
1261 C<Archive::Tar> will use the current directory setting from then on
1262 and won't call C<Cwd::cwd()> internally.
1264 To switch back to the default behaviour, use
1266 $tar->setcwd( undef );
1268 and C<Archive::Tar> will call C<Cwd::cwd()> internally again.
1270 If you're using C<Archive::Tar>'s C<exract()> method, C<setcwd()> will
1279 $self->{cwd} = $cwd;
1282 =head2 $bool = $tar->has_io_string
1284 Returns true if we currently have C<IO::String> support loaded.
1286 Either C<IO::String> or C<perlio> support is needed to support writing
1287 stringified archives. Currently, C<perlio> is the preferred method, if
1290 See the C<GLOBAL VARIABLES> section to see how to change this preference.
1294 sub has_io_string { return $HAS_IO_STRING; }
1296 =head2 $bool = $tar->has_perlio
1298 Returns true if we currently have C<perlio> support loaded.
1300 This requires C<perl-5.8> or higher, compiled with C<perlio>
1302 Either C<IO::String> or C<perlio> support is needed to support writing
1303 stringified archives. Currently, C<perlio> is the preferred method, if
1306 See the C<GLOBAL VARIABLES> section to see how to change this preference.
1310 sub has_perlio { return $HAS_PERLIO; }
1313 =head1 Class Methods
1315 =head2 Archive::Tar->create_archive($file, $compression, @filelist)
1317 Creates a tar file from the list of files provided. The first
1318 argument can either be the name of the tar file to create or a
1319 reference to an open file handle (e.g. a GLOB reference).
1321 The second argument specifies the level of compression to be used, if
1322 any. Compression of tar files requires the installation of the
1323 IO::Zlib module. Specific levels of compression may be
1324 requested by passing a value between 2 and 9 as the second argument.
1325 Any other value evaluating as true will result in the default
1326 compression level being used.
1328 Note that when you pass in a filehandle, the compression argument
1329 is ignored, as all files are printed verbatim to your filehandle.
1330 If you wish to enable compression with filehandles, use an
1331 C<IO::Zlib> filehandle instead.
1333 The remaining arguments list the files to be included in the tar file.
1334 These files must all exist. Any files which don't exist or can't be
1335 read are silently ignored.
1337 If the archive creation fails for any reason, C<create_archive> will
1338 return false. Please use the C<error> method to find the cause of the
1341 Note that this method does not write C<on the fly> as it were; it
1342 still reads all the files into memory before writing out the archive.
1343 Consult the FAQ below if this is a problem.
1347 sub create_archive {
1350 my $file = shift; return unless defined $file;
1351 my $gzip = shift || 0;
1355 return $class->_error( qq[Cowardly refusing to create empty archive!] );
1358 my $tar = $class->new;
1359 $tar->add_files( @files );
1360 return $tar->write( $file, $gzip );
1363 =head2 Archive::Tar->list_archive ($file, $compressed, [\@properties])
1365 Returns a list of the names of all the files in the archive. The
1366 first argument can either be the name of the tar file to list or a
1367 reference to an open file handle (e.g. a GLOB reference).
1369 If C<list_archive()> is passed an array reference as its third
1370 argument it returns a list of hash references containing the requested
1371 properties of each file. The following list of properties is
1372 supported: full_path, name, size, mtime (last modified date), mode,
1373 uid, gid, linkname, uname, gname, devmajor, devminor, prefix.
1375 See C<Archive::Tar::File> for details about supported properties.
1377 Passing an array reference containing only one element, 'name', is
1378 special cased to return a list of names rather than a list of hash
1385 my $file = shift; return unless defined $file;
1386 my $gzip = shift || 0;
1388 my $tar = $class->new($file, $gzip);
1391 return $tar->list_files( @_ );
1394 =head2 Archive::Tar->extract_archive ($file, $gzip)
1396 Extracts the contents of the tar file. The first argument can either
1397 be the name of the tar file to create or a reference to an open file
1398 handle (e.g. a GLOB reference). All relative paths in the tar file will
1399 be created underneath the current working directory.
1401 C<extract_archive> will return a list of files it extracted.
1402 If the archive extraction fails for any reason, C<extract_archive>
1403 will return false. Please use the C<error> method to find the cause
1408 sub extract_archive {
1410 my $file = shift; return unless defined $file;
1411 my $gzip = shift || 0;
1413 my $tar = $class->new( ) or return;
1415 return $tar->read( $file, $gzip, { extract => 1 } );
1418 =head2 Archive::Tar->can_handle_compressed_files
1420 A simple checking routine, which will return true if C<Archive::Tar>
1421 is able to uncompress compressed archives on the fly with C<IO::Zlib>,
1422 or false if C<IO::Zlib> is not installed.
1424 You can use this as a shortcut to determine whether C<Archive::Tar>
1425 will do what you think before passing compressed archives to its
1430 sub can_handle_compressed_files { return ZLIB ? 1 : 0 }
1432 sub no_string_support {
1433 croak("You have to install IO::String to support writing archives to strings");
1440 =head1 GLOBAL VARIABLES
1442 =head2 $Archive::Tar::FOLLOW_SYMLINK
1444 Set this variable to C<1> to make C<Archive::Tar> effectively make a
1445 copy of the file when extracting. Default is C<0>, which
1446 means the symlink stays intact. Of course, you will have to pack the
1447 file linked to as well.
1449 This option is checked when you write out the tarfile using C<write>
1450 or C<create_archive>.
1452 This works just like C</bin/tar>'s C<-h> option.
1454 =head2 $Archive::Tar::CHOWN
1456 By default, C<Archive::Tar> will try to C<chown> your files if it is
1457 able to. In some cases, this may not be desired. In that case, set
1458 this variable to C<0> to disable C<chown>-ing, even if it were
1461 The default is C<1>.
1463 =head2 $Archive::Tar::CHMOD
1465 By default, C<Archive::Tar> will try to C<chmod> your files to
1466 whatever mode was specified for the particular file in the archive.
1467 In some cases, this may not be desired. In that case, set this
1468 variable to C<0> to disable C<chmod>-ing.
1470 The default is C<1>.
1472 =head2 $Archive::Tar::DO_NOT_USE_PREFIX
1474 By default, C<Archive::Tar> will try to put paths that are over
1475 100 characters in the C<prefix> field of your tar header, as
1476 defined per POSIX-standard. However, some (older) tar programs
1477 do not implement this spec. To retain compatibility with these older
1478 or non-POSIX compliant versions, you can set the C<$DO_NOT_USE_PREFIX>
1479 variable to a true value, and C<Archive::Tar> will use an alternate
1480 way of dealing with paths over 100 characters by using the
1481 C<GNU Extended Header> feature.
1483 Note that clients who do not support the C<GNU Extended Header>
1484 feature will not be able to read these archives. Such clients include
1485 tars on C<Solaris>, C<Irix> and C<AIX>.
1487 The default is C<0>.
1489 =head2 $Archive::Tar::DEBUG
1491 Set this variable to C<1> to always get the C<Carp::longmess> output
1492 of the warnings, instead of the regular C<carp>. This is the same
1493 message you would get by doing:
1499 =head2 $Archive::Tar::WARN
1501 Set this variable to C<0> if you do not want any warnings printed.
1502 Personally I recommend against doing this, but people asked for the
1503 option. Also, be advised that this is of course not threadsafe.
1507 =head2 $Archive::Tar::error
1509 Holds the last reported error. Kept for historical reasons, but its
1510 use is very much discouraged. Use the C<error()> method instead:
1512 warn $tar->error unless $tar->extract;
1514 =head2 $Archive::Tar::HAS_PERLIO
1516 This variable holds a boolean indicating if we currently have
1517 C<perlio> support loaded. This will be enabled for any perl
1518 greater than C<5.8> compiled with C<perlio>.
1520 If you feel strongly about disabling it, set this variable to
1521 C<false>. Note that you will then need C<IO::String> installed
1522 to support writing stringified archives.
1524 Don't change this variable unless you B<really> know what you're
1527 =head2 $Archive::Tar::HAS_IO_STRING
1529 This variable holds a boolean indicating if we currently have
1530 C<IO::String> support loaded. This will be enabled for any perl
1531 that has a loadable C<IO::String> module.
1533 If you feel strongly about disabling it, set this variable to
1534 C<false>. Note that you will then need C<perlio> support from
1535 your perl to be able to write stringified archives.
1537 Don't change this variable unless you B<really> know what you're
1544 =item What's the minimum perl version required to run Archive::Tar?
1546 You will need perl version 5.005_03 or newer.
1548 =item Isn't Archive::Tar slow?
1550 Yes it is. It's pure perl, so it's a lot slower then your C</bin/tar>
1551 However, it's very portable. If speed is an issue, consider using
1552 C</bin/tar> instead.
1554 =item Isn't Archive::Tar heavier on memory than /bin/tar?
1556 Yes it is, see previous answer. Since C<Compress::Zlib> and therefore
1557 C<IO::Zlib> doesn't support C<seek> on their filehandles, there is little
1558 choice but to read the archive into memory.
1559 This is ok if you want to do in-memory manipulation of the archive.
1560 If you just want to extract, use the C<extract_archive> class method
1561 instead. It will optimize and write to disk immediately.
1563 =item Can't you lazy-load data instead?
1565 No, not easily. See previous question.
1567 =item How much memory will an X kb tar file need?
1569 Probably more than X kb, since it will all be read into memory. If
1570 this is a problem, and you don't need to do in memory manipulation
1571 of the archive, consider using C</bin/tar> instead.
1573 =item What do you do with unsupported filetypes in an archive?
1575 C<Unix> has a few filetypes that aren't supported on other platforms,
1576 like C<Win32>. If we encounter a C<hardlink> or C<symlink> we'll just
1577 try to make a copy of the original file, rather than throwing an error.
1579 This does require you to read the entire archive in to memory first,
1580 since otherwise we wouldn't know what data to fill the copy with.
1581 (This means that you cannot use the class methods on archives that
1582 have incompatible filetypes and still expect things to work).
1584 For other filetypes, like C<chardevs> and C<blockdevs> we'll warn that
1585 the extraction of this particular item didn't work.
1587 =item I'm using WinZip, or some other non-POSIX client, and files are not being extracted properly!
1589 By default, C<Archive::Tar> is in a completely POSIX-compatible
1590 mode, which uses the POSIX-specification of C<tar> to store files.
1591 For paths greather than 100 characters, this is done using the
1592 C<POSIX header prefix>. Non-POSIX-compatible clients may not support
1593 this part of the specification, and may only support the C<GNU Extended
1594 Header> functionality. To facilitate those clients, you can set the
1595 C<$Archive::Tar::DO_NOT_USE_PREFIX> variable to C<true>. See the
1596 C<GLOBAL VARIABLES> section for details on this variable.
1598 =item How do I extract only files that have property X from an archive?
1600 Sometimes, you might not wish to extract a complete archive, just
1601 the files that are relevant to you, based on some criteria.
1603 You can do this by filtering a list of C<Archive::Tar::File> objects
1604 based on your criteria. For example, to extract only files that have
1605 the string C<foo> in their title, you would use:
1608 grep { $_->full_path =~ /foo/ } $tar->get_files
1611 This way, you can filter on any attribute of the files in the archive.
1612 Consult the C<Archive::Tar::File> documentation on how to use these
1615 =item How do I access .tar.Z files?
1617 The C<Archive::Tar> module can optionally use C<Compress::Zlib> (via
1618 the C<IO::Zlib> module) to access tar files that have been compressed
1619 with C<gzip>. Unfortunately tar files compressed with the Unix C<compress>
1620 utility cannot be read by C<Compress::Zlib> and so cannot be directly
1621 accesses by C<Archive::Tar>.
1623 If the C<uncompress> or C<gunzip> programs are available, you can use
1624 one of these workarounds to read C<.tar.Z> files from C<Archive::Tar>
1626 Firstly with C<uncompress>
1630 open F, "uncompress -c $filename |";
1631 my $tar = Archive::Tar->new(*F);
1634 and this with C<gunzip>
1638 open F, "gunzip -c $filename |";
1639 my $tar = Archive::Tar->new(*F);
1642 Similarly, if the C<compress> program is available, you can use this to
1643 write a C<.tar.Z> file
1648 my $fh = new IO::File "| compress -c >$filename";
1649 my $tar = Archive::Tar->new();
1661 =item Check if passed in handles are open for read/write
1663 Currently I don't know of any portable pure perl way to do this.
1664 Suggestions welcome.
1666 =item Allow archives to be passed in as string
1668 Currently, we only allow opened filehandles or filenames, but
1669 not strings. The internals would need some reworking to facilitate
1670 stringified archives.
1672 =item Facilitate processing an opened filehandle of a compressed archive
1674 Currently, we only support this if the filehandle is an IO::Zlib object.
1675 Environments, like apache, will present you with an opened filehandle
1676 to an uploaded file, which might be a compressed archive.
1684 =item The GNU tar specification
1686 C<http://www.gnu.org/software/tar/manual/tar.html>
1688 =item The PAX format specication
1690 The specifcation which tar derives from; C< http://www.opengroup.org/onlinepubs/007904975/utilities/pax.html>
1692 =item A comparison of GNU and POSIX tar standards; C<http://www.delorie.com/gnu/docs/tar/tar_114.html>
1694 =item GNU tar intends to switch to POSIX compatibility
1696 GNU Tar authors have expressed their intention to become completely
1697 POSIX-compatible; C<http://www.gnu.org/software/tar/manual/html_node/Formats.html>
1699 =item A Comparison between various tar implementations
1701 Lists known issues and incompatibilities; C<http://gd.tuwien.ac.at/utils/archivers/star/README.otherbugs>
1708 Jos Boumans E<lt>kane@cpan.orgE<gt>.
1710 =head1 ACKNOWLEDGEMENTS
1712 Thanks to Sean Burke, Chris Nandor, Chip Salzenberg, Tim Heaney and
1713 especially Andrew Savige for their help and suggestions.
1718 copyright (c) 2002 Jos Boumans E<lt>kane@cpan.orgE<gt>.
1719 All rights reserved.
1721 This library is free software;
1722 you may redistribute and/or modify it under the same
1723 terms as Perl itself.