lib/Archive/Tar.pm

   1 ### the gnu tar specification:
   2 ### http://www.gnu.org/software/tar/manual/tar.html
   3 ###
   4 ### and the pax format spec, which tar derives from:
   5 ### http://www.opengroup.org/onlinepubs/007904975/utilities/pax.html
   6
   7 package Archive::Tar;
   8 require 5.005_03;
   9
  10 use Cwd;
  11 use IO::Zlib;
  12 use IO::File;
  13 use Carp                qw(carp croak);
  14 use File::Spec          ();
  15 use File::Spec::Unix    ();
  16 use File::Path          ();
  17
  18 use Archive::Tar::File;
  19 use Archive::Tar::Constant;
  20
  21 require Exporter;
  22
  23 use strict;
  24 use vars qw[$DEBUG $error $VERSION $WARN $FOLLOW_SYMLINK $CHOWN $CHMOD
  25             $DO_NOT_USE_PREFIX $HAS_PERLIO $HAS_IO_STRING
  26             $INSECURE_EXTRACT_MODE @ISA @EXPORT
  27          ];
  28
  29 @ISA                    = qw[Exporter];
  30 @EXPORT                 = ( COMPRESS_GZIP, COMPRESS_BZIP );
  31 $DEBUG                  = 0;
  32 $WARN                   = 1;
  33 $FOLLOW_SYMLINK         = 0;
  34 $VERSION                = "1.42";
  35 $CHOWN                  = 1;
  36 $CHMOD                  = 1;
  37 $DO_NOT_USE_PREFIX      = 0;
  38 $INSECURE_EXTRACT_MODE  = 0;
  39
  40 BEGIN {
  41     use Config;
  42     $HAS_PERLIO = $Config::Config{useperlio};
  43
  44     ### try and load IO::String anyway, so you can dynamically
  45     ### switch between perlio and IO::String
  46     $HAS_IO_STRING = eval {
  47         require IO::String;
  48         import IO::String;
  49         1;
  50     } || 0;
  51 }
  52
  53 =head1 NAME
  54
  55 Archive::Tar - module for manipulations of tar archives
  56
  57 =head1 SYNOPSIS
  58
  59     use Archive::Tar;
  60     my $tar = Archive::Tar->new;
  61
  62     $tar->read('origin.tgz');
  63     $tar->extract();
  64
  65     $tar->add_files('file/foo.pl', 'docs/README');
  66     $tar->add_data('file/baz.txt', 'This is the contents now');
  67
  68     $tar->rename('oldname', 'new/file/name');
  69
  70     $tar->write('files.tar');                   # plain tar
  71     $tar->write('files.tgz', COMPRESSED_GZIP);  # gzip compressed
  72     $tar->write('files.tbz', COMPRESSED_BZIP);  # bzip2 compressed
  73
  74 =head1 DESCRIPTION
  75
  76 Archive::Tar provides an object oriented mechanism for handling tar
  77 files.  It provides class methods for quick and easy files handling
  78 while also allowing for the creation of tar file objects for custom
  79 manipulation.  If you have the IO::Zlib module installed,
  80 Archive::Tar will also support compressed or gzipped tar files.
  81
  82 An object of class Archive::Tar represents a .tar(.gz) archive full
  83 of files and things.
  84
  85 =head1 Object Methods
  86
  87 =head2 Archive::Tar->new( [$file, $compressed] )
  88
  89 Returns a new Tar object. If given any arguments, C<new()> calls the
  90 C<read()> method automatically, passing on the arguments provided to
  91 the C<read()> method.
  92
  93 If C<new()> is invoked with arguments and the C<read()> method fails
  94 for any reason, C<new()> returns undef.
  95
  96 =cut
  97
  98 my $tmpl = {
  99     _data   => [ ],
 100     _file   => 'Unknown',
 101 };
 102
 103 ### install get/set accessors for this object.
 104 for my $key ( keys %$tmpl ) {
 105     no strict 'refs';
 106     *{__PACKAGE__."::$key"} = sub {
 107         my $self = shift;
 108         $self->{$key} = $_[0] if @_;
 109         return $self->{$key};
 110     }
 111 }
 112
 113 sub new {
 114     my $class = shift;
 115     $class = ref $class if ref $class;
 116
 117     ### copying $tmpl here since a shallow copy makes it use the
 118     ### same aref, causing for files to remain in memory always.
 119     my $obj = bless { _data => [ ], _file => 'Unknown' }, $class;
 120
 121     if (@_) {
 122         unless ( $obj->read( @_ ) ) {
 123             $obj->_error(qq[No data could be read from file]);
 124             return;
 125         }
 126     }
 127
 128     return $obj;
 129 }
 130
 131 =head2 $tar->read ( $filename|$handle, [$compressed, {opt => 'val'}] )
 132
 133 Read the given tar file into memory.
 134 The first argument can either be the name of a file or a reference to
 135 an already open filehandle (or an IO::Zlib object if it's compressed)
 136
 137 The C<read> will I<replace> any previous content in C<$tar>!
 138
 139 The second argument may be considered optional, but remains for
 140 backwards compatibility. Archive::Tar now looks at the file
 141 magic to determine what class should be used to open the file
 142 and will transparently Do The Right Thing.
 143
 144 Archive::Tar will warn if you try to pass a bzip2 compressed file and the
 145 IO::Zlib / IO::Uncompress::Bunzip2 modules are not available and simply return.
 146
 147 Note that you can currently B<not> pass a C<gzip> compressed
 148 filehandle, which is not opened with C<IO::Zlib>, a C<bzip2> compressed
 149 filehandle, which is not opened with C<IO::Uncompress::Bunzip2>, nor a string
 150 containing the full archive information (either compressed or
 151 uncompressed). These are worth while features, but not currently
 152 implemented. See the C<TODO> section.
 153
 154 The third argument can be a hash reference with options. Note that
 155 all options are case-sensitive.
 156
 157 =over 4
 158
 159 =item limit
 160
 161 Do not read more than C<limit> files. This is useful if you have
 162 very big archives, and are only interested in the first few files.
 163
 164 =item filter
 165
 166 Can be set to a regular expression.  Only files with names that match
 167 the expression will be read.
 168
 169 =item extract
 170
 171 If set to true, immediately extract entries when reading them. This
 172 gives you the same memory break as the C<extract_archive> function.
 173 Note however that entries will not be read into memory, but written
 174 straight to disk. This means no C<Archive::Tar::File> objects are
 175 created for you to inspect.
 176
 177 =back
 178
 179 All files are stored internally as C<Archive::Tar::File> objects.
 180 Please consult the L<Archive::Tar::File> documentation for details.
 181
 182 Returns the number of files read in scalar context, and a list of
 183 C<Archive::Tar::File> objects in list context.
 184
 185 =cut
 186
 187 sub read {
 188     my $self = shift;
 189     my $file = shift;
 190     my $gzip = shift || 0;
 191     my $opts = shift || {};
 192
 193     unless( defined $file ) {
 194         $self->_error( qq[No file to read from!] );
 195         return;
 196     } else {
 197         $self->_file( $file );
 198     }
 199
 200     my $handle = $self->_get_handle($file, $gzip, READ_ONLY->( ZLIB ) )
 201                     or return;
 202
 203     my $data = $self->_read_tar( $handle, $opts ) or return;
 204
 205     $self->_data( $data );
 206
 207     return wantarray ? @$data : scalar @$data;
 208 }
 209
 210 sub _get_handle {
 211     my $self     = shift;
 212     my $file     = shift;   return unless defined $file;
 213                             return $file if ref $file;
 214     my $compress = shift || 0;
 215     my $mode     = shift || READ_ONLY->( ZLIB ); # default to read only
 216
 217
 218     ### get a FH opened to the right class, so we can use it transparently
 219     ### throughout the program
 220     my $fh;
 221     {   ### reading magic only makes sense if we're opening a file for
 222         ### reading. otherwise, just use what the user requested.
 223         my $magic = '';
 224         if( MODE_READ->($mode) ) {
 225             open my $tmp, $file or do {
 226                 $self->_error( qq[Could not open '$file' for reading: $!] );
 227                 return;
 228             };
 229
 230             ### read the first 4 bites of the file to figure out which class to
 231             ### use to open the file.
 232             sysread( $tmp, $magic, 4 );
 233             close $tmp;
 234         }
 235
 236         ### is it bzip?
 237         ### if you asked specifically for bzip compression, or if we're in
 238         ### read mode and the magic numbers add up, use bzip
 239         if( BZIP and (
 240                 ($compress eq COMPRESS_BZIP) or
 241                 ( MODE_READ->($mode) and $magic =~ BZIP_MAGIC_NUM )
 242             )
 243         ) {
 244
 245             ### different reader/writer modules, different error vars... sigh
 246             if( MODE_READ->($mode) ) {
 247                 $fh = IO::Uncompress::Bunzip2->new( $file ) or do {
 248                     $self->_error( qq[Could not read '$file': ] .
 249                         $IO::Uncompress::Bunzip2::Bunzip2Error
 250                     );
 251                     return;
 252                 };
 253
 254             } else {
 255                 $fh = IO::Compress::Bzip2->new( $file ) or do {
 256                     $self->_error( qq[Could not write to '$file': ] .
 257                         $IO::Compress::Bzip2::Bzip2Error
 258                     );
 259                     return;
 260                 };
 261             }
 262
 263         ### is it gzip?
 264         ### if you asked for compression, if you wanted to read or the gzip
 265         ### magic number is present (redundant with read)
 266         } elsif( ZLIB and (
 267                     $compress or MODE_READ->($mode) or $magic =~ GZIP_MAGIC_NUM
 268                  )
 269         ) {
 270             $fh = IO::Zlib->new;
 271
 272             unless( $fh->open( $file, $mode ) ) {
 273                 $self->_error(qq[Could not create filehandle for '$file': $!]);
 274                 return;
 275             }
 276
 277         ### is it plain tar?
 278         } else {
 279             $fh = IO::File->new;
 280
 281             unless( $fh->open( $file, $mode ) ) {
 282                 $self->_error(qq[Could not create filehandle for '$file': $!]);
 283                 return;
 284             }
 285
 286             ### enable bin mode on tar archives
 287             binmode $fh;
 288         }
 289     }
 290
 291     return $fh;
 292 }
 293
 294
 295 sub _read_tar {
 296     my $self    = shift;
 297     my $handle  = shift or return;
 298     my $opts    = shift || {};
 299
 300     my $count   = $opts->{limit}    || 0;
 301     my $filter  = $opts->{filter};
 302     my $extract = $opts->{extract}  || 0;
 303
 304     ### set a cap on the amount of files to extract ###
 305     my $limit   = 0;
 306     $limit = 1 if $count > 0;
 307
 308     my $tarfile = [ ];
 309     my $chunk;
 310     my $read = 0;
 311     my $real_name;  # to set the name of a file when
 312                     # we're encountering @longlink
 313     my $data;
 314
 315     LOOP:
 316     while( $handle->read( $chunk, HEAD ) ) {
 317         ### IO::Zlib doesn't support this yet
 318         my $offset = eval { tell $handle } || 'unknown';
 319
 320         unless( $read++ ) {
 321             my $gzip = GZIP_MAGIC_NUM;
 322             if( $chunk =~ /$gzip/ ) {
 323                 $self->_error( qq[Cannot read compressed format in tar-mode] );
 324                 return;
 325             }
 326         }
 327
 328         ### if we can't read in all bytes... ###
 329         last if length $chunk != HEAD;
 330
 331         ### Apparently this should really be two blocks of 512 zeroes,
 332         ### but GNU tar sometimes gets it wrong. See comment in the
 333         ### source code (tar.c) to GNU cpio.
 334         next if $chunk eq TAR_END;
 335
 336         ### according to the posix spec, the last 12 bytes of the header are
 337         ### null bytes, to pad it to a 512 byte block. That means if these
 338         ### bytes are NOT null bytes, it's a corrrupt header. See:
 339         ### www.koders.com/c/fidCE473AD3D9F835D690259D60AD5654591D91D5BA.aspx
 340         ### line 111
 341         {   my $nulls = join '', "\0" x 12;
 342             unless( $nulls eq substr( $chunk, 500, 12 ) ) {
 343                 $self->_error( qq[Invalid header block at offset $offset] );
 344                 next LOOP;
 345             }
 346         }
 347
 348         ### pass the realname, so we can set it 'proper' right away
 349         ### some of the heuristics are done on the name, so important
 350         ### to set it ASAP
 351         my $entry;
 352         {   my %extra_args = ();
 353             $extra_args{'name'} = $$real_name if defined $real_name;
 354
 355             unless( $entry = Archive::Tar::File->new(   chunk => $chunk,
 356                                                         %extra_args )
 357             ) {
 358                 $self->_error( qq[Couldn't read chunk at offset $offset] );
 359                 next LOOP;
 360             }
 361         }
 362
 363         ### ignore labels:
 364         ### http://www.gnu.org/manual/tar/html_node/tar_139.html
 365         next if $entry->is_label;
 366
 367         if( length $entry->type and ($entry->is_file || $entry->is_longlink) ) {
 368
 369             if ( $entry->is_file && !$entry->validate ) {
 370                 ### sometimes the chunk is rather fux0r3d and a whole 512
 371                 ### bytes ends up in the ->name area.
 372                 ### clean it up, if need be
 373                 my $name = $entry->name;
 374                 $name = substr($name, 0, 100) if length $name > 100;
 375                 $name =~ s/\n/ /g;
 376
 377                 $self->_error( $name . qq[: checksum error] );
 378                 next LOOP;
 379             }
 380
 381             my $block = BLOCK_SIZE->( $entry->size );
 382
 383             $data = $entry->get_content_by_ref;
 384
 385             ### just read everything into memory
 386             ### can't do lazy loading since IO::Zlib doesn't support 'seek'
 387             ### this is because Compress::Zlib doesn't support it =/
 388             ### this reads in the whole data in one read() call.
 389             if( $handle->read( $$data, $block ) < $block ) {
 390                 $self->_error( qq[Read error on tarfile (missing data) '].
 391                                     $entry->full_path ."' at offset $offset" );
 392                 next LOOP;
 393             }
 394
 395             ### throw away trailing garbage ###
 396             substr ($$data, $entry->size) = "" if defined $$data;
 397
 398             ### part II of the @LongLink munging -- need to do /after/
 399             ### the checksum check.
 400             if( $entry->is_longlink ) {
 401                 ### weird thing in tarfiles -- if the file is actually a
 402                 ### @LongLink, the data part seems to have a trailing ^@
 403                 ### (unprintable) char. to display, pipe output through less.
 404                 ### but that doesn't *always* happen.. so check if the last
 405                 ### character is a control character, and if so remove it
 406                 ### at any rate, we better remove that character here, or tests
 407                 ### like 'eq' and hashlook ups based on names will SO not work
 408                 ### remove it by calculating the proper size, and then
 409                 ### tossing out everything that's longer than that size.
 410
 411                 ### count number of nulls
 412                 my $nulls = $$data =~ tr/\0/\0/;
 413
 414                 ### cut data + size by that many bytes
 415                 $entry->size( $entry->size - $nulls );
 416                 substr ($$data, $entry->size) = "";
 417             }
 418         }
 419
 420         ### clean up of the entries.. posix tar /apparently/ has some
 421         ### weird 'feature' that allows for filenames > 255 characters
 422         ### they'll put a header in with as name '././@LongLink' and the
 423         ### contents will be the name of the /next/ file in the archive
 424         ### pretty crappy and kludgy if you ask me
 425
 426         ### set the name for the next entry if this is a @LongLink;
 427         ### this is one ugly hack =/ but needed for direct extraction
 428         if( $entry->is_longlink ) {
 429             $real_name = $data;
 430             next LOOP;
 431         } elsif ( defined $real_name ) {
 432             $entry->name( $$real_name );
 433             $entry->prefix('');
 434             undef $real_name;
 435         }
 436
 437         ### skip this entry if we're filtering
 438         if ($filter && $entry->name !~ $filter) {
 439             next LOOP;
 440
 441         ### skip this entry if it's a pax header. This is a special file added
 442         ### by, among others, git-generated tarballs. It holds comments and is
 443         ### not meant for extracting. See #38932: pax_global_header extracted
 444         } elsif ( $entry->name eq PAX_HEADER ) {
 445             next LOOP;
 446         }
 447
 448         $self->_extract_file( $entry ) if $extract
 449                                             && !$entry->is_longlink
 450                                             && !$entry->is_unknown
 451                                             && !$entry->is_label;
 452
 453         ### Guard against tarfiles with garbage at the end
 454             last LOOP if $entry->name eq '';
 455
 456         ### push only the name on the rv if we're extracting
 457         ### -- for extract_archive
 458         push @$tarfile, ($extract ? $entry->name : $entry);
 459
 460         if( $limit ) {
 461             $count-- unless $entry->is_longlink || $entry->is_dir;
 462             last LOOP unless $count;
 463         }
 464     } continue {
 465         undef $data;
 466     }
 467
 468     return $tarfile;
 469 }
 470
 471 =head2 $tar->contains_file( $filename )
 472
 473 Check if the archive contains a certain file.
 474 It will return true if the file is in the archive, false otherwise.
 475
 476 Note however, that this function does an exact match using C<eq>
 477 on the full path. So it cannot compensate for case-insensitive file-
 478 systems or compare 2 paths to see if they would point to the same
 479 underlying file.
 480
 481 =cut
 482
 483 sub contains_file {
 484     my $self = shift;
 485     my $full = shift;
 486
 487     return unless defined $full;
 488
 489     ### don't warn if the entry isn't there.. that's what this function
 490     ### is for after all.
 491     local $WARN = 0;
 492     return 1 if $self->_find_entry($full);
 493     return;
 494 }
 495
 496 =head2 $tar->extract( [@filenames] )
 497
 498 Write files whose names are equivalent to any of the names in
 499 C<@filenames> to disk, creating subdirectories as necessary. This
 500 might not work too well under VMS.
 501 Under MacPerl, the file's modification time will be converted to the
 502 MacOS zero of time, and appropriate conversions will be done to the
 503 path.  However, the length of each element of the path is not
 504 inspected to see whether it's longer than MacOS currently allows (32
 505 characters).
 506
 507 If C<extract> is called without a list of file names, the entire
 508 contents of the archive are extracted.
 509
 510 Returns a list of filenames extracted.
 511
 512 =cut
 513
 514 sub extract {
 515     my $self    = shift;
 516     my @args    = @_;
 517     my @files;
 518
 519     # use the speed optimization for all extracted files
 520     local($self->{cwd}) = cwd() unless $self->{cwd};
 521
 522     ### you requested the extraction of only certian files
 523     if( @args ) {
 524         for my $file ( @args ) {
 525
 526             ### it's already an object?
 527             if( UNIVERSAL::isa( $file, 'Archive::Tar::File' ) ) {
 528                 push @files, $file;
 529                 next;
 530
 531             ### go find it then
 532             } else {
 533
 534                 my $found;
 535                 for my $entry ( @{$self->_data} ) {
 536                     next unless $file eq $entry->full_path;
 537
 538                     ### we found the file you're looking for
 539                     push @files, $entry;
 540                     $found++;
 541                 }
 542
 543                 unless( $found ) {
 544                     return $self->_error(
 545                         qq[Could not find '$file' in archive] );
 546                 }
 547             }
 548         }
 549
 550     ### just grab all the file items
 551     } else {
 552         @files = $self->get_files;
 553     }
 554
 555     ### nothing found? that's an error
 556     unless( scalar @files ) {
 557         $self->_error( qq[No files found for ] . $self->_file );
 558         return;
 559     }
 560
 561     ### now extract them
 562     for my $entry ( @files ) {
 563         unless( $self->_extract_file( $entry ) ) {
 564             $self->_error(q[Could not extract ']. $entry->full_path .q['] );
 565             return;
 566         }
 567     }
 568
 569     return @files;
 570 }
 571
 572 =head2 $tar->extract_file( $file, [$extract_path] )
 573
 574 Write an entry, whose name is equivalent to the file name provided to
 575 disk. Optionally takes a second parameter, which is the full native
 576 path (including filename) the entry will be written to.
 577
 578 For example:
 579
 580     $tar->extract_file( 'name/in/archive', 'name/i/want/to/give/it' );
 581
 582     $tar->extract_file( $at_file_object,   'name/i/want/to/give/it' );
 583
 584 Returns true on success, false on failure.
 585
 586 =cut
 587
 588 sub extract_file {
 589     my $self = shift;
 590     my $file = shift;   return unless defined $file;
 591     my $alt  = shift;
 592
 593     my $entry = $self->_find_entry( $file )
 594         or $self->_error( qq[Could not find an entry for '$file'] ), return;
 595
 596     return $self->_extract_file( $entry, $alt );
 597 }
 598
 599 sub _extract_file {
 600     my $self    = shift;
 601     my $entry   = shift or return;
 602     my $alt     = shift;
 603
 604     ### you wanted an alternate extraction location ###
 605     my $name = defined $alt ? $alt : $entry->full_path;
 606
 607                             ### splitpath takes a bool at the end to indicate
 608                             ### that it's splitting a dir
 609     my ($vol,$dirs,$file);
 610     if ( defined $alt ) { # It's a local-OS path
 611         ($vol,$dirs,$file) = File::Spec->splitpath(       $alt,
 612                                                           $entry->is_dir );
 613     } else {
 614         ($vol,$dirs,$file) = File::Spec::Unix->splitpath( $name,
 615                                                           $entry->is_dir );
 616     }
 617
 618     my $dir;
 619     ### is $name an absolute path? ###
 620     if( $vol || File::Spec->file_name_is_absolute( $dirs ) ) {
 621
 622         ### absolute names are not allowed to be in tarballs under
 623         ### strict mode, so only allow it if a user tells us to do it
 624         if( not defined $alt and not $INSECURE_EXTRACT_MODE ) {
 625             $self->_error(
 626                 q[Entry ']. $entry->full_path .q[' is an absolute path. ].
 627                 q[Not extracting absolute paths under SECURE EXTRACT MODE]
 628             );
 629             return;
 630         }
 631
 632         ### user asked us to, it's fine.
 633         $dir = File::Spec->catpath( $vol, $dirs, "" );
 634
 635     ### it's a relative path ###
 636     } else {
 637         my $cwd     = (ref $self and defined $self->{cwd})
 638                         ? $self->{cwd}
 639                         : cwd();
 640
 641         my @dirs = defined $alt
 642             ? File::Spec->splitdir( $dirs )         # It's a local-OS path
 643             : File::Spec::Unix->splitdir( $dirs );  # it's UNIX-style, likely
 644                                                     # straight from the tarball
 645
 646         if( not defined $alt            and
 647             not $INSECURE_EXTRACT_MODE
 648         ) {
 649
 650             ### paths that leave the current directory are not allowed under
 651             ### strict mode, so only allow it if a user tells us to do this.
 652             if( grep { $_ eq '..' } @dirs ) {
 653
 654                 $self->_error(
 655                     q[Entry ']. $entry->full_path .q[' is attempting to leave ].
 656                     q[the current working directory. Not extracting under ].
 657                     q[SECURE EXTRACT MODE]
 658                 );
 659                 return;
 660             }
 661
 662             ### the archive may be asking us to extract into a symlink. This
 663             ### is not sane and a possible security issue, as outlined here:
 664             ### https://rt.cpan.org/Ticket/Display.html?id=30380
 665             ### https://bugzilla.redhat.com/show_bug.cgi?id=295021
 666             ### https://issues.rpath.com/browse/RPL-1716
 667             my $full_path = $cwd;
 668             for my $d ( @dirs ) {
 669                 $full_path = File::Spec->catdir( $full_path, $d );
 670
 671                 ### we've already checked this one, and it's safe. Move on.
 672                 next if ref $self and $self->{_link_cache}->{$full_path};
 673
 674                 if( -l $full_path ) {
 675                     my $to   = readlink $full_path;
 676                     my $diag = "symlinked directory ($full_path => $to)";
 677
 678                     $self->_error(
 679                         q[Entry ']. $entry->full_path .q[' is attempting to ].
 680                         qq[extract to a $diag. This is considered a security ].
 681                         q[vulnerability and not allowed under SECURE EXTRACT ].
 682                         q[MODE]
 683                     );
 684                     return;
 685                 }
 686
 687                 ### XXX keep a cache if possible, so the stats become cheaper:
 688                 $self->{_link_cache}->{$full_path} = 1 if ref $self;
 689             }
 690         }
 691
 692         ### '.' is the directory delimiter on VMS, which has to be escaped
 693         ### or changed to '_' on vms.  vmsify is used, because older versions
 694         ### of vmspath do not handle this properly.
 695         ### Must not add a '/' to an empty directory though.
 696         map { length() ? VMS::Filespec::vmsify($_.'/') : $_ } @dirs if ON_VMS;
 697
 698         my ($cwd_vol,$cwd_dir,$cwd_file)
 699                     = File::Spec->splitpath( $cwd );
 700         my @cwd     = File::Spec->splitdir( $cwd_dir );
 701         push @cwd, $cwd_file if length $cwd_file;
 702
 703         ### We need to pass '' as the last elemant to catpath. Craig Berry
 704         ### explains why (msgid <p0624083dc311ae541393@[172.16.52.1]>):
 705         ### The root problem is that splitpath on UNIX always returns the
 706         ### final path element as a file even if it is a directory, and of
 707         ### course there is no way it can know the difference without checking
 708         ### against the filesystem, which it is documented as not doing.  When
 709         ### you turn around and call catpath, on VMS you have to know which bits
 710         ### are directory bits and which bits are file bits.  In this case we
 711         ### know the result should be a directory.  I had thought you could omit
 712         ### the file argument to catpath in such a case, but apparently on UNIX
 713         ### you can't.
 714         $dir        = File::Spec->catpath(
 715                             $cwd_vol, File::Spec->catdir( @cwd, @dirs ), ''
 716                         );
 717
 718         ### catdir() returns undef if the path is longer than 255 chars on
 719         ### older VMS systems.
 720         unless ( defined $dir ) {
 721             $^W && $self->_error( qq[Could not compose a path for '$dirs'\n] );
 722             return;
 723         }
 724
 725     }
 726
 727     if( -e $dir && !-d _ ) {
 728         $^W && $self->_error( qq['$dir' exists, but it's not a directory!\n] );
 729         return;
 730     }
 731
 732     unless ( -d _ ) {
 733         eval { File::Path::mkpath( $dir, 0, 0777 ) };
 734         if( $@ ) {
 735             my $fp = $entry->full_path;
 736             $self->_error(qq[Could not create directory '$dir' for '$fp': $@]);
 737             return;
 738         }
 739
 740         ### XXX chown here? that might not be the same as in the archive
 741         ### as we're only chown'ing to the owner of the file we're extracting
 742         ### not to the owner of the directory itself, which may or may not
 743         ### be another entry in the archive
 744         ### Answer: no, gnu tar doesn't do it either, it'd be the wrong
 745         ### way to go.
 746         #if( $CHOWN && CAN_CHOWN ) {
 747         #    chown $entry->uid, $entry->gid, $dir or
 748         #        $self->_error( qq[Could not set uid/gid on '$dir'] );
 749         #}
 750     }
 751
 752     ### we're done if we just needed to create a dir ###
 753     return 1 if $entry->is_dir;
 754
 755     my $full = File::Spec->catfile( $dir, $file );
 756
 757     if( $entry->is_unknown ) {
 758         $self->_error( qq[Unknown file type for file '$full'] );
 759         return;
 760     }
 761
 762     if( length $entry->type && $entry->is_file ) {
 763         my $fh = IO::File->new;
 764         $fh->open( '>' . $full ) or (
 765             $self->_error( qq[Could not open file '$full': $!] ),
 766             return
 767         );
 768
 769         if( $entry->size ) {
 770             binmode $fh;
 771             syswrite $fh, $entry->data or (
 772                 $self->_error( qq[Could not write data to '$full'] ),
 773                 return
 774             );
 775         }
 776
 777         close $fh or (
 778             $self->_error( qq[Could not close file '$full'] ),
 779             return
 780         );
 781
 782     } else {
 783         $self->_make_special_file( $entry, $full ) or return;
 784     }
 785
 786     ### only update the timestamp if it's not a symlink; that will change the
 787     ### timestamp of the original. This addresses bug #33669: Could not update
 788     ### timestamp warning on symlinks
 789     if( not -l $full ) {
 790         utime time, $entry->mtime - TIME_OFFSET, $full or
 791             $self->_error( qq[Could not update timestamp] );
 792     }
 793
 794     if( $CHOWN && CAN_CHOWN->() ) {
 795         chown $entry->uid, $entry->gid, $full or
 796             $self->_error( qq[Could not set uid/gid on '$full'] );
 797     }
 798
 799     ### only chmod if we're allowed to, but never chmod symlinks, since they'll
 800     ### change the perms on the file they're linking too...
 801     if( $CHMOD and not -l $full ) {
 802         chmod $entry->mode, $full or
 803             $self->_error( qq[Could not chown '$full' to ] . $entry->mode );
 804     }
 805
 806     return 1;
 807 }
 808
 809 sub _make_special_file {
 810     my $self    = shift;
 811     my $entry   = shift     or return;
 812     my $file    = shift;    return unless defined $file;
 813
 814     my $err;
 815
 816     if( $entry->is_symlink ) {
 817         my $fail;
 818         if( ON_UNIX ) {
 819             symlink( $entry->linkname, $file ) or $fail++;
 820
 821         } else {
 822             $self->_extract_special_file_as_plain_file( $entry, $file )
 823                 or $fail++;
 824         }
 825
 826         $err =  qq[Making symbolic link '$file' to '] .
 827                 $entry->linkname .q[' failed] if $fail;
 828
 829     } elsif ( $entry->is_hardlink ) {
 830         my $fail;
 831         if( ON_UNIX ) {
 832             link( $entry->linkname, $file ) or $fail++;
 833
 834         } else {
 835             $self->_extract_special_file_as_plain_file( $entry, $file )
 836                 or $fail++;
 837         }
 838
 839         $err =  qq[Making hard link from '] . $entry->linkname .
 840                 qq[' to '$file' failed] if $fail;
 841
 842     } elsif ( $entry->is_fifo ) {
 843         ON_UNIX && !system('mknod', $file, 'p') or
 844             $err = qq[Making fifo ']. $entry->name .qq[' failed];
 845
 846     } elsif ( $entry->is_blockdev or $entry->is_chardev ) {
 847         my $mode = $entry->is_blockdev ? 'b' : 'c';
 848
 849         ON_UNIX && !system('mknod', $file, $mode,
 850                             $entry->devmajor, $entry->devminor) or
 851             $err =  qq[Making block device ']. $entry->name .qq[' (maj=] .
 852                     $entry->devmajor . qq[ min=] . $entry->devminor .
 853                     qq[) failed.];
 854
 855     } elsif ( $entry->is_socket ) {
 856         ### the original doesn't do anything special for sockets.... ###
 857         1;
 858     }
 859
 860     return $err ? $self->_error( $err ) : 1;
 861 }
 862
 863 ### don't know how to make symlinks, let's just extract the file as
 864 ### a plain file
 865 sub _extract_special_file_as_plain_file {
 866     my $self    = shift;
 867     my $entry   = shift     or return;
 868     my $file    = shift;    return unless defined $file;
 869
 870     my $err;
 871     TRY: {
 872         my $orig = $self->_find_entry( $entry->linkname );
 873
 874         unless( $orig ) {
 875             $err =  qq[Could not find file '] . $entry->linkname .
 876                     qq[' in memory.];
 877             last TRY;
 878         }
 879
 880         ### clone the entry, make it appear as a normal file ###
 881         my $clone = $entry->clone;
 882         $clone->_downgrade_to_plainfile;
 883         $self->_extract_file( $clone, $file ) or last TRY;
 884
 885         return 1;
 886     }
 887
 888     return $self->_error($err);
 889 }
 890
 891 =head2 $tar->list_files( [\@properties] )
 892
 893 Returns a list of the names of all the files in the archive.
 894
 895 If C<list_files()> is passed an array reference as its first argument
 896 it returns a list of hash references containing the requested
 897 properties of each file.  The following list of properties is
 898 supported: name, size, mtime (last modified date), mode, uid, gid,
 899 linkname, uname, gname, devmajor, devminor, prefix.
 900
 901 Passing an array reference containing only one element, 'name', is
 902 special cased to return a list of names rather than a list of hash
 903 references, making it equivalent to calling C<list_files> without
 904 arguments.
 905
 906 =cut
 907
 908 sub list_files {
 909     my $self = shift;
 910     my $aref = shift || [ ];
 911
 912     unless( $self->_data ) {
 913         $self->read() or return;
 914     }
 915
 916     if( @$aref == 0 or ( @$aref == 1 and $aref->[0] eq 'name' ) ) {
 917         return map { $_->full_path } @{$self->_data};
 918     } else {
 919
 920         #my @rv;
 921         #for my $obj ( @{$self->_data} ) {
 922         #    push @rv, { map { $_ => $obj->$_() } @$aref };
 923         #}
 924         #return @rv;
 925
 926         ### this does the same as the above.. just needs a +{ }
 927         ### to make sure perl doesn't confuse it for a block
 928         return map {    my $o=$_;
 929                         +{ map { $_ => $o->$_() } @$aref }
 930                     } @{$self->_data};
 931     }
 932 }
 933
 934 sub _find_entry {
 935     my $self = shift;
 936     my $file = shift;
 937
 938     unless( defined $file ) {
 939         $self->_error( qq[No file specified] );
 940         return;
 941     }
 942
 943     ### it's an object already
 944     return $file if UNIVERSAL::isa( $file, 'Archive::Tar::File' );
 945
 946     for my $entry ( @{$self->_data} ) {
 947         my $path = $entry->full_path;
 948         return $entry if $path eq $file;
 949     }
 950
 951     $self->_error( qq[No such file in archive: '$file'] );
 952     return;
 953 }
 954
 955 =head2 $tar->get_files( [@filenames] )
 956
 957 Returns the C<Archive::Tar::File> objects matching the filenames
 958 provided. If no filename list was passed, all C<Archive::Tar::File>
 959 objects in the current Tar object are returned.
 960
 961 Please refer to the C<Archive::Tar::File> documentation on how to
 962 handle these objects.
 963
 964 =cut
 965
 966 sub get_files {
 967     my $self = shift;
 968
 969     return @{ $self->_data } unless @_;
 970
 971     my @list;
 972     for my $file ( @_ ) {
 973         push @list, grep { defined } $self->_find_entry( $file );
 974     }
 975
 976     return @list;
 977 }
 978
 979 =head2 $tar->get_content( $file )
 980
 981 Return the content of the named file.
 982
 983 =cut
 984
 985 sub get_content {
 986     my $self = shift;
 987     my $entry = $self->_find_entry( shift ) or return;
 988
 989     return $entry->data;
 990 }
 991
 992 =head2 $tar->replace_content( $file, $content )
 993
 994 Make the string $content be the content for the file named $file.
 995
 996 =cut
 997
 998 sub replace_content {
 999     my $self = shift;
1000     my $entry = $self->_find_entry( shift ) or return;
1001
1002     return $entry->replace_content( shift );
1003 }
1004
1005 =head2 $tar->rename( $file, $new_name )
1006
1007 Rename the file of the in-memory archive to $new_name.
1008
1009 Note that you must specify a Unix path for $new_name, since per tar
1010 standard, all files in the archive must be Unix paths.
1011
1012 Returns true on success and false on failure.
1013
1014 =cut
1015
1016 sub rename {
1017     my $self = shift;
1018     my $file = shift; return unless defined $file;
1019     my $new  = shift; return unless defined $new;
1020
1021     my $entry = $self->_find_entry( $file ) or return;
1022
1023     return $entry->rename( $new );
1024 }
1025
1026 =head2 $tar->remove (@filenamelist)
1027
1028 Removes any entries with names matching any of the given filenames
1029 from the in-memory archive. Returns a list of C<Archive::Tar::File>
1030 objects that remain.
1031
1032 =cut
1033
1034 sub remove {
1035     my $self = shift;
1036     my @list = @_;
1037
1038     my %seen = map { $_->full_path => $_ } @{$self->_data};
1039     delete $seen{ $_ } for @list;
1040
1041     $self->_data( [values %seen] );
1042
1043     return values %seen;
1044 }
1045
1046 =head2 $tar->clear
1047
1048 C<clear> clears the current in-memory archive. This effectively gives
1049 you a 'blank' object, ready to be filled again. Note that C<clear>
1050 only has effect on the object, not the underlying tarfile.
1051
1052 =cut
1053
1054 sub clear {
1055     my $self = shift or return;
1056
1057     $self->_data( [] );
1058     $self->_file( '' );
1059
1060     return 1;
1061 }
1062
1063
1064 =head2 $tar->write ( [$file, $compressed, $prefix] )
1065
1066 Write the in-memory archive to disk.  The first argument can either
1067 be the name of a file or a reference to an already open filehandle (a
1068 GLOB reference).
1069
1070 The second argument is used to indicate compression. You can either
1071 compress using C<gzip> or C<bzip2>. If you pass a digit, it's assumed
1072 to be the C<gzip> compression level (between 1 and 9), but the use of
1073 constants is prefered:
1074
1075   # write a gzip compressed file
1076   $tar->write( 'out.tgz', COMPRESSION_GZIP );
1077
1078   # write a bzip compressed file
1079   $tar->write( 'out.tbz', COMPRESSION_BZIP );
1080
1081 Note that when you pass in a filehandle, the compression argument
1082 is ignored, as all files are printed verbatim to your filehandle.
1083 If you wish to enable compression with filehandles, use an
1084 C<IO::Zlib> or C<IO::Compress::Bzip2> filehandle instead.
1085
1086 The third argument is an optional prefix. All files will be tucked
1087 away in the directory you specify as prefix. So if you have files
1088 'a' and 'b' in your archive, and you specify 'foo' as prefix, they
1089 will be written to the archive as 'foo/a' and 'foo/b'.
1090
1091 If no arguments are given, C<write> returns the entire formatted
1092 archive as a string, which could be useful if you'd like to stuff the
1093 archive into a socket or a pipe to gzip or something.
1094
1095
1096 =cut
1097
1098 sub write {
1099     my $self        = shift;
1100     my $file        = shift; $file = '' unless defined $file;
1101     my $gzip        = shift || 0;
1102     my $ext_prefix  = shift; $ext_prefix = '' unless defined $ext_prefix;
1103     my $dummy       = '';
1104
1105     ### only need a handle if we have a file to print to ###
1106     my $handle = length($file)
1107                     ? ( $self->_get_handle($file, $gzip, WRITE_ONLY->($gzip) )
1108                         or return )
1109                     : $HAS_PERLIO    ? do { open my $h, '>', \$dummy; $h }
1110                     : $HAS_IO_STRING ? IO::String->new
1111                     : __PACKAGE__->no_string_support();
1112
1113
1114
1115     for my $entry ( @{$self->_data} ) {
1116         ### entries to be written to the tarfile ###
1117         my @write_me;
1118
1119         ### only now will we change the object to reflect the current state
1120         ### of the name and prefix fields -- this needs to be limited to
1121         ### write() only!
1122         my $clone = $entry->clone;
1123
1124
1125         ### so, if you don't want use to use the prefix, we'll stuff
1126         ### everything in the name field instead
1127         if( $DO_NOT_USE_PREFIX ) {
1128
1129             ### you might have an extended prefix, if so, set it in the clone
1130             ### XXX is ::Unix right?
1131             $clone->name( length $ext_prefix
1132                             ? File::Spec::Unix->catdir( $ext_prefix,
1133                                                         $clone->full_path)
1134                             : $clone->full_path );
1135             $clone->prefix( '' );
1136
1137         ### otherwise, we'll have to set it properly -- prefix part in the
1138         ### prefix and name part in the name field.
1139         } else {
1140
1141             ### split them here, not before!
1142             my ($prefix,$name) = $clone->_prefix_and_file( $clone->full_path );
1143
1144             ### you might have an extended prefix, if so, set it in the clone
1145             ### XXX is ::Unix right?
1146             $prefix = File::Spec::Unix->catdir( $ext_prefix, $prefix )
1147                 if length $ext_prefix;
1148
1149             $clone->prefix( $prefix );
1150             $clone->name( $name );
1151         }
1152
1153         ### names are too long, and will get truncated if we don't add a
1154         ### '@LongLink' file...
1155         my $make_longlink = (   length($clone->name)    > NAME_LENGTH or
1156                                 length($clone->prefix)  > PREFIX_LENGTH
1157                             ) || 0;
1158
1159         ### perhaps we need to make a longlink file?
1160         if( $make_longlink ) {
1161             my $longlink = Archive::Tar::File->new(
1162                             data => LONGLINK_NAME,
1163                             $clone->full_path,
1164                             { type => LONGLINK }
1165                         );
1166
1167             unless( $longlink ) {
1168                 $self->_error(  qq[Could not create 'LongLink' entry for ] .
1169                                 qq[oversize file '] . $clone->full_path ."'" );
1170                 return;
1171             };
1172
1173             push @write_me, $longlink;
1174         }
1175
1176         push @write_me, $clone;
1177
1178         ### write the one, optionally 2 a::t::file objects to the handle
1179         for my $clone (@write_me) {
1180
1181             ### if the file is a symlink, there are 2 options:
1182             ### either we leave the symlink intact, but then we don't write any
1183             ### data OR we follow the symlink, which means we actually make a
1184             ### copy. if we do the latter, we have to change the TYPE of the
1185             ### clone to 'FILE'
1186             my $link_ok =  $clone->is_symlink && $Archive::Tar::FOLLOW_SYMLINK;
1187             my $data_ok = !$clone->is_symlink && $clone->has_content;
1188
1189             ### downgrade to a 'normal' file if it's a symlink we're going to
1190             ### treat as a regular file
1191             $clone->_downgrade_to_plainfile if $link_ok;
1192
1193             ### get the header for this block
1194             my $header = $self->_format_tar_entry( $clone );
1195             unless( $header ) {
1196                 $self->_error(q[Could not format header for: ] .
1197                                     $clone->full_path );
1198                 return;
1199             }
1200
1201             unless( print $handle $header ) {
1202                 $self->_error(q[Could not write header for: ] .
1203                                     $clone->full_path);
1204                 return;
1205             }
1206
1207             if( $link_ok or $data_ok ) {
1208                 unless( print $handle $clone->data ) {
1209                     $self->_error(q[Could not write data for: ] .
1210                                     $clone->full_path);
1211                     return;
1212                 }
1213
1214                 ### pad the end of the clone if required ###
1215                 print $handle TAR_PAD->( $clone->size ) if $clone->size % BLOCK
1216             }
1217
1218         } ### done writing these entries
1219     }
1220
1221     ### write the end markers ###
1222     print $handle TAR_END x 2 or
1223             return $self->_error( qq[Could not write tar end markers] );
1224
1225     ### did you want it written to a file, or returned as a string? ###
1226     my $rv =  length($file) ? 1
1227                         : $HAS_PERLIO ? $dummy
1228                         : do { seek $handle, 0, 0; local $/; <$handle> };
1229
1230     ### make sure to close the handle;
1231     close $handle;
1232
1233     return $rv;
1234 }
1235
1236 sub _format_tar_entry {
1237     my $self        = shift;
1238     my $entry       = shift or return;
1239     my $ext_prefix  = shift; $ext_prefix = '' unless defined $ext_prefix;
1240     my $no_prefix   = shift || 0;
1241
1242     my $file    = $entry->name;
1243     my $prefix  = $entry->prefix; $prefix = '' unless defined $prefix;
1244
1245     ### remove the prefix from the file name
1246     ### not sure if this is still neeeded --kane
1247     ### no it's not -- Archive::Tar::File->_new_from_file will take care of
1248     ### this for us. Even worse, this would break if we tried to add a file
1249     ### like x/x.
1250     #if( length $prefix ) {
1251     #    $file =~ s/^$match//;
1252     #}
1253
1254     $prefix = File::Spec::Unix->catdir($ext_prefix, $prefix)
1255                 if length $ext_prefix;
1256
1257     ### not sure why this is... ###
1258     my $l = PREFIX_LENGTH; # is ambiguous otherwise...
1259     substr ($prefix, 0, -$l) = "" if length $prefix >= PREFIX_LENGTH;
1260
1261     my $f1 = "%06o"; my $f2  = "%11o";
1262
1263     ### this might be optimizable with a 'changed' flag in the file objects ###
1264     my $tar = pack (
1265                 PACK,
1266                 $file,
1267
1268                 (map { sprintf( $f1, $entry->$_() ) } qw[mode uid gid]),
1269                 (map { sprintf( $f2, $entry->$_() ) } qw[size mtime]),
1270
1271                 "",  # checksum field - space padded a bit down
1272
1273                 (map { $entry->$_() }                 qw[type linkname magic]),
1274
1275                 $entry->version || TAR_VERSION,
1276
1277                 (map { $entry->$_() }                 qw[uname gname]),
1278                 (map { sprintf( $f1, $entry->$_() ) } qw[devmajor devminor]),
1279
1280                 ($no_prefix ? '' : $prefix)
1281     );
1282
1283     ### add the checksum ###
1284     substr($tar,148,7) = sprintf("%6o\0", unpack("%16C*",$tar));
1285
1286     return $tar;
1287 }
1288
1289 =head2 $tar->add_files( @filenamelist )
1290
1291 Takes a list of filenames and adds them to the in-memory archive.
1292
1293 The path to the file is automatically converted to a Unix like
1294 equivalent for use in the archive, and, if on MacOS, the file's
1295 modification time is converted from the MacOS epoch to the Unix epoch.
1296 So tar archives created on MacOS with B<Archive::Tar> can be read
1297 both with I<tar> on Unix and applications like I<suntar> or
1298 I<Stuffit Expander> on MacOS.
1299
1300 Be aware that the file's type/creator and resource fork will be lost,
1301 which is usually what you want in cross-platform archives.
1302
1303 Instead of a filename, you can also pass it an existing C<Archive::Tar::File>
1304 object from, for example, another archive. The object will be clone, and
1305 effectively be a copy of the original, not an alias.
1306
1307 Returns a list of C<Archive::Tar::File> objects that were just added.
1308
1309 =cut
1310
1311 sub add_files {
1312     my $self    = shift;
1313     my @files   = @_ or return;
1314
1315     my @rv;
1316     for my $file ( @files ) {
1317
1318         ### you passed an Archive::Tar::File object
1319         ### clone it so we don't accidentally have a reference to
1320         ### an object from another archive
1321         if( UNIVERSAL::isa( $file,'Archive::Tar::File' ) ) {
1322             push @rv, $file->clone;
1323             next;
1324         }
1325
1326         unless( -e $file || -l $file ) {
1327             $self->_error( qq[No such file: '$file'] );
1328             next;
1329         }
1330
1331         my $obj = Archive::Tar::File->new( file => $file );
1332         unless( $obj ) {
1333             $self->_error( qq[Unable to add file: '$file'] );
1334             next;
1335         }
1336
1337         push @rv, $obj;
1338     }
1339
1340     push @{$self->{_data}}, @rv;
1341
1342     return @rv;
1343 }
1344
1345 =head2 $tar->add_data ( $filename, $data, [$opthashref] )
1346
1347 Takes a filename, a scalar full of data and optionally a reference to
1348 a hash with specific options.
1349
1350 Will add a file to the in-memory archive, with name C<$filename> and
1351 content C<$data>. Specific properties can be set using C<$opthashref>.
1352 The following list of properties is supported: name, size, mtime
1353 (last modified date), mode, uid, gid, linkname, uname, gname,
1354 devmajor, devminor, prefix, type.  (On MacOS, the file's path and
1355 modification times are converted to Unix equivalents.)
1356
1357 Valid values for the file type are the following constants defined in
1358 Archive::Tar::Constants:
1359
1360 =over 4
1361
1362 =item FILE
1363
1364 Regular file.
1365
1366 =item HARDLINK
1367
1368 =item SYMLINK
1369
1370 Hard and symbolic ("soft") links; linkname should specify target.
1371
1372 =item CHARDEV
1373
1374 =item BLOCKDEV
1375
1376 Character and block devices. devmajor and devminor should specify the major
1377 and minor device numbers.
1378
1379 =item DIR
1380
1381 Directory.
1382
1383 =item FIFO
1384
1385 FIFO (named pipe).
1386
1387 =item SOCKET
1388
1389 Socket.
1390
1391 =back
1392
1393 Returns the C<Archive::Tar::File> object that was just added, or
1394 C<undef> on failure.
1395
1396 =cut
1397
1398 sub add_data {
1399     my $self    = shift;
1400     my ($file, $data, $opt) = @_;
1401
1402     my $obj = Archive::Tar::File->new( data => $file, $data, $opt );
1403     unless( $obj ) {
1404         $self->_error( qq[Unable to add file: '$file'] );
1405         return;
1406     }
1407
1408     push @{$self->{_data}}, $obj;
1409
1410     return $obj;
1411 }
1412
1413 =head2 $tar->error( [$BOOL] )
1414
1415 Returns the current errorstring (usually, the last error reported).
1416 If a true value was specified, it will give the C<Carp::longmess>
1417 equivalent of the error, in effect giving you a stacktrace.
1418
1419 For backwards compatibility, this error is also available as
1420 C<$Archive::Tar::error> although it is much recommended you use the
1421 method call instead.
1422
1423 =cut
1424
1425 {
1426     $error = '';
1427     my $longmess;
1428
1429     sub _error {
1430         my $self    = shift;
1431         my $msg     = $error = shift;
1432         $longmess   = Carp::longmess($error);
1433
1434         ### set Archive::Tar::WARN to 0 to disable printing
1435         ### of errors
1436         if( $WARN ) {
1437             carp $DEBUG ? $longmess : $msg;
1438         }
1439
1440         return;
1441     }
1442
1443     sub error {
1444         my $self = shift;
1445         return shift() ? $longmess : $error;
1446     }
1447 }
1448
1449 =head2 $tar->setcwd( $cwd );
1450
1451 C<Archive::Tar> needs to know the current directory, and it will run
1452 C<Cwd::cwd()> I<every> time it extracts a I<relative> entry from the
1453 tarfile and saves it in the file system. (As of version 1.30, however,
1454 C<Archive::Tar> will use the speed optimization described below
1455 automatically, so it's only relevant if you're using C<extract_file()>).
1456
1457 Since C<Archive::Tar> doesn't change the current directory internally
1458 while it is extracting the items in a tarball, all calls to C<Cwd::cwd()>
1459 can be avoided if we can guarantee that the current directory doesn't
1460 get changed externally.
1461
1462 To use this performance boost, set the current directory via
1463
1464     use Cwd;
1465     $tar->setcwd( cwd() );
1466
1467 once before calling a function like C<extract_file> and
1468 C<Archive::Tar> will use the current directory setting from then on
1469 and won't call C<Cwd::cwd()> internally.
1470
1471 To switch back to the default behaviour, use
1472
1473     $tar->setcwd( undef );
1474
1475 and C<Archive::Tar> will call C<Cwd::cwd()> internally again.
1476
1477 If you're using C<Archive::Tar>'s C<exract()> method, C<setcwd()> will
1478 be called for you.
1479
1480 =cut
1481
1482 sub setcwd {
1483     my $self     = shift;
1484     my $cwd      = shift;
1485
1486     $self->{cwd} = $cwd;
1487 }
1488
1489 =head1 Class Methods
1490
1491 =head2 Archive::Tar->create_archive($file, $compressed, @filelist)
1492
1493 Creates a tar file from the list of files provided.  The first
1494 argument can either be the name of the tar file to create or a
1495 reference to an open file handle (e.g. a GLOB reference).
1496
1497 The second argument is used to indicate compression. You can either
1498 compress using C<gzip> or C<bzip2>. If you pass a digit, it's assumed
1499 to be the C<gzip> compression level (between 1 and 9), but the use of
1500 constants is prefered:
1501
1502   # write a gzip compressed file
1503   Archive::Tar->create_archive( 'out.tgz', COMPRESSION_GZIP, @filelist );
1504
1505   # write a bzip compressed file
1506   Archive::Tar->create_archive( 'out.tbz', COMPRESSION_BZIP, @filelist );
1507
1508 Note that when you pass in a filehandle, the compression argument
1509 is ignored, as all files are printed verbatim to your filehandle.
1510 If you wish to enable compression with filehandles, use an
1511 C<IO::Zlib> or C<IO::Compress::Bzip2> filehandle instead.
1512
1513 The remaining arguments list the files to be included in the tar file.
1514 These files must all exist. Any files which don't exist or can't be
1515 read are silently ignored.
1516
1517 If the archive creation fails for any reason, C<create_archive> will
1518 return false. Please use the C<error> method to find the cause of the
1519 failure.
1520
1521 Note that this method does not write C<on the fly> as it were; it
1522 still reads all the files into memory before writing out the archive.
1523 Consult the FAQ below if this is a problem.
1524
1525 =cut
1526
1527 sub create_archive {
1528     my $class = shift;
1529
1530     my $file    = shift; return unless defined $file;
1531     my $gzip    = shift || 0;
1532     my @files   = @_;
1533
1534     unless( @files ) {
1535         return $class->_error( qq[Cowardly refusing to create empty archive!] );
1536     }
1537
1538     my $tar = $class->new;
1539     $tar->add_files( @files );
1540     return $tar->write( $file, $gzip );
1541 }
1542
1543 =head2 Archive::Tar->iter( $filename, [ $compressed, {opt => $val} ] )
1544
1545 Returns an iterator function that reads the tar file without loading
1546 it all in memory.  Each time the function is called it will return the
1547 next file in the tarball. The files are returned as
1548 C<Archive::Tar::File> objects. The iterator function returns the
1549 empty list once it has exhausted the the files contained.
1550
1551 The second argument can be a hash reference with options, which are
1552 identical to the arguments passed to C<read()>.
1553
1554 Example usage:
1555
1556     my $next = Archive::Tar->iter( "example.tar.gz", 1, {filter => qr/\.pm$/} );
1557
1558     while( my $f = $next->() ) {
1559         print $f->name, "\n";
1560
1561         $f->extract or warn "Extraction failed";
1562
1563         # ....
1564     }
1565
1566 =cut
1567
1568
1569 sub iter {
1570     my $class       = shift;
1571     my $filename    = shift or return;
1572     my $compressed  = shift or 0;
1573     my $opts        = shift || {};
1574
1575     ### get a handle to read from.
1576     my $handle = $class->_get_handle(
1577         $filename,
1578         $compressed,
1579         READ_ONLY->( ZLIB )
1580     ) or return;
1581
1582     my @data;
1583     return sub {
1584         return shift(@data)     if @data;       # more than one file returned?
1585         return                  unless $handle; # handle exhausted?
1586
1587         ### read data, should only return file
1588         @data = @{ $class->_read_tar($handle, { %$opts, limit => 1 }) };
1589
1590         ### return one piece of data
1591         return shift(@data)     if @data;
1592
1593         ### data is exhausted, free the filehandle
1594         undef $handle;
1595         return;
1596     };
1597 }
1598
1599 =head2 Archive::Tar->list_archive($file, $compressed, [\@properties])
1600
1601 Returns a list of the names of all the files in the archive.  The
1602 first argument can either be the name of the tar file to list or a
1603 reference to an open file handle (e.g. a GLOB reference).
1604
1605 If C<list_archive()> is passed an array reference as its third
1606 argument it returns a list of hash references containing the requested
1607 properties of each file.  The following list of properties is
1608 supported: full_path, name, size, mtime (last modified date), mode,
1609 uid, gid, linkname, uname, gname, devmajor, devminor, prefix.
1610
1611 See C<Archive::Tar::File> for details about supported properties.
1612
1613 Passing an array reference containing only one element, 'name', is
1614 special cased to return a list of names rather than a list of hash
1615 references.
1616
1617 =cut
1618
1619 sub list_archive {
1620     my $class   = shift;
1621     my $file    = shift; return unless defined $file;
1622     my $gzip    = shift || 0;
1623
1624     my $tar = $class->new($file, $gzip);
1625     return unless $tar;
1626
1627     return $tar->list_files( @_ );
1628 }
1629
1630 =head2 Archive::Tar->extract_archive($file, $compressed)
1631
1632 Extracts the contents of the tar file.  The first argument can either
1633 be the name of the tar file to create or a reference to an open file
1634 handle (e.g. a GLOB reference).  All relative paths in the tar file will
1635 be created underneath the current working directory.
1636
1637 C<extract_archive> will return a list of files it extracted.
1638 If the archive extraction fails for any reason, C<extract_archive>
1639 will return false.  Please use the C<error> method to find the cause
1640 of the failure.
1641
1642 =cut
1643
1644 sub extract_archive {
1645     my $class   = shift;
1646     my $file    = shift; return unless defined $file;
1647     my $gzip    = shift || 0;
1648
1649     my $tar = $class->new( ) or return;
1650
1651     return $tar->read( $file, $gzip, { extract => 1 } );
1652 }
1653
1654 =head2 $bool = Archive::Tar->has_io_string
1655
1656 Returns true if we currently have C<IO::String> support loaded.
1657
1658 Either C<IO::String> or C<perlio> support is needed to support writing
1659 stringified archives. Currently, C<perlio> is the preferred method, if
1660 available.
1661
1662 See the C<GLOBAL VARIABLES> section to see how to change this preference.
1663
1664 =cut
1665
1666 sub has_io_string { return $HAS_IO_STRING; }
1667
1668 =head2 $bool = Archive::Tar->has_perlio
1669
1670 Returns true if we currently have C<perlio> support loaded.
1671
1672 This requires C<perl-5.8> or higher, compiled with C<perlio>
1673
1674 Either C<IO::String> or C<perlio> support is needed to support writing
1675 stringified archives. Currently, C<perlio> is the preferred method, if
1676 available.
1677
1678 See the C<GLOBAL VARIABLES> section to see how to change this preference.
1679
1680 =cut
1681
1682 sub has_perlio { return $HAS_PERLIO; }
1683
1684 =head2 $bool = Archive::Tar->has_zlib_support
1685
1686 Returns true if C<Archive::Tar> can extract C<zlib> compressed archives
1687
1688 =cut
1689
1690 sub has_zlib_support { return ZLIB }
1691
1692 =head2 $bool = Archive::Tar->has_bzip2_support
1693
1694 Returns true if C<Archive::Tar> can extract C<bzip2> compressed archives
1695
1696 =cut
1697
1698 sub has_bzip2_support { return BZIP }
1699
1700 =head2 Archive::Tar->can_handle_compressed_files
1701
1702 A simple checking routine, which will return true if C<Archive::Tar>
1703 is able to uncompress compressed archives on the fly with C<IO::Zlib>
1704 and C<IO::Compress::Bzip2> or false if not both are installed.
1705
1706 You can use this as a shortcut to determine whether C<Archive::Tar>
1707 will do what you think before passing compressed archives to its
1708 C<read> method.
1709
1710 =cut
1711
1712 sub can_handle_compressed_files { return ZLIB && BZIP ? 1 : 0 }
1713
1714 sub no_string_support {
1715     croak("You have to install IO::String to support writing archives to strings");
1716 }
1717
1718 1;
1719
1720 __END__
1721
1722 =head1 GLOBAL VARIABLES
1723
1724 =head2 $Archive::Tar::FOLLOW_SYMLINK
1725
1726 Set this variable to C<1> to make C<Archive::Tar> effectively make a
1727 copy of the file when extracting. Default is C<0>, which
1728 means the symlink stays intact. Of course, you will have to pack the
1729 file linked to as well.
1730
1731 This option is checked when you write out the tarfile using C<write>
1732 or C<create_archive>.
1733
1734 This works just like C</bin/tar>'s C<-h> option.
1735
1736 =head2 $Archive::Tar::CHOWN
1737
1738 By default, C<Archive::Tar> will try to C<chown> your files if it is
1739 able to. In some cases, this may not be desired. In that case, set
1740 this variable to C<0> to disable C<chown>-ing, even if it were
1741 possible.
1742
1743 The default is C<1>.
1744
1745 =head2 $Archive::Tar::CHMOD
1746
1747 By default, C<Archive::Tar> will try to C<chmod> your files to
1748 whatever mode was specified for the particular file in the archive.
1749 In some cases, this may not be desired. In that case, set this
1750 variable to C<0> to disable C<chmod>-ing.
1751
1752 The default is C<1>.
1753
1754 =head2 $Archive::Tar::DO_NOT_USE_PREFIX
1755
1756 By default, C<Archive::Tar> will try to put paths that are over
1757 100 characters in the C<prefix> field of your tar header, as
1758 defined per POSIX-standard. However, some (older) tar programs
1759 do not implement this spec. To retain compatibility with these older
1760 or non-POSIX compliant versions, you can set the C<$DO_NOT_USE_PREFIX>
1761 variable to a true value, and C<Archive::Tar> will use an alternate
1762 way of dealing with paths over 100 characters by using the
1763 C<GNU Extended Header> feature.
1764
1765 Note that clients who do not support the C<GNU Extended Header>
1766 feature will not be able to read these archives. Such clients include
1767 tars on C<Solaris>, C<Irix> and C<AIX>.
1768
1769 The default is C<0>.
1770
1771 =head2 $Archive::Tar::DEBUG
1772
1773 Set this variable to C<1> to always get the C<Carp::longmess> output
1774 of the warnings, instead of the regular C<carp>. This is the same
1775 message you would get by doing:
1776
1777     $tar->error(1);
1778
1779 Defaults to C<0>.
1780
1781 =head2 $Archive::Tar::WARN
1782
1783 Set this variable to C<0> if you do not want any warnings printed.
1784 Personally I recommend against doing this, but people asked for the
1785 option. Also, be advised that this is of course not threadsafe.
1786
1787 Defaults to C<1>.
1788
1789 =head2 $Archive::Tar::error
1790
1791 Holds the last reported error. Kept for historical reasons, but its
1792 use is very much discouraged. Use the C<error()> method instead:
1793
1794     warn $tar->error unless $tar->extract;
1795
1796 =head2 $Archive::Tar::INSECURE_EXTRACT_MODE
1797
1798 This variable indicates whether C<Archive::Tar> should allow
1799 files to be extracted outside their current working directory.
1800
1801 Allowing this could have security implications, as a malicious
1802 tar archive could alter or replace any file the extracting user
1803 has permissions to. Therefor, the default is to not allow
1804 insecure extractions.
1805
1806 If you trust the archive, or have other reasons to allow the
1807 archive to write files outside your current working directory,
1808 set this variable to C<true>.
1809
1810 Note that this is a backwards incompatible change from version
1811 C<1.36> and before.
1812
1813 =head2 $Archive::Tar::HAS_PERLIO
1814
1815 This variable holds a boolean indicating if we currently have
1816 C<perlio> support loaded. This will be enabled for any perl
1817 greater than C<5.8> compiled with C<perlio>.
1818
1819 If you feel strongly about disabling it, set this variable to
1820 C<false>. Note that you will then need C<IO::String> installed
1821 to support writing stringified archives.
1822
1823 Don't change this variable unless you B<really> know what you're
1824 doing.
1825
1826 =head2 $Archive::Tar::HAS_IO_STRING
1827
1828 This variable holds a boolean indicating if we currently have
1829 C<IO::String> support loaded. This will be enabled for any perl
1830 that has a loadable C<IO::String> module.
1831
1832 If you feel strongly about disabling it, set this variable to
1833 C<false>. Note that you will then need C<perlio> support from
1834 your perl to be able to  write stringified archives.
1835
1836 Don't change this variable unless you B<really> know what you're
1837 doing.
1838
1839 =head1 FAQ
1840
1841 =over 4
1842
1843 =item What's the minimum perl version required to run Archive::Tar?
1844
1845 You will need perl version 5.005_03 or newer.
1846
1847 =item Isn't Archive::Tar slow?
1848
1849 Yes it is. It's pure perl, so it's a lot slower then your C</bin/tar>
1850 However, it's very portable. If speed is an issue, consider using
1851 C</bin/tar> instead.
1852
1853 =item Isn't Archive::Tar heavier on memory than /bin/tar?
1854
1855 Yes it is, see previous answer. Since C<Compress::Zlib> and therefore
1856 C<IO::Zlib> doesn't support C<seek> on their filehandles, there is little
1857 choice but to read the archive into memory.
1858 This is ok if you want to do in-memory manipulation of the archive.
1859
1860 If you just want to extract, use the C<extract_archive> class method
1861 instead. It will optimize and write to disk immediately.
1862
1863 Another option is to use the C<iter> class method to iterate over
1864 the files in the tarball without reading them all in memory at once.
1865
1866 =item Can you lazy-load data instead?
1867
1868 In some cases, yes. You can use the C<iter> class method to iterate
1869 over the files in the tarball without reading them all in memory at once.
1870
1871 =item How much memory will an X kb tar file need?
1872
1873 Probably more than X kb, since it will all be read into memory. If
1874 this is a problem, and you don't need to do in memory manipulation
1875 of the archive, consider using the C<iter> class method, or C</bin/tar>
1876 instead.
1877
1878 =item What do you do with unsupported filetypes in an archive?
1879
1880 C<Unix> has a few filetypes that aren't supported on other platforms,
1881 like C<Win32>. If we encounter a C<hardlink> or C<symlink> we'll just
1882 try to make a copy of the original file, rather than throwing an error.
1883
1884 This does require you to read the entire archive in to memory first,
1885 since otherwise we wouldn't know what data to fill the copy with.
1886 (This means that you cannot use the class methods, including C<iter>
1887 on archives that have incompatible filetypes and still expect things
1888 to work).
1889
1890 For other filetypes, like C<chardevs> and C<blockdevs> we'll warn that
1891 the extraction of this particular item didn't work.
1892
1893 =item I'm using WinZip, or some other non-POSIX client, and files are not being extracted properly!
1894
1895 By default, C<Archive::Tar> is in a completely POSIX-compatible
1896 mode, which uses the POSIX-specification of C<tar> to store files.
1897 For paths greather than 100 characters, this is done using the
1898 C<POSIX header prefix>. Non-POSIX-compatible clients may not support
1899 this part of the specification, and may only support the C<GNU Extended
1900 Header> functionality. To facilitate those clients, you can set the
1901 C<$Archive::Tar::DO_NOT_USE_PREFIX> variable to C<true>. See the
1902 C<GLOBAL VARIABLES> section for details on this variable.
1903
1904 Note that GNU tar earlier than version 1.14 does not cope well with
1905 the C<POSIX header prefix>. If you use such a version, consider setting
1906 the C<$Archive::Tar::DO_NOT_USE_PREFIX> variable to C<true>.
1907
1908 =item How do I extract only files that have property X from an archive?
1909
1910 Sometimes, you might not wish to extract a complete archive, just
1911 the files that are relevant to you, based on some criteria.
1912
1913 You can do this by filtering a list of C<Archive::Tar::File> objects
1914 based on your criteria. For example, to extract only files that have
1915 the string C<foo> in their title, you would use:
1916
1917     $tar->extract(
1918         grep { $_->full_path =~ /foo/ } $tar->get_files
1919     );
1920
1921 This way, you can filter on any attribute of the files in the archive.
1922 Consult the C<Archive::Tar::File> documentation on how to use these
1923 objects.
1924
1925 =item How do I access .tar.Z files?
1926
1927 The C<Archive::Tar> module can optionally use C<Compress::Zlib> (via
1928 the C<IO::Zlib> module) to access tar files that have been compressed
1929 with C<gzip>. Unfortunately tar files compressed with the Unix C<compress>
1930 utility cannot be read by C<Compress::Zlib> and so cannot be directly
1931 accesses by C<Archive::Tar>.
1932
1933 If the C<uncompress> or C<gunzip> programs are available, you can use
1934 one of these workarounds to read C<.tar.Z> files from C<Archive::Tar>
1935
1936 Firstly with C<uncompress>
1937
1938     use Archive::Tar;
1939
1940     open F, "uncompress -c $filename |";
1941     my $tar = Archive::Tar->new(*F);
1942     ...
1943
1944 and this with C<gunzip>
1945
1946     use Archive::Tar;
1947
1948     open F, "gunzip -c $filename |";
1949     my $tar = Archive::Tar->new(*F);
1950     ...
1951
1952 Similarly, if the C<compress> program is available, you can use this to
1953 write a C<.tar.Z> file
1954
1955     use Archive::Tar;
1956     use IO::File;
1957
1958     my $fh = new IO::File "| compress -c >$filename";
1959     my $tar = Archive::Tar->new();
1960     ...
1961     $tar->write($fh);
1962     $fh->close ;
1963
1964 =item How do I handle Unicode strings?
1965
1966 C<Archive::Tar> uses byte semantics for any files it reads from or writes
1967 to disk. This is not a problem if you only deal with files and never
1968 look at their content or work solely with byte strings. But if you use
1969 Unicode strings with character semantics, some additional steps need
1970 to be taken.
1971
1972 For example, if you add a Unicode string like
1973
1974     # Problem
1975     $tar->add_data('file.txt', "Euro: \x{20AC}");
1976
1977 then there will be a problem later when the tarfile gets written out
1978 to disk via C<$tar->write()>:
1979
1980     Wide character in print at .../Archive/Tar.pm line 1014.
1981
1982 The data was added as a Unicode string and when writing it out to disk,
1983 the C<:utf8> line discipline wasn't set by C<Archive::Tar>, so Perl
1984 tried to convert the string to ISO-8859 and failed. The written file
1985 now contains garbage.
1986
1987 For this reason, Unicode strings need to be converted to UTF-8-encoded
1988 bytestrings before they are handed off to C<add_data()>:
1989
1990     use Encode;
1991     my $data = "Accented character: \x{20AC}";
1992     $data = encode('utf8', $data);
1993
1994     $tar->add_data('file.txt', $data);
1995
1996 A opposite problem occurs if you extract a UTF8-encoded file from a
1997 tarball. Using C<get_content()> on the C<Archive::Tar::File> object
1998 will return its content as a bytestring, not as a Unicode string.
1999
2000 If you want it to be a Unicode string (because you want character
2001 semantics with operations like regular expression matching), you need
2002 to decode the UTF8-encoded content and have Perl convert it into
2003 a Unicode string:
2004
2005     use Encode;
2006     my $data = $tar->get_content();
2007
2008     # Make it a Unicode string
2009     $data = decode('utf8', $data);
2010
2011 There is no easy way to provide this functionality in C<Archive::Tar>,
2012 because a tarball can contain many files, and each of which could be
2013 encoded in a different way.
2014
2015 =back
2016
2017 =head1 TODO
2018
2019 =over 4
2020
2021 =item Check if passed in handles are open for read/write
2022
2023 Currently I don't know of any portable pure perl way to do this.
2024 Suggestions welcome.
2025
2026 =item Allow archives to be passed in as string
2027
2028 Currently, we only allow opened filehandles or filenames, but
2029 not strings. The internals would need some reworking to facilitate
2030 stringified archives.
2031
2032 =item Facilitate processing an opened filehandle of a compressed archive
2033
2034 Currently, we only support this if the filehandle is an IO::Zlib object.
2035 Environments, like apache, will present you with an opened filehandle
2036 to an uploaded file, which might be a compressed archive.
2037
2038 =back
2039
2040 =head1 SEE ALSO
2041
2042 =over 4
2043
2044 =item The GNU tar specification
2045
2046 C<http://www.gnu.org/software/tar/manual/tar.html>
2047
2048 =item The PAX format specication
2049
2050 The specifcation which tar derives from; C< http://www.opengroup.org/onlinepubs/007904975/utilities/pax.html>
2051
2052 =item A comparison of GNU and POSIX tar standards; C<http://www.delorie.com/gnu/docs/tar/tar_114.html>
2053
2054 =item GNU tar intends to switch to POSIX compatibility
2055
2056 GNU Tar authors have expressed their intention to become completely
2057 POSIX-compatible; C<http://www.gnu.org/software/tar/manual/html_node/Formats.html>
2058
2059 =item A Comparison between various tar implementations
2060
2061 Lists known issues and incompatibilities; C<http://gd.tuwien.ac.at/utils/archivers/star/README.otherbugs>
2062
2063 =back
2064
2065 =head1 AUTHOR
2066
2067 This module by Jos Boumans E<lt>kane@cpan.orgE<gt>.
2068
2069 Please reports bugs to E<lt>bug-archive-tar@rt.cpan.orgE<gt>.
2070
2071 =head1 ACKNOWLEDGEMENTS
2072
2073 Thanks to Sean Burke, Chris Nandor, Chip Salzenberg, Tim Heaney, Gisle Aas
2074 and especially Andrew Savige for their help and suggestions.
2075
2076 =head1 COPYRIGHT
2077
2078 This module is copyright (c) 2002 - 2008 Jos Boumans
2079 E<lt>kane@cpan.orgE<gt>. All rights reserved.
2080
2081 This library is free software; you may redistribute and/or modify
2082 it under the same terms as Perl itself.
2083
2084 =cut