installperl

   1 #!./perl
   2
   3 use strict;
   4 use vars qw($Is_VMS $Is_W32 $Is_OS2 $nonono $versiononly $depth);
   5
   6 BEGIN {
   7     require 5.004;
   8     chdir '..' if !-d 'lib' and -d '..\lib';
   9     @INC = 'lib';
  10     $ENV{PERL5LIB} = 'lib';
  11     $Is_VMS = $^O eq 'VMS';
  12     $Is_W32 = $^O eq 'MSWin32';
  13     $Is_OS2 = $^O eq 'os2';
  14     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  15 }
  16
  17 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  18
  19 use File::Find;
  20 use File::Compare;
  21 use File::Copy ();
  22 use File::Path ();
  23 use ExtUtils::Packlist;
  24 use Config;
  25 use subs qw(unlink link chmod);
  26 use vars qw($packlist);
  27
  28 # override the ones in the rest of the script
  29 sub mkpath {
  30     File::Path::mkpath(@_) unless $nonono;
  31 }
  32
  33 my $mainperldir = "/usr/bin";
  34 my $exe_ext = $Config{exe_ext};
  35
  36 # Allow ``make install PERLNAME=something_besides_perl'':
  37 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  38
  39 while (@ARGV) {
  40     $nonono = 1 if $ARGV[0] eq '-n';
  41     $versiononly = 1 if $ARGV[0] eq '-v';
  42     shift;
  43 }
  44
  45 umask 022 unless $Is_VMS;
  46
  47 my @scripts = qw(utils/c2ph utils/h2ph utils/h2xs utils/perlbug utils/perldoc
  48                 utils/pl2pm utils/splain utils/perlcc
  49                 x2p/s2p x2p/find2perl
  50                 pod/pod2man pod/pod2html pod/pod2latex pod/pod2text);
  51
  52 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
  53
  54 my @pods = (<pod/*.pod>);
  55
  56 # Specify here any .pm files that are actually architecture-dependent.
  57 # (Those included with XS extensions under ext/ are automatically
  58 # added later.)
  59 # Now that the default privlib has the full perl version number included,
  60 # we no longer have to play the trick of sticking version-specific .pm
  61 # files under the archlib directory.
  62 my %archpms = (
  63     Config => 1,
  64 );
  65
  66 if ($^O eq 'dos') {
  67     push(@scripts,'djgpp/fixpmain');
  68     $archpms{config} = $archpms{filehand} = 1;
  69 }
  70
  71 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
  72 {
  73         push(@scripts, map("$_.exe", @scripts));
  74 }
  75
  76 find(sub {
  77         if ("$File::Find::dir/$_" =~ m{^ext/[^/]+/(.*)\.pm$}) {
  78             (my $pm = $1) =~ s{^lib/}{};
  79             $archpms{$pm} = 1;
  80         }
  81     }, 'ext');
  82
  83 my $ver = $];
  84 my $release = substr($ver,0,3);   # Not used presently.
  85 my $patchlevel = substr($ver,3,2);
  86 die "Patchlevel of perl ($patchlevel)",
  87     "and patchlevel of config.sh ($Config{'PATCHLEVEL'}) don't match\n"
  88         if $patchlevel != $Config{'PATCHLEVEL'};
  89
  90 # Fetch some frequently-used items from %Config
  91 my $installbin = $Config{installbin};
  92 my $installscript = $Config{installscript};
  93 my $installprivlib = $Config{installprivlib};
  94 my $installarchlib = $Config{installarchlib};
  95 my $installsitelib = $Config{installsitelib};
  96 my $installsitearch = $Config{installsitearch};
  97 my $installman1dir = $Config{installman1dir};
  98 my $man1ext = $Config{man1ext};
  99 my $libperl = $Config{libperl};
 100 # Shared library and dynamic loading suffixes.
 101 my $so = $Config{so};
 102 my $dlext = $Config{dlext};
 103
 104 my $d_dosuid = $Config{d_dosuid};
 105 my $binexp = $Config{binexp};
 106
 107 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 108     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 109               \$installarchlib, \$installsitelib, \$installsitearch,
 110               \$installman1dir ) {
 111       $$_ = unixify($$_);  $$_ =~ s:/$::;
 112     }
 113 }
 114
 115 # Do some quick sanity checks.
 116
 117 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 118
 119    $installbin          || die "No installbin directory in config.sh\n";
 120 -d $installbin          || mkpath($installbin, 1, 0777);
 121 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 122 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 123         unless $installbin =~ m#^/afs/# || $nonono;
 124
 125 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 126 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 127
 128 -x 't/TEST'             || $Is_W32
 129                         || warn "WARNING: You've never run 'make test'!!!",
 130                                 "  (Installing anyway.)\n";
 131
 132 if ($Is_W32) {
 133
 134 my $perldll = 'perl.' . $dlext;
 135 $perldll = 'perlcore.' . $dlext if $Config{'ccflags'} =~ /PERL_OBJECT/i;
 136
 137 -f $perldll || die "No perl DLL built\n";
 138
 139 # Install the DLL
 140
 141 safe_unlink("$installbin/$perldll");
 142 copy("$perldll", "$installbin/$perldll");
 143 chmod(0755, "$installbin/$perldll");
 144 }
 145
 146 # This will be used to store the packlist
 147 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 148
 149 # First we install the version-numbered executables.
 150
 151 if ($Is_VMS) {
 152     safe_unlink("$installbin/$perl$exe_ext");
 153     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 154     chmod(0755, "$installbin/$perl$exe_ext");
 155     safe_unlink("$installbin/${perl}shr$exe_ext");
 156     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 157     chmod(0755, "$installbin/${perl}shr$exe_ext");
 158 }
 159 elsif ($^O ne 'dos') {
 160     safe_unlink("$installbin/$perl$ver$exe_ext");
 161     copy("perl$exe_ext", "$installbin/$perl$ver$exe_ext");
 162     chmod(0755, "$installbin/$perl$ver$exe_ext");
 163 } else {
 164     safe_unlink("$installbin/$perl.exe");
 165     copy("perl.exe", "$installbin/$perl.exe");
 166 }
 167
 168 safe_unlink("$installbin/s$perl$ver$exe_ext");
 169 if ($d_dosuid) {
 170     copy("suidperl$exe_ext", "$installbin/s$perl$ver$exe_ext");
 171     chmod(04711, "$installbin/s$perl$ver$exe_ext");
 172 }
 173
 174 # Install library files.
 175
 176 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 177
 178 mkpath($installprivlib, 1, 0777);
 179 mkpath($installarchlib, 1, 0777);
 180 mkpath($installsitelib, 1, 0777) if ($installsitelib);
 181 mkpath($installsitearch, 1, 0777) if ($installsitearch);
 182
 183 if (chdir "lib") {
 184     $do_installarchlib = ! samepath($installarchlib, '.');
 185     $do_installprivlib = ! samepath($installprivlib, '.');
 186     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$]/);
 187
 188     if ($do_installarchlib || $do_installprivlib) {
 189         find(\&installlib, '.');
 190     }
 191     chdir ".." || die "Can't cd back to source directory: $!\n";
 192 }
 193 else {
 194     warn "Can't cd to lib to install lib files: $!\n";
 195 }
 196
 197 # Install header files and libraries.
 198 mkpath("$installarchlib/CORE", 1, 0777);
 199 my @corefiles;
 200 if ($Is_VMS) {  # We did core file selection during build
 201     my $coredir = "lib/$Config{'arch'}/$]";
 202     $coredir =~ tr/./_/;
 203     @corefiles = <$coredir/*.*>;
 204 }
 205 else {
 206     @corefiles = <*.h libperl*.*>;
 207     # AIX needs perl.exp installed as well.
 208     push(@corefiles,'perl.exp') if $^O eq 'aix';
 209     # If they have built sperl.o...
 210     push(@corefiles,'sperl.o') if -f 'sperl.o';
 211 }
 212 foreach my $file (@corefiles) {
 213     # HP-UX (at least) needs to maintain execute permissions
 214     # on dynamically-loadable libraries. So we do it for all.
 215     copy_if_diff($file,"$installarchlib/CORE/$file")
 216         and chmod($file =~ /\.(so|\Q$dlext\E)$/ ? 0555 : 0444,
 217                    "$installarchlib/CORE/$file");
 218 }
 219
 220 # Install main perl executables
 221 # Make links to ordinary names if installbin directory isn't current directory.
 222
 223 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 224     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 225     link("$installbin/$perl$ver$exe_ext", "$installbin/$perl$exe_ext");
 226     link("$installbin/s$perl$ver$exe_ext", "$installbin/suid$perl$exe_ext")
 227       if $d_dosuid;
 228 }
 229
 230 # Offer to install perl in a "standard" location
 231
 232 my $mainperl_is_instperl = 0;
 233
 234 if (!$versiononly && !$nonono && !$Is_W32 && !$Is_VMS && -t STDIN && -t STDERR
 235         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 236     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 237     my($instperl)       = "$installbin/$perl$exe_ext";
 238     my($expinstperl)    = "$binexp/$perl$exe_ext";
 239
 240     # First make sure $usrbinperl is not already the same as the perl we
 241     # just installed.
 242     if (-x $usrbinperl) {
 243         # Try to be clever about mainperl being a symbolic link
 244         # to binexp/perl if binexp and installbin are different.
 245         $mainperl_is_instperl =
 246             samepath($usrbinperl, $instperl) ||
 247             samepath($usrbinperl, $expinstperl) ||
 248              (($binexp ne $installbin) &&
 249               (-l $usrbinperl) &&
 250               ((readlink $usrbinperl) eq $expinstperl));
 251     }
 252     if ((! $mainperl_is_instperl) &&
 253         (yn("Many scripts expect perl to be installed as $usrbinperl.\n" .
 254              "Do you wish to have $usrbinperl be the same as\n" .
 255              "$expinstperl? [y] ")))
 256     {
 257         unlink($usrbinperl);
 258         eval { CORE::link $instperl, $usrbinperl } ||
 259             eval { symlink $expinstperl, $usrbinperl } ||
 260                 copy($instperl, $usrbinperl);
 261         $mainperl_is_instperl = 1;
 262     }
 263 }
 264
 265 # Make links to ordinary names if installbin directory isn't current directory.
 266
 267 if (!$versiononly && ! samepath($installbin, 'x2p')) {
 268     safe_unlink("$installbin/a2p$exe_ext");
 269     copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 270     chmod(0755, "$installbin/a2p$exe_ext");
 271 }
 272
 273 # cppstdin is just a script, but it is architecture-dependent, so
 274 # it can't safely be shared.  Place it in $installbin.
 275 # Note that Configure doesn't build cppstin if it isn't needed, so
 276 # we skip this if cppstdin doesn't exist.
 277 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 278     safe_unlink("$installbin/cppstdin");
 279     copy("cppstdin", "$installbin/cppstdin");
 280     chmod(0755, "$installbin/cppstdin");
 281 }
 282
 283 # Install scripts.
 284
 285 mkpath($installscript, 1, 0777);
 286
 287 if (! $versiononly) {
 288     for (@scripts) {
 289         (my $base = $_) =~ s#.*/##;
 290         copy($_, "$installscript/$base");
 291         chmod(0755, "$installscript/$base");
 292     }
 293 }
 294
 295 # pstruct should be a link to c2ph
 296
 297 if (! $versiononly) {
 298     safe_unlink("$installscript/pstruct$scr_ext");
 299     if ($^O eq 'dos' or $Is_VMS) {
 300         copy("$installscript/c2ph$scr_ext", "$installscript/pstruct$scr_ext");
 301     } else {
 302         link("$installscript/c2ph$scr_ext", "$installscript/pstruct$scr_ext");
 303     }
 304 }
 305
 306 # Install pod pages.  Where? I guess in $installprivlib/pod.
 307
 308 if (! $versiononly || !($installprivlib =~ m/\Q$]/)) {
 309     mkpath("${installprivlib}/pod", 1, 0777);
 310
 311     # If Perl 5.003's perldiag.pod is there, rename it.
 312     if (open POD, "${installprivlib}/pod/perldiag.pod") {
 313         read POD, $_, 4000;
 314         close POD;
 315         # Some of Perl 5.003's diagnostic messages ended with periods.
 316         if (/^=.*\.$/m) {
 317             my ($from, $to) = ("${installprivlib}/pod/perldiag.pod",
 318                                "${installprivlib}/pod/perldiag-5.003.pod");
 319             print STDERR "  rename $from $to";
 320             rename($from, $to)
 321                 or warn "Couldn't rename $from to $to: $!\n"
 322                 unless $nonono;
 323         }
 324     }
 325
 326     foreach my $file (@pods) {
 327         # $file is a name like  pod/perl.pod
 328         copy_if_diff($file, "${installprivlib}/${file}");
 329     }
 330
 331 }
 332
 333 # Check to make sure there aren't other perls around in installer's
 334 # path.  This is probably UNIX-specific.  Check all absolute directories
 335 # in the path except for where public executables are supposed to live.
 336 # Also skip $mainperl if the user opted to have it be a link to the
 337 # installed perl.
 338
 339 if (!$versiononly) {
 340         my ($path, @path);
 341     my $dirsep = ($Is_OS2 || $Is_W32) ? ';' : ':' ;
 342     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 343     @path = split(/$dirsep/, $path);
 344     if ($Is_VMS) {
 345         my $i = 0;
 346         while (exists $ENV{'DCL$PATH' . $i}) {
 347             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 348             push(@path,$dir);
 349         }
 350     }
 351     my @otherperls;
 352     for (@path) {
 353         next unless m,^/,;
 354         # Use &samepath here because some systems have other dirs linked
 355         # to $mainperldir (like SunOS)
 356         next if samepath($_, $binexp);
 357         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 358         push(@otherperls, "$_/$perl$exe_ext")
 359             if (-x "$_/$perl$exe_ext" && ! -d "$_/$perl$exe_ext");
 360     }
 361     if (@otherperls) {
 362         print STDERR "\nWarning: $perl appears in your path in the following " .
 363             "locations beyond where\nwe just installed it:\n";
 364         for (@otherperls) {
 365             print STDERR "    ", $_, "\n";
 366         }
 367         print STDERR "\n";
 368     }
 369
 370 }
 371
 372 $packlist->write() unless $nonono;
 373 print STDERR "  Installation complete\n";
 374
 375 exit 0;
 376
 377 ###############################################################################
 378
 379 sub yn {
 380     my($prompt) = @_;
 381     my($answer);
 382     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 383     print STDERR $prompt;
 384     chop($answer = <STDIN>);
 385     $answer = $default if $answer =~ m/^\s*$/;
 386     ($answer =~ m/^[yY]/);
 387 }
 388
 389 sub unlink {
 390     my(@names) = @_;
 391     my($cnt) = 0;
 392
 393     return scalar(@names) if $Is_VMS;
 394
 395     foreach my $name (@names) {
 396         next unless -e $name;
 397         chmod 0777, $name if ($Is_OS2 || $Is_W32);
 398         print STDERR "  unlink $name\n";
 399         ( CORE::unlink($name) and ++$cnt
 400           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 401     }
 402     return $cnt;
 403 }
 404
 405 sub safe_unlink {
 406     return if $nonono or $Is_VMS;
 407     my @names = @_;
 408     foreach my $name (@names) {
 409         next unless -e $name;
 410         chmod 0777, $name if ($Is_OS2 || $Is_W32);
 411         print STDERR "  unlink $name\n";
 412         next if CORE::unlink($name);
 413         warn "Couldn't unlink $name: $!\n";
 414         if ($! =~ /busy/i) {
 415             print STDERR "  mv $name $name.old\n";
 416             safe_rename($name, "$name.old")
 417                 or warn "Couldn't rename $name: $!\n";
 418         }
 419     }
 420 }
 421
 422 sub safe_rename {
 423     my($from,$to) = @_;
 424     if (-f $to and not unlink($to)) {
 425         my($i);
 426         for ($i = 1; $i < 50; $i++) {
 427             last if rename($to, "$to.$i");
 428         }
 429         warn("Cannot rename to `$to.$i': $!"), return 0
 430            if $i >= 50; # Give up!
 431     }
 432     link($from,$to) || return 0;
 433     unlink($from);
 434 }
 435
 436 sub link {
 437     my($from,$to) = @_;
 438     my($success) = 0;
 439
 440     print STDERR "  ln $from $to\n";
 441     eval {
 442         CORE::link($from, $to)
 443             ? $success++
 444             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 445               ? die "AFS"  # okay inside eval {}
 446               : warn "Couldn't link $from to $to: $!\n"
 447           unless $nonono;
 448         $packlist->{$to} = { from => $from, type => 'link' };
 449     };
 450     if ($@) {
 451         print STDERR "  creating new version of $to\n" if $Is_VMS and -e $to;
 452         File::Copy::copy($from, $to)
 453             ? $success++
 454             : warn "Couldn't copy $from to $to: $!\n"
 455           unless $nonono;
 456         $packlist->{$to} = { type => 'file' };
 457     }
 458     $success;
 459 }
 460
 461 sub chmod {
 462     my($mode,$name) = @_;
 463
 464     return if ($^O eq 'dos');
 465     printf STDERR "  chmod %o %s\n", $mode, $name;
 466     CORE::chmod($mode,$name)
 467         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 468       unless $nonono;
 469 }
 470
 471 sub copy {
 472     my($from,$to) = @_;
 473
 474     print STDERR "  cp $from $to\n";
 475     print STDERR "  creating new version of $to\n" if $Is_VMS and -e $to;
 476     File::Copy::copy($from, $to)
 477         || warn "Couldn't copy $from to $to: $!\n"
 478       unless $nonono;
 479     $packlist->{$to} = { type => 'file' };
 480 }
 481
 482 sub samepath {
 483     my($p1, $p2) = @_;
 484
 485     return (lc($p1) eq lc($p2)) if $Is_W32;
 486
 487     if ($p1 ne $p2) {
 488         my($dev1, $ino1, $dev2, $ino2);
 489         ($dev1, $ino1) = stat($p1);
 490         ($dev2, $ino2) = stat($p2);
 491         ($dev1 == $dev2 && $ino1 == $ino2);
 492     }
 493     else {
 494         1;
 495     }
 496 }
 497
 498 sub installlib {
 499     my $dir = $File::Find::dir;
 500     $dir =~ s#^\.(?![^/])/?##;
 501     local($depth) = $dir ? "lib/$dir" : "lib";
 502
 503     my $name = $_;
 504
 505     if ($name eq 'CVS' && -d $name) {
 506         $File::Find::prune = 1;
 507         return;
 508     }
 509
 510     # ignore patch backups and the .exists files.
 511     return if $name =~ m{\.orig$|~$|^\.exists};
 512
 513     $name = "$dir/$name" if $dir ne '';
 514
 515     my $installlib = $installprivlib;
 516     if ($dir =~ /^auto/ ||
 517           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 518           ($name =~ /^(.*)\.(?:h|lib)$/i && $Is_W32)
 519        ) {
 520         $installlib = $installarchlib;
 521         return unless $do_installarchlib;
 522     } else {
 523         return unless $do_installprivlib;
 524     }
 525
 526     if (-f $_) {
 527         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 528             $installlib = $installprivlib;
 529             #We're installing *.al and *.ix files into $installprivlib,
 530             #but we have to delete old *.al and *.ix files from the 5.000
 531             #distribution:
 532             #This might not work because $archname might have changed.
 533             unlink("$installarchlib/$name");
 534         }
 535         $packlist->{"$installlib/$name"} = { type => 'file' };
 536         if (compare($_, "$installlib/$name") || $nonono) {
 537             unlink("$installlib/$name");
 538             mkpath("$installlib/$dir", 1, 0777);
 539             # HP-UX (at least) needs to maintain execute permissions
 540             # on dynamically-loaded libraries.
 541             copy_if_diff($_, "$installlib/$name")
 542                 and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 543                            "$installlib/$name");
 544         }
 545     } elsif (-d $_) {
 546         mkpath("$installlib/$name", 1, 0777);
 547     }
 548 }
 549
 550 # Copy $from to $to, only if $from is different than $to.
 551 # Also preserve modification times for .a libraries.
 552 # On some systems, if you do
 553 #   ranlib libperl.a
 554 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 555 # and then try to link against the installed libperl.a, you might
 556 # get an error message to the effect that the symbol table is older
 557 # than the library.
 558 # Return true if copying occurred.
 559
 560 sub copy_if_diff {
 561     my($from,$to)=@_;
 562     return 1 if (($^O eq 'VMS') && (-d $from));
 563     -f $from || die "$0: $from not found";
 564     $packlist->{$to} = { type => 'file' };
 565     if (compare($from, $to) || $nonono) {
 566         safe_unlink($to);   # In case we don't have write permissions.
 567         if ($nonono) {
 568             $from = $depth . "/" . $from if $depth;
 569         }
 570         copy($from, $to);
 571         # Restore timestamps if it's a .a library or for OS/2.
 572         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 573             my ($atime, $mtime) = (stat $from)[8,9];
 574             utime $atime, $mtime, $to;
 575         }
 576         1;
 577     }
 578 }