installperl

   1 #!./perl
   2 BEGIN { @INC=('./lib', '../lib') }
   3 use File::Find;
   4
   5 $mainperldir = "/usr/bin";
   6
   7 while (@ARGV) {
   8     $nonono = 1 if $ARGV[0] eq '-n';
   9     $versiononly = 1 if $ARGV[0] eq '-v';
  10     shift;
  11 }
  12
  13 umask 022;
  14
  15 @scripts = ('cppstdin', 'c2ph', 'h2xs', 'pstruct', 'x2p/s2p', 'x2p/find2perl',
  16             'pod/pod2man', 'pod/pod2html', 'pod/pod2latex' );
  17 @manpages = (<pod/*.man>, 'x2p/a2p.man', 'x2p/s2p.man');
  18
  19 # Read in the config file.
  20
  21 open(CONFIG, "config.sh") || die "You haven't run Configure yet!\n";
  22 while (<CONFIG>) {
  23     if (s/^(\w+=)/\$$1/) {
  24         $accum =~ s/'undef'/undef/g;
  25         eval $accum;
  26         $accum = '';
  27     }
  28     $accum .= $_;
  29 }
  30 close CONFIG;
  31
  32 $ver = $];
  33 $release = substr($ver,0,3);
  34 $patchlevel = substr($ver,3,2);
  35 die "Patchlevel of perl ($patchlevel)",
  36     "and patchlevel of config.sh ($PATCHLEVEL) don't match\n"
  37         if $patchlevel != $PATCHLEVEL;
  38
  39 # Do some quick sanity checks.
  40
  41 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
  42
  43    $installbin          || die "No installbin directory in config.sh\n";
  44 -d $installbin          || die "$installbin is not a directory\n";
  45 -w $installbin          || die "$installbin is not writable by you\n"
  46         unless $installbin =~ m#^/afs/# || $nonono;
  47
  48 -x 'perl'               || die "perl isn't executable!\n";
  49 -x 'suidperl'           || die "suidperl isn't executable!\n" if $d_dosuid;
  50
  51 -x 't/TEST'             || warn "WARNING: You've never run 'make test'!!!",
  52         "  (Installing anyway.)\n";
  53
  54 if ($d_shrplib) {
  55     if (!<libperl*.$so*>) {
  56         warn "WARNING: Can't find libperl*.$so* to install into $shrpdir.",
  57             "  (Installing other things anyway.)\n";
  58     } else {
  59         &makedir($shrpdir);
  60         -w $shrpdir     || die "$shrpdir is not writable by you\n";
  61         &cmd("cp libperl*.$so* $shrpdir");
  62     }
  63 }
  64
  65 # First we install the version-numbered executables.
  66
  67 &unlink("$installbin/perl$ver");
  68 &cmd("cp perl $installbin/perl$ver");
  69
  70 &unlink("$installbin/sperl$ver");
  71 if ($d_dosuid) {
  72     &cmd("cp suidperl $installbin/sperl$ver");
  73     &chmod(04711, "$installbin/sperl$ver");
  74 }
  75
  76 exit 0 if $versiononly;
  77
  78 # Make links to ordinary names if installbin directory isn't current directory.
  79
  80 if (! &samepath($installbin, '.')) {
  81     &unlink("$installbin/perl", "$installbin/suidperl");
  82     &link("$installbin/perl$ver", "$installbin/perl");
  83     &link("$installbin/sperl$ver", "$installbin/suidperl") if $d_dosuid;
  84 }
  85
  86 if (! &samepath($installbin, 'x2p')) {
  87     &unlink("$installbin/a2p");
  88     &cmd("cp x2p/a2p $installbin/a2p");
  89     &chmod(0755, "$installbin/a2p");
  90 }
  91
  92 # Install scripts.
  93
  94 &makedir($installscript);
  95
  96 for (@scripts) {
  97     if (-f $_) {   # cppstdin might not exist on this system.
  98         &cmd("cp $_ $installscript");
  99         s#.*/##; &chmod(0755, "$installscript/$_");
 100     }
 101 }
 102
 103 # Install man pages.
 104
 105 if ($installmansrc ne '') {
 106     &makedir($installmansrc);
 107
 108     if (! &samepath($installmansrc, '.')) {
 109         for (@manpages) {
 110             ($new = $_) =~ s/man$/$manext/;
 111             $new =~ s#.*/##;
 112             print STDERR "  Installing $installmansrc/$new\n";
 113             next if $nonono;
 114             open(MI,$_) || warn "Can't open $_: $!\n";
 115             open(MO,">$installmansrc/$new") || warn "Can't install $installmansrc/$new: $!\n";
 116             print MO ".ds RP Release $release Patchlevel $patchlevel\n";
 117             while (<MI>) {
 118                 print MO;
 119             }
 120             close MI;
 121             close MO;
 122         }
 123     }
 124 }
 125
 126 # Install library files.
 127
 128 $do_installarchlib = $do_installprivlib = 0;
 129
 130 &makedir($installprivlib);
 131 &makedir($installarchlib);
 132 if (chdir "lib") {
 133     $do_installarchlib = ! &samepath($installarchlib, '.');
 134     $do_installprivlib = ! &samepath($installprivlib, '.');
 135
 136     if ($do_installarchlib || $do_installprivlib) {
 137         find(\&installlib, '.');
 138     }
 139     chdir ".." || die "Can't cd back to source directory: $!\n";
 140 }
 141 else {
 142     warn "Can't cd to lib to install lib files: $!\n";
 143 }
 144
 145 # Install header files and libraries.
 146 makedir("$installarchlib/CORE");
 147 foreach $file (<*.h libperl*.*>) {
 148     cp_if_diff($file,"$installarchlib/CORE/$file");
 149     if ($file =~ /\.a$/ && $osname =~ /^(next|sunos)$/) {
 150        # on NeXTs and Suns we have to rerun ranlib after copying libraries
 151            # (maybe on all platforms which have ranlib ?)
 152        &cmd("$ranlib $installarchlib/CORE/$file");
 153     }
 154 }
 155 # AIX needs perl.exp installed as well.
 156 cp_if_diff("perl.exp" ,"$installarchlib/CORE/perl.exp") if ($osname eq 'aix');
 157
 158 # If they have built sperl.o...
 159 cp_if_diff("sperl.o" ,"$installarchlib/CORE/sperl.o") if (-f 'sperl.o');
 160
 161
 162 # Offer to install perl in a "standard" location
 163
 164 $mainperl_is_instperl = 0;
 165
 166 if (-w $mainperldir && ! &samepath($mainperldir, $installbin) && !$nonono) {
 167     # First make sure $mainperldir/perl is not already the same as
 168     # the perl we just installed
 169     if (-x "$mainperldir/perl") {
 170         # Try to be clever about mainperl being a symbolic link
 171         # to binexp/perl if binexp and installbin are different.
 172         $mainperl_is_instperl =
 173             &samepath("$mainperldir/perl", "$installbin/perl") ||
 174              (($binexp ne $installbin) &&
 175               (-l "$mainperldir/perl") &&
 176               ((readlink "$mainperldir/perl") eq "$binexp/perl"));
 177     }
 178     if ((! $mainperl_is_instperl) &&
 179         (&yn("Many scripts expect perl to be installed as " .
 180              "$mainperldir/perl.\n" .
 181              "Do you wish to have $mainperldir/perl be the same as\n" .
 182              "$binexp/perl? [y] ")))
 183     {
 184         unlink("$mainperldir/perl");
 185         eval 'link("$installbin/perl", "$mainperldir/perl")' ||
 186         eval 'symlink("$binexp/perl", "$mainperldir/perl")' ||
 187         &cmd("cp $installbin/perl $mainperldir");
 188         $mainperl_is_instperl = 1;
 189     }
 190 }
 191
 192 # Check to make sure there aren't other perls around in installer's
 193 # path.  This is probably UNIX-specific.  Check all absolute directories
 194 # in the path except for where public executables are supposed to live.
 195 # Also skip $mainperl if the user opted to have it be a link to the
 196 # installed perl.
 197
 198 @path = split(/:/, $ENV{"PATH"});
 199 @otherperls = ();
 200 for (@path) {
 201     next unless m,^/,;
 202     next if ($_ eq $binexp);
 203     # Use &samepath here because some systems have other dirs linked
 204     # to $mainperldir (like SunOS)
 205     next if ($mainperl_is_instperl && &samepath($_, $mainperldir));
 206     push(@otherperls, "$_/perl") if (-x "$_/perl" && ! -d "$_/perl");
 207 }
 208 if (@otherperls) {
 209     print STDERR "\nWarning: perl appears in your path in the following " .
 210         "locations beyond where\nwe just installed it:\n";
 211     for (@otherperls) {
 212         print STDERR "    ", $_, "\n";
 213     }
 214     print STDERR "\n";
 215 }
 216
 217 print STDERR "  Installation complete\n";
 218
 219 exit 0;
 220
 221 ###############################################################################
 222
 223 sub yn {
 224     local($prompt) = @_;
 225     local($answer);
 226     local($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 227     print STDERR $prompt;
 228     chop($answer = <STDIN>);
 229     $answer = $default if $answer =~ m/^\s*$/;
 230     ($answer =~ m/^[yY]/);
 231 }
 232
 233 sub unlink {
 234     local(@names) = @_;
 235
 236     foreach $name (@names) {
 237         next unless -e $name;
 238         print STDERR "  unlink $name\n";
 239         unlink($name) || warn "Couldn't unlink $name: $!\n" unless $nonono;
 240     }
 241 }
 242
 243 sub cmd {
 244     local($cmd) = @_;
 245     print STDERR "  $cmd\n";
 246     unless ($nonono) {
 247         system $cmd;
 248         warn "Command failed!!!\n" if $?;
 249     }
 250 }
 251
 252 sub link {
 253     local($from,$to) = @_;
 254
 255     print STDERR "  ln $from $to\n";
 256     link($from,$to) || warn "Couldn't link $from to $to: $!\n" unless $nonono;
 257 }
 258
 259 sub chmod {
 260     local($mode,$name) = @_;
 261
 262     printf STDERR "  chmod %o %s\n", $mode, $name;
 263     chmod($mode,$name) || warn sprintf("Couldn't chmod %o %s: $!\n",$mode,$name)
 264         unless $nonono;
 265 }
 266
 267 sub makedir {
 268     local($dir) = @_;
 269     unless (-d $dir) {
 270         local($shortdir) = $dir;
 271
 272         $shortdir =~ s#(.*)/.*#$1#;
 273         &makedir($shortdir);
 274
 275         print STDERR "  mkdir $dir\n";
 276         mkdir($dir, 0777) || warn "Couldn't create $dir: $!\n" unless $nonono;
 277     }
 278 }
 279
 280 sub samepath {
 281     local($p1, $p2) = @_;
 282     local($dev1, $ino1, $dev2, $ino2);
 283
 284     if ($p1 ne $p2) {
 285         ($dev1, $ino1) = stat($p1);
 286         ($dev2, $ino2) = stat($p2);
 287         ($dev1 == $dev2 && $ino1 == $ino2);
 288     }
 289     else {
 290         1;
 291     }
 292 }
 293
 294 sub installlib {
 295     my $dir = $File::Find::dir;
 296     $dir =~ s#^\.(?![^/])/?##;
 297
 298     my $name = $_;
 299     $name = "$dir/$name" if $dir ne '';
 300
 301     my $installlib = $installprivlib;
 302     if ((substr($dir, 0, 4) eq 'auto') || ($name eq 'Config.pm')) {
 303         $installlib = $installarchlib;
 304         return unless $do_installarchlib;
 305     } else {
 306         return unless $do_installprivlib;
 307     }
 308
 309     if (-f $_) {
 310         if (/\.al$/ || /\.ix$/) {
 311             $installlib = $installprivlib;
 312             #We're installing *.al and *.ix files into $installprivlib,
 313             #but we have to delete old *.al and *.ix files from the 5.000
 314             #distribution:
 315             #This might not work because $archname might have changed.
 316             &unlink("$installarchlib/$name");
 317         }
 318         system "cmp", "-s", $_, "$installlib/$name";
 319         if ($?) {
 320             &unlink("$installlib/$name");
 321             &makedir("$installlib/$dir");
 322             &cmd("cp $_ $installlib/$dir");
 323             if (/\.a$/ && $osname eq 'next') {
 324                 #on NeXTs we have to rerun ranlib after copying libraries
 325                 &cmd("$ranlib $installlib/$dir/$_");
 326             }
 327             # HP-UX (at least) needs to maintain execute permissions
 328             # on dynamically-loaded libraries.
 329             if ($name =~ /\.(so|$dlext)$/o) {
 330                 &chmod(0555, "$installlib/$name");
 331             }
 332             else {
 333                 &chmod(0444, "$installlib/$name");
 334             }
 335         }
 336     } elsif (-d $_) {
 337         &makedir("$installlib/$name");
 338     }
 339 }
 340
 341 sub cp_if_diff {
 342     my($from,$to)=@_;
 343     -f $from || die "$0: $from not found";
 344     system "cmp", "-s", $from, $to;
 345     if ($?) {
 346         unlink($to);   # In case we don't have write permissions.
 347         cmd("cp $from $to");
 348     }
 349 }