installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $nonono, $dostrip,
  12     $versiononly, $silent, $verbose, $otherperls);
  13 use vars qw /$depth/;
  14
  15 BEGIN {
  16     $Is_VMS = $^O eq 'VMS';
  17     $Is_W32 = $^O eq 'MSWin32';
  18     $Is_OS2 = $^O eq 'os2';
  19     $Is_Cygwin = $^O eq 'cygwin';
  20     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  21 }
  22
  23 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  24
  25 use File::Find;
  26 use File::Compare;
  27 use File::Copy ();
  28 use File::Path ();
  29 use ExtUtils::Packlist;
  30 use Config;
  31 use subs qw(unlink link chmod);
  32
  33 # override the ones in the rest of the script
  34 sub mkpath {
  35     File::Path::mkpath(@_) unless $nonono;
  36 }
  37
  38 my $mainperldir = "/usr/bin";
  39 my $exe_ext = $Config{exe_ext};
  40
  41 # Allow ``make install PERLNAME=something_besides_perl'':
  42 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  43
  44 # This is the base used for versioned names, like "perl5.6.0".
  45 # It's separate because a common use of $PERLNAME is to install
  46 # perl as "perl5", if that's used as base for versioned files you
  47 # get "perl55.6.0".
  48 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  49                     ? $ENV{PERLNAME_VERBASE}
  50                     : $perl;
  51
  52 $otherperls = 1;
  53 while (@ARGV) {
  54     $nonono = 1 if $ARGV[0] eq '-n';
  55     $dostrip = 1 if $ARGV[0] eq '-s';
  56     $versiononly = 1 if $ARGV[0] eq '-v';
  57     $silent = 1 if $ARGV[0] eq '-S';
  58     $otherperls = 0 if $ARGV[0] eq '-o';
  59     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  60     shift;
  61 }
  62
  63 my @scripts = qw(utils/c2ph utils/h2ph utils/h2xs utils/perlbug utils/perldoc
  64                 utils/pl2pm utils/splain utils/perlcc utils/dprofpp
  65                 x2p/s2p x2p/find2perl
  66                 pod/pod2man pod/pod2html pod/pod2latex pod/pod2text
  67                 pod/pod2usage pod/podchecker pod/podselect);
  68
  69 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
  70
  71 my @pods = (<pod/*.pod>);
  72
  73 # Specify here any .pm files that are actually architecture-dependent.
  74 # (Those included with XS extensions under ext/ are automatically
  75 # added later.)
  76 # Now that the default privlib has the full perl version number included,
  77 # we no longer have to play the trick of sticking version-specific .pm
  78 # files under the archlib directory.
  79 my %archpms = (
  80     Config => 1,
  81 );
  82
  83 if ($^O eq 'dos') {
  84     push(@scripts,'djgpp/fixpmain');
  85     $archpms{config} = $archpms{filehand} = 1;
  86 }
  87
  88 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
  89 {
  90         push(@scripts, map("$_.exe", @scripts));
  91 }
  92
  93 find(sub {
  94         if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
  95             my($path, $modname) = ($1,$2);
  96
  97             # strip trailing component first
  98             $path =~ s{/[^/]*$}{};
  99
 100             # strip optional "/lib";
 101             $path =~ s{/lib\b}{};
 102
 103             # strip any leading /
 104             $path =~ s{^/}{};
 105
 106             # reconstitute canonical module name
 107             $modname = "$path/$modname" if length $path;
 108
 109             # remember it
 110             $archpms{$modname} = 1;
 111         }
 112     }, 'ext');
 113
 114 # print "[$_]\n" for sort keys %archpms;
 115
 116 my $ver = $Config{version};
 117 my $release = substr($],0,3);   # Not used presently.
 118 my $patchlevel = substr($],3,2);
 119 die "Patchlevel of perl ($patchlevel)",
 120     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 121         if $patchlevel != $Config{'PERL_VERSION'};
 122
 123 # Fetch some frequently-used items from %Config
 124 my $installbin = $Config{installbin};
 125 my $installscript = $Config{installscript};
 126 my $installprivlib = $Config{installprivlib};
 127 my $installarchlib = $Config{installarchlib};
 128 my $installsitelib = $Config{installsitelib};
 129 my $installsitearch = $Config{installsitearch};
 130 my $installman1dir = $Config{installman1dir};
 131 my $man1ext = $Config{man1ext};
 132 my $libperl = $Config{libperl};
 133 # Shared library and dynamic loading suffixes.
 134 my $so = $Config{so};
 135 my $dlext = $Config{dlext};
 136 my $dlsrc = $Config{dlsrc};
 137
 138 my $d_dosuid = $Config{d_dosuid};
 139 my $binexp = $Config{binexp};
 140
 141 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 142     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 143               \$installarchlib, \$installsitelib, \$installsitearch,
 144               \$installman1dir ) {
 145       $$_ = unixify($$_);  $$_ =~ s:/$::;
 146     }
 147 }
 148
 149 # Do some quick sanity checks.
 150
 151 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 152
 153    $installbin          || die "No installbin directory in config.sh\n";
 154 -d $installbin          || mkpath($installbin, $verbose, 0777);
 155 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 156 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 157         unless $installbin =~ m#^/afs/# || $nonono;
 158
 159 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 160 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 161
 162 -f 't/rantests'         || $Is_W32
 163                         || warn "WARNING: You've never run 'make test'!!!",
 164                                 "  (Installing anyway.)\n";
 165
 166 if ($Is_W32 or $Is_Cygwin) {
 167   my $perldll;
 168
 169   if ($Is_Cygwin) {
 170     $perldll = $libperl;
 171     $perldll =~ s/(\..*)?$/.$dlext/;
 172     if ($Config{useshrplib} eq 'true') {
 173       # install ld2 and perlld as well
 174       foreach ('ld2', 'perlld') {
 175         safe_unlink("$installbin/$_");
 176         copy("$_", "$installbin/$_");
 177         chmod(0755, "$installbin/$_");
 178       };
 179     };
 180   } else {
 181     $perldll = 'perl56.' . $dlext;
 182   }
 183
 184   if ($dlsrc ne "dl_none.xs") {
 185     -f $perldll || die "No perl DLL built\n";
 186   }
 187   # Install the DLL
 188
 189   safe_unlink("$installbin/$perldll");
 190   copy("$perldll", "$installbin/$perldll");
 191   chmod(0755, "$installbin/$perldll");
 192
 193 } # if ($Is_W32 or $Is_Cygwin)
 194
 195 # This will be used to store the packlist
 196 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 197
 198 # First we install the version-numbered executables.
 199
 200 if ($Is_VMS) {
 201     safe_unlink("$installbin/$perl$exe_ext");
 202     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 203     chmod(0755, "$installbin/$perl$exe_ext");
 204     safe_unlink("$installbin/${perl}shr$exe_ext");
 205     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 206     chmod(0755, "$installbin/${perl}shr$exe_ext");
 207 }
 208 elsif ($^O eq 'mpeix') {
 209     # MPE lacks hard links and requires that executables with special
 210     # capabilities reside in the MPE namespace.
 211     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 212     # Install the primary executable into the MPE namespace as perlpath.
 213     copy("perl$exe_ext", $Config{perlpath});
 214     chmod(0755, $Config{perlpath});
 215     # Create a backup copy with the version number.
 216     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 217 }
 218 elsif ($^O ne 'dos') {
 219     safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 220     copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 221     strip("$installbin/$perl_verbase$ver$exe_ext");
 222     chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 223 }
 224 else {
 225     safe_unlink("$installbin/$perl.exe");
 226     copy("perl.exe", "$installbin/$perl.exe");
 227 }
 228
 229 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 230 if ($d_dosuid) {
 231     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 232     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 233 }
 234
 235 # Install library files.
 236
 237 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 238
 239 mkpath($installprivlib, $verbose, 0777);
 240 mkpath($installarchlib, $verbose, 0777);
 241 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 242 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 243
 244 if (chdir "lib") {
 245     $do_installarchlib = ! samepath($installarchlib, '.');
 246     $do_installprivlib = ! samepath($installprivlib, '.');
 247     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 248
 249     if ($do_installarchlib || $do_installprivlib) {
 250         find(\&installlib, '.');
 251     }
 252     chdir ".." || die "Can't cd back to source directory: $!\n";
 253 }
 254 else {
 255     warn "Can't cd to lib to install lib files: $!\n";
 256 }
 257
 258 # Install header files and libraries.
 259 mkpath("$installarchlib/CORE", $verbose, 0777);
 260 my @corefiles;
 261 if ($Is_VMS) {  # We did core file selection during build
 262     my $coredir = "lib/$Config{archname}/$ver/CORE";
 263     $coredir =~ tr/./_/;
 264     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 265 }
 266 else {
 267     # [als] hard-coded 'libperl' name... not good!
 268     @corefiles = <*.h libperl*.*>;
 269
 270     # AIX needs perl.exp installed as well.
 271     push(@corefiles,'perl.exp') if $^O eq 'aix';
 272     if ($^O eq 'mpeix') {
 273         # MPE needs mpeixish.h installed as well.
 274         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 275         push(@corefiles,'mpeix/mpeixish.h');
 276     }
 277     # If they have built sperl.o...
 278     push(@corefiles,'sperl.o') if -f 'sperl.o';
 279 }
 280 foreach my $file (@corefiles) {
 281     # HP-UX (at least) needs to maintain execute permissions
 282     # on dynamically-loadable libraries. So we do it for all.
 283     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 284         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 285             chmod(0555, "$installarchlib/CORE/$file");
 286             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 287         } else {
 288             chmod(0444, "$installarchlib/CORE/$file");
 289         }
 290     }
 291 }
 292
 293 # Install main perl executables
 294 # Make links to ordinary names if installbin directory isn't current directory.
 295
 296 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 297     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 298     if ($^O eq 'mpeix') {
 299         # MPE doesn't support hard links, so use a symlink.
 300         # We don't want another cloned copy.
 301         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 302     } else {
 303         link("$installbin/$perl_verbase$ver$exe_ext",
 304                 "$installbin/$perl$exe_ext");
 305     }
 306     link("$installbin/s$perl_verbase$ver$exe_ext",
 307             "$installbin/suid$perl$exe_ext")
 308       if $d_dosuid;
 309 }
 310
 311 # Offer to install perl in a "standard" location
 312
 313 my $mainperl_is_instperl = 0;
 314
 315 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 316     !$versiononly && !$nonono && !$Is_W32 && !$Is_VMS && -t STDIN && -t STDERR
 317         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 318     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 319     my($instperl)       = "$installbin/$perl$exe_ext";
 320     my($expinstperl)    = "$binexp/$perl$exe_ext";
 321
 322     # First make sure $usrbinperl is not already the same as the perl we
 323     # just installed.
 324     if (-x $usrbinperl) {
 325         # Try to be clever about mainperl being a symbolic link
 326         # to binexp/perl if binexp and installbin are different.
 327         $mainperl_is_instperl =
 328             samepath($usrbinperl, $instperl) ||
 329             samepath($usrbinperl, $expinstperl) ||
 330              (($binexp ne $installbin) &&
 331               (-l $usrbinperl) &&
 332               ((readlink $usrbinperl) eq $expinstperl));
 333     }
 334     if ((! $mainperl_is_instperl) &&
 335         (yn("Many scripts expect perl to be installed as $usrbinperl.\n" .
 336              "Do you wish to have $usrbinperl be the same as\n" .
 337              "$expinstperl? [y] ")))
 338     {
 339         unlink($usrbinperl);
 340         ( $Config{'d_link'} eq 'define' &&
 341           eval { CORE::link $instperl, $usrbinperl } )  ||
 342         eval { symlink $expinstperl, $usrbinperl }      ||
 343         copy($instperl, $usrbinperl);
 344
 345         $mainperl_is_instperl = 1;
 346     }
 347 }
 348
 349 # Make links to ordinary names if installbin directory isn't current directory.
 350
 351 if (!$versiononly && ! samepath($installbin, 'x2p')) {
 352     safe_unlink("$installbin/a2p$exe_ext");
 353     copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 354     chmod(0755, "$installbin/a2p$exe_ext");
 355 }
 356
 357 # cppstdin is just a script, but it is architecture-dependent, so
 358 # it can't safely be shared.  Place it in $installbin.
 359 # Note that Configure doesn't build cppstin if it isn't needed, so
 360 # we skip this if cppstdin doesn't exist.
 361 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 362     safe_unlink("$installbin/cppstdin");
 363     copy("cppstdin", "$installbin/cppstdin");
 364     chmod(0755, "$installbin/cppstdin");
 365 }
 366
 367 if ($Config{installscripts} eq 'define') {
 368     # Install scripts.
 369
 370     mkpath($installscript, $verbose, 0777);
 371
 372     if (! $versiononly) {
 373         for (@scripts) {
 374             (my $base = $_) =~ s#.*/##;
 375             copy($_, "$installscript/$base");
 376             chmod(0755, "$installscript/$base");
 377         }
 378     }
 379
 380     # pstruct should be a link to c2ph
 381
 382     if (! $versiononly) {
 383         safe_unlink("$installscript/pstruct$scr_ext");
 384         if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 385             copy("$installscript/c2ph$scr_ext",
 386                  "$installscript/pstruct$scr_ext");
 387         } else {
 388             link("$installscript/c2ph$scr_ext",
 389                  "$installscript/pstruct$scr_ext");
 390         }
 391     }
 392 }
 393
 394 # Install pod pages.  Where? I guess in $installprivlib/pod
 395 # ($installprivlib/pods for cygwin).
 396
 397 my $pod = $Is_Cygwin ? 'pods' : 'pod';
 398 unless ( $versiononly && !($installprivlib =~ m/\Q$ver/)) {
 399     mkpath("${installprivlib}/$pod", $verbose, 0777);
 400
 401     # If Perl 5.003's perldiag.pod is there, rename it.
 402     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 403         read POD, $_, 4000;
 404         close POD;
 405         # Some of Perl 5.003's diagnostic messages ended with periods.
 406         if (/^=.*\.$/m) {
 407             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 408                                "${installprivlib}/$pod/perldiag-5.003.pod");
 409             print "  rename $from $to";
 410             rename($from, $to)
 411                 or warn "Couldn't rename $from to $to: $!\n"
 412                 unless $nonono;
 413         }
 414     }
 415
 416     for (@pods) {
 417         # $_ is a name like  pod/perl.pod
 418         (my $base = $_) =~ s#.*/##;
 419         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 420     }
 421
 422 }
 423
 424 # Check to make sure there aren't other perls around in installer's
 425 # path.  This is probably UNIX-specific.  Check all absolute directories
 426 # in the path except for where public executables are supposed to live.
 427 # Also skip $mainperl if the user opted to have it be a link to the
 428 # installed perl.
 429
 430 if (!$versiononly && $otherperls) {
 431     my ($path, @path);
 432     my $dirsep = ($Is_OS2 || $Is_W32) ? ';' : ':' ;
 433     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 434     @path = split(/$dirsep/, $path);
 435     if ($Is_VMS) {
 436         my $i = 0;
 437         while (exists $ENV{'DCL$PATH' . $i}) {
 438             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 439             push(@path,$dir);
 440         }
 441     }
 442     my @otherperls;
 443     my %otherperls;
 444     for (@path) {
 445         next unless m,^/,;
 446         # Use &samepath here because some systems have other dirs linked
 447         # to $mainperldir (like SunOS)
 448         next if samepath($_, $binexp);
 449         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 450         my $otherperl = "$_/$perl$exe_ext";
 451         next if $otherperls{$otherperl}++;
 452         push(@otherperls, $otherperl)
 453             if (-x $otherperl && ! -d $otherperl);
 454     }
 455     if (@otherperls) {
 456         warn "\nWarning: $perl appears in your path in the following " .
 457             "locations beyond where\nwe just installed it:\n";
 458         for (@otherperls) {
 459             warn "    ", $_, "\n";
 460         }
 461         warn "\n";
 462     }
 463
 464 }
 465
 466 $packlist->write() unless $nonono;
 467 print "  Installation complete\n" if $verbose;
 468
 469 exit 0;
 470
 471 ###############################################################################
 472
 473 sub yn {
 474     my($prompt) = @_;
 475     my($answer);
 476     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 477     warn $prompt;
 478     chop($answer = <STDIN>);
 479     $answer = $default if $answer =~ m/^\s*$/;
 480     ($answer =~ m/^[yY]/);
 481 }
 482
 483 sub unlink {
 484     my(@names) = @_;
 485     my($cnt) = 0;
 486
 487     return scalar(@names) if $Is_VMS;
 488
 489     foreach my $name (@names) {
 490         next unless -e $name;
 491         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin);
 492         print "  unlink $name\n" if $verbose;
 493         ( CORE::unlink($name) and ++$cnt
 494           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 495     }
 496     return $cnt;
 497 }
 498
 499 sub safe_unlink {
 500     return if $nonono or $Is_VMS;
 501     my @names = @_;
 502     foreach my $name (@names) {
 503         next unless -e $name;
 504         chmod 0777, $name if ($Is_OS2 || $Is_W32);
 505         print "  unlink $name\n" if $verbose;
 506         next if CORE::unlink($name);
 507         warn "Couldn't unlink $name: $!\n";
 508         if ($! =~ /busy/i) {
 509             print "  mv $name $name.old\n" if $verbose;
 510             safe_rename($name, "$name.old")
 511                 or warn "Couldn't rename $name: $!\n";
 512         }
 513     }
 514 }
 515
 516 sub safe_rename {
 517     my($from,$to) = @_;
 518     if (-f $to and not unlink($to)) {
 519         my($i);
 520         for ($i = 1; $i < 50; $i++) {
 521             last if rename($to, "$to.$i");
 522         }
 523         warn("Cannot rename to `$to.$i': $!"), return 0
 524            if $i >= 50; # Give up!
 525     }
 526     link($from,$to) || return 0;
 527     unlink($from);
 528 }
 529
 530 sub link {
 531     my($from,$to) = @_;
 532     my($success) = 0;
 533
 534     print $verbose ? "  ln $from $to\n" : "  $to\n" unless $silent;
 535     eval {
 536         CORE::link($from, $to)
 537             ? $success++
 538             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 539               ? die "AFS"  # okay inside eval {}
 540               : die "Couldn't link $from to $to: $!\n"
 541           unless $nonono;
 542         $packlist->{$to} = { from => $from, type => 'link' };
 543     };
 544     if ($@) {
 545         warn $@;
 546         print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 547         print "  creating new version of $to\n"
 548                  if $Is_VMS and -e $to and !$silent;
 549         File::Copy::copy($from, $to)
 550             ? $success++
 551             : warn "Couldn't copy $from to $to: $!\n"
 552           unless $nonono;
 553         $packlist->{$to} = { type => 'file' };
 554     }
 555     $success;
 556 }
 557
 558 sub chmod {
 559     my($mode,$name) = @_;
 560
 561     return if ($^O eq 'dos');
 562     printf "  chmod %o %s\n", $mode, $name if $verbose;
 563     CORE::chmod($mode,$name)
 564         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 565       unless $nonono;
 566 }
 567
 568 sub copy {
 569     my($from,$to) = @_;
 570
 571     print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 572     print "  creating new version of $to\n" if $Is_VMS and -e $to and !$silent;
 573     File::Copy::copy($from, $to)
 574         || warn "Couldn't copy $from to $to: $!\n"
 575       unless $nonono;
 576     $packlist->{$to} = { type => 'file' };
 577 }
 578
 579 sub samepath {
 580     my($p1, $p2) = @_;
 581
 582     return (lc($p1) eq lc($p2)) if $Is_W32;
 583
 584     if ($p1 ne $p2) {
 585         my($dev1, $ino1, $dev2, $ino2);
 586         ($dev1, $ino1) = stat($p1);
 587         ($dev2, $ino2) = stat($p2);
 588         ($dev1 == $dev2 && $ino1 == $ino2);
 589     }
 590     else {
 591         1;
 592     }
 593 }
 594
 595 sub installlib {
 596     my $dir = $File::Find::dir;
 597     $dir =~ s#^\.(?![^/])/?##;
 598     local($depth) = $dir ? "lib/$dir" : "lib";
 599
 600     my $name = $_;
 601
 602     # Ignore RCS and CVS directories.
 603     if (($name eq 'CVS' or $name eq 'RCS') and -d $name) {
 604         $File::Find::prune = 1;
 605         return;
 606     }
 607
 608     # ignore patch backups, RCS files, emacs backup & temp files and the
 609     # .exists files.
 610     return if $name =~ m{\.orig$|~$|^#.+#$|,v$|^\.exists};
 611
 612     $name = "$dir/$name" if $dir ne '';
 613
 614     my $installlib = $installprivlib;
 615     if ($dir =~ /^auto/ ||
 616           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 617           ($name =~ /^(.*)\.(?:h|lib)$/i && $Is_W32)
 618        ) {
 619         $installlib = $installarchlib;
 620         return unless $do_installarchlib;
 621     } else {
 622         return unless $do_installprivlib;
 623     }
 624
 625     if (-f $_) {
 626         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 627             $installlib = $installprivlib;
 628             #We're installing *.al and *.ix files into $installprivlib,
 629             #but we have to delete old *.al and *.ix files from the 5.000
 630             #distribution:
 631             #This might not work because $archname might have changed.
 632             unlink("$installarchlib/$name");
 633         }
 634         $packlist->{"$installlib/$name"} = { type => 'file' };
 635         if (compare($_, "$installlib/$name") || $nonono) {
 636             unlink("$installlib/$name");
 637             mkpath("$installlib/$dir", $verbose, 0777);
 638             # HP-UX (at least) needs to maintain execute permissions
 639             # on dynamically-loaded libraries.
 640             copy_if_diff($_, "$installlib/$name")
 641                 and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 642                            "$installlib/$name");
 643         }
 644     }
 645 }
 646
 647 # Copy $from to $to, only if $from is different than $to.
 648 # Also preserve modification times for .a libraries.
 649 # On some systems, if you do
 650 #   ranlib libperl.a
 651 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 652 # and then try to link against the installed libperl.a, you might
 653 # get an error message to the effect that the symbol table is older
 654 # than the library.
 655 # Return true if copying occurred.
 656
 657 sub copy_if_diff {
 658     my($from,$to)=@_;
 659     return 1 if (($^O eq 'VMS') && (-d $from));
 660     -f $from || warn "$0: $from not found";
 661     $packlist->{$to} = { type => 'file' };
 662     if (compare($from, $to) || $nonono) {
 663         safe_unlink($to);   # In case we don't have write permissions.
 664         if ($nonono) {
 665             $from = $depth . "/" . $from if $depth;
 666         }
 667         copy($from, $to);
 668         # Restore timestamps if it's a .a library or for OS/2.
 669         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 670             my ($atime, $mtime) = (stat $from)[8,9];
 671             utime $atime, $mtime, $to;
 672         }
 673         1;
 674     }
 675 }
 676
 677 sub strip
 678 {
 679     my(@args) = @_;
 680
 681     return unless $dostrip;
 682
 683     my @opts;
 684     while (@args && $args[0] =~ /^(-\w+)$/) {
 685         push @opts, shift @args;
 686     }
 687
 688     foreach my $file (@args) {
 689         if (-f $file) {
 690             print "  strip $file\n" if $verbose;
 691             system("strip", @opts, $file);
 692         } else {
 693             print "# file '$file' skipped\n" if $verbose;
 694         }
 695     }
 696 }
 697