installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose,
  13     $otherperls, $archname,$Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41         $Is_W32 = 0;
  42         $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63
  64 $otherperls = 1;
  65 while (@ARGV) {
  66     $nonono = 1 if $ARGV[0] eq '-n';
  67     $dostrip = 1 if $ARGV[0] eq '-s';
  68     $versiononly = 1 if $ARGV[0] eq '-v';
  69     $versiononly = 0 if $ARGV[0] eq '+v';
  70     $silent = 1 if $ARGV[0] eq '-S';
  71     $otherperls = 0 if $ARGV[0] eq '-o';
  72     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  73     $archname = 1 if $ARGV[0] eq '-A';
  74         $nwinstall = 1 if $ARGV[0] eq '-netware';
  75     $nopods = 1 if $ARGV[0] eq '-p';
  76     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  77       print <<"EOT";
  78 Usage $0: [switches]
  79   -n        Don't actually run any commands; just print them.
  80   -s        Run strip on installed binaries.
  81   -v        Only install perl as a binary with the version number in the name.
  82             (Override whatever config.sh says)
  83   +v        Install perl as "perl" and as a binary with the version number in
  84             the name.  (Override whatever config.sh says)
  85   -S        Silent mode.
  86   -o        Skip checking for other copies of perl in your PATH.
  87   -V        Verbose mode.
  88   -A        Also install perl with the architecture's name in the perl binary's
  89             name.
  90   -p        Don't install the pod files. [This will break use diagnostics;]
  91   -netware  Install correctly on a Netware server.
  92 EOT
  93       exit;
  94     }
  95     shift;
  96 }
  97
  98 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
  99 my (@scripts, @tolink);
 100 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 101 while (<SCRIPTS>) {
 102     next if /^#/;
 103     next if /#\s*pod\s*=/; # Binary programs need separate treatment
 104     chomp;
 105     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 106         push @scripts, $1;
 107         push @tolink, [$1, $2];
 108     } else {
 109         push @scripts, $_;
 110     }
 111 }
 112 close SCRIPTS;
 113
 114 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 115
 116 my @pods = $nopods ? () : (<pod/*.pod>);
 117
 118 # Specify here any .pm files that are actually architecture-dependent.
 119 # (Those included with XS extensions under ext/ are automatically
 120 # added later.)
 121 # Now that the default privlib has the full perl version number included,
 122 # we no longer have to play the trick of sticking version-specific .pm
 123 # files under the archlib directory.
 124 my %archpms = (
 125     Config => 1,
 126     lib => 1,
 127     Cwd => 1,
 128 );
 129
 130 if ($^O eq 'dos') {
 131     push(@scripts,'djgpp/fixpmain');
 132     $archpms{config} = $archpms{filehand} = 1;
 133 }
 134
 135 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
 136 {
 137         push(@scripts, map("$_.exe", @scripts));
 138 }
 139
 140 find(sub {
 141         if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 142             my($path, $modname) = ($1,$2);
 143
 144             # strip trailing component first
 145             $path =~ s{/[^/]*$}{};
 146
 147             # strip optional "/lib";
 148             $path =~ s{/lib\b}{};
 149
 150             # strip any leading /
 151             $path =~ s{^/}{};
 152
 153             # reconstitute canonical module name
 154             $modname = "$path/$modname" if length $path;
 155
 156             # remember it
 157             $archpms{$modname} = 1;
 158         }
 159     }, 'ext');
 160
 161 # print "[$_]\n" for sort keys %archpms;
 162
 163 my $ver = $Config{version};
 164 my $release = substr($],0,3);   # Not used currently.
 165 my $patchlevel = substr($],3,2);
 166 die "Patchlevel of perl ($patchlevel)",
 167     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 168         if $patchlevel != $Config{'PERL_VERSION'};
 169
 170 # Fetch some frequently-used items from %Config
 171 my $installbin = $Config{installbin};
 172 my $installscript = $Config{installscript};
 173 my $installprivlib = $Config{installprivlib};
 174 my $installarchlib = $Config{installarchlib};
 175 my $installsitelib = $Config{installsitelib};
 176 my $installsitearch = $Config{installsitearch};
 177 my $installman1dir = $Config{installman1dir};
 178 my $man1ext = $Config{man1ext};
 179 my $libperl = $Config{libperl};
 180 # Shared library and dynamic loading suffixes.
 181 my $so = $Config{so};
 182 my $dlext = $Config{dlext};
 183 my $dlsrc = $Config{dlsrc};
 184 if ($^O eq 'os390') {
 185     my $pwd;
 186     chomp($pwd=`pwd`);
 187     my $archlibexp = $Config{archlibexp};
 188     my $usedl = $Config{usedl};
 189     if ($usedl eq 'define') {
 190         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 191     }
 192 }
 193
 194 if ($nwinstall) {
 195         # This is required only if we are installing on a NetWare server
 196         $installscript = $Config{installnwscripts};
 197         $installprivlib = $Config{installnwlib};
 198         $installarchlib = $Config{installnwlib};
 199         $installsitelib = $Config{installnwlib};
 200 }
 201
 202 my $d_dosuid = $Config{d_dosuid};
 203 my $binexp = $Config{binexp};
 204
 205 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 206     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 207               \$installarchlib, \$installsitelib, \$installsitearch,
 208               \$installman1dir ) {
 209       $$_ = unixify($$_);  $$_ =~ s:/$::;
 210     }
 211 }
 212
 213 # Do some quick sanity checks.
 214
 215 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 216
 217    $installbin          || die "No installbin directory in config.sh\n";
 218 -d $installbin          || mkpath($installbin, $verbose, 0777);
 219 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 220 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 221         unless $installbin =~ m#^/afs/# || $nonono;
 222
 223 if (!$Is_NetWare) {
 224 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 225 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 226
 227 -f 't/rantests'         || $Is_W32
 228                         || warn "WARNING: You've never run 'make test' or",
 229                                 " some tests failed! (Installing anyway.)\n";
 230 } #if (!$Is_NetWare)
 231
 232 if (($Is_W32 and ! $Is_NetWare)  or $Is_Cygwin) {
 233   my $perldll;
 234
 235   if ($Is_Cygwin) {
 236     $perldll = $libperl;
 237     my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 238     $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 239     $perldll =~ s/^lib/cyg/;
 240     if ($Config{useshrplib} eq 'true') {
 241       # install ld2 and perlld as well
 242       foreach ('ld2', 'perlld') {
 243         safe_unlink("$installbin/$_");
 244         copy("$_", "$installbin/$_");
 245         chmod(0755, "$installbin/$_");
 246       };
 247       {
 248                 open (LD2, ">$installbin/ld2");
 249                 print LD2 "#!/bin/sh\n#\n# ld wrapper, passes all args to perlld;\n#\n"
 250                           . "for trythis in $installbin/perl\ndo\n  if [ -x \$trythis ]\n"
 251                           . "  then\n    \$trythis $installbin/perlld \"\$\@\"\n"
 252                           . "    exit \$?\n  fi\ndone\n# hard luck!\necho i see no perl"
 253                           . " executable around there\necho perl is required to build "
 254                           . "dynamic libraries\necho look if the path to perl in /bin/ld2"
 255                           . " is correct\nexit 1\n";
 256                 close LD2;
 257       };
 258       chmod(0755, "$installbin/ld2");
 259     };
 260   } else {
 261     $perldll = 'perl58.' . $dlext;
 262   }
 263
 264   if ($dlsrc ne "dl_none.xs") {
 265     -f $perldll || die "No perl DLL built\n";
 266   }
 267   # Install the DLL
 268
 269   safe_unlink("$installbin/$perldll");
 270   copy("$perldll", "$installbin/$perldll");
 271   chmod(0755, "$installbin/$perldll");
 272
 273 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 274
 275 # This will be used to store the packlist
 276 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 277
 278 # First we install the version-numbered executables.
 279
 280 if ($Is_VMS) {
 281     safe_unlink("$installbin/$perl$exe_ext");
 282     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 283     chmod(0755, "$installbin/$perl$exe_ext");
 284     safe_unlink("$installbin/${perl}shr$exe_ext");
 285     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 286     chmod(0755, "$installbin/${perl}shr$exe_ext");
 287 }
 288 elsif ($^O eq 'mpeix') {
 289     # MPE lacks hard links and requires that executables with special
 290     # capabilities reside in the MPE namespace.
 291     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 292     # Install the primary executable into the MPE namespace as perlpath.
 293     copy("perl$exe_ext", $Config{perlpath});
 294     chmod(0755, $Config{perlpath});
 295     # Create a backup copy with the version number.
 296     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 297 }
 298 elsif ($^O ne 'dos') {
 299         if (!$Is_NetWare) {
 300                 safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 301                 copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 302                 strip("$installbin/$perl_verbase$ver$exe_ext");
 303                 chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 304         }
 305         else {
 306                 # If installing onto a NetWare server
 307                 if ($nwinstall) {
 308                         # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 309                         mkpath($Config{installnwsystem}, 1, 0777);
 310                         copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 311                         copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 312                         copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 313                         copy("x2p\\a2p.nlm", $Config{installnwsystem});
 314                         chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 315                         mkpath($Config{installnwlcgi}, 1, 0777);
 316                         copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 317                 }
 318         } #if (!$Is_NetWare)
 319 }
 320 else {
 321     safe_unlink("$installbin/$perl.exe");
 322     copy("perl.exe", "$installbin/$perl.exe");
 323 }
 324
 325 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 326 if ($d_dosuid) {
 327     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 328     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 329 }
 330
 331 # Install library files.
 332
 333 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 334
 335 mkpath($installprivlib, $verbose, 0777);
 336 mkpath($installarchlib, $verbose, 0777);
 337 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 338 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 339
 340 if (chdir "lib") {
 341     $do_installarchlib = ! samepath($installarchlib, '.');
 342     $do_installprivlib = ! samepath($installprivlib, '.');
 343     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 344
 345     if ($do_installarchlib || $do_installprivlib) {
 346         find(\&installlib, '.');
 347     }
 348     chdir ".." || die "Can't cd back to source directory: $!\n";
 349 }
 350 else {
 351     warn "Can't cd to lib to install lib files: $!\n";
 352 }
 353
 354 # Install header files and libraries.
 355 mkpath("$installarchlib/CORE", $verbose, 0777);
 356 my @corefiles;
 357 if ($Is_VMS) {  # We did core file selection during build
 358     my $coredir = "lib/$Config{archname}/$ver/CORE";
 359     $coredir =~ tr/./_/;
 360     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 361 }
 362 else {
 363     # [als] hard-coded 'libperl' name... not good!
 364     @corefiles = <*.h libperl*.*>;
 365
 366     # AIX needs perl.exp installed as well.
 367     push(@corefiles,'perl.exp') if $^O eq 'aix';
 368     if ($^O eq 'mpeix') {
 369         # MPE needs mpeixish.h installed as well.
 370         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 371         push(@corefiles,'mpeix/mpeixish.h');
 372     }
 373     # If they have built sperl.o...
 374     push(@corefiles,'sperl.o') if -f 'sperl.o';
 375 }
 376 foreach my $file (@corefiles) {
 377     # HP-UX (at least) needs to maintain execute permissions
 378     # on dynamically-loadable libraries. So we do it for all.
 379     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 380         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 381             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 382            chmod(0555, "$installarchlib/CORE/$file");
 383         } else {
 384             chmod(0444, "$installarchlib/CORE/$file");
 385         }
 386     }
 387 }
 388
 389 # Switch in the 5.005-threads versions of he threadsafe queue and semaphore
 390 # modules if so needed.
 391 if ($Config{use5005threads}) {
 392     for my $m (qw(Queue Semaphore)) {
 393         copy("ext/Thread/$m.pmx", "$installprivlib/Thread/$m.pm")
 394     }
 395 }
 396
 397 # Install main perl executables
 398 # Make links to ordinary names if installbin directory isn't current directory.
 399
 400 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 401     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 402     if ($^O eq 'mpeix') {
 403         # MPE doesn't support hard links, so use a symlink.
 404         # We don't want another cloned copy.
 405         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 406     } elsif ($^O eq 'vos') {
 407         # VOS doesn't support hard links, so use a symlink.
 408         symlink("$installbin/$perl_verbase$ver$exe_ext",
 409                 "$installbin/$perl$exe_ext");
 410     } else {
 411         link("$installbin/$perl_verbase$ver$exe_ext",
 412                 "$installbin/$perl$exe_ext");
 413     }
 414     link("$installbin/s$perl_verbase$ver$exe_ext",
 415             "$installbin/suid$perl$exe_ext")
 416       if $d_dosuid;
 417 }
 418
 419 # For development purposes it can be very useful to have multiple perls
 420 # build for different "architectures" (eg threading or not) simultaneously.
 421 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 422     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 423     safe_unlink("$installbin/$archperl");
 424     if ($^O eq 'mpeix') {
 425         # MPE doesn't support hard links, so use a symlink.
 426         # We don't want another cloned copy.
 427         symlink($Config{perlpath}, "$installbin/$archperl");
 428     } elsif ($^O eq 'vos') {
 429         # VOS doesn't support hard links, so use a symlink.
 430         symlink("$installbin/$perl_verbase$ver$exe_ext",
 431                 "$installbin/$archperl");
 432     } else {
 433         link("$installbin/$perl_verbase$ver$exe_ext",
 434                 "$installbin/$archperl");
 435     }
 436 }
 437
 438 # Offer to install perl in a "standard" location
 439
 440 my $mainperl_is_instperl = 0;
 441
 442 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 443     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 444         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 445     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 446     my($instperl)       = "$installbin/$perl$exe_ext";
 447     my($expinstperl)    = "$binexp/$perl$exe_ext";
 448
 449     # First make sure $usrbinperl is not already the same as the perl we
 450     # just installed.
 451     if (-x $usrbinperl) {
 452         # Try to be clever about mainperl being a symbolic link
 453         # to binexp/perl if binexp and installbin are different.
 454         $mainperl_is_instperl =
 455             samepath($usrbinperl, $instperl) ||
 456             samepath($usrbinperl, $expinstperl) ||
 457              (($binexp ne $installbin) &&
 458               (-l $usrbinperl) &&
 459               ((readlink $usrbinperl) eq $expinstperl));
 460     }
 461     if (! $mainperl_is_instperl) {
 462         unlink($usrbinperl);
 463         ( $Config{'d_link'} eq 'define' &&
 464           eval { CORE::link $instperl, $usrbinperl } )  ||
 465         eval { symlink $expinstperl, $usrbinperl }      ||
 466         copy($instperl, $usrbinperl);
 467
 468         $mainperl_is_instperl = 1;
 469     }
 470 }
 471
 472 # Make links to ordinary names if installbin directory isn't current directory.
 473 if (!$Is_NetWare) {
 474         if (!$versiononly && ! samepath($installbin, 'x2p')) {
 475                 safe_unlink("$installbin/a2p$exe_ext");
 476                 copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 477                strip("$installbin/a2p$exe_ext");
 478                 chmod(0755, "$installbin/a2p$exe_ext");
 479         }
 480 }
 481
 482 # cppstdin is just a script, but it is architecture-dependent, so
 483 # it can't safely be shared.  Place it in $installbin.
 484 # Note that Configure doesn't build cppstin if it isn't needed, so
 485 # we skip this if cppstdin doesn't exist.
 486 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 487     safe_unlink("$installbin/cppstdin");
 488     copy("cppstdin", "$installbin/cppstdin");
 489     chmod(0755, "$installbin/cppstdin");
 490 }
 491
 492 sub script_alias {
 493     my ($installscript, $orig, $alias, $scr_ext) = @_;
 494
 495     safe_unlink("$installscript/$alias$scr_ext");
 496     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 497         copy("$installscript/$orig$scr_ext",
 498              "$installscript/$alias$scr_ext");
 499     } elsif ($^O eq 'vos') {
 500         symlink("$installscript/$orig$scr_ext",
 501                 "$installscript/$alias$scr_ext");
 502     } else {
 503         link("$installscript/$orig$scr_ext",
 504              "$installscript/$alias$scr_ext");
 505     }
 506 }
 507
 508 # Install scripts.
 509 mkpath($installscript, $verbose, 0777);
 510 if ($versiononly) {
 511     for (@scripts) {
 512         (my $base = $_) =~ s#.*/##;
 513         $base .= $ver;
 514         copy($_,    "$installscript/$base");
 515         chmod(0755, "$installscript/$base");
 516     }
 517
 518     for (@tolink) {
 519         my ($from, $to) = map { "$_$ver" } @$_;
 520         (my $frbase = $from) =~ s#.*/##;
 521         (my $tobase = $to) =~ s#.*/##;
 522         script_alias($installscript, $frbase, $tobase, $scr_ext);
 523     }
 524 } else {
 525     for (@scripts) {
 526         (my $base = $_) =~ s#.*/##;
 527         copy($_, "$installscript/$base");
 528         chmod(0755, "$installscript/$base");
 529     }
 530
 531     for (@tolink) {
 532         my ($from, $to) = @$_;
 533         (my $frbase = $from) =~ s#.*/##;
 534         (my $tobase = $to) =~ s#.*/##;
 535         script_alias($installscript, $frbase, $tobase, $scr_ext);
 536     }
 537 }
 538
 539 # Install pod pages.  Where? I guess in $installprivlib/pod
 540 # ($installprivlib/pods for cygwin).
 541
 542 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 543 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 544     mkpath("${installprivlib}/$pod", $verbose, 0777);
 545
 546     # If Perl 5.003's perldiag.pod is there, rename it.
 547     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 548         read POD, $_, 4000;
 549         close POD;
 550         # Some of Perl 5.003's diagnostic messages ended with periods.
 551         if (/^=.*\.$/m) {
 552             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 553                                "${installprivlib}/$pod/perldiag-5.003.pod");
 554             print "  rename $from $to";
 555             rename($from, $to)
 556                 or warn "Couldn't rename $from to $to: $!\n"
 557                 unless $nonono;
 558         }
 559     }
 560
 561     for (@pods) {
 562         # $_ is a name like  pod/perl.pod
 563         (my $base = $_) =~ s#.*/##;
 564         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 565     }
 566
 567 }
 568
 569 # Check to make sure there aren't other perls around in installer's
 570 # path.  This is probably UNIX-specific.  Check all absolute directories
 571 # in the path except for where public executables are supposed to live.
 572 # Also skip $mainperl if the user opted to have it be a link to the
 573 # installed perl.
 574
 575 if (!$versiononly && $otherperls) {
 576     my ($path, @path);
 577     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 578     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 579     @path = split(/$dirsep/, $path);
 580     if ($Is_VMS) {
 581         my $i = 0;
 582         while (exists $ENV{'DCL$PATH' . $i}) {
 583             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 584             push(@path,$dir);
 585         }
 586     }
 587     my @otherperls;
 588     my %otherperls;
 589     for (@path) {
 590         next unless m,^/,;
 591         # Use &samepath here because some systems have other dirs linked
 592         # to $mainperldir (like SunOS)
 593         next if samepath($_, $binexp);
 594         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 595         my $otherperl = "$_/$perl$exe_ext";
 596         next if $otherperls{$otherperl}++;
 597         push(@otherperls, $otherperl)
 598             if (-x $otherperl && ! -d $otherperl);
 599     }
 600     if (@otherperls) {
 601         warn "\nWarning: $perl appears in your path in the following " .
 602             "locations beyond where\nwe just installed it:\n";
 603         for (@otherperls) {
 604             warn "    ", $_, "\n";
 605         }
 606         warn "\n";
 607     }
 608
 609 }
 610
 611 $packlist->write() unless $nonono;
 612 print "  Installation complete\n" if $verbose;
 613
 614 exit 0;
 615
 616 ###############################################################################
 617
 618 sub yn {
 619     my($prompt) = @_;
 620     my($answer);
 621     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 622     print STDERR $prompt;
 623     chop($answer = <STDIN>);
 624     $answer = $default if $answer =~ m/^\s*$/;
 625     ($answer =~ m/^[yY]/);
 626 }
 627
 628 sub unlink {
 629     my(@names) = @_;
 630     my($cnt) = 0;
 631
 632     return scalar(@names) if $Is_VMS;
 633
 634     foreach my $name (@names) {
 635         next unless -e $name;
 636         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 637         print "  unlink $name\n" if $verbose;
 638         ( CORE::unlink($name) and ++$cnt
 639           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 640     }
 641     return $cnt;
 642 }
 643
 644 sub safe_unlink {
 645     return if $nonono or $Is_VMS;
 646     my @names = @_;
 647     foreach my $name (@names) {
 648         next unless -e $name;
 649         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 650         print "  unlink $name\n" if $verbose;
 651         next if CORE::unlink($name);
 652         warn "Couldn't unlink $name: $!\n";
 653         if ($! =~ /busy/i) {
 654             print "  mv $name $name.old\n" if $verbose;
 655             safe_rename($name, "$name.old")
 656                 or warn "Couldn't rename $name: $!\n";
 657         }
 658     }
 659 }
 660
 661 sub safe_rename {
 662     my($from,$to) = @_;
 663     if (-f $to and not unlink($to)) {
 664         my($i);
 665         for ($i = 1; $i < 50; $i++) {
 666             last if rename($to, "$to.$i");
 667         }
 668         warn("Cannot rename to `$to.$i': $!"), return 0
 669            if $i >= 50; # Give up!
 670     }
 671     link($from,$to) || return 0;
 672     unlink($from);
 673 }
 674
 675 sub link {
 676     my($from,$to) = @_;
 677     my($success) = 0;
 678
 679     print $verbose ? "  ln $from $to\n" : "  $to\n" unless $silent;
 680     eval {
 681         CORE::link($from, $to)
 682             ? $success++
 683             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 684               ? die "AFS"  # okay inside eval {}
 685               : die "Couldn't link $from to $to: $!\n"
 686           unless $nonono;
 687         $packlist->{$to} = { from => $from, type => 'link' };
 688     };
 689     if ($@) {
 690         warn $@;
 691         print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 692         print "  creating new version of $to\n"
 693                  if $Is_VMS and -e $to and !$silent;
 694         File::Copy::copy($from, $to)
 695             ? $success++
 696             : warn "Couldn't copy $from to $to: $!\n"
 697           unless $nonono;
 698         $packlist->{$to} = { type => 'file' };
 699     }
 700     $success;
 701 }
 702
 703 sub chmod {
 704     my($mode,$name) = @_;
 705
 706     return if ($^O eq 'dos');
 707     printf "  chmod %o %s\n", $mode, $name if $verbose;
 708     CORE::chmod($mode,$name)
 709         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 710       unless $nonono;
 711 }
 712
 713 sub copy {
 714     my($from,$to) = @_;
 715
 716     print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 717     print "  creating new version of $to\n" if $Is_VMS and -e $to and !$silent;
 718     File::Copy::copy($from, $to)
 719         || warn "Couldn't copy $from to $to: $!\n"
 720       unless $nonono;
 721     $packlist->{$to} = { type => 'file' };
 722 }
 723
 724 sub samepath {
 725     my($p1, $p2) = @_;
 726
 727     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 728
 729     if ($p1 ne $p2) {
 730         my($dev1, $ino1, $dev2, $ino2);
 731         ($dev1, $ino1) = stat($p1);
 732         ($dev2, $ino2) = stat($p2);
 733         ($dev1 == $dev2 && $ino1 == $ino2);
 734     }
 735     else {
 736         1;
 737     }
 738 }
 739
 740 sub installlib {
 741     my $dir = $File::Find::dir;
 742     $dir =~ s#^\.(?![^/])/?##;
 743     local($depth) = $dir ? "lib/$dir" : "lib";
 744
 745     my $name = $_;
 746
 747     # Ignore RCS and CVS directories.
 748     if (($name eq 'CVS' or $name eq 'RCS') and -d $name) {
 749         $File::Find::prune = 1;
 750         return;
 751     }
 752
 753     # ignore patch backups, RCS files, emacs backup & temp files and the
 754     # .exists files, .PL files, and .t files.
 755     return if $name =~ m{\.orig$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.t$} ||
 756               $dir  =~ m{/t(?:/|$)};
 757     # ignore the test extensions
 758     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 759
 760     $name = "$dir/$name" if $dir ne '';
 761
 762     my $installlib = $installprivlib;
 763     if ($dir =~ /^auto/ ||
 764           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 765           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
 766        ) {
 767         $installlib = $installarchlib;
 768         return unless $do_installarchlib;
 769     } else {
 770         return unless $do_installprivlib;
 771     }
 772
 773     if (-f $_) {
 774         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 775             $installlib = $installprivlib;
 776             #We're installing *.al and *.ix files into $installprivlib,
 777             #but we have to delete old *.al and *.ix files from the 5.000
 778             #distribution:
 779             #This might not work because $archname might have changed.
 780             unlink("$installarchlib/$name");
 781         }
 782         $packlist->{"$installlib/$name"} = { type => 'file' };
 783         if (compare($_, "$installlib/$name") || $nonono) {
 784             unlink("$installlib/$name");
 785             mkpath("$installlib/$dir", $verbose, 0777);
 786             # HP-UX (at least) needs to maintain execute permissions
 787             # on dynamically-loaded libraries.
 788            if ($Is_NetWare && !$nwinstall) {
 789                # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 790                # if copied will give problems when building new extensions.
 791                # Has to be copied if we are installing on a NetWare server and hence
 792                # the check !$nwinstall
 793                if (!(/\.(?:nlp|nlm|bs)$/)) {
 794                    copy_if_diff($_, "$installlib/$name")
 795                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 796                                  "$installlib/$name");
 797                }
 798            } else {
 799                if (copy_if_diff($_, "$installlib/$name")) {
 800                    if ($name =~ /\.(so|$dlext)$/o) {
 801                        strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 802                        chmod(0555, "$installlib/$name");
 803                    } else {
 804                        strip("-S", "$installlib/$name")
 805                            if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 806                        chmod(0444, "$installlib/$name");
 807                    }
 808                }
 809            } #if ($Is_NetWare)
 810         }
 811     }
 812 }
 813
 814 # Copy $from to $to, only if $from is different than $to.
 815 # Also preserve modification times for .a libraries.
 816 # On some systems, if you do
 817 #   ranlib libperl.a
 818 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 819 # and then try to link against the installed libperl.a, you might
 820 # get an error message to the effect that the symbol table is older
 821 # than the library.
 822 # Return true if copying occurred.
 823
 824 sub copy_if_diff {
 825     my($from,$to)=@_;
 826     return 1 if (($^O eq 'VMS') && (-d $from));
 827     my $perlpodbadsymlink;
 828     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 829         -l $from &&
 830         ! -e $from) {
 831         # Some Linux implementations have problems traversing over
 832         # multiple symlinks (when going over NFS?) and fail to read
 833         # the symlink target.  Combine this with the fact that some
 834         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 835         # and you end up with those pods not getting installed.
 836         $perlpodbadsymlink = 1;
 837     }
 838     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 839     $packlist->{$to} = { type => 'file' };
 840     if (compare($from, $to) || $nonono) {
 841         safe_unlink($to);   # In case we don't have write permissions.
 842         if ($nonono) {
 843             $from = $depth . "/" . $from if $depth;
 844         }
 845         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 846             $from = "README.$1";
 847         }
 848         copy($from, $to);
 849         # Restore timestamps if it's a .a library or for OS/2.
 850         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 851             my ($atime, $mtime) = (stat $from)[8,9];
 852             utime $atime, $mtime, $to;
 853         }
 854         1;
 855     }
 856 }
 857
 858 sub strip
 859 {
 860     my(@args) = @_;
 861
 862     return unless $dostrip;
 863
 864     my @opts;
 865     while (@args && $args[0] =~ /^(-\w+)$/) {
 866         push @opts, shift @args;
 867     }
 868
 869     foreach my $file (@args) {
 870         if (-f $file) {
 871            if ($verbose) {
 872                print "  strip " . join(' ', @opts);
 873                print " " if (@opts);
 874                print "$file\n";
 875            }
 876             system("strip", @opts, $file);
 877         } else {
 878             print "# file '$file' skipped\n" if $verbose;
 879         }
 880     }
 881 }