installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  13     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41     $Is_W32 = 0;
  42     $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63
  64 $otherperls = 1;
  65 while (@ARGV) {
  66     $nonono = 1 if $ARGV[0] eq '-n';
  67     $dostrip = 1 if $ARGV[0] eq '-s';
  68     $versiononly = 1 if $ARGV[0] eq '-v';
  69     $versiononly = 0 if $ARGV[0] eq '+v';
  70     $silent = 1 if $ARGV[0] eq '-S';
  71     $otherperls = 0 if $ARGV[0] eq '-o';
  72     $force = 1 if $ARGV[0] eq '-f';
  73     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  74     $archname = 1 if $ARGV[0] eq '-A';
  75     $nwinstall = 1 if $ARGV[0] eq '-netware';
  76     $nopods = 1 if $ARGV[0] eq '-p';
  77     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  78         print <<"EOT";
  79 Usage $0: [switches]
  80   -n        Don't actually run any commands; just print them.
  81   -s        Run strip on installed binaries.
  82   -v        Only install perl as a binary with the version number in the name.
  83             (Override whatever config.sh says)
  84   +v        Install perl as "perl" and as a binary with the version number in
  85             the name.  (Override whatever config.sh says)
  86   -S        Silent mode.
  87   -f        Force installation (don't check if same version is there)
  88   -o        Skip checking for other copies of perl in your PATH.
  89   -V        Verbose mode.
  90   -A        Also install perl with the architecture's name in the perl binary's
  91             name.
  92   -p        Don't install the pod files. [This will break use diagnostics;]
  93   -netware  Install correctly on a Netware server.
  94 EOT
  95         exit;
  96     }
  97     shift;
  98 }
  99
 100 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 101 my (@scripts, @tolink);
 102 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 103 while (<SCRIPTS>) {
 104     next if /^#/;
 105     next if /#\s*pod\s*=/; # Binary programs need separate treatment
 106     chomp;
 107     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 108         push @scripts, $1;
 109         push @tolink, [$1, $2];
 110     } else {
 111         push @scripts, $_;
 112     }
 113 }
 114 close SCRIPTS;
 115
 116 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 117
 118 my @pods = $nopods ? () : (<pod/*.pod>);
 119
 120 # Specify here any .pm files that are actually architecture-dependent.
 121 # (Those included with XS extensions under ext/ are automatically
 122 # added later.)
 123 # Now that the default privlib has the full perl version number included,
 124 # we no longer have to play the trick of sticking version-specific .pm
 125 # files under the archlib directory.
 126 my %archpms = (
 127     Config => 1,
 128     lib => 1,
 129     Cwd => 1,
 130 );
 131
 132 if ($^O eq 'dos') {
 133     push(@scripts,'djgpp/fixpmain');
 134     $archpms{config} = $archpms{filehand} = 1;
 135 }
 136
 137 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 138     push(@scripts, map("$_.exe", @scripts));
 139 }
 140
 141 find(sub {
 142     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 143         my($path, $modname) = ($1,$2);
 144
 145         # strip trailing component first
 146         $path =~ s{/[^/]*$}{};
 147
 148         # strip optional "/lib";
 149         $path =~ s{/lib\b}{};
 150
 151         # strip any leading /
 152         $path =~ s{^/}{};
 153
 154         # reconstitute canonical module name
 155         $modname = "$path/$modname" if length $path;
 156
 157         # remember it
 158         $archpms{$modname} = 1;
 159     }
 160 }, 'ext');
 161
 162 # print "[$_]\n" for sort keys %archpms;
 163
 164 my $ver = $Config{version};
 165 my $release = substr($],0,3);   # Not used currently.
 166 my $patchlevel = substr($],3,2);
 167 die "Patchlevel of perl ($patchlevel)",
 168     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 169         if $patchlevel != $Config{'PERL_VERSION'};
 170
 171 # Fetch some frequently-used items from %Config
 172 my $installbin = $Config{installbin};
 173 my $installscript = $Config{installscript};
 174 my $installprivlib = $Config{installprivlib};
 175 my $installarchlib = $Config{installarchlib};
 176 my $installsitelib = $Config{installsitelib};
 177 my $installsitearch = $Config{installsitearch};
 178 my $installman1dir = $Config{installman1dir};
 179 my $man1ext = $Config{man1ext};
 180 my $libperl = $Config{libperl};
 181 # Shared library and dynamic loading suffixes.
 182 my $so = $Config{so};
 183 my $dlext = $Config{dlext};
 184 my $dlsrc = $Config{dlsrc};
 185 if ($^O eq 'os390') {
 186     my $pwd;
 187     chomp($pwd=`pwd`);
 188     my $archlibexp = $Config{archlibexp};
 189     my $usedl = $Config{usedl};
 190     if ($usedl eq 'define') {
 191         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 192     }
 193 }
 194
 195 if ($nwinstall) {
 196     # This is required only if we are installing on a NetWare server
 197     $installscript = $Config{installnwscripts};
 198     $installprivlib = $Config{installnwlib};
 199     $installarchlib = $Config{installnwlib};
 200     $installsitelib = $Config{installnwlib};
 201 }
 202
 203 my $d_dosuid = $Config{d_dosuid};
 204 my $binexp = $Config{binexp};
 205
 206 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 207     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 208               \$installarchlib, \$installsitelib, \$installsitearch,
 209               \$installman1dir ) {
 210         $$_ = unixify($$_);  $$_ =~ s:/$::;
 211     }
 212 }
 213
 214 # Do some quick sanity checks.
 215
 216 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 217
 218    $installbin          || die "No installbin directory in config.sh\n";
 219 -d $installbin          || mkpath($installbin, $verbose, 0777);
 220 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 221 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 222         unless $installbin =~ m#^/afs/# || $nonono;
 223
 224 if (!$Is_NetWare) {
 225 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 226 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 227
 228 -f 't/rantests'         || $Is_W32
 229                         || warn "WARNING: You've never run 'make test' or",
 230                                 " some tests failed! (Installing anyway.)\n";
 231 } #if (!$Is_NetWare)
 232
 233 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 234     my $perldll;
 235
 236     if ($Is_Cygwin) {
 237         $perldll = $libperl;
 238         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 239         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 240         $perldll =~ s/^lib/cyg/;
 241         if ($Config{useshrplib} eq 'true') {
 242             # install ld2 and perlld as well
 243             foreach ('ld2', 'perlld') {
 244                 safe_unlink("$installbin/$_");
 245                 copy("$_", "$installbin/$_");
 246                 chmod(0755, "$installbin/$_");
 247             };
 248             open (LD2, ">$installbin/ld2");
 249             print LD2 <<SHELL;
 250 #!/bin/sh
 251 #
 252 # ld wrapper, passes all args to perlld;
 253 #
 254 for trythis in $installbin/perl
 255 do
 256   if [ -x \$trythis ]
 257   then
 258     \$trythis $installbin/perlld "\$\@"
 259     exit \$?
 260   fi
 261 done
 262 # hard luck!
 263 echo I see no perl executable around there
 264 echo perl is required to build dynamic libraries
 265 echo look if the path to perl in /bin/ld2 is correct
 266 exit 1
 267 SHELL
 268             close LD2;
 269             chmod(0755, "$installbin/ld2");
 270         };
 271     } else {
 272         $perldll = 'perl59.' . $dlext;
 273     }
 274
 275     if ($dlsrc ne "dl_none.xs") {
 276         -f $perldll || die "No perl DLL built\n";
 277     }
 278
 279     # Install the DLL
 280     safe_unlink("$installbin/$perldll");
 281     copy("$perldll", "$installbin/$perldll");
 282     chmod(0755, "$installbin/$perldll");
 283 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 284
 285 # This will be used to store the packlist
 286 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 287
 288 # First we install the version-numbered executables.
 289
 290 if ($Is_VMS) {
 291     safe_unlink("$installbin/$perl$exe_ext");
 292     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 293     chmod(0755, "$installbin/$perl$exe_ext");
 294     safe_unlink("$installbin/${perl}shr$exe_ext");
 295     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 296     chmod(0755, "$installbin/${perl}shr$exe_ext");
 297 }
 298 elsif ($^O eq 'mpeix') {
 299     # MPE lacks hard links and requires that executables with special
 300     # capabilities reside in the MPE namespace.
 301     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 302     # Install the primary executable into the MPE namespace as perlpath.
 303     copy("perl$exe_ext", $Config{perlpath});
 304     chmod(0755, $Config{perlpath});
 305     # Create a backup copy with the version number.
 306     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 307 }
 308 elsif ($^O ne 'dos') {
 309     if (!$Is_NetWare) {
 310         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 311         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 312         strip("$installbin/$perl_verbase$ver$exe_ext");
 313         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 314     }
 315     else {
 316         # If installing onto a NetWare server
 317         if ($nwinstall) {
 318             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 319             mkpath($Config{installnwsystem}, 1, 0777);
 320             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 321             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 322             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 323             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 324             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 325             mkpath($Config{installnwlcgi}, 1, 0777);
 326             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 327         }
 328     } #if (!$Is_NetWare)
 329 }
 330 else {
 331     safe_unlink("$installbin/$perl.exe");
 332     copy("perl.exe", "$installbin/$perl.exe");
 333 }
 334
 335 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 336 if ($d_dosuid) {
 337     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 338     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 339 }
 340
 341 # Install library files.
 342
 343 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 344
 345 mkpath($installprivlib, $verbose, 0777);
 346 mkpath($installarchlib, $verbose, 0777);
 347 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 348 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 349
 350 if (chdir "lib") {
 351     $do_installarchlib = ! samepath($installarchlib, '.');
 352     $do_installprivlib = ! samepath($installprivlib, '.');
 353     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 354
 355     if ($do_installarchlib || $do_installprivlib) {
 356         find(\&installlib, '.');
 357     }
 358     chdir ".." || die "Can't cd back to source directory: $!\n";
 359 }
 360 else {
 361     warn "Can't cd to lib to install lib files: $!\n";
 362 }
 363
 364 # Install header files and libraries.
 365 mkpath("$installarchlib/CORE", $verbose, 0777);
 366 my @corefiles;
 367 if ($Is_VMS) {  # We did core file selection during build
 368     my $coredir = "lib/$Config{archname}/$ver/CORE";
 369     $coredir =~ tr/./_/;
 370     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 371 }
 372 else {
 373     # [als] hard-coded 'libperl' name... not good!
 374     @corefiles = <*.h libperl*.*>;
 375
 376     # AIX needs perl.exp installed as well.
 377     push(@corefiles,'perl.exp') if $^O eq 'aix';
 378     if ($^O eq 'mpeix') {
 379         # MPE needs mpeixish.h installed as well.
 380         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 381         push(@corefiles,'mpeix/mpeixish.h');
 382     }
 383     # If they have built sperl.o...
 384     push(@corefiles,'sperl.o') if -f 'sperl.o';
 385 }
 386 foreach my $file (@corefiles) {
 387     # HP-UX (at least) needs to maintain execute permissions
 388     # on dynamically-loadable libraries. So we do it for all.
 389     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 390         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 391             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 392             chmod(0555, "$installarchlib/CORE/$file");
 393         } else {
 394             chmod(0444, "$installarchlib/CORE/$file");
 395         }
 396     }
 397 }
 398
 399 # Install main perl executables
 400 # Make links to ordinary names if installbin directory isn't current directory.
 401
 402 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 403     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 404     if ($^O eq 'mpeix') {
 405         # MPE doesn't support hard links, so use a symlink.
 406         # We don't want another cloned copy.
 407         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 408     } elsif ($^O eq 'vos') {
 409         # VOS doesn't support hard links, so use a symlink.
 410         symlink("$installbin/$perl_verbase$ver$exe_ext",
 411                 "$installbin/$perl$exe_ext");
 412     } else {
 413         link("$installbin/$perl_verbase$ver$exe_ext",
 414                 "$installbin/$perl$exe_ext");
 415     }
 416     link("$installbin/s$perl_verbase$ver$exe_ext",
 417             "$installbin/suid$perl$exe_ext")
 418       if $d_dosuid;
 419 }
 420
 421 # For development purposes it can be very useful to have multiple perls
 422 # build for different "architectures" (eg threading or not) simultaneously.
 423 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 424     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 425     safe_unlink("$installbin/$archperl");
 426     if ($^O eq 'mpeix') {
 427         # MPE doesn't support hard links, so use a symlink.
 428         # We don't want another cloned copy.
 429         symlink($Config{perlpath}, "$installbin/$archperl");
 430     } elsif ($^O eq 'vos') {
 431         # VOS doesn't support hard links, so use a symlink.
 432         symlink("$installbin/$perl_verbase$ver$exe_ext",
 433                 "$installbin/$archperl");
 434     } else {
 435         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 436     }
 437 }
 438
 439 # Offer to install perl in a "standard" location
 440
 441 my $mainperl_is_instperl = 0;
 442
 443 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 444     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 445         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 446     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 447     my($instperl)       = "$installbin/$perl$exe_ext";
 448     my($expinstperl)    = "$binexp/$perl$exe_ext";
 449
 450     # First make sure $usrbinperl is not already the same as the perl we
 451     # just installed.
 452     if (-x $usrbinperl) {
 453         # Try to be clever about mainperl being a symbolic link
 454         # to binexp/perl if binexp and installbin are different.
 455         $mainperl_is_instperl =
 456             samepath($usrbinperl, $instperl) ||
 457             samepath($usrbinperl, $expinstperl) ||
 458              (($binexp ne $installbin) &&
 459               (-l $usrbinperl) &&
 460               ((readlink $usrbinperl) eq $expinstperl));
 461     }
 462     if (! $mainperl_is_instperl) {
 463         unlink($usrbinperl);
 464         ( $Config{'d_link'} eq 'define' &&
 465           eval { CORE::link $instperl, $usrbinperl } )  ||
 466         eval { symlink $expinstperl, $usrbinperl }      ||
 467         copy($instperl, $usrbinperl);
 468
 469         $mainperl_is_instperl = 1;
 470     }
 471 }
 472
 473 # Make links to ordinary names if installbin directory isn't current directory.
 474 if (!$Is_NetWare) {
 475     if (! samepath($installbin, 'x2p')) {
 476         my $base = 'a2p';
 477         $base .= $ver if $versiononly;
 478         safe_unlink("$installbin/$base$exe_ext");
 479         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 480         strip("$installbin/$base$exe_ext");
 481         chmod(0755, "$installbin/$base$exe_ext");
 482     }
 483 }
 484
 485 # cppstdin is just a script, but it is architecture-dependent, so
 486 # it can't safely be shared.  Place it in $installbin.
 487 # Note that Configure doesn't build cppstin if it isn't needed, so
 488 # we skip this if cppstdin doesn't exist.
 489 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 490     safe_unlink("$installbin/cppstdin");
 491     copy("cppstdin", "$installbin/cppstdin");
 492     chmod(0755, "$installbin/cppstdin");
 493 }
 494
 495 sub script_alias {
 496     my ($installscript, $orig, $alias, $scr_ext) = @_;
 497
 498     safe_unlink("$installscript/$alias$scr_ext");
 499     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 500         copy("$installscript/$orig$scr_ext",
 501              "$installscript/$alias$scr_ext");
 502     } elsif ($^O eq 'vos') {
 503         symlink("$installscript/$orig$scr_ext",
 504                 "$installscript/$alias$scr_ext");
 505     } else {
 506         link("$installscript/$orig$scr_ext",
 507              "$installscript/$alias$scr_ext");
 508     }
 509 }
 510
 511 # Install scripts.
 512 mkpath($installscript, $verbose, 0777);
 513 if ($versiononly) {
 514     for (@scripts) {
 515         (my $base = $_) =~ s#.*/##;
 516         $base .= $ver;
 517         copy($_,    "$installscript/$base");
 518         chmod(0755, "$installscript/$base");
 519     }
 520
 521     for (@tolink) {
 522         my ($from, $to) = map { "$_$ver" } @$_;
 523         (my $frbase = $from) =~ s#.*/##;
 524         (my $tobase = $to) =~ s#.*/##;
 525         script_alias($installscript, $frbase, $tobase, $scr_ext);
 526     }
 527 } else {
 528     for (@scripts) {
 529         (my $base = $_) =~ s#.*/##;
 530         copy($_, "$installscript/$base");
 531         chmod(0755, "$installscript/$base");
 532     }
 533
 534     for (@tolink) {
 535         my ($from, $to) = @$_;
 536         (my $frbase = $from) =~ s#.*/##;
 537         (my $tobase = $to) =~ s#.*/##;
 538         script_alias($installscript, $frbase, $tobase, $scr_ext);
 539     }
 540 }
 541
 542 # Install pod pages.  Where? I guess in $installprivlib/pod
 543 # ($installprivlib/pods for cygwin).
 544
 545 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 546 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 547     mkpath("${installprivlib}/$pod", $verbose, 0777);
 548
 549     # If Perl 5.003's perldiag.pod is there, rename it.
 550     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 551         read POD, $_, 4000;
 552         close POD;
 553         # Some of Perl 5.003's diagnostic messages ended with periods.
 554         if (/^=.*\.$/m) {
 555             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 556                                "${installprivlib}/$pod/perldiag-5.003.pod");
 557             print "  rename $from $to";
 558             rename($from, $to)
 559                 or warn "Couldn't rename $from to $to: $!\n"
 560                 unless $nonono;
 561         }
 562     }
 563
 564     for (@pods) {
 565         # $_ is a name like  pod/perl.pod
 566         (my $base = $_) =~ s#.*/##;
 567         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 568     }
 569
 570 }
 571
 572 # Check to make sure there aren't other perls around in installer's
 573 # path.  This is probably UNIX-specific.  Check all absolute directories
 574 # in the path except for where public executables are supposed to live.
 575 # Also skip $mainperl if the user opted to have it be a link to the
 576 # installed perl.
 577
 578 if (!$versiononly && $otherperls) {
 579     my ($path, @path);
 580     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 581     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 582     @path = split(/$dirsep/, $path);
 583     if ($Is_VMS) {
 584         my $i = 0;
 585         while (exists $ENV{'DCL$PATH' . $i}) {
 586             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 587             push(@path,$dir);
 588         }
 589     }
 590     my @otherperls;
 591     my %otherperls;
 592     for (@path) {
 593         next unless m,^/,;
 594         # Use &samepath here because some systems have other dirs linked
 595         # to $mainperldir (like SunOS)
 596         next if samepath($_, $binexp);
 597         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 598         my $otherperl = "$_/$perl$exe_ext";
 599         next if $otherperls{$otherperl}++;
 600         push(@otherperls, $otherperl)
 601             if (-x $otherperl && ! -d $otherperl);
 602     }
 603     if (@otherperls) {
 604         warn "\nWarning: $perl appears in your path in the following " .
 605             "locations beyond where\nwe just installed it:\n";
 606         for (@otherperls) {
 607             warn "    ", $_, "\n";
 608         }
 609         warn "\n";
 610     }
 611
 612 }
 613
 614 $packlist->write() unless $nonono;
 615 print "  Installation complete\n" if $verbose;
 616
 617 exit 0;
 618
 619 ###############################################################################
 620
 621 sub yn {
 622     my($prompt) = @_;
 623     my($answer);
 624     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 625     print STDERR $prompt;
 626     chop($answer = <STDIN>);
 627     $answer = $default if $answer =~ m/^\s*$/;
 628     ($answer =~ m/^[yY]/);
 629 }
 630
 631 sub unlink {
 632     my(@names) = @_;
 633     my($cnt) = 0;
 634
 635     return scalar(@names) if $Is_VMS;
 636
 637     foreach my $name (@names) {
 638         next unless -e $name;
 639         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 640         print "  unlink $name\n" if $verbose;
 641         ( CORE::unlink($name) and ++$cnt
 642           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 643     }
 644     return $cnt;
 645 }
 646
 647 sub safe_unlink {
 648     return if $nonono or $Is_VMS;
 649     my @names = @_;
 650     foreach my $name (@names) {
 651         next unless -e $name;
 652         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 653         print "  unlink $name\n" if $verbose;
 654         next if CORE::unlink($name);
 655         warn "Couldn't unlink $name: $!\n";
 656         if ($! =~ /busy/i) {
 657             print "  mv $name $name.old\n" if $verbose;
 658             safe_rename($name, "$name.old")
 659                 or warn "Couldn't rename $name: $!\n";
 660         }
 661     }
 662 }
 663
 664 sub safe_rename {
 665     my($from,$to) = @_;
 666     if (-f $to and not unlink($to)) {
 667         my($i);
 668         for ($i = 1; $i < 50; $i++) {
 669             last if rename($to, "$to.$i");
 670         }
 671         warn("Cannot rename to `$to.$i': $!"), return 0
 672            if $i >= 50; # Give up!
 673     }
 674     link($from,$to) || return 0;
 675     unlink($from);
 676 }
 677
 678 sub link {
 679     my($from,$to) = @_;
 680     my($success) = 0;
 681
 682     print $verbose ? "  ln $from $to\n" : "  $to\n" unless $silent;
 683     eval {
 684         CORE::link($from, $to)
 685             ? $success++
 686             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 687               ? die "AFS"  # okay inside eval {}
 688               : die "Couldn't link $from to $to: $!\n"
 689           unless $nonono;
 690         $packlist->{$to} = { from => $from, type => 'link' };
 691     };
 692     if ($@) {
 693         warn $@;
 694         print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 695         print "  creating new version of $to\n"
 696                  if $Is_VMS and -e $to and !$silent;
 697         File::Copy::copy($from, $to)
 698             ? $success++
 699             : warn "Couldn't copy $from to $to: $!\n"
 700           unless $nonono;
 701         $packlist->{$to} = { type => 'file' };
 702     }
 703     $success;
 704 }
 705
 706 sub chmod {
 707     my($mode,$name) = @_;
 708
 709     return if ($^O eq 'dos');
 710     printf "  chmod %o %s\n", $mode, $name if $verbose;
 711     CORE::chmod($mode,$name)
 712         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 713       unless $nonono;
 714 }
 715
 716 sub copy {
 717     my($from,$to) = @_;
 718
 719     print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 720     print "  creating new version of $to\n" if $Is_VMS and -e $to and !$silent;
 721     File::Copy::copy($from, $to)
 722         || warn "Couldn't copy $from to $to: $!\n"
 723       unless $nonono;
 724     $packlist->{$to} = { type => 'file' };
 725 }
 726
 727 sub samepath {
 728     my($p1, $p2) = @_;
 729
 730     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 731
 732     if ($p1 ne $p2) {
 733         my($dev1, $ino1, $dev2, $ino2);
 734         ($dev1, $ino1) = stat($p1);
 735         ($dev2, $ino2) = stat($p2);
 736         ($dev1 == $dev2 && $ino1 == $ino2);
 737     }
 738     else {
 739         1;
 740     }
 741 }
 742
 743 sub installlib {
 744     my $dir = $File::Find::dir;
 745     $dir =~ s#^\.(?![^/])/?##;
 746     local($depth) = $dir ? "lib/$dir" : "lib";
 747
 748     my $name = $_;
 749
 750     # Ignore version control directories.
 751     if (($name eq 'CVS' or $name eq 'RCS' or $name eq '.svn') and -d $name) {
 752         $File::Find::prune = 1;
 753         return;
 754     }
 755
 756     # ignore patch backups, RCS files, emacs backup & temp files and the
 757     # .exists files, .PL files, and .t files.
 758     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.t$} ||
 759               $dir  =~ m{/t(?:/|$)};
 760     # ignore the cpan script in lib/CPAN/bin (installed later with other utils)
 761     return if $name eq 'cpan';
 762     # ignore the test extensions
 763     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 764
 765     $name = "$dir/$name" if $dir ne '';
 766
 767     my $installlib = $installprivlib;
 768     if ($dir =~ /^auto/ ||
 769           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 770           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
 771        ) {
 772         $installlib = $installarchlib;
 773         return unless $do_installarchlib;
 774     } else {
 775         return unless $do_installprivlib;
 776     }
 777
 778     if (-f $_) {
 779         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 780             $installlib = $installprivlib;
 781             #We're installing *.al and *.ix files into $installprivlib,
 782             #but we have to delete old *.al and *.ix files from the 5.000
 783             #distribution:
 784             #This might not work because $archname might have changed.
 785             unlink("$installarchlib/$name");
 786         }
 787         $packlist->{"$installlib/$name"} = { type => 'file' };
 788         if ($force || compare($_, "$installlib/$name") || $nonono) {
 789             unlink("$installlib/$name");
 790             mkpath("$installlib/$dir", $verbose, 0777);
 791             # HP-UX (at least) needs to maintain execute permissions
 792             # on dynamically-loaded libraries.
 793             if ($Is_NetWare && !$nwinstall) {
 794                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 795                 # if copied will give problems when building new extensions.
 796                 # Has to be copied if we are installing on a NetWare server and hence
 797                 # the check !$nwinstall
 798                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 799                     copy_if_diff($_, "$installlib/$name")
 800                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 801                                   "$installlib/$name");
 802                 }
 803            } else {
 804                 if (copy_if_diff($_, "$installlib/$name")) {
 805                     if ($name =~ /\.(so|$dlext)$/o) {
 806                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 807                         chmod(0555, "$installlib/$name");
 808                     } else {
 809                         strip("-S", "$installlib/$name")
 810                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 811                         chmod(0444, "$installlib/$name");
 812                     }
 813                 }
 814             } #if ($Is_NetWare)
 815         }
 816     }
 817 }
 818
 819 # Copy $from to $to, only if $from is different than $to.
 820 # Also preserve modification times for .a libraries.
 821 # On some systems, if you do
 822 #   ranlib libperl.a
 823 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 824 # and then try to link against the installed libperl.a, you might
 825 # get an error message to the effect that the symbol table is older
 826 # than the library.
 827 # Return true if copying occurred.
 828
 829 sub copy_if_diff {
 830     my($from,$to)=@_;
 831     return 1 if (($^O eq 'VMS') && (-d $from));
 832     my $perlpodbadsymlink;
 833     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 834         -l $from &&
 835         ! -e $from) {
 836         # Some Linux implementations have problems traversing over
 837         # multiple symlinks (when going over NFS?) and fail to read
 838         # the symlink target.  Combine this with the fact that some
 839         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 840         # and you end up with those pods not getting installed.
 841         $perlpodbadsymlink = 1;
 842     }
 843     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 844     $packlist->{$to} = { type => 'file' };
 845     if ($force || compare($from, $to) || $nonono) {
 846         safe_unlink($to);   # In case we don't have write permissions.
 847         if ($nonono) {
 848             $from = $depth . "/" . $from if $depth;
 849         }
 850         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 851             $from = "README.$1";
 852         }
 853         copy($from, $to);
 854         # Restore timestamps if it's a .a library or for OS/2.
 855         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 856             my ($atime, $mtime) = (stat $from)[8,9];
 857             utime $atime, $mtime, $to;
 858         }
 859         1;
 860     }
 861 }
 862
 863 sub strip
 864 {
 865     my(@args) = @_;
 866
 867     return unless $dostrip;
 868
 869     my @opts;
 870     while (@args && $args[0] =~ /^(-\w+)$/) {
 871         push @opts, shift @args;
 872     }
 873
 874     foreach my $file (@args) {
 875         if (-f $file) {
 876             if ($verbose) {
 877                 print "  strip " . join(' ', @opts);
 878                 print " " if (@opts);
 879                 print "$file\n";
 880             }
 881             system("strip", @opts, $file);
 882         } else {
 883             print "# file '$file' skipped\n" if $verbose;
 884         }
 885     }
 886 }