installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $nonono $versiononly $depth);
  12
  13 BEGIN {
  14     $Is_VMS = $^O eq 'VMS';
  15     $Is_W32 = $^O eq 'MSWin32';
  16     $Is_OS2 = $^O eq 'os2';
  17     $Is_Cygwin = $^O =~ /cygwin/i;
  18     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  19 }
  20
  21 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  22
  23 use File::Find;
  24 use File::Compare;
  25 use File::Copy ();
  26 use File::Path ();
  27 use ExtUtils::Packlist;
  28 use Config;
  29 use subs qw(unlink link chmod);
  30 use vars qw($packlist);
  31
  32 # override the ones in the rest of the script
  33 sub mkpath {
  34     File::Path::mkpath(@_) unless $nonono;
  35 }
  36
  37 my $mainperldir = "/usr/bin";
  38 my $exe_ext = $Config{exe_ext};
  39
  40 # Allow ``make install PERLNAME=something_besides_perl'':
  41 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  42
  43 # This is the base used for versioned names, like "perl5.005".
  44 # It's separate because a common use of $PERLNAME is to install
  45 # perl as "perl5", if that's used as base for versioned files you
  46 # get "perl55.005".
  47 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  48                     ? $ENV{PERLNAME_VERBASE}
  49                     : $perl;
  50
  51 while (@ARGV) {
  52     $nonono = 1 if $ARGV[0] eq '-n';
  53     $versiononly = 1 if $ARGV[0] eq '-v';
  54     shift;
  55 }
  56
  57 umask 022 unless $Is_VMS;
  58
  59 my @scripts = qw(utils/c2ph utils/h2ph utils/h2xs utils/perlbug utils/perldoc
  60                 utils/pl2pm utils/splain utils/perlcc
  61                 x2p/s2p x2p/find2perl
  62                 pod/pod2man pod/pod2html pod/pod2latex pod/pod2text
  63                 pod/pod2usage pod/podchecker pod/podselect);
  64
  65 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
  66
  67 my @pods = (<pod/*.pod>);
  68
  69 # Specify here any .pm files that are actually architecture-dependent.
  70 # (Those included with XS extensions under ext/ are automatically
  71 # added later.)
  72 # Now that the default privlib has the full perl version number included,
  73 # we no longer have to play the trick of sticking version-specific .pm
  74 # files under the archlib directory.
  75 my %archpms = (
  76     Config => 1,
  77 );
  78
  79 if ($^O eq 'dos') {
  80     push(@scripts,'djgpp/fixpmain');
  81     $archpms{config} = $archpms{filehand} = 1;
  82 }
  83
  84 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
  85 {
  86         push(@scripts, map("$_.exe", @scripts));
  87 }
  88
  89 find(sub {
  90         if ("$File::Find::dir/$_" =~ m{^ext/[^/]+/(.*)\.pm$}) {
  91             (my $pm = $1) =~ s{^lib/}{};
  92             $archpms{$pm} = 1;
  93         }
  94     }, 'ext');
  95
  96 my $ver = $];
  97 my $release = substr($ver,0,3);   # Not used presently.
  98 my $patchlevel = substr($ver,3,2);
  99 die "Patchlevel of perl ($patchlevel)",
 100     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 101         if $patchlevel != $Config{'PERL_VERSION'};
 102
 103 # Fetch some frequently-used items from %Config
 104 my $installbin = $Config{installbin};
 105 my $installscript = $Config{installscript};
 106 my $installprivlib = $Config{installprivlib};
 107 my $installarchlib = $Config{installarchlib};
 108 my $installsitelib = $Config{installsitelib};
 109 my $installsitearch = $Config{installsitearch};
 110 my $installman1dir = $Config{installman1dir};
 111 my $man1ext = $Config{man1ext};
 112 my $libperl = $Config{libperl};
 113 # Shared library and dynamic loading suffixes.
 114 my $so = $Config{so};
 115 my $dlext = $Config{dlext};
 116
 117 my $d_dosuid = $Config{d_dosuid};
 118 my $binexp = $Config{binexp};
 119
 120 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 121     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 122               \$installarchlib, \$installsitelib, \$installsitearch,
 123               \$installman1dir ) {
 124       $$_ = unixify($$_);  $$_ =~ s:/$::;
 125     }
 126 }
 127
 128 # Do some quick sanity checks.
 129
 130 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 131
 132    $installbin          || die "No installbin directory in config.sh\n";
 133 -d $installbin          || mkpath($installbin, 1, 0777);
 134 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 135 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 136         unless $installbin =~ m#^/afs/# || $nonono;
 137
 138 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 139 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 140
 141 -x 't/TEST'             || $Is_W32
 142                         || warn "WARNING: You've never run 'make test'!!!",
 143                                 "  (Installing anyway.)\n";
 144
 145 if ($Is_W32 or $Is_Cygwin) {
 146   my $perldll;
 147
 148 if ($Is_Cygwin) {
 149   $perldll = $libperl;
 150   $perldll =~ s/(\..*)?$/.$dlext/;
 151   if ($Config{useshrplib} eq 'true') {
 152     # install ld2 and perlld as well
 153     foreach ('ld2', 'perlld') {
 154       safe_unlink("$installbin/$_");
 155       copy("$_", "$installbin/$_");
 156       chmod(0755, "$installbin/$_");
 157     };
 158   };
 159 } else {
 160   $perldll = 'perl.' . $dlext;
 161   $perldll = 'perlcore.' . $dlext if $Config{'ccflags'} =~ /PERL_OBJECT/i;
 162 }
 163
 164 -f $perldll || die "No perl DLL built\n";
 165
 166 # Install the DLL
 167
 168 safe_unlink("$installbin/$perldll");
 169 copy("$perldll", "$installbin/$perldll");
 170 chmod(0755, "$installbin/$perldll");
 171 }
 172
 173 # This will be used to store the packlist
 174 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 175
 176 # First we install the version-numbered executables.
 177
 178 if ($Is_VMS) {
 179     safe_unlink("$installbin/$perl$exe_ext");
 180     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 181     chmod(0755, "$installbin/$perl$exe_ext");
 182     safe_unlink("$installbin/${perl}shr$exe_ext");
 183     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 184     chmod(0755, "$installbin/${perl}shr$exe_ext");
 185 }
 186 elsif ($^O eq 'mpeix') {
 187     # MPE lacks hard links and requires that executables with special
 188     # capabilities reside in the MPE namespace.
 189     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 190     # Install the primary executable into the MPE namespace as perlpath.
 191     copy("perl$exe_ext", $Config{perlpath});
 192     chmod(0755, $Config{perlpath});
 193     # Create a backup copy with the version number.
 194     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 195 }
 196 elsif ($^O ne 'dos') {
 197     safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 198     copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 199     strip("$installbin/$perl_verbase$ver$exe_ext") if $^O =~ /^(rhapsody)$/;
 200     chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 201 }
 202 else {
 203     safe_unlink("$installbin/$perl.exe");
 204     copy("perl.exe", "$installbin/$perl.exe");
 205 }
 206
 207 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 208 if ($d_dosuid) {
 209     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 210     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 211 }
 212
 213 # Install library files.
 214
 215 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 216
 217 mkpath($installprivlib, 1, 0777);
 218 mkpath($installarchlib, 1, 0777);
 219 mkpath($installsitelib, 1, 0777) if ($installsitelib);
 220 mkpath($installsitearch, 1, 0777) if ($installsitearch);
 221
 222 if (chdir "lib") {
 223     $do_installarchlib = ! samepath($installarchlib, '.');
 224     $do_installprivlib = ! samepath($installprivlib, '.');
 225     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$]/);
 226
 227     if ($do_installarchlib || $do_installprivlib) {
 228         find(\&installlib, '.');
 229     }
 230     chdir ".." || die "Can't cd back to source directory: $!\n";
 231 }
 232 else {
 233     warn "Can't cd to lib to install lib files: $!\n";
 234 }
 235
 236 # Install header files and libraries.
 237 mkpath("$installarchlib/CORE", 1, 0777);
 238 my @corefiles;
 239 if ($Is_VMS) {  # We did core file selection during build
 240     my $coredir = "lib/$Config{'arch'}/$]";
 241     $coredir =~ tr/./_/;
 242     @corefiles = <$coredir/*.*>;
 243 }
 244 else {
 245     # [als] hard-coded 'libperl' name... not good!
 246     @corefiles = <*.h libperl*.*>;
 247
 248     # cygwin needs special stub for dll loading
 249     push @corefiles, 'impure_ptr.o'
 250       if ($Is_Cygwin and $Config{useshrplib} eq 'true');
 251
 252     # AIX needs perl.exp installed as well.
 253     push(@corefiles,'perl.exp') if $^O eq 'aix';
 254     if ($^O eq 'mpeix') {
 255         # MPE needs mpeixish.h installed as well.
 256         mkpath("$installarchlib/CORE/mpeix", 1, 0777);
 257         push(@corefiles,'mpeix/mpeixish.h');
 258     }
 259     # If they have built sperl.o...
 260     push(@corefiles,'sperl.o') if -f 'sperl.o';
 261 }
 262 foreach my $file (@corefiles) {
 263     # HP-UX (at least) needs to maintain execute permissions
 264     # on dynamically-loadable libraries. So we do it for all.
 265     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 266         if ($file =~ /\.(so|\Q$dlext\E)$/) {
 267             chmod(0555, "$installarchlib/CORE/$file");
 268             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody)$/;
 269         } else {
 270             chmod(0444, "$installarchlib/CORE/$file");
 271         }
 272     }
 273 }
 274
 275 # Install main perl executables
 276 # Make links to ordinary names if installbin directory isn't current directory.
 277
 278 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 279     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 280     if ($^O eq 'mpeix') {
 281         # MPE doesn't support hard links, so use a symlink.
 282         # We don't want another cloned copy.
 283         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 284     } else {
 285         link("$installbin/$perl_verbase$ver$exe_ext",
 286                 "$installbin/$perl$exe_ext");
 287     }
 288     link("$installbin/s$perl_verbase$ver$exe_ext",
 289             "$installbin/suid$perl$exe_ext")
 290       if $d_dosuid;
 291 }
 292
 293 # Offer to install perl in a "standard" location
 294
 295 my $mainperl_is_instperl = 0;
 296
 297 if ($Config{installusrbinperl} eq 'define' &&
 298     !$versiononly && !$nonono && !$Is_W32 && !$Is_VMS && -t STDIN && -t STDERR
 299         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 300     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 301     my($instperl)       = "$installbin/$perl$exe_ext";
 302     my($expinstperl)    = "$binexp/$perl$exe_ext";
 303
 304     # First make sure $usrbinperl is not already the same as the perl we
 305     # just installed.
 306     if (-x $usrbinperl) {
 307         # Try to be clever about mainperl being a symbolic link
 308         # to binexp/perl if binexp and installbin are different.
 309         $mainperl_is_instperl =
 310             samepath($usrbinperl, $instperl) ||
 311             samepath($usrbinperl, $expinstperl) ||
 312              (($binexp ne $installbin) &&
 313               (-l $usrbinperl) &&
 314               ((readlink $usrbinperl) eq $expinstperl));
 315     }
 316     if ((! $mainperl_is_instperl) &&
 317         (yn("Many scripts expect perl to be installed as $usrbinperl.\n" .
 318              "Do you wish to have $usrbinperl be the same as\n" .
 319              "$expinstperl? [y] ")))
 320     {
 321         unlink($usrbinperl);
 322         ( $Config{'d_link'} eq 'define' &&
 323           eval { CORE::link $instperl, $usrbinperl } )  ||
 324         eval { symlink $expinstperl, $usrbinperl }      ||
 325         copy($instperl, $usrbinperl);
 326
 327         $mainperl_is_instperl = 1;
 328     }
 329 }
 330
 331 # Make links to ordinary names if installbin directory isn't current directory.
 332
 333 if (!$versiononly && ! samepath($installbin, 'x2p')) {
 334     safe_unlink("$installbin/a2p$exe_ext");
 335     copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 336     chmod(0755, "$installbin/a2p$exe_ext");
 337 }
 338
 339 # cppstdin is just a script, but it is architecture-dependent, so
 340 # it can't safely be shared.  Place it in $installbin.
 341 # Note that Configure doesn't build cppstin if it isn't needed, so
 342 # we skip this if cppstdin doesn't exist.
 343 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 344     safe_unlink("$installbin/cppstdin");
 345     copy("cppstdin", "$installbin/cppstdin");
 346     chmod(0755, "$installbin/cppstdin");
 347 }
 348
 349 # Install scripts.
 350
 351 mkpath($installscript, 1, 0777);
 352
 353 if (! $versiononly) {
 354     for (@scripts) {
 355         (my $base = $_) =~ s#.*/##;
 356         copy($_, "$installscript/$base");
 357         chmod(0755, "$installscript/$base");
 358     }
 359 }
 360
 361 # pstruct should be a link to c2ph
 362
 363 if (! $versiononly) {
 364     safe_unlink("$installscript/pstruct$scr_ext");
 365     if ($^O eq 'dos' or $Is_VMS) {
 366         copy("$installscript/c2ph$scr_ext", "$installscript/pstruct$scr_ext");
 367     } else {
 368         link("$installscript/c2ph$scr_ext", "$installscript/pstruct$scr_ext");
 369     }
 370 }
 371
 372 # Install pod pages.  Where? I guess in $installprivlib/pod.
 373
 374 unless ( $versiononly && !($installprivlib =~ m/\Q$]/)) {
 375     mkpath("${installprivlib}/pod", 1, 0777);
 376
 377     # If Perl 5.003's perldiag.pod is there, rename it.
 378     if (open POD, "${installprivlib}/pod/perldiag.pod") {
 379         read POD, $_, 4000;
 380         close POD;
 381         # Some of Perl 5.003's diagnostic messages ended with periods.
 382         if (/^=.*\.$/m) {
 383             my ($from, $to) = ("${installprivlib}/pod/perldiag.pod",
 384                                "${installprivlib}/pod/perldiag-5.003.pod");
 385             print STDERR "  rename $from $to";
 386             rename($from, $to)
 387                 or warn "Couldn't rename $from to $to: $!\n"
 388                 unless $nonono;
 389         }
 390     }
 391
 392     foreach my $file (@pods) {
 393         # $file is a name like  pod/perl.pod
 394         copy_if_diff($file, "${installprivlib}/${file}");
 395     }
 396
 397 }
 398
 399 # Check to make sure there aren't other perls around in installer's
 400 # path.  This is probably UNIX-specific.  Check all absolute directories
 401 # in the path except for where public executables are supposed to live.
 402 # Also skip $mainperl if the user opted to have it be a link to the
 403 # installed perl.
 404
 405 if (!$versiononly) {
 406         my ($path, @path);
 407     my $dirsep = ($Is_OS2 || $Is_W32) ? ';' : ':' ;
 408     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 409     @path = split(/$dirsep/, $path);
 410     if ($Is_VMS) {
 411         my $i = 0;
 412         while (exists $ENV{'DCL$PATH' . $i}) {
 413             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 414             push(@path,$dir);
 415         }
 416     }
 417     my @otherperls;
 418     for (@path) {
 419         next unless m,^/,;
 420         # Use &samepath here because some systems have other dirs linked
 421         # to $mainperldir (like SunOS)
 422         next if samepath($_, $binexp);
 423         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 424         push(@otherperls, "$_/$perl$exe_ext")
 425             if (-x "$_/$perl$exe_ext" && ! -d "$_/$perl$exe_ext");
 426     }
 427     if (@otherperls) {
 428         print STDERR "\nWarning: $perl appears in your path in the following " .
 429             "locations beyond where\nwe just installed it:\n";
 430         for (@otherperls) {
 431             print STDERR "    ", $_, "\n";
 432         }
 433         print STDERR "\n";
 434     }
 435
 436 }
 437
 438 $packlist->write() unless $nonono;
 439 print STDERR "  Installation complete\n";
 440
 441 exit 0;
 442
 443 ###############################################################################
 444
 445 sub yn {
 446     my($prompt) = @_;
 447     my($answer);
 448     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 449     print STDERR $prompt;
 450     chop($answer = <STDIN>);
 451     $answer = $default if $answer =~ m/^\s*$/;
 452     ($answer =~ m/^[yY]/);
 453 }
 454
 455 sub unlink {
 456     my(@names) = @_;
 457     my($cnt) = 0;
 458
 459     return scalar(@names) if $Is_VMS;
 460
 461     foreach my $name (@names) {
 462         next unless -e $name;
 463         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin);
 464         print STDERR "  unlink $name\n";
 465         ( CORE::unlink($name) and ++$cnt
 466           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 467     }
 468     return $cnt;
 469 }
 470
 471 sub safe_unlink {
 472     return if $nonono or $Is_VMS;
 473     my @names = @_;
 474     foreach my $name (@names) {
 475         next unless -e $name;
 476         chmod 0777, $name if ($Is_OS2 || $Is_W32);
 477         print STDERR "  unlink $name\n";
 478         next if CORE::unlink($name);
 479         warn "Couldn't unlink $name: $!\n";
 480         if ($! =~ /busy/i) {
 481             print STDERR "  mv $name $name.old\n";
 482             safe_rename($name, "$name.old")
 483                 or warn "Couldn't rename $name: $!\n";
 484         }
 485     }
 486 }
 487
 488 sub safe_rename {
 489     my($from,$to) = @_;
 490     if (-f $to and not unlink($to)) {
 491         my($i);
 492         for ($i = 1; $i < 50; $i++) {
 493             last if rename($to, "$to.$i");
 494         }
 495         warn("Cannot rename to `$to.$i': $!"), return 0
 496            if $i >= 50; # Give up!
 497     }
 498     link($from,$to) || return 0;
 499     unlink($from);
 500 }
 501
 502 sub link {
 503     my($from,$to) = @_;
 504     my($success) = 0;
 505
 506     print STDERR "  ln $from $to\n";
 507     eval {
 508         CORE::link($from, $to)
 509             ? $success++
 510             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 511               ? die "AFS"  # okay inside eval {}
 512               : warn "Couldn't link $from to $to: $!\n"
 513           unless $nonono;
 514         $packlist->{$to} = { from => $from, type => 'link' };
 515     };
 516     if ($@) {
 517         print STDERR "  creating new version of $to\n" if $Is_VMS and -e $to;
 518         File::Copy::copy($from, $to)
 519             ? $success++
 520             : warn "Couldn't copy $from to $to: $!\n"
 521           unless $nonono;
 522         $packlist->{$to} = { type => 'file' };
 523     }
 524     $success;
 525 }
 526
 527 sub chmod {
 528     my($mode,$name) = @_;
 529
 530     return if ($^O eq 'dos');
 531     printf STDERR "  chmod %o %s\n", $mode, $name;
 532     CORE::chmod($mode,$name)
 533         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 534       unless $nonono;
 535 }
 536
 537 sub copy {
 538     my($from,$to) = @_;
 539
 540     print STDERR "  cp $from $to\n";
 541     print STDERR "  creating new version of $to\n" if $Is_VMS and -e $to;
 542     File::Copy::copy($from, $to)
 543         || warn "Couldn't copy $from to $to: $!\n"
 544       unless $nonono;
 545     $packlist->{$to} = { type => 'file' };
 546 }
 547
 548 sub samepath {
 549     my($p1, $p2) = @_;
 550
 551     return (lc($p1) eq lc($p2)) if $Is_W32;
 552
 553     if ($p1 ne $p2) {
 554         my($dev1, $ino1, $dev2, $ino2);
 555         ($dev1, $ino1) = stat($p1);
 556         ($dev2, $ino2) = stat($p2);
 557         ($dev1 == $dev2 && $ino1 == $ino2);
 558     }
 559     else {
 560         1;
 561     }
 562 }
 563
 564 sub installlib {
 565     my $dir = $File::Find::dir;
 566     $dir =~ s#^\.(?![^/])/?##;
 567     local($depth) = $dir ? "lib/$dir" : "lib";
 568
 569     my $name = $_;
 570
 571     if ($name eq 'CVS' && -d $name) {
 572         $File::Find::prune = 1;
 573         return;
 574     }
 575
 576     # ignore patch backups and the .exists files.
 577     return if $name =~ m{\.orig$|~$|^\.exists};
 578
 579     $name = "$dir/$name" if $dir ne '';
 580
 581     my $installlib = $installprivlib;
 582     if ($dir =~ /^auto/ ||
 583           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 584           ($name =~ /^(.*)\.(?:h|lib)$/i && $Is_W32)
 585        ) {
 586         $installlib = $installarchlib;
 587         return unless $do_installarchlib;
 588     } else {
 589         return unless $do_installprivlib;
 590     }
 591
 592     if (-f $_) {
 593         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 594             $installlib = $installprivlib;
 595             #We're installing *.al and *.ix files into $installprivlib,
 596             #but we have to delete old *.al and *.ix files from the 5.000
 597             #distribution:
 598             #This might not work because $archname might have changed.
 599             unlink("$installarchlib/$name");
 600         }
 601         $packlist->{"$installlib/$name"} = { type => 'file' };
 602         if (compare($_, "$installlib/$name") || $nonono) {
 603             unlink("$installlib/$name");
 604             mkpath("$installlib/$dir", 1, 0777);
 605             # HP-UX (at least) needs to maintain execute permissions
 606             # on dynamically-loaded libraries.
 607             copy_if_diff($_, "$installlib/$name")
 608                 and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 609                            "$installlib/$name");
 610         }
 611     }
 612 }
 613
 614 # Copy $from to $to, only if $from is different than $to.
 615 # Also preserve modification times for .a libraries.
 616 # On some systems, if you do
 617 #   ranlib libperl.a
 618 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 619 # and then try to link against the installed libperl.a, you might
 620 # get an error message to the effect that the symbol table is older
 621 # than the library.
 622 # Return true if copying occurred.
 623
 624 sub copy_if_diff {
 625     my($from,$to)=@_;
 626     return 1 if (($^O eq 'VMS') && (-d $from));
 627     -f $from || die "$0: $from not found";
 628     $packlist->{$to} = { type => 'file' };
 629     if (compare($from, $to) || $nonono) {
 630         safe_unlink($to);   # In case we don't have write permissions.
 631         if ($nonono) {
 632             $from = $depth . "/" . $from if $depth;
 633         }
 634         copy($from, $to);
 635         # Restore timestamps if it's a .a library or for OS/2.
 636         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 637             my ($atime, $mtime) = (stat $from)[8,9];
 638             utime $atime, $mtime, $to;
 639         }
 640         1;
 641     }
 642 }
 643
 644 sub strip
 645 {
 646     my(@args) = @_;
 647
 648     my @opts;
 649     while (@args && $args[0] =~ /^(-\w+)$/) {
 650         push @opts, shift @args;
 651     }
 652
 653     foreach my $file (@args) {
 654         if (-f $file) {
 655             print STDERR "  strip $file\n";
 656             system("strip", @opts, $file);
 657         } else {
 658             print STDERR "# file '$file' skipped\n";
 659         }
 660     }
 661 }
 662