installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  13     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41     $Is_W32 = 0;
  42     $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63 my $dbg = '';
  64 my $ndbg = '';
  65 if ( $Is_VMS ) {
  66     if ( defined $Config{usevmsdebug} ) {
  67         if ( $Config{usevmsdebug} eq 'define' ) {
  68             $dbg = 'dbg';
  69             $ndbg = 'ndbg';
  70         }
  71     }
  72 }
  73
  74 $otherperls = 1;
  75 my $destdir = '';
  76 while (@ARGV) {
  77     $nonono = 1 if $ARGV[0] eq '-n';
  78     $dostrip = 1 if $ARGV[0] eq '-s';
  79     $versiononly = 1 if $ARGV[0] eq '-v';
  80     $versiononly = 0 if $ARGV[0] eq '+v';
  81     $silent = 1 if $ARGV[0] eq '-S';
  82     $otherperls = 0 if $ARGV[0] eq '-o';
  83     $force = 1 if $ARGV[0] eq '-f';
  84     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  85     $archname = 1 if $ARGV[0] eq '-A';
  86     $nwinstall = 1 if $ARGV[0] eq '-netware';
  87     $nopods = 1 if $ARGV[0] eq '-p';
  88     $destdir = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
  89     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  90         print <<"EOT";
  91 Usage $0: [switches]
  92   -n        Don't actually run any commands; just print them.
  93   -s        Run strip on installed binaries.
  94   -v        Only install perl as a binary with the version number in the name.
  95             (Override whatever config.sh says)
  96   +v        Install perl as "perl" and as a binary with the version number in
  97             the name.  (Override whatever config.sh says)
  98   -S        Silent mode.
  99   -f        Force installation (don't check if same version is there)
 100   -o        Skip checking for other copies of perl in your PATH.
 101   -V        Verbose mode.
 102   -A        Also install perl with the architecture's name in the perl binary's
 103             name.
 104   -p        Don't install the pod files. [This will break use diagnostics;]
 105   -netware  Install correctly on a Netware server.
 106 EOT
 107         exit;
 108     }
 109     shift;
 110 }
 111
 112 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 113 my (@scripts, @tolink);
 114 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 115 while (<SCRIPTS>) {
 116     next if /^#/;
 117     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 118     next if /a2p/; # a2p is binary, to be installed separately
 119     chomp;
 120     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 121         push @scripts, $1;
 122         push @tolink, [$1, $2];
 123     } else {
 124         push @scripts, $_;
 125     }
 126 }
 127 close SCRIPTS;
 128
 129 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 130
 131 my @pods = $nopods ? () : (<pod/*.pod>);
 132
 133 # Specify here any .pm files that are actually architecture-dependent.
 134 # (Those included with XS extensions under ext/ are automatically
 135 # added later.)
 136 # Now that the default privlib has the full perl version number included,
 137 # we no longer have to play the trick of sticking version-specific .pm
 138 # files under the archlib directory.
 139 my %archpms = (
 140     Config => 1,
 141     lib => 1,
 142     Cwd => 1,
 143 );
 144
 145 if ($^O eq 'dos') {
 146     push(@scripts,'djgpp/fixpmain');
 147     $archpms{config} = $archpms{filehand} = 1;
 148 }
 149
 150 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 151     push(@scripts, map("$_.exe", @scripts));
 152 }
 153
 154 find(sub {
 155     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 156         my($path, $modname) = ($1,$2);
 157
 158         # strip trailing component first
 159         $path =~ s{/[^/]*$}{};
 160
 161         # strip optional "/lib";
 162         $path =~ s{/lib\b}{};
 163
 164         # strip any leading /
 165         $path =~ s{^/}{};
 166
 167         # reconstitute canonical module name
 168         $modname = "$path/$modname" if length $path;
 169
 170         # remember it
 171         $archpms{$modname} = 1;
 172     }
 173 }, 'ext');
 174
 175 # print "[$_]\n" for sort keys %archpms;
 176
 177 my $ver = $Config{version};
 178 my $release = substr($],0,3);   # Not used currently.
 179 my $patchlevel = substr($],3,2);
 180 die "Patchlevel of perl ($patchlevel)",
 181     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 182         if $patchlevel != $Config{'PERL_VERSION'};
 183
 184 # Fetch some frequently-used items from %Config
 185 my $installbin = "$destdir$Config{installbin}";
 186 my $installscript = "$destdir$Config{installscript}";
 187 my $installprivlib = "$destdir$Config{installprivlib}";
 188 my $installarchlib = "$destdir$Config{installarchlib}";
 189 my $installsitelib = "$destdir$Config{installsitelib}";
 190 my $installsitearch = "$destdir$Config{installsitearch}";
 191 my $installman1dir = "$destdir$Config{installman1dir}";
 192 my $man1ext = $Config{man1ext};
 193 my $libperl = $Config{libperl};
 194 # Shared library and dynamic loading suffixes.
 195 my $so = $Config{so};
 196 my $dlext = $Config{dlext};
 197 my $dlsrc = $Config{dlsrc};
 198 if ($^O eq 'os390') {
 199     my $pwd;
 200     chomp($pwd=`pwd`);
 201     my $archlibexp = $Config{archlibexp};
 202     my $usedl = $Config{usedl};
 203     if ($usedl eq 'define') {
 204         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 205     }
 206 }
 207
 208 if ($nwinstall) {
 209     # This is required only if we are installing on a NetWare server
 210     $installscript = $Config{installnwscripts};
 211     $installprivlib = $Config{installnwlib};
 212     $installarchlib = $Config{installnwlib};
 213     $installsitelib = $Config{installnwlib};
 214 }
 215
 216 my $d_dosuid = $Config{d_dosuid};
 217 my $binexp = $Config{binexp};
 218
 219 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 220     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 221               \$installarchlib, \$installsitelib, \$installsitearch,
 222               \$installman1dir ) {
 223         $$_ = unixify($$_);  $$_ =~ s:/$::;
 224     }
 225 }
 226
 227 # Do some quick sanity checks.
 228
 229 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 230
 231    $installbin          || die "No installbin directory in config.sh\n";
 232 -d $installbin          || mkpath($installbin, $verbose, 0777);
 233 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 234 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 235         unless $installbin =~ m#^/afs/# || $nonono;
 236
 237 if (!$Is_NetWare) {
 238 if (!$Is_VMS) {
 239 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 240 }
 241 else {
 242 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 243     if ($dbg) {
 244         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 245     }
 246 }
 247 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 248
 249 -f 't/rantests'         || $Is_W32
 250                         || warn "WARNING: You've never run 'make test' or",
 251                                 " some tests failed! (Installing anyway.)\n";
 252 } #if (!$Is_NetWare)
 253
 254 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 255     my $perldll;
 256
 257     if ($Is_Cygwin) {
 258         $perldll = $libperl;
 259         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 260         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 261         $perldll =~ s/^lib/cyg/;
 262         if ($Config{useshrplib} eq 'true') {
 263             # install ld2 and perlld as well
 264             foreach ('ld2', 'perlld') {
 265                 safe_unlink("$installbin/$_");
 266                 copy("$_", "$installbin/$_");
 267                 chmod(0755, "$installbin/$_");
 268             };
 269             open (LD2, ">$installbin/ld2");
 270             print LD2 <<SHELL;
 271 #!/bin/sh
 272 #
 273 # ld wrapper, passes all args to perlld;
 274 #
 275 for trythis in $installbin/perl
 276 do
 277   if [ -x \$trythis ]
 278   then
 279     \$trythis $installbin/perlld "\$\@"
 280     exit \$?
 281   fi
 282 done
 283 # hard luck!
 284 echo I see no perl executable around there
 285 echo perl is required to build dynamic libraries
 286 echo look if the path to perl in /bin/ld2 is correct
 287 exit 1
 288 SHELL
 289             close LD2;
 290             chmod(0755, "$installbin/ld2");
 291         };
 292     } else {
 293         $perldll = 'perl59.' . $dlext;
 294     }
 295
 296     if ($dlsrc ne "dl_none.xs") {
 297         -f $perldll || die "No perl DLL built\n";
 298     }
 299
 300     # Install the DLL
 301     safe_unlink("$installbin/$perldll");
 302     copy("$perldll", "$installbin/$perldll");
 303     chmod(0755, "$installbin/$perldll");
 304 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 305
 306 # This will be used to store the packlist
 307 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 308
 309 # First we install the version-numbered executables.
 310
 311 if ($Is_VMS) {
 312     safe_unlink("$installbin/$dbg$perl$exe_ext");
 313     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 314     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 315     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 316     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 317     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 318     if ($ndbg) {
 319        safe_unlink("$installbin/$ndbg$perl$exe_ext");
 320        copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 321        chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 322     }
 323 }
 324 elsif ($^O eq 'mpeix') {
 325     # MPE lacks hard links and requires that executables with special
 326     # capabilities reside in the MPE namespace.
 327     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 328     # Install the primary executable into the MPE namespace as perlpath.
 329     copy("perl$exe_ext", $Config{perlpath});
 330     chmod(0755, $Config{perlpath});
 331     # Create a backup copy with the version number.
 332     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 333 }
 334 elsif ($^O ne 'dos') {
 335     if (!$Is_NetWare) {
 336         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 337         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 338         strip("$installbin/$perl_verbase$ver$exe_ext");
 339         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 340     }
 341     else {
 342         # If installing onto a NetWare server
 343         if ($nwinstall) {
 344             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 345             mkpath($Config{installnwsystem}, 1, 0777);
 346             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 347             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 348             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 349             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 350             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 351             mkpath($Config{installnwlcgi}, 1, 0777);
 352             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 353         }
 354     } #if (!$Is_NetWare)
 355 }
 356 else {
 357     safe_unlink("$installbin/$perl.exe");
 358     copy("perl.exe", "$installbin/$perl.exe");
 359 }
 360
 361 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 362 if ($d_dosuid) {
 363     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 364     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 365 }
 366
 367 # Install library files.
 368
 369 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 370
 371 mkpath($installprivlib, $verbose, 0777);
 372 mkpath($installarchlib, $verbose, 0777);
 373 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 374 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 375
 376 if (chdir "lib") {
 377     $do_installarchlib = ! samepath($installarchlib, '.');
 378     $do_installprivlib = ! samepath($installprivlib, '.');
 379     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 380
 381     if ($do_installarchlib || $do_installprivlib) {
 382         find(\&installlib, '.');
 383     }
 384     chdir ".." || die "Can't cd back to source directory: $!\n";
 385 }
 386 else {
 387     warn "Can't cd to lib to install lib files: $!\n";
 388 }
 389
 390 # Install header files and libraries.
 391 mkpath("$installarchlib/CORE", $verbose, 0777);
 392 my @corefiles;
 393 if ($Is_VMS) {  # We did core file selection during build
 394     my $coredir = "lib/$Config{archname}/$ver/CORE";
 395     $coredir =~ tr/./_/;
 396     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 397 }
 398 else {
 399     # [als] hard-coded 'libperl' name... not good!
 400     @corefiles = <*.h libperl*.*>;
 401
 402     # AIX needs perl.exp installed as well.
 403     push(@corefiles,'perl.exp') if $^O eq 'aix';
 404     if ($^O eq 'mpeix') {
 405         # MPE needs mpeixish.h installed as well.
 406         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 407         push(@corefiles,'mpeix/mpeixish.h');
 408     }
 409     # If they have built sperl.o...
 410     push(@corefiles,'sperl.o') if -f 'sperl.o';
 411 }
 412 foreach my $file (@corefiles) {
 413     # HP-UX (at least) needs to maintain execute permissions
 414     # on dynamically-loadable libraries. So we do it for all.
 415     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 416         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 417             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 418             chmod(0555, "$installarchlib/CORE/$file");
 419         } else {
 420             chmod(0444, "$installarchlib/CORE/$file");
 421         }
 422     }
 423 }
 424
 425 # Install main perl executables
 426 # Make links to ordinary names if installbin directory isn't current directory.
 427
 428 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 429     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 430     if ($^O eq 'mpeix') {
 431         # MPE doesn't support hard links, so use a symlink.
 432         # We don't want another cloned copy.
 433         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 434     } elsif ($^O eq 'vos') {
 435         # VOS doesn't support hard links, so use a symlink.
 436         symlink("$installbin/$perl_verbase$ver$exe_ext",
 437                 "$installbin/$perl$exe_ext");
 438     } else {
 439         link("$installbin/$perl_verbase$ver$exe_ext",
 440                 "$installbin/$perl$exe_ext");
 441     }
 442     link("$installbin/s$perl_verbase$ver$exe_ext",
 443             "$installbin/suid$perl$exe_ext")
 444       if $d_dosuid;
 445 }
 446
 447 # For development purposes it can be very useful to have multiple perls
 448 # build for different "architectures" (eg threading or not) simultaneously.
 449 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 450     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 451     safe_unlink("$installbin/$archperl");
 452     if ($^O eq 'mpeix') {
 453         # MPE doesn't support hard links, so use a symlink.
 454         # We don't want another cloned copy.
 455         symlink($Config{perlpath}, "$installbin/$archperl");
 456     } elsif ($^O eq 'vos') {
 457         # VOS doesn't support hard links, so use a symlink.
 458         symlink("$installbin/$perl_verbase$ver$exe_ext",
 459                 "$installbin/$archperl");
 460     } else {
 461         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 462     }
 463 }
 464
 465 # Offer to install perl in a "standard" location
 466
 467 my $mainperl_is_instperl = 0;
 468
 469 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 470     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 471         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 472     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 473     my($instperl)       = "$installbin/$perl$exe_ext";
 474     my($expinstperl)    = "$binexp/$perl$exe_ext";
 475
 476     # First make sure $usrbinperl is not already the same as the perl we
 477     # just installed.
 478     if (-x $usrbinperl) {
 479         # Try to be clever about mainperl being a symbolic link
 480         # to binexp/perl if binexp and installbin are different.
 481         $mainperl_is_instperl =
 482             samepath($usrbinperl, $instperl) ||
 483             samepath($usrbinperl, $expinstperl) ||
 484              (($binexp ne $installbin) &&
 485               (-l $usrbinperl) &&
 486               ((readlink $usrbinperl) eq $expinstperl));
 487     }
 488     if (! $mainperl_is_instperl) {
 489         unlink($usrbinperl);
 490         ( $Config{'d_link'} eq 'define' &&
 491           eval { CORE::link $instperl, $usrbinperl } )  ||
 492         eval { symlink $expinstperl, $usrbinperl }      ||
 493         copy($instperl, $usrbinperl);
 494
 495         $mainperl_is_instperl = 1;
 496     }
 497 }
 498
 499 # Make links to ordinary names if installbin directory isn't current directory.
 500 if (!$Is_NetWare) {
 501     if (! samepath($installbin, 'x2p')) {
 502         my $base = 'a2p';
 503         $base .= $ver if $versiononly;
 504         safe_unlink("$installbin/$base$exe_ext");
 505         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 506         strip("$installbin/$base$exe_ext");
 507         chmod(0755, "$installbin/$base$exe_ext");
 508     }
 509 }
 510
 511 # cppstdin is just a script, but it is architecture-dependent, so
 512 # it can't safely be shared.  Place it in $installbin.
 513 # Note that Configure doesn't build cppstin if it isn't needed, so
 514 # we skip this if cppstdin doesn't exist.
 515 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 516     safe_unlink("$installbin/cppstdin");
 517     copy("cppstdin", "$installbin/cppstdin");
 518     chmod(0755, "$installbin/cppstdin");
 519 }
 520
 521 sub script_alias {
 522     my ($installscript, $orig, $alias, $scr_ext) = @_;
 523
 524     safe_unlink("$installscript/$alias$scr_ext");
 525     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 526         copy("$installscript/$orig$scr_ext",
 527              "$installscript/$alias$scr_ext");
 528     } elsif ($^O eq 'vos') {
 529         symlink("$installscript/$orig$scr_ext",
 530                 "$installscript/$alias$scr_ext");
 531     } else {
 532         link("$installscript/$orig$scr_ext",
 533              "$installscript/$alias$scr_ext");
 534     }
 535 }
 536
 537 # Install scripts.
 538 mkpath($installscript, $verbose, 0777);
 539 if ($versiononly) {
 540     for (@scripts) {
 541         (my $base = $_) =~ s#.*/##;
 542         $base .= $ver;
 543         copy($_,    "$installscript/$base");
 544         chmod(0755, "$installscript/$base");
 545     }
 546
 547     for (@tolink) {
 548         my ($from, $to) = map { "$_$ver" } @$_;
 549         (my $frbase = $from) =~ s#.*/##;
 550         (my $tobase = $to) =~ s#.*/##;
 551         script_alias($installscript, $frbase, $tobase, $scr_ext);
 552     }
 553 } else {
 554     for (@scripts) {
 555         (my $base = $_) =~ s#.*/##;
 556         copy($_, "$installscript/$base");
 557         chmod(0755, "$installscript/$base");
 558     }
 559
 560     for (@tolink) {
 561         my ($from, $to) = @$_;
 562         (my $frbase = $from) =~ s#.*/##;
 563         (my $tobase = $to) =~ s#.*/##;
 564         script_alias($installscript, $frbase, $tobase, $scr_ext);
 565     }
 566 }
 567
 568 # Install pod pages.  Where? I guess in $installprivlib/pod
 569 # ($installprivlib/pods for cygwin).
 570
 571 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 572 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 573     mkpath("${installprivlib}/$pod", $verbose, 0777);
 574
 575     # If Perl 5.003's perldiag.pod is there, rename it.
 576     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 577         read POD, $_, 4000;
 578         close POD;
 579         # Some of Perl 5.003's diagnostic messages ended with periods.
 580         if (/^=.*\.$/m) {
 581             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 582                                "${installprivlib}/$pod/perldiag-5.003.pod");
 583             print "  rename $from $to";
 584             rename($from, $to)
 585                 or warn "Couldn't rename $from to $to: $!\n"
 586                 unless $nonono;
 587         }
 588     }
 589
 590     for (@pods) {
 591         # $_ is a name like  pod/perl.pod
 592         (my $base = $_) =~ s#.*/##;
 593         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 594     }
 595
 596 }
 597
 598 # Check to make sure there aren't other perls around in installer's
 599 # path.  This is probably UNIX-specific.  Check all absolute directories
 600 # in the path except for where public executables are supposed to live.
 601 # Also skip $mainperl if the user opted to have it be a link to the
 602 # installed perl.
 603
 604 if (!$versiononly && $otherperls) {
 605     my ($path, @path);
 606     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 607     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 608     @path = split(/$dirsep/, $path);
 609     if ($Is_VMS) {
 610         my $i = 0;
 611         while (exists $ENV{'DCL$PATH' . $i}) {
 612             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 613             push(@path,$dir);
 614         }
 615     }
 616     my @otherperls;
 617     my %otherperls;
 618     for (@path) {
 619         next unless m,^/,;
 620         # Use &samepath here because some systems have other dirs linked
 621         # to $mainperldir (like SunOS)
 622         next if samepath($_, $binexp);
 623         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 624         my $otherperl = "$_/$perl$exe_ext";
 625         next if $otherperls{$otherperl}++;
 626         push(@otherperls, $otherperl)
 627             if (-x $otherperl && ! -d $otherperl);
 628     }
 629     if (@otherperls) {
 630         warn "\nWarning: $perl appears in your path in the following " .
 631             "locations beyond where\nwe just installed it:\n";
 632         for (@otherperls) {
 633             warn "    ", $_, "\n";
 634         }
 635         warn "\n";
 636     }
 637
 638 }
 639
 640 $packlist->write() unless $nonono;
 641 print "  Installation complete\n" if $verbose;
 642
 643 exit 0;
 644
 645 ###############################################################################
 646
 647 sub yn {
 648     my($prompt) = @_;
 649     my($answer);
 650     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 651     print STDERR $prompt;
 652     chop($answer = <STDIN>);
 653     $answer = $default if $answer =~ m/^\s*$/;
 654     ($answer =~ m/^[yY]/);
 655 }
 656
 657 sub unlink {
 658     my(@names) = @_;
 659     my($cnt) = 0;
 660
 661     return scalar(@names) if $Is_VMS;
 662
 663     foreach my $name (@names) {
 664         next unless -e $name;
 665         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 666         print "  unlink $name\n" if $verbose;
 667         ( CORE::unlink($name) and ++$cnt
 668           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 669     }
 670     return $cnt;
 671 }
 672
 673 sub safe_unlink {
 674     return if $nonono or $Is_VMS;
 675     my @names = @_;
 676     foreach my $name (@names) {
 677         next unless -e $name;
 678         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 679         print "  unlink $name\n" if $verbose;
 680         next if CORE::unlink($name);
 681         warn "Couldn't unlink $name: $!\n";
 682         if ($! =~ /busy/i) {
 683             print "  mv $name $name.old\n" if $verbose;
 684             safe_rename($name, "$name.old")
 685                 or warn "Couldn't rename $name: $!\n";
 686         }
 687     }
 688 }
 689
 690 sub safe_rename {
 691     my($from,$to) = @_;
 692     if (-f $to and not unlink($to)) {
 693         my($i);
 694         for ($i = 1; $i < 50; $i++) {
 695             last if rename($to, "$to.$i");
 696         }
 697         warn("Cannot rename to `$to.$i': $!"), return 0
 698            if $i >= 50; # Give up!
 699     }
 700     link($from,$to) || return 0;
 701     unlink($from);
 702 }
 703
 704 sub link {
 705     my($from,$to) = @_;
 706     my($success) = 0;
 707
 708     my $xfrom = $from;
 709     $xfrom =~ s/^\Q$destdir\E// if $destdir;
 710     my $xto = $to;
 711     $xto =~ s/^\Q$destdir\E// if $destdir;
 712     print $verbose ? "  ln $xfrom $xto\n" : "  $xto\n" unless $silent;
 713     eval {
 714         CORE::link($from, $to)
 715             ? $success++
 716             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 717               ? die "AFS"  # okay inside eval {}
 718               : die "Couldn't link $from to $to: $!\n"
 719           unless $nonono;
 720         $packlist->{$xto} = { from => $xfrom, type => 'link' };
 721     };
 722     if ($@) {
 723         warn $@;
 724         print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 725         print "  creating new version of $xto\n"
 726                  if $Is_VMS and -e $to and !$silent;
 727         File::Copy::copy($from, $to)
 728             ? $success++
 729             : warn "Couldn't copy $from to $to: $!\n"
 730           unless $nonono;
 731         $packlist->{$xto} = { type => 'file' };
 732     }
 733     $success;
 734 }
 735
 736 sub chmod {
 737     my($mode,$name) = @_;
 738
 739     return if ($^O eq 'dos');
 740     printf "  chmod %o %s\n", $mode, $name if $verbose;
 741     CORE::chmod($mode,$name)
 742         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 743       unless $nonono;
 744 }
 745
 746 sub copy {
 747     my($from,$to) = @_;
 748
 749     my $xto = $to;
 750     $xto =~ s/^\Q$destdir\E// if $destdir;
 751     print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 752     print "  creating new version of $xto\n" if $Is_VMS and -e $to and !$silent;
 753     File::Copy::copy($from, $to)
 754         || warn "Couldn't copy $from to $to: $!\n"
 755       unless $nonono;
 756     $packlist->{$xto} = { type => 'file' };
 757 }
 758
 759 sub samepath {
 760     my($p1, $p2) = @_;
 761
 762     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 763
 764     if ($p1 ne $p2) {
 765         my($dev1, $ino1, $dev2, $ino2);
 766         ($dev1, $ino1) = stat($p1);
 767         ($dev2, $ino2) = stat($p2);
 768         ($dev1 == $dev2 && $ino1 == $ino2);
 769     }
 770     else {
 771         1;
 772     }
 773 }
 774
 775 sub installlib {
 776     my $dir = $File::Find::dir;
 777     $dir =~ s#^\.(?![^/])/?##;
 778     local($depth) = $dir ? "lib/$dir" : "lib";
 779
 780     my $name = $_;
 781
 782     # Ignore version control directories.
 783     if (($name eq 'CVS' or $name eq 'RCS' or $name eq '.svn') and -d $name) {
 784         $File::Find::prune = 1;
 785         return;
 786     }
 787
 788     # ignore patch backups, RCS files, emacs backup & temp files and the
 789     # .exists files, .PL files, and test files.
 790     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$} ||
 791               $dir  =~ m{/t(?:/|$)};
 792     # ignore the cpan script in lib/CPAN/bin (installed later with other utils)
 793     return if $name eq 'cpan';
 794     # ignore the test extensions
 795     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 796
 797     $name = "$dir/$name" if $dir ne '';
 798
 799     my $installlib = $installprivlib;
 800     if ($dir =~ /^auto/ ||
 801           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 802           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
 803        ) {
 804         $installlib = $installarchlib;
 805         return unless $do_installarchlib;
 806     } else {
 807         return unless $do_installprivlib;
 808     }
 809
 810     if (-f $_) {
 811         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 812             $installlib = $installprivlib;
 813             #We're installing *.al and *.ix files into $installprivlib,
 814             #but we have to delete old *.al and *.ix files from the 5.000
 815             #distribution:
 816             #This might not work because $archname might have changed.
 817             unlink("$installarchlib/$name");
 818         }
 819         my $xname = "$installlib/$name";
 820         $xname =~ s/^\Q$destdir\E// if $destdir;
 821         $packlist->{$xname} = { type => 'file' };
 822         if ($force || compare($_, "$installlib/$name") || $nonono) {
 823             unlink("$installlib/$name");
 824             mkpath("$installlib/$dir", $verbose, 0777);
 825             # HP-UX (at least) needs to maintain execute permissions
 826             # on dynamically-loaded libraries.
 827             if ($Is_NetWare && !$nwinstall) {
 828                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 829                 # if copied will give problems when building new extensions.
 830                 # Has to be copied if we are installing on a NetWare server and hence
 831                 # the check !$nwinstall
 832                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 833                     copy_if_diff($_, "$installlib/$name")
 834                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 835                                   "$installlib/$name");
 836                 }
 837            } else {
 838                 if (copy_if_diff($_, "$installlib/$name")) {
 839                     if ($name =~ /\.(so|$dlext)$/o) {
 840                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 841                         chmod(0555, "$installlib/$name");
 842                     } else {
 843                         strip("-S", "$installlib/$name")
 844                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 845                         chmod(0444, "$installlib/$name");
 846                     }
 847                 }
 848             } #if ($Is_NetWare)
 849         }
 850     }
 851 }
 852
 853 # Copy $from to $to, only if $from is different than $to.
 854 # Also preserve modification times for .a libraries.
 855 # On some systems, if you do
 856 #   ranlib libperl.a
 857 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 858 # and then try to link against the installed libperl.a, you might
 859 # get an error message to the effect that the symbol table is older
 860 # than the library.
 861 # Return true if copying occurred.
 862
 863 sub copy_if_diff {
 864     my($from,$to)=@_;
 865     return 1 if (($^O eq 'VMS') && (-d $from));
 866     my $xto = $to;
 867     $xto =~ s/^\Q$destdir\E// if $destdir;
 868     my $perlpodbadsymlink;
 869     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 870         -l $from &&
 871         ! -e $from) {
 872         # Some Linux implementations have problems traversing over
 873         # multiple symlinks (when going over NFS?) and fail to read
 874         # the symlink target.  Combine this with the fact that some
 875         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 876         # and you end up with those pods not getting installed.
 877         $perlpodbadsymlink = 1;
 878     }
 879     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 880     $packlist->{$xto} = { type => 'file' };
 881     if ($force || compare($from, $to) || $nonono) {
 882         safe_unlink($to);   # In case we don't have write permissions.
 883         if ($nonono) {
 884             $from = $depth . "/" . $from if $depth;
 885         }
 886         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 887             $from = "README.$1";
 888         }
 889         copy($from, $to);
 890         # Restore timestamps if it's a .a library or for OS/2.
 891         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 892             my ($atime, $mtime) = (stat $from)[8,9];
 893             utime $atime, $mtime, $to;
 894         }
 895         1;
 896     }
 897 }
 898
 899 sub strip
 900 {
 901     my(@args) = @_;
 902
 903     return unless $dostrip;
 904
 905     my @opts;
 906     while (@args && $args[0] =~ /^(-\w+)$/) {
 907         push @opts, shift @args;
 908     }
 909
 910     foreach my $file (@args) {
 911         if (-f $file) {
 912             if ($verbose) {
 913                 print "  strip " . join(' ', @opts);
 914                 print " " if (@opts);
 915                 print "$file\n";
 916             }
 917             system("strip", @opts, $file);
 918         } else {
 919             print "# file '$file' skipped\n" if $verbose;
 920         }
 921     }
 922 }