installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose,
  13     $otherperls, $archname,$Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41         $Is_W32 = 0;
  42         $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63
  64 $otherperls = 1;
  65 while (@ARGV) {
  66     $nonono = 1 if $ARGV[0] eq '-n';
  67     $dostrip = 1 if $ARGV[0] eq '-s';
  68     $versiononly = 1 if $ARGV[0] eq '-v';
  69     $versiononly = 0 if $ARGV[0] eq '+v';
  70     $silent = 1 if $ARGV[0] eq '-S';
  71     $otherperls = 0 if $ARGV[0] eq '-o';
  72     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  73     $archname = 1 if $ARGV[0] eq '-A';
  74         $nwinstall = 1 if $ARGV[0] eq '-netware';
  75     $nopods = 1 if $ARGV[0] eq '-p';
  76     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  77       print <<"EOT";
  78 Usage $0: [switches]
  79   -n        Don't actually run any commands; just print them.
  80   -s        Run strip on installed binaries.
  81   -v        Only install perl as a binary with the version number in the name.
  82             (Override whatever config.sh says)
  83   +v        Install perl as "perl" and as a binary with the version number in
  84             the name.  (Override whatever config.sh says)
  85   -S        Silent mode.
  86   -o        Skip checking for other copies of perl in your PATH.
  87   -V        Verbose mode.
  88   -A        Also install perl with the architecture's name in the perl binary's
  89             name.
  90   -p        Don't install the pod files. [This will break use diagnostics;]
  91   -netware  Install correctly on a Netware server.
  92 EOT
  93       exit;
  94     }
  95     shift;
  96 }
  97
  98 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
  99 my (@scripts, @tolink);
 100 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 101 while (<SCRIPTS>) {
 102     next if /^#/;
 103     next if /#\s*pod\s*=/; # Binary programs need separate treatment
 104     chomp;
 105     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 106         push @scripts, $1;
 107         push @tolink, [$1, $2];
 108     } else {
 109         push @scripts, $_;
 110     }
 111 }
 112 close SCRIPTS;
 113
 114 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 115
 116 my @pods = $nopods ? () : (<pod/*.pod>);
 117
 118 # Specify here any .pm files that are actually architecture-dependent.
 119 # (Those included with XS extensions under ext/ are automatically
 120 # added later.)
 121 # Now that the default privlib has the full perl version number included,
 122 # we no longer have to play the trick of sticking version-specific .pm
 123 # files under the archlib directory.
 124 my %archpms = (
 125     Config => 1,
 126     lib => 1,
 127     Cwd => 1,
 128 );
 129
 130 if ($^O eq 'dos') {
 131     push(@scripts,'djgpp/fixpmain');
 132     $archpms{config} = $archpms{filehand} = 1;
 133 }
 134
 135 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
 136 {
 137         push(@scripts, map("$_.exe", @scripts));
 138 }
 139
 140 find(sub {
 141         if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 142             my($path, $modname) = ($1,$2);
 143
 144             # strip trailing component first
 145             $path =~ s{/[^/]*$}{};
 146
 147             # strip optional "/lib";
 148             $path =~ s{/lib\b}{};
 149
 150             # strip any leading /
 151             $path =~ s{^/}{};
 152
 153             # reconstitute canonical module name
 154             $modname = "$path/$modname" if length $path;
 155
 156             # remember it
 157             $archpms{$modname} = 1;
 158         }
 159     }, 'ext');
 160
 161 # print "[$_]\n" for sort keys %archpms;
 162
 163 my $ver = $Config{version};
 164 my $release = substr($],0,3);   # Not used currently.
 165 my $patchlevel = substr($],3,2);
 166 die "Patchlevel of perl ($patchlevel)",
 167     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 168         if $patchlevel != $Config{'PERL_VERSION'};
 169
 170 # Fetch some frequently-used items from %Config
 171 my $installbin = $Config{installbin};
 172 my $installscript = $Config{installscript};
 173 my $installprivlib = $Config{installprivlib};
 174 my $installarchlib = $Config{installarchlib};
 175 my $installsitelib = $Config{installsitelib};
 176 my $installsitearch = $Config{installsitearch};
 177 my $installman1dir = $Config{installman1dir};
 178 my $man1ext = $Config{man1ext};
 179 my $libperl = $Config{libperl};
 180 # Shared library and dynamic loading suffixes.
 181 my $so = $Config{so};
 182 my $dlext = $Config{dlext};
 183 my $dlsrc = $Config{dlsrc};
 184 if ($^O eq 'os390') {
 185     my $pwd;
 186     chomp($pwd=`pwd`);
 187     my $archlibexp = $Config{archlibexp};
 188     my $usedl = $Config{usedl};
 189     if ($usedl eq 'define') {
 190         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 191     }
 192 }
 193
 194 if ($nwinstall) {
 195         # This is required only if we are installing on a NetWare server
 196         $installscript = $Config{installnwscripts};
 197         $installprivlib = $Config{installnwlib};
 198         $installarchlib = $Config{installnwlib};
 199         $installsitelib = $Config{installnwlib};
 200 }
 201
 202 my $d_dosuid = $Config{d_dosuid};
 203 my $binexp = $Config{binexp};
 204
 205 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 206     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 207               \$installarchlib, \$installsitelib, \$installsitearch,
 208               \$installman1dir ) {
 209       $$_ = unixify($$_);  $$_ =~ s:/$::;
 210     }
 211 }
 212
 213 # Do some quick sanity checks.
 214
 215 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 216
 217    $installbin          || die "No installbin directory in config.sh\n";
 218 -d $installbin          || mkpath($installbin, $verbose, 0777);
 219 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 220 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 221         unless $installbin =~ m#^/afs/# || $nonono;
 222
 223 if (!$Is_NetWare) {
 224 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 225 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 226
 227 -f 't/rantests'         || $Is_W32
 228                         || warn "WARNING: You've never run 'make test' or",
 229                                 " some tests failed! (Installing anyway.)\n";
 230 } #if (!$Is_NetWare)
 231
 232 if (($Is_W32 and ! $Is_NetWare)  or $Is_Cygwin) {
 233   my $perldll;
 234
 235   if ($Is_Cygwin) {
 236     $perldll = $libperl;
 237     my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 238     $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 239     $perldll =~ s/^lib/cyg/;
 240     if ($Config{useshrplib} eq 'true') {
 241       # install ld2 and perlld as well
 242       foreach ('ld2', 'perlld') {
 243         safe_unlink("$installbin/$_");
 244         copy("$_", "$installbin/$_");
 245         chmod(0755, "$installbin/$_");
 246       };
 247       {
 248                 open (LD2, ">$installbin/ld2");
 249                 print LD2 "#!/bin/sh\n#\n# ld wrapper, passes all args to perlld;\n#\n"
 250                           . "for trythis in $installbin/perl\ndo\n  if [ -x \$trythis ]\n"
 251                           . "  then\n    \$trythis $installbin/perlld \"\$\@\"\n"
 252                           . "    exit \$?\n  fi\ndone\n# hard luck!\necho i see no perl"
 253                           . " executable around there\necho perl is required to build "
 254                           . "dynamic libraries\necho look if the path to perl in /bin/ld2"
 255                           . " is correct\nexit 1\n";
 256                 close LD2;
 257       };
 258       chmod(0755, "$installbin/ld2");
 259     };
 260   } else {
 261     $perldll = 'perl58.' . $dlext;
 262   }
 263
 264   if ($dlsrc ne "dl_none.xs") {
 265     -f $perldll || die "No perl DLL built\n";
 266   }
 267   # Install the DLL
 268
 269   safe_unlink("$installbin/$perldll");
 270   copy("$perldll", "$installbin/$perldll");
 271   chmod(0755, "$installbin/$perldll");
 272
 273 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 274
 275 # This will be used to store the packlist
 276 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 277
 278 # First we install the version-numbered executables.
 279
 280 if ($Is_VMS) {
 281     safe_unlink("$installbin/$perl$exe_ext");
 282     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 283     chmod(0755, "$installbin/$perl$exe_ext");
 284     safe_unlink("$installbin/${perl}shr$exe_ext");
 285     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 286     chmod(0755, "$installbin/${perl}shr$exe_ext");
 287 }
 288 elsif ($^O eq 'mpeix') {
 289     # MPE lacks hard links and requires that executables with special
 290     # capabilities reside in the MPE namespace.
 291     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 292     # Install the primary executable into the MPE namespace as perlpath.
 293     copy("perl$exe_ext", $Config{perlpath});
 294     chmod(0755, $Config{perlpath});
 295     # Create a backup copy with the version number.
 296     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 297 }
 298 elsif ($^O ne 'dos') {
 299         if (!$Is_NetWare) {
 300                 safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 301                 copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 302                 strip("$installbin/$perl_verbase$ver$exe_ext");
 303                 chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 304         }
 305         else {
 306                 # If installing onto a NetWare server
 307                 if ($nwinstall) {
 308                         # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 309                         mkpath($Config{installnwsystem}, 1, 0777);
 310                         copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 311                         copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 312                         copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 313                         copy("x2p\\a2p.nlm", $Config{installnwsystem});
 314                         chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 315                         mkpath($Config{installnwlcgi}, 1, 0777);
 316                         copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 317                 }
 318         } #if (!$Is_NetWare)
 319 }
 320 else {
 321     safe_unlink("$installbin/$perl.exe");
 322     copy("perl.exe", "$installbin/$perl.exe");
 323 }
 324
 325 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 326 if ($d_dosuid) {
 327     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 328     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 329 }
 330
 331 # Install library files.
 332
 333 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 334
 335 mkpath($installprivlib, $verbose, 0777);
 336 mkpath($installarchlib, $verbose, 0777);
 337 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 338 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 339
 340 if (chdir "lib") {
 341     $do_installarchlib = ! samepath($installarchlib, '.');
 342     $do_installprivlib = ! samepath($installprivlib, '.');
 343     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 344
 345     if ($do_installarchlib || $do_installprivlib) {
 346         find(\&installlib, '.');
 347     }
 348     chdir ".." || die "Can't cd back to source directory: $!\n";
 349 }
 350 else {
 351     warn "Can't cd to lib to install lib files: $!\n";
 352 }
 353
 354 # Install header files and libraries.
 355 mkpath("$installarchlib/CORE", $verbose, 0777);
 356 my @corefiles;
 357 if ($Is_VMS) {  # We did core file selection during build
 358     my $coredir = "lib/$Config{archname}/$ver/CORE";
 359     $coredir =~ tr/./_/;
 360     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 361 }
 362 else {
 363     # [als] hard-coded 'libperl' name... not good!
 364     @corefiles = <*.h libperl*.*>;
 365
 366     # AIX needs perl.exp installed as well.
 367     push(@corefiles,'perl.exp') if $^O eq 'aix';
 368     if ($^O eq 'mpeix') {
 369         # MPE needs mpeixish.h installed as well.
 370         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 371         push(@corefiles,'mpeix/mpeixish.h');
 372     }
 373     # If they have built sperl.o...
 374     push(@corefiles,'sperl.o') if -f 'sperl.o';
 375 }
 376 foreach my $file (@corefiles) {
 377     # HP-UX (at least) needs to maintain execute permissions
 378     # on dynamically-loadable libraries. So we do it for all.
 379     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 380         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 381             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 382            chmod(0555, "$installarchlib/CORE/$file");
 383         } else {
 384             chmod(0444, "$installarchlib/CORE/$file");
 385         }
 386     }
 387 }
 388
 389 # Install main perl executables
 390 # Make links to ordinary names if installbin directory isn't current directory.
 391
 392 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 393     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 394     if ($^O eq 'mpeix') {
 395         # MPE doesn't support hard links, so use a symlink.
 396         # We don't want another cloned copy.
 397         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 398     } elsif ($^O eq 'vos') {
 399         # VOS doesn't support hard links, so use a symlink.
 400         symlink("$installbin/$perl_verbase$ver$exe_ext",
 401                 "$installbin/$perl$exe_ext");
 402     } else {
 403         link("$installbin/$perl_verbase$ver$exe_ext",
 404                 "$installbin/$perl$exe_ext");
 405     }
 406     link("$installbin/s$perl_verbase$ver$exe_ext",
 407             "$installbin/suid$perl$exe_ext")
 408       if $d_dosuid;
 409 }
 410
 411 # For development purposes it can be very useful to have multiple perls
 412 # build for different "architectures" (eg threading or not) simultaneously.
 413 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 414     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 415     safe_unlink("$installbin/$archperl");
 416     if ($^O eq 'mpeix') {
 417         # MPE doesn't support hard links, so use a symlink.
 418         # We don't want another cloned copy.
 419         symlink($Config{perlpath}, "$installbin/$archperl");
 420     } elsif ($^O eq 'vos') {
 421         # VOS doesn't support hard links, so use a symlink.
 422         symlink("$installbin/$perl_verbase$ver$exe_ext",
 423                 "$installbin/$archperl");
 424     } else {
 425         link("$installbin/$perl_verbase$ver$exe_ext",
 426                 "$installbin/$archperl");
 427     }
 428 }
 429
 430 # Offer to install perl in a "standard" location
 431
 432 my $mainperl_is_instperl = 0;
 433
 434 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 435     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 436         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 437     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 438     my($instperl)       = "$installbin/$perl$exe_ext";
 439     my($expinstperl)    = "$binexp/$perl$exe_ext";
 440
 441     # First make sure $usrbinperl is not already the same as the perl we
 442     # just installed.
 443     if (-x $usrbinperl) {
 444         # Try to be clever about mainperl being a symbolic link
 445         # to binexp/perl if binexp and installbin are different.
 446         $mainperl_is_instperl =
 447             samepath($usrbinperl, $instperl) ||
 448             samepath($usrbinperl, $expinstperl) ||
 449              (($binexp ne $installbin) &&
 450               (-l $usrbinperl) &&
 451               ((readlink $usrbinperl) eq $expinstperl));
 452     }
 453     if (! $mainperl_is_instperl) {
 454         unlink($usrbinperl);
 455         ( $Config{'d_link'} eq 'define' &&
 456           eval { CORE::link $instperl, $usrbinperl } )  ||
 457         eval { symlink $expinstperl, $usrbinperl }      ||
 458         copy($instperl, $usrbinperl);
 459
 460         $mainperl_is_instperl = 1;
 461     }
 462 }
 463
 464 # Make links to ordinary names if installbin directory isn't current directory.
 465 if (!$Is_NetWare) {
 466         if (!$versiononly && ! samepath($installbin, 'x2p')) {
 467                 safe_unlink("$installbin/a2p$exe_ext");
 468                 copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 469                strip("$installbin/a2p$exe_ext");
 470                 chmod(0755, "$installbin/a2p$exe_ext");
 471         }
 472 }
 473
 474 # cppstdin is just a script, but it is architecture-dependent, so
 475 # it can't safely be shared.  Place it in $installbin.
 476 # Note that Configure doesn't build cppstin if it isn't needed, so
 477 # we skip this if cppstdin doesn't exist.
 478 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 479     safe_unlink("$installbin/cppstdin");
 480     copy("cppstdin", "$installbin/cppstdin");
 481     chmod(0755, "$installbin/cppstdin");
 482 }
 483
 484 sub script_alias {
 485     my ($installscript, $orig, $alias, $scr_ext) = @_;
 486
 487     safe_unlink("$installscript/$alias$scr_ext");
 488     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 489         copy("$installscript/$orig$scr_ext",
 490              "$installscript/$alias$scr_ext");
 491     } elsif ($^O eq 'vos') {
 492         symlink("$installscript/$orig$scr_ext",
 493                 "$installscript/$alias$scr_ext");
 494     } else {
 495         link("$installscript/$orig$scr_ext",
 496              "$installscript/$alias$scr_ext");
 497     }
 498 }
 499
 500 # Install scripts.
 501 mkpath($installscript, $verbose, 0777);
 502 if ($versiononly) {
 503     for (@scripts) {
 504         (my $base = $_) =~ s#.*/##;
 505         $base .= $ver;
 506         copy($_,    "$installscript/$base");
 507         chmod(0755, "$installscript/$base");
 508     }
 509
 510     for (@tolink) {
 511         my ($from, $to) = map { "$_$ver" } @$_;
 512         (my $frbase = $from) =~ s#.*/##;
 513         (my $tobase = $to) =~ s#.*/##;
 514         script_alias($installscript, $frbase, $tobase, $scr_ext);
 515     }
 516 } else {
 517     for (@scripts) {
 518         (my $base = $_) =~ s#.*/##;
 519         copy($_, "$installscript/$base");
 520         chmod(0755, "$installscript/$base");
 521     }
 522
 523     for (@tolink) {
 524         my ($from, $to) = @$_;
 525         (my $frbase = $from) =~ s#.*/##;
 526         (my $tobase = $to) =~ s#.*/##;
 527         script_alias($installscript, $frbase, $tobase, $scr_ext);
 528     }
 529 }
 530
 531 # Install pod pages.  Where? I guess in $installprivlib/pod
 532 # ($installprivlib/pods for cygwin).
 533
 534 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 535 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 536     mkpath("${installprivlib}/$pod", $verbose, 0777);
 537
 538     # If Perl 5.003's perldiag.pod is there, rename it.
 539     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 540         read POD, $_, 4000;
 541         close POD;
 542         # Some of Perl 5.003's diagnostic messages ended with periods.
 543         if (/^=.*\.$/m) {
 544             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 545                                "${installprivlib}/$pod/perldiag-5.003.pod");
 546             print "  rename $from $to";
 547             rename($from, $to)
 548                 or warn "Couldn't rename $from to $to: $!\n"
 549                 unless $nonono;
 550         }
 551     }
 552
 553     for (@pods) {
 554         # $_ is a name like  pod/perl.pod
 555         (my $base = $_) =~ s#.*/##;
 556         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 557     }
 558
 559 }
 560
 561 # Check to make sure there aren't other perls around in installer's
 562 # path.  This is probably UNIX-specific.  Check all absolute directories
 563 # in the path except for where public executables are supposed to live.
 564 # Also skip $mainperl if the user opted to have it be a link to the
 565 # installed perl.
 566
 567 if (!$versiononly && $otherperls) {
 568     my ($path, @path);
 569     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 570     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 571     @path = split(/$dirsep/, $path);
 572     if ($Is_VMS) {
 573         my $i = 0;
 574         while (exists $ENV{'DCL$PATH' . $i}) {
 575             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 576             push(@path,$dir);
 577         }
 578     }
 579     my @otherperls;
 580     my %otherperls;
 581     for (@path) {
 582         next unless m,^/,;
 583         # Use &samepath here because some systems have other dirs linked
 584         # to $mainperldir (like SunOS)
 585         next if samepath($_, $binexp);
 586         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 587         my $otherperl = "$_/$perl$exe_ext";
 588         next if $otherperls{$otherperl}++;
 589         push(@otherperls, $otherperl)
 590             if (-x $otherperl && ! -d $otherperl);
 591     }
 592     if (@otherperls) {
 593         warn "\nWarning: $perl appears in your path in the following " .
 594             "locations beyond where\nwe just installed it:\n";
 595         for (@otherperls) {
 596             warn "    ", $_, "\n";
 597         }
 598         warn "\n";
 599     }
 600
 601 }
 602
 603 $packlist->write() unless $nonono;
 604 print "  Installation complete\n" if $verbose;
 605
 606 exit 0;
 607
 608 ###############################################################################
 609
 610 sub yn {
 611     my($prompt) = @_;
 612     my($answer);
 613     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 614     print STDERR $prompt;
 615     chop($answer = <STDIN>);
 616     $answer = $default if $answer =~ m/^\s*$/;
 617     ($answer =~ m/^[yY]/);
 618 }
 619
 620 sub unlink {
 621     my(@names) = @_;
 622     my($cnt) = 0;
 623
 624     return scalar(@names) if $Is_VMS;
 625
 626     foreach my $name (@names) {
 627         next unless -e $name;
 628         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 629         print "  unlink $name\n" if $verbose;
 630         ( CORE::unlink($name) and ++$cnt
 631           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 632     }
 633     return $cnt;
 634 }
 635
 636 sub safe_unlink {
 637     return if $nonono or $Is_VMS;
 638     my @names = @_;
 639     foreach my $name (@names) {
 640         next unless -e $name;
 641         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 642         print "  unlink $name\n" if $verbose;
 643         next if CORE::unlink($name);
 644         warn "Couldn't unlink $name: $!\n";
 645         if ($! =~ /busy/i) {
 646             print "  mv $name $name.old\n" if $verbose;
 647             safe_rename($name, "$name.old")
 648                 or warn "Couldn't rename $name: $!\n";
 649         }
 650     }
 651 }
 652
 653 sub safe_rename {
 654     my($from,$to) = @_;
 655     if (-f $to and not unlink($to)) {
 656         my($i);
 657         for ($i = 1; $i < 50; $i++) {
 658             last if rename($to, "$to.$i");
 659         }
 660         warn("Cannot rename to `$to.$i': $!"), return 0
 661            if $i >= 50; # Give up!
 662     }
 663     link($from,$to) || return 0;
 664     unlink($from);
 665 }
 666
 667 sub link {
 668     my($from,$to) = @_;
 669     my($success) = 0;
 670
 671     print $verbose ? "  ln $from $to\n" : "  $to\n" unless $silent;
 672     eval {
 673         CORE::link($from, $to)
 674             ? $success++
 675             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 676               ? die "AFS"  # okay inside eval {}
 677               : die "Couldn't link $from to $to: $!\n"
 678           unless $nonono;
 679         $packlist->{$to} = { from => $from, type => 'link' };
 680     };
 681     if ($@) {
 682         warn $@;
 683         print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 684         print "  creating new version of $to\n"
 685                  if $Is_VMS and -e $to and !$silent;
 686         File::Copy::copy($from, $to)
 687             ? $success++
 688             : warn "Couldn't copy $from to $to: $!\n"
 689           unless $nonono;
 690         $packlist->{$to} = { type => 'file' };
 691     }
 692     $success;
 693 }
 694
 695 sub chmod {
 696     my($mode,$name) = @_;
 697
 698     return if ($^O eq 'dos');
 699     printf "  chmod %o %s\n", $mode, $name if $verbose;
 700     CORE::chmod($mode,$name)
 701         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 702       unless $nonono;
 703 }
 704
 705 sub copy {
 706     my($from,$to) = @_;
 707
 708     print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 709     print "  creating new version of $to\n" if $Is_VMS and -e $to and !$silent;
 710     File::Copy::copy($from, $to)
 711         || warn "Couldn't copy $from to $to: $!\n"
 712       unless $nonono;
 713     $packlist->{$to} = { type => 'file' };
 714 }
 715
 716 sub samepath {
 717     my($p1, $p2) = @_;
 718
 719     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 720
 721     if ($p1 ne $p2) {
 722         my($dev1, $ino1, $dev2, $ino2);
 723         ($dev1, $ino1) = stat($p1);
 724         ($dev2, $ino2) = stat($p2);
 725         ($dev1 == $dev2 && $ino1 == $ino2);
 726     }
 727     else {
 728         1;
 729     }
 730 }
 731
 732 sub installlib {
 733     my $dir = $File::Find::dir;
 734     $dir =~ s#^\.(?![^/])/?##;
 735     local($depth) = $dir ? "lib/$dir" : "lib";
 736
 737     my $name = $_;
 738
 739     # Ignore RCS and CVS directories.
 740     if (($name eq 'CVS' or $name eq 'RCS') and -d $name) {
 741         $File::Find::prune = 1;
 742         return;
 743     }
 744
 745     # ignore patch backups, RCS files, emacs backup & temp files and the
 746     # .exists files, .PL files, and .t files.
 747     return if $name =~ m{\.orig$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.t$} ||
 748               $dir  =~ m{/t(?:/|$)};
 749
 750     $name = "$dir/$name" if $dir ne '';
 751
 752     my $installlib = $installprivlib;
 753     if ($dir =~ /^auto/ ||
 754           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 755           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
 756        ) {
 757         $installlib = $installarchlib;
 758         return unless $do_installarchlib;
 759     } else {
 760         return unless $do_installprivlib;
 761     }
 762
 763     if (-f $_) {
 764         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 765             $installlib = $installprivlib;
 766             #We're installing *.al and *.ix files into $installprivlib,
 767             #but we have to delete old *.al and *.ix files from the 5.000
 768             #distribution:
 769             #This might not work because $archname might have changed.
 770             unlink("$installarchlib/$name");
 771         }
 772         $packlist->{"$installlib/$name"} = { type => 'file' };
 773         if (compare($_, "$installlib/$name") || $nonono) {
 774             unlink("$installlib/$name");
 775             mkpath("$installlib/$dir", $verbose, 0777);
 776             # HP-UX (at least) needs to maintain execute permissions
 777             # on dynamically-loaded libraries.
 778            if ($Is_NetWare && !$nwinstall) {
 779                # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 780                # if copied will give problems when building new extensions.
 781                # Has to be copied if we are installing on a NetWare server and hence
 782                # the check !$nwinstall
 783                if (!(/\.(?:nlp|nlm|bs)$/)) {
 784                    copy_if_diff($_, "$installlib/$name")
 785                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 786                                  "$installlib/$name");
 787                }
 788            } else {
 789                if (copy_if_diff($_, "$installlib/$name")) {
 790                    if ($name =~ /\.(so|$dlext)$/o) {
 791                        strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 792                        chmod(0555, "$installlib/$name");
 793                    } else {
 794                        strip("-S", "$installlib/$name")
 795                            if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 796                        chmod(0444, "$installlib/$name");
 797                    }
 798                }
 799            } #if ($Is_NetWare)
 800         }
 801     }
 802 }
 803
 804 # Copy $from to $to, only if $from is different than $to.
 805 # Also preserve modification times for .a libraries.
 806 # On some systems, if you do
 807 #   ranlib libperl.a
 808 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 809 # and then try to link against the installed libperl.a, you might
 810 # get an error message to the effect that the symbol table is older
 811 # than the library.
 812 # Return true if copying occurred.
 813
 814 sub copy_if_diff {
 815     my($from,$to)=@_;
 816     return 1 if (($^O eq 'VMS') && (-d $from));
 817     my $perlpodbadsymlink;
 818     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 819         -l $from &&
 820         ! -e $from) {
 821         # Some Linux implementations have problems traversing over
 822         # multiple symlinks (when going over NFS?) and fail to read
 823         # the symlink target.  Combine this with the fact that some
 824         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 825         # and you end up with those pods not getting installed.
 826         $perlpodbadsymlink = 1;
 827     }
 828     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 829     $packlist->{$to} = { type => 'file' };
 830     if (compare($from, $to) || $nonono) {
 831         safe_unlink($to);   # In case we don't have write permissions.
 832         if ($nonono) {
 833             $from = $depth . "/" . $from if $depth;
 834         }
 835         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 836             $from = "README.$1";
 837         }
 838         copy($from, $to);
 839         # Restore timestamps if it's a .a library or for OS/2.
 840         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 841             my ($atime, $mtime) = (stat $from)[8,9];
 842             utime $atime, $mtime, $to;
 843         }
 844         1;
 845     }
 846 }
 847
 848 sub strip
 849 {
 850     my(@args) = @_;
 851
 852     return unless $dostrip;
 853
 854     my @opts;
 855     while (@args && $args[0] =~ /^(-\w+)$/) {
 856         push @opts, shift @args;
 857     }
 858
 859     foreach my $file (@args) {
 860         if (-f $file) {
 861            if ($verbose) {
 862                print "  strip " . join(' ', @opts);
 863                print " " if (@opts);
 864                print "$file\n";
 865            }
 866             system("strip", @opts, $file);
 867         } else {
 868             print "# file '$file' skipped\n" if $verbose;
 869         }
 870     }
 871 }