installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  13     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41     $Is_W32 = 0;
  42     $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63
  64 $otherperls = 1;
  65 while (@ARGV) {
  66     $nonono = 1 if $ARGV[0] eq '-n';
  67     $dostrip = 1 if $ARGV[0] eq '-s';
  68     $versiononly = 1 if $ARGV[0] eq '-v';
  69     $versiononly = 0 if $ARGV[0] eq '+v';
  70     $silent = 1 if $ARGV[0] eq '-S';
  71     $otherperls = 0 if $ARGV[0] eq '-o';
  72     $force = 1 if $ARGV[0] eq '-f';
  73     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  74     $archname = 1 if $ARGV[0] eq '-A';
  75     $nwinstall = 1 if $ARGV[0] eq '-netware';
  76     $nopods = 1 if $ARGV[0] eq '-p';
  77     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  78         print <<"EOT";
  79 Usage $0: [switches]
  80   -n        Don't actually run any commands; just print them.
  81   -s        Run strip on installed binaries.
  82   -v        Only install perl as a binary with the version number in the name.
  83             (Override whatever config.sh says)
  84   +v        Install perl as "perl" and as a binary with the version number in
  85             the name.  (Override whatever config.sh says)
  86   -S        Silent mode.
  87   -f        Force installation (don't check if same version is there)
  88   -o        Skip checking for other copies of perl in your PATH.
  89   -V        Verbose mode.
  90   -A        Also install perl with the architecture's name in the perl binary's
  91             name.
  92   -p        Don't install the pod files. [This will break use diagnostics;]
  93   -netware  Install correctly on a Netware server.
  94 EOT
  95         exit;
  96     }
  97     shift;
  98 }
  99
 100 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 101 my (@scripts, @tolink);
 102 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 103 while (<SCRIPTS>) {
 104     next if /^#/;
 105     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 106     next if /a2p/; # a2p is binary, to be installed separately
 107     chomp;
 108     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 109         push @scripts, $1;
 110         push @tolink, [$1, $2];
 111     } else {
 112         push @scripts, $_;
 113     }
 114 }
 115 close SCRIPTS;
 116
 117 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 118
 119 my @pods = $nopods ? () : (<pod/*.pod>);
 120
 121 # Specify here any .pm files that are actually architecture-dependent.
 122 # (Those included with XS extensions under ext/ are automatically
 123 # added later.)
 124 # Now that the default privlib has the full perl version number included,
 125 # we no longer have to play the trick of sticking version-specific .pm
 126 # files under the archlib directory.
 127 my %archpms = (
 128     Config => 1,
 129     lib => 1,
 130     Cwd => 1,
 131 );
 132
 133 if ($^O eq 'dos') {
 134     push(@scripts,'djgpp/fixpmain');
 135     $archpms{config} = $archpms{filehand} = 1;
 136 }
 137
 138 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 139     push(@scripts, map("$_.exe", @scripts));
 140 }
 141
 142 find(sub {
 143     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 144         my($path, $modname) = ($1,$2);
 145
 146         # strip trailing component first
 147         $path =~ s{/[^/]*$}{};
 148
 149         # strip optional "/lib";
 150         $path =~ s{/lib\b}{};
 151
 152         # strip any leading /
 153         $path =~ s{^/}{};
 154
 155         # reconstitute canonical module name
 156         $modname = "$path/$modname" if length $path;
 157
 158         # remember it
 159         $archpms{$modname} = 1;
 160     }
 161 }, 'ext');
 162
 163 # print "[$_]\n" for sort keys %archpms;
 164
 165 my $ver = $Config{version};
 166 my $release = substr($],0,3);   # Not used currently.
 167 my $patchlevel = substr($],3,2);
 168 die "Patchlevel of perl ($patchlevel)",
 169     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 170         if $patchlevel != $Config{'PERL_VERSION'};
 171
 172 # Fetch some frequently-used items from %Config
 173 my $installbin = $Config{installbin};
 174 my $installscript = $Config{installscript};
 175 my $installprivlib = $Config{installprivlib};
 176 my $installarchlib = $Config{installarchlib};
 177 my $installsitelib = $Config{installsitelib};
 178 my $installsitearch = $Config{installsitearch};
 179 my $installman1dir = $Config{installman1dir};
 180 my $man1ext = $Config{man1ext};
 181 my $libperl = $Config{libperl};
 182 # Shared library and dynamic loading suffixes.
 183 my $so = $Config{so};
 184 my $dlext = $Config{dlext};
 185 my $dlsrc = $Config{dlsrc};
 186 if ($^O eq 'os390') {
 187     my $pwd;
 188     chomp($pwd=`pwd`);
 189     my $archlibexp = $Config{archlibexp};
 190     my $usedl = $Config{usedl};
 191     if ($usedl eq 'define') {
 192         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 193     }
 194 }
 195
 196 if ($nwinstall) {
 197     # This is required only if we are installing on a NetWare server
 198     $installscript = $Config{installnwscripts};
 199     $installprivlib = $Config{installnwlib};
 200     $installarchlib = $Config{installnwlib};
 201     $installsitelib = $Config{installnwlib};
 202 }
 203
 204 my $d_dosuid = $Config{d_dosuid};
 205 my $binexp = $Config{binexp};
 206
 207 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 208     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 209               \$installarchlib, \$installsitelib, \$installsitearch,
 210               \$installman1dir ) {
 211         $$_ = unixify($$_);  $$_ =~ s:/$::;
 212     }
 213 }
 214
 215 # Do some quick sanity checks.
 216
 217 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 218
 219    $installbin          || die "No installbin directory in config.sh\n";
 220 -d $installbin          || mkpath($installbin, $verbose, 0777);
 221 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 222 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 223         unless $installbin =~ m#^/afs/# || $nonono;
 224
 225 if (!$Is_NetWare) {
 226 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 227 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 228
 229 -f 't/rantests'         || $Is_W32
 230                         || warn "WARNING: You've never run 'make test' or",
 231                                 " some tests failed! (Installing anyway.)\n";
 232 } #if (!$Is_NetWare)
 233
 234 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 235     my $perldll;
 236
 237     if ($Is_Cygwin) {
 238         $perldll = $libperl;
 239         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 240         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 241         $perldll =~ s/^lib/cyg/;
 242         if ($Config{useshrplib} eq 'true') {
 243             # install ld2 and perlld as well
 244             foreach ('ld2', 'perlld') {
 245                 safe_unlink("$installbin/$_");
 246                 copy("$_", "$installbin/$_");
 247                 chmod(0755, "$installbin/$_");
 248             };
 249             open (LD2, ">$installbin/ld2");
 250             print LD2 <<SHELL;
 251 #!/bin/sh
 252 #
 253 # ld wrapper, passes all args to perlld;
 254 #
 255 for trythis in $installbin/perl
 256 do
 257   if [ -x \$trythis ]
 258   then
 259     \$trythis $installbin/perlld "\$\@"
 260     exit \$?
 261   fi
 262 done
 263 # hard luck!
 264 echo I see no perl executable around there
 265 echo perl is required to build dynamic libraries
 266 echo look if the path to perl in /bin/ld2 is correct
 267 exit 1
 268 SHELL
 269             close LD2;
 270             chmod(0755, "$installbin/ld2");
 271         };
 272     } else {
 273         $perldll = 'perl59.' . $dlext;
 274     }
 275
 276     if ($dlsrc ne "dl_none.xs") {
 277         -f $perldll || die "No perl DLL built\n";
 278     }
 279
 280     # Install the DLL
 281     safe_unlink("$installbin/$perldll");
 282     copy("$perldll", "$installbin/$perldll");
 283     chmod(0755, "$installbin/$perldll");
 284 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 285
 286 # This will be used to store the packlist
 287 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 288
 289 # First we install the version-numbered executables.
 290
 291 if ($Is_VMS) {
 292     safe_unlink("$installbin/$perl$exe_ext");
 293     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 294     chmod(0755, "$installbin/$perl$exe_ext");
 295     safe_unlink("$installbin/${perl}shr$exe_ext");
 296     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 297     chmod(0755, "$installbin/${perl}shr$exe_ext");
 298 }
 299 elsif ($^O eq 'mpeix') {
 300     # MPE lacks hard links and requires that executables with special
 301     # capabilities reside in the MPE namespace.
 302     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 303     # Install the primary executable into the MPE namespace as perlpath.
 304     copy("perl$exe_ext", $Config{perlpath});
 305     chmod(0755, $Config{perlpath});
 306     # Create a backup copy with the version number.
 307     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 308 }
 309 elsif ($^O ne 'dos') {
 310     if (!$Is_NetWare) {
 311         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 312         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 313         strip("$installbin/$perl_verbase$ver$exe_ext");
 314         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 315     }
 316     else {
 317         # If installing onto a NetWare server
 318         if ($nwinstall) {
 319             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 320             mkpath($Config{installnwsystem}, 1, 0777);
 321             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 322             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 323             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 324             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 325             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 326             mkpath($Config{installnwlcgi}, 1, 0777);
 327             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 328         }
 329     } #if (!$Is_NetWare)
 330 }
 331 else {
 332     safe_unlink("$installbin/$perl.exe");
 333     copy("perl.exe", "$installbin/$perl.exe");
 334 }
 335
 336 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 337 if ($d_dosuid) {
 338     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 339     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 340 }
 341
 342 # Install library files.
 343
 344 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 345
 346 mkpath($installprivlib, $verbose, 0777);
 347 mkpath($installarchlib, $verbose, 0777);
 348 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 349 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 350
 351 if (chdir "lib") {
 352     $do_installarchlib = ! samepath($installarchlib, '.');
 353     $do_installprivlib = ! samepath($installprivlib, '.');
 354     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 355
 356     if ($do_installarchlib || $do_installprivlib) {
 357         find(\&installlib, '.');
 358     }
 359     chdir ".." || die "Can't cd back to source directory: $!\n";
 360 }
 361 else {
 362     warn "Can't cd to lib to install lib files: $!\n";
 363 }
 364
 365 # Install header files and libraries.
 366 mkpath("$installarchlib/CORE", $verbose, 0777);
 367 my @corefiles;
 368 if ($Is_VMS) {  # We did core file selection during build
 369     my $coredir = "lib/$Config{archname}/$ver/CORE";
 370     $coredir =~ tr/./_/;
 371     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 372 }
 373 else {
 374     # [als] hard-coded 'libperl' name... not good!
 375     @corefiles = <*.h libperl*.*>;
 376
 377     # AIX needs perl.exp installed as well.
 378     push(@corefiles,'perl.exp') if $^O eq 'aix';
 379     if ($^O eq 'mpeix') {
 380         # MPE needs mpeixish.h installed as well.
 381         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 382         push(@corefiles,'mpeix/mpeixish.h');
 383     }
 384     # If they have built sperl.o...
 385     push(@corefiles,'sperl.o') if -f 'sperl.o';
 386 }
 387 foreach my $file (@corefiles) {
 388     # HP-UX (at least) needs to maintain execute permissions
 389     # on dynamically-loadable libraries. So we do it for all.
 390     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 391         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 392             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 393             chmod(0555, "$installarchlib/CORE/$file");
 394         } else {
 395             chmod(0444, "$installarchlib/CORE/$file");
 396         }
 397     }
 398 }
 399
 400 # Install main perl executables
 401 # Make links to ordinary names if installbin directory isn't current directory.
 402
 403 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 404     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 405     if ($^O eq 'mpeix') {
 406         # MPE doesn't support hard links, so use a symlink.
 407         # We don't want another cloned copy.
 408         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 409     } elsif ($^O eq 'vos') {
 410         # VOS doesn't support hard links, so use a symlink.
 411         symlink("$installbin/$perl_verbase$ver$exe_ext",
 412                 "$installbin/$perl$exe_ext");
 413     } else {
 414         link("$installbin/$perl_verbase$ver$exe_ext",
 415                 "$installbin/$perl$exe_ext");
 416     }
 417     link("$installbin/s$perl_verbase$ver$exe_ext",
 418             "$installbin/suid$perl$exe_ext")
 419       if $d_dosuid;
 420 }
 421
 422 # For development purposes it can be very useful to have multiple perls
 423 # build for different "architectures" (eg threading or not) simultaneously.
 424 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 425     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 426     safe_unlink("$installbin/$archperl");
 427     if ($^O eq 'mpeix') {
 428         # MPE doesn't support hard links, so use a symlink.
 429         # We don't want another cloned copy.
 430         symlink($Config{perlpath}, "$installbin/$archperl");
 431     } elsif ($^O eq 'vos') {
 432         # VOS doesn't support hard links, so use a symlink.
 433         symlink("$installbin/$perl_verbase$ver$exe_ext",
 434                 "$installbin/$archperl");
 435     } else {
 436         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 437     }
 438 }
 439
 440 # Offer to install perl in a "standard" location
 441
 442 my $mainperl_is_instperl = 0;
 443
 444 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 445     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 446         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 447     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 448     my($instperl)       = "$installbin/$perl$exe_ext";
 449     my($expinstperl)    = "$binexp/$perl$exe_ext";
 450
 451     # First make sure $usrbinperl is not already the same as the perl we
 452     # just installed.
 453     if (-x $usrbinperl) {
 454         # Try to be clever about mainperl being a symbolic link
 455         # to binexp/perl if binexp and installbin are different.
 456         $mainperl_is_instperl =
 457             samepath($usrbinperl, $instperl) ||
 458             samepath($usrbinperl, $expinstperl) ||
 459              (($binexp ne $installbin) &&
 460               (-l $usrbinperl) &&
 461               ((readlink $usrbinperl) eq $expinstperl));
 462     }
 463     if (! $mainperl_is_instperl) {
 464         unlink($usrbinperl);
 465         ( $Config{'d_link'} eq 'define' &&
 466           eval { CORE::link $instperl, $usrbinperl } )  ||
 467         eval { symlink $expinstperl, $usrbinperl }      ||
 468         copy($instperl, $usrbinperl);
 469
 470         $mainperl_is_instperl = 1;
 471     }
 472 }
 473
 474 # Make links to ordinary names if installbin directory isn't current directory.
 475 if (!$Is_NetWare) {
 476     if (! samepath($installbin, 'x2p')) {
 477         my $base = 'a2p';
 478         $base .= $ver if $versiononly;
 479         safe_unlink("$installbin/$base$exe_ext");
 480         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 481         strip("$installbin/$base$exe_ext");
 482         chmod(0755, "$installbin/$base$exe_ext");
 483     }
 484 }
 485
 486 # cppstdin is just a script, but it is architecture-dependent, so
 487 # it can't safely be shared.  Place it in $installbin.
 488 # Note that Configure doesn't build cppstin if it isn't needed, so
 489 # we skip this if cppstdin doesn't exist.
 490 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 491     safe_unlink("$installbin/cppstdin");
 492     copy("cppstdin", "$installbin/cppstdin");
 493     chmod(0755, "$installbin/cppstdin");
 494 }
 495
 496 sub script_alias {
 497     my ($installscript, $orig, $alias, $scr_ext) = @_;
 498
 499     safe_unlink("$installscript/$alias$scr_ext");
 500     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 501         copy("$installscript/$orig$scr_ext",
 502              "$installscript/$alias$scr_ext");
 503     } elsif ($^O eq 'vos') {
 504         symlink("$installscript/$orig$scr_ext",
 505                 "$installscript/$alias$scr_ext");
 506     } else {
 507         link("$installscript/$orig$scr_ext",
 508              "$installscript/$alias$scr_ext");
 509     }
 510 }
 511
 512 # Install scripts.
 513 mkpath($installscript, $verbose, 0777);
 514 if ($versiononly) {
 515     for (@scripts) {
 516         (my $base = $_) =~ s#.*/##;
 517         $base .= $ver;
 518         copy($_,    "$installscript/$base");
 519         chmod(0755, "$installscript/$base");
 520     }
 521
 522     for (@tolink) {
 523         my ($from, $to) = map { "$_$ver" } @$_;
 524         (my $frbase = $from) =~ s#.*/##;
 525         (my $tobase = $to) =~ s#.*/##;
 526         script_alias($installscript, $frbase, $tobase, $scr_ext);
 527     }
 528 } else {
 529     for (@scripts) {
 530         (my $base = $_) =~ s#.*/##;
 531         copy($_, "$installscript/$base");
 532         chmod(0755, "$installscript/$base");
 533     }
 534
 535     for (@tolink) {
 536         my ($from, $to) = @$_;
 537         (my $frbase = $from) =~ s#.*/##;
 538         (my $tobase = $to) =~ s#.*/##;
 539         script_alias($installscript, $frbase, $tobase, $scr_ext);
 540     }
 541 }
 542
 543 # Install pod pages.  Where? I guess in $installprivlib/pod
 544 # ($installprivlib/pods for cygwin).
 545
 546 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 547 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 548     mkpath("${installprivlib}/$pod", $verbose, 0777);
 549
 550     # If Perl 5.003's perldiag.pod is there, rename it.
 551     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 552         read POD, $_, 4000;
 553         close POD;
 554         # Some of Perl 5.003's diagnostic messages ended with periods.
 555         if (/^=.*\.$/m) {
 556             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 557                                "${installprivlib}/$pod/perldiag-5.003.pod");
 558             print "  rename $from $to";
 559             rename($from, $to)
 560                 or warn "Couldn't rename $from to $to: $!\n"
 561                 unless $nonono;
 562         }
 563     }
 564
 565     for (@pods) {
 566         # $_ is a name like  pod/perl.pod
 567         (my $base = $_) =~ s#.*/##;
 568         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 569     }
 570
 571 }
 572
 573 # Check to make sure there aren't other perls around in installer's
 574 # path.  This is probably UNIX-specific.  Check all absolute directories
 575 # in the path except for where public executables are supposed to live.
 576 # Also skip $mainperl if the user opted to have it be a link to the
 577 # installed perl.
 578
 579 if (!$versiononly && $otherperls) {
 580     my ($path, @path);
 581     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 582     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 583     @path = split(/$dirsep/, $path);
 584     if ($Is_VMS) {
 585         my $i = 0;
 586         while (exists $ENV{'DCL$PATH' . $i}) {
 587             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 588             push(@path,$dir);
 589         }
 590     }
 591     my @otherperls;
 592     my %otherperls;
 593     for (@path) {
 594         next unless m,^/,;
 595         # Use &samepath here because some systems have other dirs linked
 596         # to $mainperldir (like SunOS)
 597         next if samepath($_, $binexp);
 598         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 599         my $otherperl = "$_/$perl$exe_ext";
 600         next if $otherperls{$otherperl}++;
 601         push(@otherperls, $otherperl)
 602             if (-x $otherperl && ! -d $otherperl);
 603     }
 604     if (@otherperls) {
 605         warn "\nWarning: $perl appears in your path in the following " .
 606             "locations beyond where\nwe just installed it:\n";
 607         for (@otherperls) {
 608             warn "    ", $_, "\n";
 609         }
 610         warn "\n";
 611     }
 612
 613 }
 614
 615 $packlist->write() unless $nonono;
 616 print "  Installation complete\n" if $verbose;
 617
 618 exit 0;
 619
 620 ###############################################################################
 621
 622 sub yn {
 623     my($prompt) = @_;
 624     my($answer);
 625     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 626     print STDERR $prompt;
 627     chop($answer = <STDIN>);
 628     $answer = $default if $answer =~ m/^\s*$/;
 629     ($answer =~ m/^[yY]/);
 630 }
 631
 632 sub unlink {
 633     my(@names) = @_;
 634     my($cnt) = 0;
 635
 636     return scalar(@names) if $Is_VMS;
 637
 638     foreach my $name (@names) {
 639         next unless -e $name;
 640         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 641         print "  unlink $name\n" if $verbose;
 642         ( CORE::unlink($name) and ++$cnt
 643           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 644     }
 645     return $cnt;
 646 }
 647
 648 sub safe_unlink {
 649     return if $nonono or $Is_VMS;
 650     my @names = @_;
 651     foreach my $name (@names) {
 652         next unless -e $name;
 653         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 654         print "  unlink $name\n" if $verbose;
 655         next if CORE::unlink($name);
 656         warn "Couldn't unlink $name: $!\n";
 657         if ($! =~ /busy/i) {
 658             print "  mv $name $name.old\n" if $verbose;
 659             safe_rename($name, "$name.old")
 660                 or warn "Couldn't rename $name: $!\n";
 661         }
 662     }
 663 }
 664
 665 sub safe_rename {
 666     my($from,$to) = @_;
 667     if (-f $to and not unlink($to)) {
 668         my($i);
 669         for ($i = 1; $i < 50; $i++) {
 670             last if rename($to, "$to.$i");
 671         }
 672         warn("Cannot rename to `$to.$i': $!"), return 0
 673            if $i >= 50; # Give up!
 674     }
 675     link($from,$to) || return 0;
 676     unlink($from);
 677 }
 678
 679 sub link {
 680     my($from,$to) = @_;
 681     my($success) = 0;
 682
 683     print $verbose ? "  ln $from $to\n" : "  $to\n" unless $silent;
 684     eval {
 685         CORE::link($from, $to)
 686             ? $success++
 687             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 688               ? die "AFS"  # okay inside eval {}
 689               : die "Couldn't link $from to $to: $!\n"
 690           unless $nonono;
 691         $packlist->{$to} = { from => $from, type => 'link' };
 692     };
 693     if ($@) {
 694         warn $@;
 695         print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 696         print "  creating new version of $to\n"
 697                  if $Is_VMS and -e $to and !$silent;
 698         File::Copy::copy($from, $to)
 699             ? $success++
 700             : warn "Couldn't copy $from to $to: $!\n"
 701           unless $nonono;
 702         $packlist->{$to} = { type => 'file' };
 703     }
 704     $success;
 705 }
 706
 707 sub chmod {
 708     my($mode,$name) = @_;
 709
 710     return if ($^O eq 'dos');
 711     printf "  chmod %o %s\n", $mode, $name if $verbose;
 712     CORE::chmod($mode,$name)
 713         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 714       unless $nonono;
 715 }
 716
 717 sub copy {
 718     my($from,$to) = @_;
 719
 720     print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 721     print "  creating new version of $to\n" if $Is_VMS and -e $to and !$silent;
 722     File::Copy::copy($from, $to)
 723         || warn "Couldn't copy $from to $to: $!\n"
 724       unless $nonono;
 725     $packlist->{$to} = { type => 'file' };
 726 }
 727
 728 sub samepath {
 729     my($p1, $p2) = @_;
 730
 731     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 732
 733     if ($p1 ne $p2) {
 734         my($dev1, $ino1, $dev2, $ino2);
 735         ($dev1, $ino1) = stat($p1);
 736         ($dev2, $ino2) = stat($p2);
 737         ($dev1 == $dev2 && $ino1 == $ino2);
 738     }
 739     else {
 740         1;
 741     }
 742 }
 743
 744 sub installlib {
 745     my $dir = $File::Find::dir;
 746     $dir =~ s#^\.(?![^/])/?##;
 747     local($depth) = $dir ? "lib/$dir" : "lib";
 748
 749     my $name = $_;
 750
 751     # Ignore version control directories.
 752     if (($name eq 'CVS' or $name eq 'RCS' or $name eq '.svn') and -d $name) {
 753         $File::Find::prune = 1;
 754         return;
 755     }
 756
 757     # ignore patch backups, RCS files, emacs backup & temp files and the
 758     # .exists files, .PL files, and test files.
 759     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.t$|^test\.pl$} ||
 760               $dir  =~ m{/t(?:/|$)};
 761     # ignore the cpan script in lib/CPAN/bin (installed later with other utils)
 762     return if $name eq 'cpan';
 763     # ignore the test extensions
 764     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 765
 766     $name = "$dir/$name" if $dir ne '';
 767
 768     my $installlib = $installprivlib;
 769     if ($dir =~ /^auto/ ||
 770           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 771           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
 772        ) {
 773         $installlib = $installarchlib;
 774         return unless $do_installarchlib;
 775     } else {
 776         return unless $do_installprivlib;
 777     }
 778
 779     if (-f $_) {
 780         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 781             $installlib = $installprivlib;
 782             #We're installing *.al and *.ix files into $installprivlib,
 783             #but we have to delete old *.al and *.ix files from the 5.000
 784             #distribution:
 785             #This might not work because $archname might have changed.
 786             unlink("$installarchlib/$name");
 787         }
 788         $packlist->{"$installlib/$name"} = { type => 'file' };
 789         if ($force || compare($_, "$installlib/$name") || $nonono) {
 790             unlink("$installlib/$name");
 791             mkpath("$installlib/$dir", $verbose, 0777);
 792             # HP-UX (at least) needs to maintain execute permissions
 793             # on dynamically-loaded libraries.
 794             if ($Is_NetWare && !$nwinstall) {
 795                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 796                 # if copied will give problems when building new extensions.
 797                 # Has to be copied if we are installing on a NetWare server and hence
 798                 # the check !$nwinstall
 799                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 800                     copy_if_diff($_, "$installlib/$name")
 801                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 802                                   "$installlib/$name");
 803                 }
 804            } else {
 805                 if (copy_if_diff($_, "$installlib/$name")) {
 806                     if ($name =~ /\.(so|$dlext)$/o) {
 807                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 808                         chmod(0555, "$installlib/$name");
 809                     } else {
 810                         strip("-S", "$installlib/$name")
 811                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 812                         chmod(0444, "$installlib/$name");
 813                     }
 814                 }
 815             } #if ($Is_NetWare)
 816         }
 817     }
 818 }
 819
 820 # Copy $from to $to, only if $from is different than $to.
 821 # Also preserve modification times for .a libraries.
 822 # On some systems, if you do
 823 #   ranlib libperl.a
 824 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 825 # and then try to link against the installed libperl.a, you might
 826 # get an error message to the effect that the symbol table is older
 827 # than the library.
 828 # Return true if copying occurred.
 829
 830 sub copy_if_diff {
 831     my($from,$to)=@_;
 832     return 1 if (($^O eq 'VMS') && (-d $from));
 833     my $perlpodbadsymlink;
 834     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 835         -l $from &&
 836         ! -e $from) {
 837         # Some Linux implementations have problems traversing over
 838         # multiple symlinks (when going over NFS?) and fail to read
 839         # the symlink target.  Combine this with the fact that some
 840         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 841         # and you end up with those pods not getting installed.
 842         $perlpodbadsymlink = 1;
 843     }
 844     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 845     $packlist->{$to} = { type => 'file' };
 846     if ($force || compare($from, $to) || $nonono) {
 847         safe_unlink($to);   # In case we don't have write permissions.
 848         if ($nonono) {
 849             $from = $depth . "/" . $from if $depth;
 850         }
 851         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 852             $from = "README.$1";
 853         }
 854         copy($from, $to);
 855         # Restore timestamps if it's a .a library or for OS/2.
 856         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 857             my ($atime, $mtime) = (stat $from)[8,9];
 858             utime $atime, $mtime, $to;
 859         }
 860         1;
 861     }
 862 }
 863
 864 sub strip
 865 {
 866     my(@args) = @_;
 867
 868     return unless $dostrip;
 869
 870     my @opts;
 871     while (@args && $args[0] =~ /^(-\w+)$/) {
 872         push @opts, shift @args;
 873     }
 874
 875     foreach my $file (@args) {
 876         if (-f $file) {
 877             if ($verbose) {
 878                 print "  strip " . join(' ', @opts);
 879                 print " " if (@opts);
 880                 print "$file\n";
 881             }
 882             system("strip", @opts, $file);
 883         } else {
 884             print "# file '$file' skipped\n" if $verbose;
 885         }
 886     }
 887 }