installperl

   1 #!./perl -w
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8
   9     # This needs to be at BEGIN time, before any use of Config
  10     require './install_lib.pl';
  11 }
  12
  13 use strict;
  14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
  15             %opts $packlist);
  16 my ($dostrip, $versiononly, $force,
  17     $otherperls, $archname, $nwinstall, $nopods);
  18 # Not sure how easy it would be to refactor to remove the need for local $depth
  19 # below
  20 use vars qw /$depth/;
  21
  22 BEGIN {
  23     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  24 }
  25
  26 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  27
  28 use File::Find;
  29 use File::Compare;
  30 use File::Copy ();
  31 use File::Path ();
  32 use ExtUtils::Packlist;
  33 use Cwd;
  34
  35 if ($Is_NetWare) {
  36     $Is_W32 = 0;
  37     $scr_ext = '.pl';
  38 }
  39
  40 # override the ones in the rest of the script
  41 sub mkpath {
  42     File::Path::mkpath(@_) unless $opts{notify};
  43 }
  44
  45 my $mainperldir = "/usr/bin";
  46 my $exe_ext = $Config{exe_ext};
  47
  48 # Allow "make install PERLNAME=something_besides_perl":
  49 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  50
  51 # This is the base used for versioned names, like "perl5.6.0".
  52 # It's separate because a common use of $PERLNAME is to install
  53 # perl as "perl5", if that's used as base for versioned files you
  54 # get "perl55.6.0".
  55 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  56                     ? $ENV{PERLNAME_VERBASE}
  57                     : $perl;
  58 my $dbg = '';
  59 my $ndbg = '';
  60 if ( $Is_VMS ) {
  61     if ( defined $Config{usevmsdebug} ) {
  62         if ( $Config{usevmsdebug} eq 'define' ) {
  63             $dbg = 'dbg';
  64             $ndbg = 'ndbg';
  65         }
  66     }
  67 }
  68
  69 $otherperls = 1;
  70 # This little hack simplifies making the code after the comment "Fetch some
  71 # frequently-used items from %Config" warning free. With $opts{destdir} always
  72 # defined, it's also possible to make the s/\Q$opts{destdir}\E unconditional.
  73
  74 $opts{destdir} = '';
  75 # Consider refactoring this to use Getopt::Long once Getopt::Long's planned
  76 # feature is implemented, to distinguish + and - options.
  77 while (@ARGV) {
  78     $opts{notify} = 1 if $ARGV[0] eq '-n';
  79     $dostrip = 1 if $ARGV[0] eq '-s';
  80     $versiononly = 1 if $ARGV[0] eq '-v';
  81     $versiononly = 0 if $ARGV[0] eq '+v';
  82     $opts{silent} = 1 if $ARGV[0] eq '-S';
  83     $otherperls = 0 if $ARGV[0] eq '-o';
  84     $force = 1 if $ARGV[0] eq '-f';
  85     $opts{verbose} = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  86     $archname = 1 if $ARGV[0] eq '-A';
  87     $nwinstall = 1 if $ARGV[0] eq '-netware';
  88     $nopods = 1 if $ARGV[0] eq '-p';
  89     $opts{destdir} = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
  90     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  91         print <<"EOT";
  92 Usage $0: [switches]
  93   -n        Don't actually run any commands; just print them.
  94   -s        Run strip on installed binaries.
  95   -v        Only install perl as a binary with the version number in the name.
  96             (Override whatever config.sh says)
  97   +v        Install perl as "perl" and as a binary with the version number in
  98             the name.  (Override whatever config.sh says)
  99   -S        Silent mode.
 100   -f        Force installation (don't check if same version is there)
 101   -o        Skip checking for other copies of perl in your PATH.
 102   -V        Verbose mode.
 103   -A        Also install perl with the architecture's name in the perl binary's
 104             name.
 105   -p        Don't install the pod files. [This will break use diagnostics;]
 106   -netware  Install correctly on a Netware server.
 107   -destdir  Prefix installation directories by this string.
 108 EOT
 109         exit;
 110     }
 111     shift;
 112 }
 113
 114 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 115 my (@scripts, @tolink);
 116 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 117 while (<SCRIPTS>) {
 118     next if /^#/;
 119     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 120     next if /a2p/; # a2p is binary, to be installed separately
 121     chomp;
 122     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 123         push @scripts, $1;
 124         push @tolink, [$1, $2];
 125     } else {
 126         push @scripts, $_;
 127     }
 128 }
 129 close SCRIPTS;
 130
 131 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 132
 133 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
 134
 135 # Specify here any .pm files that are actually architecture-dependent.
 136 # (Those included with XS extensions under ext/ are automatically
 137 # added later.)
 138 # Now that the default privlib has the full perl version number included,
 139 # we no longer have to play the trick of sticking version-specific .pm
 140 # files under the archlib directory.
 141 my %archpms = (
 142     Config => 1,
 143     lib => 1,
 144     Cwd => 1,
 145 );
 146
 147 if ($^O eq 'dos') {
 148     push(@scripts,'djgpp/fixpmain');
 149     $archpms{config} = $archpms{filehand} = 1;
 150 }
 151
 152 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 153     push(@scripts, map("$_.exe", @scripts));
 154 }
 155
 156 # Exclude nonxs extensions that are not architecture dependent
 157 my @nonxs = grep(!/^Errno$/, split(' ', $Config{'nonxs_ext'}));
 158
 159 my @ext_dirs = qw(cpan dist ext);
 160 foreach my $ext_dir (@ext_dirs) {
 161     find(sub {
 162         if (($File::Find::name =~ m{^$ext_dir\b(.*)/([^/]+)\.pm$}) &&
 163             ! grep { (my $dir = $_) =~ s/\//-/g;
 164                      $File::Find::name =~ /^$ext_dir\/$dir\// } @nonxs)
 165         {
 166             my($path, $modname) = ($1,$2);
 167
 168             # Change hypenated name like Filter-Util-Call to nested
 169             # directory name Filter/Util/Call
 170             $path =~ s{-}{/}g;
 171
 172             # strip to optional "/lib", or remove trailing component
 173             $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
 174
 175             # strip any leading /
 176             $path =~ s{^/}{};
 177
 178             # reconstitute canonical module name
 179             $modname = "$path/$modname" if length $path;
 180
 181             # remember it
 182             $archpms{$modname} = 1;
 183         }
 184     }, $ext_dir);
 185 }
 186
 187 # print "[$_]\n" for sort keys %archpms;
 188
 189 my $ver = $Config{version};
 190 my $release = substr($],0,3);   # Not used currently.
 191 my $patchlevel = substr($],3,2);
 192 die "Patchlevel of perl ($patchlevel)",
 193     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 194         if $patchlevel != $Config{'PERL_VERSION'};
 195
 196 # Fetch some frequently-used items from %Config
 197 my $installbin = "$opts{destdir}$Config{installbin}";
 198 my $installscript = "$opts{destdir}$Config{installscript}";
 199 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
 200 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
 201 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
 202 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
 203 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
 204 my $man1ext = $Config{man1ext};
 205 my $libperl = $Config{libperl};
 206 # Shared library and dynamic loading suffixes.
 207 my $so = $Config{so};
 208 my $dlext = $Config{dlext};
 209 my $dlsrc = $Config{dlsrc};
 210 if ($^O eq 'os390') {
 211     my $pwd;
 212     chomp($pwd=`pwd`);
 213     my $archlibexp = $Config{archlibexp};
 214     my $usedl = $Config{usedl};
 215     if ($usedl eq 'define') {
 216         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 217     }
 218 }
 219
 220 if ($nwinstall) {
 221     # This is required only if we are installing on a NetWare server
 222     $installscript = $Config{installnwscripts};
 223     $installprivlib = $Config{installnwlib};
 224     $installarchlib = $Config{installnwlib};
 225     $installsitelib = $Config{installnwlib};
 226 }
 227
 228 my $binexp = $Config{binexp};
 229
 230 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 231     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 232               \$installarchlib, \$installsitelib, \$installsitearch,
 233               \$installman1dir ) {
 234         $$_ = unixify($$_);  $$_ =~ s:/$::;
 235     }
 236 }
 237
 238 # Do some quick sanity checks.
 239
 240    $installbin          || die "No installbin directory in config.sh\n";
 241 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
 242 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
 243 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
 244         unless $installbin =~ m#^/afs/# || $opts{notify};
 245
 246 if (!$Is_NetWare) {
 247 if (!$Is_VMS) {
 248 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 249 }
 250 else {
 251 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 252     if ($dbg) {
 253         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 254     }
 255 }
 256
 257 -f 't/rantests'         || $Is_W32
 258                         || warn "WARNING: You've never run 'make test' or",
 259                                 " some tests failed! (Installing anyway.)\n";
 260 } #if (!$Is_NetWare)
 261
 262 # This will be used to store the packlist
 263 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 264
 265 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 266     my $perldll;
 267
 268     if ($Is_Cygwin) {
 269         $perldll = $libperl;
 270     } else {
 271         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
 272     }
 273
 274     if ($dlsrc ne "dl_none.xs") {
 275         -f $perldll || die "No perl DLL built\n";
 276     }
 277
 278     # Install the DLL
 279     safe_unlink("$installbin/$perldll");
 280     copy("$perldll", "$installbin/$perldll");
 281     chmod(0755, "$installbin/$perldll");
 282     $packlist->{"$installbin/$perldll"} = { type => 'file' };
 283 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 284
 285 # First we install the version-numbered executables.
 286
 287 if ($Is_VMS) {
 288     safe_unlink("$installbin/perl_setup.com");
 289     copy("perl_setup.com", "$installbin/perl_setup.com");
 290     chmod(0755, "$installbin/perl_setup.com");
 291     safe_unlink("$installbin/$dbg$perl$exe_ext");
 292     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 293     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 294     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 295     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 296     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 297     if ($ndbg) {
 298         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 299         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 300         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 301         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 302         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 303         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 304     }
 305 }
 306 elsif ($^O eq 'mpeix') {
 307     # MPE lacks hard links and requires that executables with special
 308     # capabilities reside in the MPE namespace.
 309     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 310     # Install the primary executable into the MPE namespace as perlpath.
 311     copy("perl$exe_ext", $Config{perlpath});
 312     chmod(0755, $Config{perlpath});
 313     # Create a backup copy with the version number.
 314     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 315 }
 316 elsif ($^O ne 'dos') {
 317     if (!$Is_NetWare) {
 318         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 319         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 320         strip("$installbin/$perl_verbase$ver$exe_ext");
 321         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 322     }
 323     else {
 324         # If installing onto a NetWare server
 325         if ($nwinstall) {
 326             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 327             mkpath($Config{installnwsystem}, 1, 0777);
 328             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 329             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 330             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 331             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 332             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 333             mkpath($Config{installnwlcgi}, 1, 0777);
 334             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 335         }
 336     } #if (!$Is_NetWare)
 337 }
 338 else {
 339     safe_unlink("$installbin/$perl.exe");
 340     copy("perl.exe", "$installbin/$perl.exe");
 341 }
 342
 343 # Install library files.
 344
 345 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 346 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
 347
 348 mkpath($installprivlib, $opts{verbose}, 0777);
 349 mkpath($installarchlib, $opts{verbose}, 0777);
 350 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
 351 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
 352
 353 if (chdir "lib") {
 354     $do_installarchlib = ! samepath($installarchlib, '.');
 355     $do_installprivlib = ! samepath($installprivlib, '.');
 356     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
 357
 358     if ($do_installarchlib || $do_installprivlib) {
 359         find(\&installlib, '.');
 360     }
 361     chdir ".." || die "Can't cd back to source directory: $!\n";
 362 }
 363 else {
 364     warn "Can't cd to lib to install lib files: $!\n";
 365 }
 366
 367 # Install header files and libraries.
 368 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
 369 my @corefiles;
 370 if ($Is_VMS) {  # We did core file selection during build
 371     my $coredir = "lib/$Config{archname}/$ver/CORE";
 372     $coredir =~ tr/./_/;
 373     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 374 }
 375 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
 376     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 377     my $coredll = "$installarchlib/CORE/$libperl";
 378     safe_unlink($coredll);
 379     ( $Config{'d_link'} eq 'define' &&
 380       eval {
 381           CORE::link("$installbin/$libperl", $coredll);
 382           $packlist->{$coredll} = { from => "$installbin/$libperl",
 383                                     type => 'link' };
 384       }
 385     ) ||
 386     eval {
 387         symlink("$installbin/$libperl", $coredll);
 388         $packlist->{$coredll} = { from => "$installbin/$libperl",
 389                                   type => 'link' };
 390     } ||
 391     ( copy("$installbin/$libperl", $coredll) &&
 392       push(@corefiles, $coredll)
 393     )
 394 } else {
 395     # [als] hard-coded 'libperl' name... not good!
 396     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 397
 398     # AIX needs perl.exp installed as well.
 399     push(@corefiles,'perl.exp') if $^O eq 'aix';
 400     if ($^O eq 'mpeix') {
 401         # MPE needs mpeixish.h installed as well.
 402         mkpath("$installarchlib/CORE/mpeix", $opts{verbose}, 0777);
 403         push(@corefiles,'mpeix/mpeixish.h');
 404     }
 405     # If they have built sperl.o...
 406     push(@corefiles,'sperl.o') if -f 'sperl.o';
 407 }
 408 foreach my $file (@corefiles) {
 409     # HP-UX (at least) needs to maintain execute permissions
 410     # on dynamically-loadable libraries. So we do it for all.
 411     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 412         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 413             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 414             chmod(0555, "$installarchlib/CORE/$file");
 415         } else {
 416             chmod(0444, "$installarchlib/CORE/$file");
 417         }
 418     }
 419 }
 420
 421 # Install main perl executables
 422 # Make links to ordinary names if installbin directory isn't current directory.
 423
 424 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 425     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 426     if ($^O eq 'mpeix') {
 427         # MPE doesn't support hard links, so use a symlink.
 428         # We don't want another cloned copy.
 429         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 430     } elsif ($^O eq 'vos') {
 431         # VOS doesn't support hard links, so use a symlink.
 432         symlink("$installbin/$perl_verbase$ver$exe_ext",
 433                 "$installbin/$perl$exe_ext");
 434     } else {
 435         link("$installbin/$perl_verbase$ver$exe_ext",
 436                 "$installbin/$perl$exe_ext");
 437     }
 438 }
 439
 440 # For development purposes it can be very useful to have multiple perls
 441 # build for different "architectures" (eg threading or not) simultaneously.
 442 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 443     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 444     safe_unlink("$installbin/$archperl");
 445     if ($^O eq 'mpeix') {
 446         # MPE doesn't support hard links, so use a symlink.
 447         # We don't want another cloned copy.
 448         symlink($Config{perlpath}, "$installbin/$archperl");
 449     } elsif ($^O eq 'vos') {
 450         # VOS doesn't support hard links, so use a symlink.
 451         symlink("$installbin/$perl_verbase$ver$exe_ext",
 452                 "$installbin/$archperl");
 453     } else {
 454         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 455     }
 456 }
 457
 458 # Offer to install perl in a "standard" location
 459
 460 my $mainperl_is_instperl = 0;
 461
 462 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 463     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 464         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 465     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 466     my($instperl)       = "$installbin/$perl$exe_ext";
 467     my($expinstperl)    = "$binexp/$perl$exe_ext";
 468
 469     # First make sure $usrbinperl is not already the same as the perl we
 470     # just installed.
 471     if (-x $usrbinperl) {
 472         # Try to be clever about mainperl being a symbolic link
 473         # to binexp/perl if binexp and installbin are different.
 474         $mainperl_is_instperl =
 475             samepath($usrbinperl, $instperl) ||
 476             samepath($usrbinperl, $expinstperl) ||
 477              (($binexp ne $installbin) &&
 478               (-l $usrbinperl) &&
 479               ((readlink $usrbinperl) eq $expinstperl));
 480     }
 481     if (! $mainperl_is_instperl) {
 482         unlink($usrbinperl);
 483         ( $Config{'d_link'} eq 'define' &&
 484           eval { CORE::link $instperl, $usrbinperl } )  ||
 485         eval { symlink $expinstperl, $usrbinperl }      ||
 486         copy($instperl, $usrbinperl);
 487
 488         $mainperl_is_instperl = 1;
 489     }
 490 }
 491
 492 # Make links to ordinary names if installbin directory isn't current directory.
 493 if (!$Is_NetWare && $dbg eq '') {
 494     if (! samepath($installbin, 'x2p')) {
 495         my $base = 'a2p';
 496         $base .= $ver if $versiononly;
 497         safe_unlink("$installbin/$base$exe_ext");
 498         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 499         strip("$installbin/$base$exe_ext");
 500         chmod(0755, "$installbin/$base$exe_ext");
 501     }
 502 }
 503
 504 # cppstdin is just a script, but it is architecture-dependent, so
 505 # it can't safely be shared.  Place it in $installbin.
 506 # Note that Configure doesn't build cppstin if it isn't needed, so
 507 # we skip this if cppstdin doesn't exist.
 508 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 509     safe_unlink("$installbin/cppstdin");
 510     copy("cppstdin", "$installbin/cppstdin");
 511     chmod(0755, "$installbin/cppstdin");
 512 }
 513
 514 sub script_alias {
 515     my ($installscript, $orig, $alias, $scr_ext) = @_;
 516
 517     safe_unlink("$installscript/$alias$scr_ext");
 518     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 519         copy("$installscript/$orig$scr_ext",
 520              "$installscript/$alias$scr_ext");
 521     } elsif ($^O eq 'vos') {
 522         symlink("$installscript/$orig$scr_ext",
 523                 "$installscript/$alias$scr_ext");
 524     } else {
 525         link("$installscript/$orig$scr_ext",
 526              "$installscript/$alias$scr_ext");
 527     }
 528 }
 529
 530 # Install scripts.
 531 mkpath($installscript, $opts{verbose}, 0777);
 532 if ($versiononly) {
 533     for (@scripts) {
 534         (my $base = $_) =~ s#.*/##;
 535         $base .= $ver;
 536         copy($_,    "$installscript/$base");
 537         chmod(0755, "$installscript/$base");
 538     }
 539
 540     for (@tolink) {
 541         my ($from, $to) = map { "$_$ver" } @$_;
 542         (my $frbase = $from) =~ s#.*/##;
 543         (my $tobase = $to) =~ s#.*/##;
 544         script_alias($installscript, $frbase, $tobase, $scr_ext);
 545     }
 546 } else {
 547     for (@scripts) {
 548         (my $base = $_) =~ s#.*/##;
 549         copy($_, "$installscript/$base");
 550         chmod(0755, "$installscript/$base");
 551     }
 552
 553     for (@tolink) {
 554         my ($from, $to) = @$_;
 555         (my $frbase = $from) =~ s#.*/##;
 556         (my $tobase = $to) =~ s#.*/##;
 557         script_alias($installscript, $frbase, $tobase, $scr_ext);
 558     }
 559 }
 560
 561 # Install pod pages.  Where? I guess in $installprivlib/pod
 562 # ($installprivlib/pods for cygwin).
 563
 564 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
 565 if ( !$versiononly || ($installprivlib =~ m/\Q$vershort/)) {
 566     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
 567
 568     # If Perl 5.003's perldiag.pod is there, rename it.
 569     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 570         read POD, $_, 4000;
 571         close POD;
 572         # Some of Perl 5.003's diagnostic messages ended with periods.
 573         if (/^=.*\.$/m) {
 574             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 575                                "${installprivlib}/$pod/perldiag-5.003.pod");
 576             print "  rename $from $to";
 577             rename($from, $to)
 578                 or warn "Couldn't rename $from to $to: $!\n"
 579                 unless $opts{notify};
 580         }
 581     }
 582
 583     for (@pods) {
 584         # $_ is a name like  pod/perl.pod
 585         (my $base = $_) =~ s#.*/##;
 586         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 587     }
 588
 589 }
 590
 591 # Check to make sure there aren't other perls around in installer's
 592 # path.  This is probably UNIX-specific.  Check all absolute directories
 593 # in the path except for where public executables are supposed to live.
 594 # Also skip $mainperl if the user opted to have it be a link to the
 595 # installed perl.
 596
 597 if (!$versiononly && $otherperls) {
 598     my ($path, @path);
 599     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 600     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 601     @path = split(/$dirsep/, $path);
 602     if ($Is_VMS) {
 603         my $i = 0;
 604         while (exists $ENV{'DCL$PATH' . $i}) {
 605             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 606             push(@path,$dir);
 607         }
 608     }
 609     my @otherperls;
 610     my %otherperls;
 611     for (@path) {
 612         next unless m,^/,;
 613         # Use &samepath here because some systems have other dirs linked
 614         # to $mainperldir (like SunOS)
 615         next unless -d;
 616         next if samepath($_, $binexp);
 617         next if samepath($_, cwd());
 618         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 619         my $otherperl = "$_/$perl$exe_ext";
 620         next if $otherperls{$otherperl}++;
 621         push(@otherperls, $otherperl)
 622             if (-x $otherperl && ! -d $otherperl);
 623     }
 624     if (@otherperls) {
 625         warn "\nWarning: $perl appears in your path in the following " .
 626             "locations beyond where\nwe just installed it:\n";
 627         for (@otherperls) {
 628             warn "    ", $_, "\n";
 629         }
 630         warn "\n";
 631     }
 632
 633 }
 634
 635 $packlist->write() unless $opts{notify};
 636 print "  Installation complete\n" if $opts{verbose};
 637
 638 exit 0;
 639
 640 ###############################################################################
 641
 642 # If these are needed elsewhere, move them into install_lib.pl rather than
 643 # copying them.
 644
 645 sub yn {
 646     my($prompt) = @_;
 647     my($answer);
 648     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 649     print STDERR $prompt;
 650     chop($answer = <STDIN>);
 651     $answer = $default if $answer =~ m/^\s*$/;
 652     ($answer =~ m/^[yY]/);
 653 }
 654
 655 sub safe_unlink {
 656     return if $opts{notify} or $Is_VMS;
 657     my @names = @_;
 658     foreach my $name (@names) {
 659         next unless -e $name;
 660         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 661         print "  unlink $name\n" if $opts{verbose};
 662         next if CORE::unlink($name);
 663         warn "Couldn't unlink $name: $!\n";
 664         if ($! =~ /busy/i) {
 665             print "  mv $name $name.old\n" if $opts{verbose};
 666             safe_rename($name, "$name.old")
 667                 or warn "Couldn't rename $name: $!\n";
 668         }
 669     }
 670 }
 671
 672 sub safe_rename {
 673     my($from,$to) = @_;
 674     if (-f $to and not unlink($to)) {
 675         my($i);
 676         for ($i = 1; $i < 50; $i++) {
 677             last if rename($to, "$to.$i");
 678         }
 679         warn("Cannot rename to `$to.$i': $!"), return 0
 680            if $i >= 50; # Give up!
 681     }
 682     link($from,$to) || return 0;
 683     unlink($from);
 684 }
 685
 686 sub copy {
 687     my($from,$to) = @_;
 688
 689     my $xto = $to;
 690     $xto =~ s/^\Q$opts{destdir}\E//;
 691     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
 692         unless $opts{silent};
 693     print "  creating new version of $xto\n"
 694         if $Is_VMS and -e $to and !$opts{silent};
 695     unless ($opts{notify} or File::Copy::copy($from, $to)) {
 696         # Might have been that F::C::c can't overwrite the target
 697         warn "Couldn't copy $from to $to: $!\n"
 698             unless -f $to and (chmod(0666, $to), unlink $to)
 699                    and File::Copy::copy($from, $to);
 700     }
 701     $packlist->{$xto} = { type => 'file' };
 702 }
 703
 704 sub installlib {
 705     my $dir = $File::Find::dir;
 706     $dir =~ s#^\.(?![^/])/?##;
 707     local($depth) = $dir ? "lib/$dir" : "lib";
 708
 709     my $name = $_;
 710
 711     # Ignore version control directories.
 712     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 713         $File::Find::prune = 1;
 714         return;
 715     }
 716
 717     # ignore patch backups, RCS files, emacs backup & temp files and the
 718     # .exists files, .PL files, and test files.
 719     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util\.pl$|^filter-util\.pl$|^uupacktool\.pl$|^\.gitignore$} ||
 720               $dir  =~ m{/t(?:/|$)};
 721     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 722     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
 723     # the corelist script from lib/Module/CoreList/bin and ptar* in
 724     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
 725     # (they're installed later with other utils)
 726     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|cpan2dist|cpanp|cpanp-run-perl|ptardiff|config_data)\z/;
 727     # ignore the Makefiles
 728     return if $name =~ /^makefile$/i;
 729     # ignore the test extensions
 730     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
 731     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
 732     # ignore the demo files
 733     return if $dir =~ /\b(?:demos?|eg)\b/;
 734
 735     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
 736     # Changes.e2x and README.e2x are needed by enc2xs.
 737     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
 738     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
 739     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
 740     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
 741     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
 742     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
 743
 744     # if using a shared perl library then ignore:
 745     # - static library files [of statically linked extensions];
 746     # - import library files and export library files (only present on Win32
 747     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
 748     return if $Config{useshrplib} eq 'true' and
 749              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
 750
 751     $name = "$dir/$name" if $dir ne '';
 752
 753     return if $name eq 'ExtUtils/XSSymSet.pm' and !$Is_VMS;
 754
 755     my $installlib = $installprivlib;
 756     if ($dir =~ /^auto\// ||
 757           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 758           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
 759           $name=~/^Config_(heavy|git)\.pl\z/
 760        ) {
 761         $installlib = $installarchlib;
 762         return unless $do_installarchlib;
 763     } else {
 764         return unless $do_installprivlib;
 765     }
 766
 767     if (-f $_) {
 768         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$])) {
 769             $installlib = $installprivlib;
 770             #We're installing *.al and *.ix files into $installprivlib,
 771             #but we have to delete old *.al and *.ix files from the 5.000
 772             #distribution:
 773             #This might not work because $archname might have changed.
 774             unlink("$installarchlib/$name");
 775         }
 776         my $xname = "$installlib/$name";
 777         $xname =~ s/^\Q$opts{destdir}\E//;
 778         $packlist->{$xname} = { type => 'file' };
 779         if ($force || compare($_, "$installlib/$name") || $opts{notify}) {
 780             unlink("$installlib/$name");
 781             mkpath("$installlib/$dir", $opts{verbose}, 0777);
 782             # HP-UX (at least) needs to maintain execute permissions
 783             # on dynamically-loaded libraries.
 784             if ($Is_NetWare && !$nwinstall) {
 785                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 786                 # if copied will give problems when building new extensions.
 787                 # Has to be copied if we are installing on a NetWare server and hence
 788                 # the check !$nwinstall
 789                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 790                     copy_if_diff($_, "$installlib/$name")
 791                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 792                                   "$installlib/$name");
 793                 }
 794            } else {
 795                 if (copy_if_diff($_, "$installlib/$name")) {
 796                     if ($name =~ /\.(so|$dlext)$/o) {
 797                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 798                         chmod(0555, "$installlib/$name");
 799                     } else {
 800                         strip("-S", "$installlib/$name")
 801                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 802                         chmod(0444, "$installlib/$name");
 803                     }
 804                 }
 805             } #if ($Is_NetWare)
 806         }
 807     }
 808 }
 809
 810 # Copy $from to $to, only if $from is different than $to.
 811 # Also preserve modification times for .a libraries.
 812 # On some systems, if you do
 813 #   ranlib libperl.a
 814 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 815 # and then try to link against the installed libperl.a, you might
 816 # get an error message to the effect that the symbol table is older
 817 # than the library.
 818 # Return true if copying occurred.
 819
 820 sub copy_if_diff {
 821     my($from,$to)=@_;
 822     return 1 if (($^O eq 'VMS') && (-d $from));
 823     my $xto = $to;
 824     $xto =~ s/^\Q$opts{destdir}\E//;
 825     my $perlpodbadsymlink;
 826     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 827         -l $from &&
 828         ! -e $from) {
 829         # Some Linux implementations have problems traversing over
 830         # multiple symlinks (when going over NFS?) and fail to read
 831         # the symlink target.  Combine this with the fact that some
 832         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 833         # and you end up with those pods not getting installed.
 834         $perlpodbadsymlink = 1;
 835     }
 836     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 837     $packlist->{$xto} = { type => 'file' };
 838     if ($force || compare($from, $to) || $opts{notify}) {
 839         safe_unlink($to);   # In case we don't have write permissions.
 840         if ($opts{notify}) {
 841             $from = $depth . "/" . $from if $depth;
 842         }
 843         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 844             $from = "README.$1";
 845         }
 846         copy($from, $to);
 847         # Restore timestamps if it's a .a library or for OS/2.
 848         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
 849             my ($atime, $mtime) = (stat $from)[8,9];
 850             utime $atime, $mtime, $to;
 851         }
 852         1;
 853     }
 854 }
 855
 856 sub strip
 857 {
 858     my(@args) = @_;
 859
 860     return unless $dostrip;
 861
 862     my @opts;
 863     while (@args && $args[0] =~ /^(-\w+)$/) {
 864         push @opts, shift @args;
 865     }
 866
 867     foreach my $file (@args) {
 868         if (-f $file) {
 869             if ($opts{verbose}) {
 870                 print "  strip " . join(' ', @opts);
 871                 print " " if (@opts);
 872                 print "$file\n";
 873             }
 874             system("strip", @opts, $file);
 875         } else {
 876             print "# file '$file' skipped\n" if $opts{verbose};
 877         }
 878     }
 879 }