installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 use vars qw($Is_VMS $Is_W32 $Is_OS2 $nonono $versiononly $depth);
  12
  13 BEGIN {
  14     $Is_VMS = $^O eq 'VMS';
  15     $Is_W32 = $^O eq 'MSWin32';
  16     $Is_OS2 = $^O eq 'os2';
  17     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  18 }
  19
  20 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  21
  22 use File::Find;
  23 use File::Compare;
  24 use File::Copy ();
  25 use File::Path ();
  26 use ExtUtils::Packlist;
  27 use Config;
  28 use subs qw(unlink link chmod);
  29 use vars qw($packlist);
  30
  31 # override the ones in the rest of the script
  32 sub mkpath {
  33     File::Path::mkpath(@_) unless $nonono;
  34 }
  35
  36 my $mainperldir = "/usr/bin";
  37 my $exe_ext = $Config{exe_ext};
  38
  39 # Allow ``make install PERLNAME=something_besides_perl'':
  40 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  41
  42 while (@ARGV) {
  43     $nonono = 1 if $ARGV[0] eq '-n';
  44     $versiononly = 1 if $ARGV[0] eq '-v';
  45     shift;
  46 }
  47
  48 umask 022 unless $Is_VMS;
  49
  50 my @scripts = qw(utils/c2ph utils/h2ph utils/h2xs utils/perlbug utils/perldoc
  51                 utils/pl2pm utils/splain utils/perlcc
  52                 x2p/s2p x2p/find2perl
  53                 pod/pod2man pod/pod2html pod/pod2latex pod/pod2text);
  54
  55 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
  56
  57 my @pods = (<pod/*.pod>);
  58
  59 # Specify here any .pm files that are actually architecture-dependent.
  60 # (Those included with XS extensions under ext/ are automatically
  61 # added later.)
  62 # Now that the default privlib has the full perl version number included,
  63 # we no longer have to play the trick of sticking version-specific .pm
  64 # files under the archlib directory.
  65 my %archpms = (
  66     Config => 1,
  67 );
  68
  69 if ($^O eq 'dos') {
  70     push(@scripts,'djgpp/fixpmain');
  71     $archpms{config} = $archpms{filehand} = 1;
  72 }
  73
  74 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
  75 {
  76         push(@scripts, map("$_.exe", @scripts));
  77 }
  78
  79 find(sub {
  80         if ("$File::Find::dir/$_" =~ m{^ext/[^/]+/(.*)\.pm$}) {
  81             (my $pm = $1) =~ s{^lib/}{};
  82             $archpms{$pm} = 1;
  83         }
  84     }, 'ext');
  85
  86 my $ver = $];
  87 my $release = substr($ver,0,3);   # Not used presently.
  88 my $patchlevel = substr($ver,3,2);
  89 die "Patchlevel of perl ($patchlevel)",
  90     "and patchlevel of config.sh ($Config{'PATCHLEVEL'}) don't match\n"
  91         if $patchlevel != $Config{'PATCHLEVEL'};
  92
  93 # Fetch some frequently-used items from %Config
  94 my $installbin = $Config{installbin};
  95 my $installscript = $Config{installscript};
  96 my $installprivlib = $Config{installprivlib};
  97 my $installarchlib = $Config{installarchlib};
  98 my $installsitelib = $Config{installsitelib};
  99 my $installsitearch = $Config{installsitearch};
 100 my $installman1dir = $Config{installman1dir};
 101 my $man1ext = $Config{man1ext};
 102 my $libperl = $Config{libperl};
 103 # Shared library and dynamic loading suffixes.
 104 my $so = $Config{so};
 105 my $dlext = $Config{dlext};
 106
 107 my $d_dosuid = $Config{d_dosuid};
 108 my $binexp = $Config{binexp};
 109
 110 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 111     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 112               \$installarchlib, \$installsitelib, \$installsitearch,
 113               \$installman1dir ) {
 114       $$_ = unixify($$_);  $$_ =~ s:/$::;
 115     }
 116 }
 117
 118 # Do some quick sanity checks.
 119
 120 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 121
 122    $installbin          || die "No installbin directory in config.sh\n";
 123 -d $installbin          || mkpath($installbin, 1, 0777);
 124 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 125 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 126         unless $installbin =~ m#^/afs/# || $nonono;
 127
 128 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 129 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 130
 131 -x 't/TEST'             || $Is_W32
 132                         || warn "WARNING: You've never run 'make test'!!!",
 133                                 "  (Installing anyway.)\n";
 134
 135 if ($Is_W32) {
 136
 137 my $perldll = 'perl.' . $dlext;
 138 $perldll = 'perlcore.' . $dlext if $Config{'ccflags'} =~ /PERL_OBJECT/i;
 139
 140 -f $perldll || die "No perl DLL built\n";
 141
 142 # Install the DLL
 143
 144 safe_unlink("$installbin/$perldll");
 145 copy("$perldll", "$installbin/$perldll");
 146 chmod(0755, "$installbin/$perldll");
 147 }
 148
 149 # This will be used to store the packlist
 150 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 151
 152 # First we install the version-numbered executables.
 153
 154 if ($Is_VMS) {
 155     safe_unlink("$installbin/$perl$exe_ext");
 156     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 157     chmod(0755, "$installbin/$perl$exe_ext");
 158     safe_unlink("$installbin/${perl}shr$exe_ext");
 159     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 160     chmod(0755, "$installbin/${perl}shr$exe_ext");
 161 }
 162 elsif ($^O eq 'mpeix') {
 163     # MPE lacks hard links and requires that executables with special
 164     # capabilities reside in the MPE namespace.
 165     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 166     # Install the primary executable into the MPE namespace as perlpath.
 167     copy("perl$exe_ext", $Config{perlpath});
 168     chmod(0755, $Config{perlpath});
 169     # Create a backup copy with the version number.
 170     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 171 }
 172 elsif ($^O ne 'dos') {
 173     safe_unlink("$installbin/$perl$ver$exe_ext");
 174     copy("perl$exe_ext", "$installbin/$perl$ver$exe_ext");
 175     chmod(0755, "$installbin/$perl$ver$exe_ext");
 176 }
 177 else {
 178     safe_unlink("$installbin/$perl.exe");
 179     copy("perl.exe", "$installbin/$perl.exe");
 180 }
 181
 182 safe_unlink("$installbin/s$perl$ver$exe_ext");
 183 if ($d_dosuid) {
 184     copy("suidperl$exe_ext", "$installbin/s$perl$ver$exe_ext");
 185     chmod(04711, "$installbin/s$perl$ver$exe_ext");
 186 }
 187
 188 # Install library files.
 189
 190 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 191
 192 mkpath($installprivlib, 1, 0777);
 193 mkpath($installarchlib, 1, 0777);
 194 mkpath($installsitelib, 1, 0777) if ($installsitelib);
 195 mkpath($installsitearch, 1, 0777) if ($installsitearch);
 196
 197 if (chdir "lib") {
 198     $do_installarchlib = ! samepath($installarchlib, '.');
 199     $do_installprivlib = ! samepath($installprivlib, '.');
 200     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$]/);
 201
 202     if ($do_installarchlib || $do_installprivlib) {
 203         find(\&installlib, '.');
 204     }
 205     chdir ".." || die "Can't cd back to source directory: $!\n";
 206 }
 207 else {
 208     warn "Can't cd to lib to install lib files: $!\n";
 209 }
 210
 211 # Install header files and libraries.
 212 mkpath("$installarchlib/CORE", 1, 0777);
 213 my @corefiles;
 214 if ($Is_VMS) {  # We did core file selection during build
 215     my $coredir = "lib/$Config{'arch'}/$]";
 216     $coredir =~ tr/./_/;
 217     @corefiles = <$coredir/*.*>;
 218 }
 219 else {
 220     @corefiles = <*.h libperl*.*>;
 221     # AIX needs perl.exp installed as well.
 222     push(@corefiles,'perl.exp') if $^O eq 'aix';
 223     # If they have built sperl.o...
 224     push(@corefiles,'sperl.o') if -f 'sperl.o';
 225 }
 226 foreach my $file (@corefiles) {
 227     # HP-UX (at least) needs to maintain execute permissions
 228     # on dynamically-loadable libraries. So we do it for all.
 229     copy_if_diff($file,"$installarchlib/CORE/$file")
 230         and chmod($file =~ /\.(so|\Q$dlext\E)$/ ? 0555 : 0444,
 231                    "$installarchlib/CORE/$file");
 232 }
 233
 234 # Install main perl executables
 235 # Make links to ordinary names if installbin directory isn't current directory.
 236
 237 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 238     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 239     if ($^O eq 'mpeix') {
 240         # MPE doesn't support hard links, so use a symlink.
 241         # We don't want another cloned copy.
 242         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 243     } else {
 244         link("$installbin/$perl$ver$exe_ext", "$installbin/$perl$exe_ext");
 245     }
 246     link("$installbin/s$perl$ver$exe_ext", "$installbin/suid$perl$exe_ext")
 247       if $d_dosuid;
 248 }
 249
 250 # Offer to install perl in a "standard" location
 251
 252 my $mainperl_is_instperl = 0;
 253
 254 if (!$versiononly && !$nonono && !$Is_W32 && !$Is_VMS && -t STDIN && -t STDERR
 255         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 256     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 257     my($instperl)       = "$installbin/$perl$exe_ext";
 258     my($expinstperl)    = "$binexp/$perl$exe_ext";
 259
 260     # First make sure $usrbinperl is not already the same as the perl we
 261     # just installed.
 262     if (-x $usrbinperl) {
 263         # Try to be clever about mainperl being a symbolic link
 264         # to binexp/perl if binexp and installbin are different.
 265         $mainperl_is_instperl =
 266             samepath($usrbinperl, $instperl) ||
 267             samepath($usrbinperl, $expinstperl) ||
 268              (($binexp ne $installbin) &&
 269               (-l $usrbinperl) &&
 270               ((readlink $usrbinperl) eq $expinstperl));
 271     }
 272     if ((! $mainperl_is_instperl) &&
 273         (yn("Many scripts expect perl to be installed as $usrbinperl.\n" .
 274              "Do you wish to have $usrbinperl be the same as\n" .
 275              "$expinstperl? [y] ")))
 276     {
 277         unlink($usrbinperl);
 278         ( $Config{'d_link'} eq 'define' &&
 279           eval { CORE::link $instperl, $usrbinperl } )  ||
 280         eval { symlink $expinstperl, $usrbinperl }      ||
 281         copy($instperl, $usrbinperl);
 282
 283         $mainperl_is_instperl = 1;
 284     }
 285 }
 286
 287 # Make links to ordinary names if installbin directory isn't current directory.
 288
 289 if (!$versiononly && ! samepath($installbin, 'x2p')) {
 290     safe_unlink("$installbin/a2p$exe_ext");
 291     copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 292     chmod(0755, "$installbin/a2p$exe_ext");
 293 }
 294
 295 # cppstdin is just a script, but it is architecture-dependent, so
 296 # it can't safely be shared.  Place it in $installbin.
 297 # Note that Configure doesn't build cppstin if it isn't needed, so
 298 # we skip this if cppstdin doesn't exist.
 299 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 300     safe_unlink("$installbin/cppstdin");
 301     copy("cppstdin", "$installbin/cppstdin");
 302     chmod(0755, "$installbin/cppstdin");
 303 }
 304
 305 # Install scripts.
 306
 307 mkpath($installscript, 1, 0777);
 308
 309 if (! $versiononly) {
 310     for (@scripts) {
 311         (my $base = $_) =~ s#.*/##;
 312         copy($_, "$installscript/$base");
 313         chmod(0755, "$installscript/$base");
 314     }
 315 }
 316
 317 # pstruct should be a link to c2ph
 318
 319 if (! $versiononly) {
 320     safe_unlink("$installscript/pstruct$scr_ext");
 321     if ($^O eq 'dos' or $Is_VMS) {
 322         copy("$installscript/c2ph$scr_ext", "$installscript/pstruct$scr_ext");
 323     } else {
 324         link("$installscript/c2ph$scr_ext", "$installscript/pstruct$scr_ext");
 325     }
 326 }
 327
 328 # Install pod pages.  Where? I guess in $installprivlib/pod.
 329
 330 if (! $versiononly || !($installprivlib =~ m/\Q$]/)) {
 331     mkpath("${installprivlib}/pod", 1, 0777);
 332
 333     # If Perl 5.003's perldiag.pod is there, rename it.
 334     if (open POD, "${installprivlib}/pod/perldiag.pod") {
 335         read POD, $_, 4000;
 336         close POD;
 337         # Some of Perl 5.003's diagnostic messages ended with periods.
 338         if (/^=.*\.$/m) {
 339             my ($from, $to) = ("${installprivlib}/pod/perldiag.pod",
 340                                "${installprivlib}/pod/perldiag-5.003.pod");
 341             print STDERR "  rename $from $to";
 342             rename($from, $to)
 343                 or warn "Couldn't rename $from to $to: $!\n"
 344                 unless $nonono;
 345         }
 346     }
 347
 348     foreach my $file (@pods) {
 349         # $file is a name like  pod/perl.pod
 350         copy_if_diff($file, "${installprivlib}/${file}");
 351     }
 352
 353 }
 354
 355 # Check to make sure there aren't other perls around in installer's
 356 # path.  This is probably UNIX-specific.  Check all absolute directories
 357 # in the path except for where public executables are supposed to live.
 358 # Also skip $mainperl if the user opted to have it be a link to the
 359 # installed perl.
 360
 361 if (!$versiononly) {
 362         my ($path, @path);
 363     my $dirsep = ($Is_OS2 || $Is_W32) ? ';' : ':' ;
 364     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 365     @path = split(/$dirsep/, $path);
 366     if ($Is_VMS) {
 367         my $i = 0;
 368         while (exists $ENV{'DCL$PATH' . $i}) {
 369             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 370             push(@path,$dir);
 371         }
 372     }
 373     my @otherperls;
 374     for (@path) {
 375         next unless m,^/,;
 376         # Use &samepath here because some systems have other dirs linked
 377         # to $mainperldir (like SunOS)
 378         next if samepath($_, $binexp);
 379         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 380         push(@otherperls, "$_/$perl$exe_ext")
 381             if (-x "$_/$perl$exe_ext" && ! -d "$_/$perl$exe_ext");
 382     }
 383     if (@otherperls) {
 384         print STDERR "\nWarning: $perl appears in your path in the following " .
 385             "locations beyond where\nwe just installed it:\n";
 386         for (@otherperls) {
 387             print STDERR "    ", $_, "\n";
 388         }
 389         print STDERR "\n";
 390     }
 391
 392 }
 393
 394 $packlist->write() unless $nonono;
 395 print STDERR "  Installation complete\n";
 396
 397 exit 0;
 398
 399 ###############################################################################
 400
 401 sub yn {
 402     my($prompt) = @_;
 403     my($answer);
 404     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 405     print STDERR $prompt;
 406     chop($answer = <STDIN>);
 407     $answer = $default if $answer =~ m/^\s*$/;
 408     ($answer =~ m/^[yY]/);
 409 }
 410
 411 sub unlink {
 412     my(@names) = @_;
 413     my($cnt) = 0;
 414
 415     return scalar(@names) if $Is_VMS;
 416
 417     foreach my $name (@names) {
 418         next unless -e $name;
 419         chmod 0777, $name if ($Is_OS2 || $Is_W32);
 420         print STDERR "  unlink $name\n";
 421         ( CORE::unlink($name) and ++$cnt
 422           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 423     }
 424     return $cnt;
 425 }
 426
 427 sub safe_unlink {
 428     return if $nonono or $Is_VMS;
 429     my @names = @_;
 430     foreach my $name (@names) {
 431         next unless -e $name;
 432         chmod 0777, $name if ($Is_OS2 || $Is_W32);
 433         print STDERR "  unlink $name\n";
 434         next if CORE::unlink($name);
 435         warn "Couldn't unlink $name: $!\n";
 436         if ($! =~ /busy/i) {
 437             print STDERR "  mv $name $name.old\n";
 438             safe_rename($name, "$name.old")
 439                 or warn "Couldn't rename $name: $!\n";
 440         }
 441     }
 442 }
 443
 444 sub safe_rename {
 445     my($from,$to) = @_;
 446     if (-f $to and not unlink($to)) {
 447         my($i);
 448         for ($i = 1; $i < 50; $i++) {
 449             last if rename($to, "$to.$i");
 450         }
 451         warn("Cannot rename to `$to.$i': $!"), return 0
 452            if $i >= 50; # Give up!
 453     }
 454     link($from,$to) || return 0;
 455     unlink($from);
 456 }
 457
 458 sub link {
 459     my($from,$to) = @_;
 460     my($success) = 0;
 461
 462     print STDERR "  ln $from $to\n";
 463     eval {
 464         CORE::link($from, $to)
 465             ? $success++
 466             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 467               ? die "AFS"  # okay inside eval {}
 468               : warn "Couldn't link $from to $to: $!\n"
 469           unless $nonono;
 470         $packlist->{$to} = { from => $from, type => 'link' };
 471     };
 472     if ($@) {
 473         print STDERR "  creating new version of $to\n" if $Is_VMS and -e $to;
 474         File::Copy::copy($from, $to)
 475             ? $success++
 476             : warn "Couldn't copy $from to $to: $!\n"
 477           unless $nonono;
 478         $packlist->{$to} = { type => 'file' };
 479     }
 480     $success;
 481 }
 482
 483 sub chmod {
 484     my($mode,$name) = @_;
 485
 486     return if ($^O eq 'dos');
 487     printf STDERR "  chmod %o %s\n", $mode, $name;
 488     CORE::chmod($mode,$name)
 489         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 490       unless $nonono;
 491 }
 492
 493 sub copy {
 494     my($from,$to) = @_;
 495
 496     print STDERR "  cp $from $to\n";
 497     print STDERR "  creating new version of $to\n" if $Is_VMS and -e $to;
 498     File::Copy::copy($from, $to)
 499         || warn "Couldn't copy $from to $to: $!\n"
 500       unless $nonono;
 501     $packlist->{$to} = { type => 'file' };
 502 }
 503
 504 sub samepath {
 505     my($p1, $p2) = @_;
 506
 507     return (lc($p1) eq lc($p2)) if $Is_W32;
 508
 509     if ($p1 ne $p2) {
 510         my($dev1, $ino1, $dev2, $ino2);
 511         ($dev1, $ino1) = stat($p1);
 512         ($dev2, $ino2) = stat($p2);
 513         ($dev1 == $dev2 && $ino1 == $ino2);
 514     }
 515     else {
 516         1;
 517     }
 518 }
 519
 520 sub installlib {
 521     my $dir = $File::Find::dir;
 522     $dir =~ s#^\.(?![^/])/?##;
 523     local($depth) = $dir ? "lib/$dir" : "lib";
 524
 525     my $name = $_;
 526
 527     if ($name eq 'CVS' && -d $name) {
 528         $File::Find::prune = 1;
 529         return;
 530     }
 531
 532     # ignore patch backups and the .exists files.
 533     return if $name =~ m{\.orig$|~$|^\.exists};
 534
 535     $name = "$dir/$name" if $dir ne '';
 536
 537     my $installlib = $installprivlib;
 538     if ($dir =~ /^auto/ ||
 539           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 540           ($name =~ /^(.*)\.(?:h|lib)$/i && $Is_W32)
 541        ) {
 542         $installlib = $installarchlib;
 543         return unless $do_installarchlib;
 544     } else {
 545         return unless $do_installprivlib;
 546     }
 547
 548     if (-f $_) {
 549         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 550             $installlib = $installprivlib;
 551             #We're installing *.al and *.ix files into $installprivlib,
 552             #but we have to delete old *.al and *.ix files from the 5.000
 553             #distribution:
 554             #This might not work because $archname might have changed.
 555             unlink("$installarchlib/$name");
 556         }
 557         $packlist->{"$installlib/$name"} = { type => 'file' };
 558         if (compare($_, "$installlib/$name") || $nonono) {
 559             unlink("$installlib/$name");
 560             mkpath("$installlib/$dir", 1, 0777);
 561             # HP-UX (at least) needs to maintain execute permissions
 562             # on dynamically-loaded libraries.
 563             copy_if_diff($_, "$installlib/$name")
 564                 and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 565                            "$installlib/$name");
 566         }
 567     } elsif (-d $_) {
 568         mkpath("$installlib/$name", 1, 0777);
 569     }
 570 }
 571
 572 # Copy $from to $to, only if $from is different than $to.
 573 # Also preserve modification times for .a libraries.
 574 # On some systems, if you do
 575 #   ranlib libperl.a
 576 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 577 # and then try to link against the installed libperl.a, you might
 578 # get an error message to the effect that the symbol table is older
 579 # than the library.
 580 # Return true if copying occurred.
 581
 582 sub copy_if_diff {
 583     my($from,$to)=@_;
 584     return 1 if (($^O eq 'VMS') && (-d $from));
 585     -f $from || die "$0: $from not found";
 586     $packlist->{$to} = { type => 'file' };
 587     if (compare($from, $to) || $nonono) {
 588         safe_unlink($to);   # In case we don't have write permissions.
 589         if ($nonono) {
 590             $from = $depth . "/" . $from if $depth;
 591         }
 592         copy($from, $to);
 593         # Restore timestamps if it's a .a library or for OS/2.
 594         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 595             my ($atime, $mtime) = (stat $from)[8,9];
 596             utime $atime, $mtime, $to;
 597         }
 598         1;
 599     }
 600 }