installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  13     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41     $Is_W32 = 0;
  42     $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63 my $dbg = '';
  64 my $ndbg = '';
  65 if ( $Is_VMS ) {
  66     if ( defined $Config{usevmsdebug} ) {
  67         if ( $Config{usevmsdebug} eq 'define' ) {
  68             $dbg = 'dbg';
  69             $ndbg = 'ndbg';
  70         }
  71     }
  72 }
  73
  74 $otherperls = 1;
  75 my $destdir = '';
  76 while (@ARGV) {
  77     $nonono = 1 if $ARGV[0] eq '-n';
  78     $dostrip = 1 if $ARGV[0] eq '-s';
  79     $versiononly = 1 if $ARGV[0] eq '-v';
  80     $versiononly = 0 if $ARGV[0] eq '+v';
  81     $silent = 1 if $ARGV[0] eq '-S';
  82     $otherperls = 0 if $ARGV[0] eq '-o';
  83     $force = 1 if $ARGV[0] eq '-f';
  84     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  85     $archname = 1 if $ARGV[0] eq '-A';
  86     $nwinstall = 1 if $ARGV[0] eq '-netware';
  87     $nopods = 1 if $ARGV[0] eq '-p';
  88     $destdir = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
  89     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  90         print <<"EOT";
  91 Usage $0: [switches]
  92   -n        Don't actually run any commands; just print them.
  93   -s        Run strip on installed binaries.
  94   -v        Only install perl as a binary with the version number in the name.
  95             (Override whatever config.sh says)
  96   +v        Install perl as "perl" and as a binary with the version number in
  97             the name.  (Override whatever config.sh says)
  98   -S        Silent mode.
  99   -f        Force installation (don't check if same version is there)
 100   -o        Skip checking for other copies of perl in your PATH.
 101   -V        Verbose mode.
 102   -A        Also install perl with the architecture's name in the perl binary's
 103             name.
 104   -p        Don't install the pod files. [This will break use diagnostics;]
 105   -netware  Install correctly on a Netware server.
 106   -destdir  Prefix installation directories by this string.
 107 EOT
 108         exit;
 109     }
 110     shift;
 111 }
 112
 113 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 114 my (@scripts, @tolink);
 115 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 116 while (<SCRIPTS>) {
 117     next if /^#/;
 118     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 119     next if /a2p/; # a2p is binary, to be installed separately
 120     chomp;
 121     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 122         push @scripts, $1;
 123         push @tolink, [$1, $2];
 124     } else {
 125         push @scripts, $_;
 126     }
 127 }
 128 close SCRIPTS;
 129
 130 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 131
 132 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
 133
 134 # Specify here any .pm files that are actually architecture-dependent.
 135 # (Those included with XS extensions under ext/ are automatically
 136 # added later.)
 137 # Now that the default privlib has the full perl version number included,
 138 # we no longer have to play the trick of sticking version-specific .pm
 139 # files under the archlib directory.
 140 my %archpms = (
 141     Config => 1,
 142     lib => 1,
 143     Cwd => 1,
 144 );
 145
 146 if ($^O eq 'dos') {
 147     push(@scripts,'djgpp/fixpmain');
 148     $archpms{config} = $archpms{filehand} = 1;
 149 }
 150
 151 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 152     push(@scripts, map("$_.exe", @scripts));
 153 }
 154
 155 find(sub {
 156     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 157         my($path, $modname) = ($1,$2);
 158
 159         # strip trailing component first
 160         $path =~ s{/[^/]*$}{};
 161
 162         # strip optional "/lib";
 163         $path =~ s{/lib\b}{};
 164
 165         # strip any leading /
 166         $path =~ s{^/}{};
 167
 168         # reconstitute canonical module name
 169         $modname = "$path/$modname" if length $path;
 170
 171         # remember it
 172         $archpms{$modname} = 1;
 173     }
 174 }, 'ext');
 175
 176 # print "[$_]\n" for sort keys %archpms;
 177
 178 my $ver = $Config{version};
 179 my $release = substr($],0,3);   # Not used currently.
 180 my $patchlevel = substr($],3,2);
 181 die "Patchlevel of perl ($patchlevel)",
 182     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 183         if $patchlevel != $Config{'PERL_VERSION'};
 184
 185 # Fetch some frequently-used items from %Config
 186 my $installbin = "$destdir$Config{installbin}";
 187 my $installscript = "$destdir$Config{installscript}";
 188 my $installprivlib = "$destdir$Config{installprivlib}";
 189 my $installarchlib = "$destdir$Config{installarchlib}";
 190 my $installsitelib = "$destdir$Config{installsitelib}";
 191 my $installsitearch = "$destdir$Config{installsitearch}";
 192 my $installman1dir = "$destdir$Config{installman1dir}";
 193 my $man1ext = $Config{man1ext};
 194 my $libperl = $Config{libperl};
 195 # Shared library and dynamic loading suffixes.
 196 my $so = $Config{so};
 197 my $dlext = $Config{dlext};
 198 my $dlsrc = $Config{dlsrc};
 199 if ($^O eq 'os390') {
 200     my $pwd;
 201     chomp($pwd=`pwd`);
 202     my $archlibexp = $Config{archlibexp};
 203     my $usedl = $Config{usedl};
 204     if ($usedl eq 'define') {
 205         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 206     }
 207 }
 208
 209 if ($nwinstall) {
 210     # This is required only if we are installing on a NetWare server
 211     $installscript = $Config{installnwscripts};
 212     $installprivlib = $Config{installnwlib};
 213     $installarchlib = $Config{installnwlib};
 214     $installsitelib = $Config{installnwlib};
 215 }
 216
 217 my $d_dosuid = $Config{d_dosuid};
 218 my $binexp = $Config{binexp};
 219
 220 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 221     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 222               \$installarchlib, \$installsitelib, \$installsitearch,
 223               \$installman1dir ) {
 224         $$_ = unixify($$_);  $$_ =~ s:/$::;
 225     }
 226 }
 227
 228 # Do some quick sanity checks.
 229
 230 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 231
 232    $installbin          || die "No installbin directory in config.sh\n";
 233 -d $installbin          || mkpath($installbin, $verbose, 0777);
 234 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 235 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 236         unless $installbin =~ m#^/afs/# || $nonono;
 237
 238 if (!$Is_NetWare) {
 239 if (!$Is_VMS) {
 240 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 241 }
 242 else {
 243 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 244     if ($dbg) {
 245         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 246     }
 247 }
 248 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 249
 250 -f 't/rantests'         || $Is_W32
 251                         || warn "WARNING: You've never run 'make test' or",
 252                                 " some tests failed! (Installing anyway.)\n";
 253 } #if (!$Is_NetWare)
 254
 255 # This will be used to store the packlist
 256 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 257
 258 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 259     my $perldll;
 260
 261     if ($Is_Cygwin) {
 262         $perldll = $libperl;
 263         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 264         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 265         $perldll =~ s/^lib/cyg/;
 266         if ($Config{useshrplib} eq 'true') {
 267             # install ld2 and perlld as well
 268             foreach ('ld2', 'perlld') {
 269                 safe_unlink("$installbin/$_");
 270                 copy("$_", "$installbin/$_");
 271                 chmod(0755, "$installbin/$_");
 272                 $packlist->{"$installbin/$_"} = { type => 'file' };
 273             };
 274             open (LD2, ">$installbin/ld2");
 275             print LD2 <<SHELL;
 276 #!/bin/sh
 277 #
 278 # ld wrapper, passes all args to perlld;
 279 #
 280 for trythis in $installbin/perl
 281 do
 282   if [ -x \$trythis ]
 283   then
 284     \$trythis $installbin/perlld "\$\@"
 285     exit \$?
 286   fi
 287 done
 288 # hard luck!
 289 echo I see no perl executable around there
 290 echo perl is required to build dynamic libraries
 291 echo look if the path to perl in /bin/ld2 is correct
 292 exit 1
 293 SHELL
 294             close LD2;
 295             chmod(0755, "$installbin/ld2");
 296         };
 297     } else {
 298         $perldll = 'perl59.' . $dlext;
 299     }
 300
 301     if ($dlsrc ne "dl_none.xs") {
 302         -f $perldll || die "No perl DLL built\n";
 303     }
 304
 305     # Install the DLL
 306     safe_unlink("$installbin/$perldll");
 307     copy("$perldll", "$installbin/$perldll");
 308     chmod(0755, "$installbin/$perldll");
 309     $packlist->{"$installbin/$perldll"} = { type => 'file' };
 310 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 311
 312 # First we install the version-numbered executables.
 313
 314 if ($Is_VMS) {
 315     safe_unlink("$installbin/perl_setup.com");
 316     copy("perl_setup.com", "$installbin/perl_setup.com");
 317     chmod(0755, "$installbin/perl_setup.com");
 318     safe_unlink("$installbin/$dbg$perl$exe_ext");
 319     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 320     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 321     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 322     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 323     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 324     if ($ndbg) {
 325         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 326         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 327         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 328         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 329         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 330         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 331     }
 332 }
 333 elsif ($^O eq 'mpeix') {
 334     # MPE lacks hard links and requires that executables with special
 335     # capabilities reside in the MPE namespace.
 336     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 337     # Install the primary executable into the MPE namespace as perlpath.
 338     copy("perl$exe_ext", $Config{perlpath});
 339     chmod(0755, $Config{perlpath});
 340     # Create a backup copy with the version number.
 341     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 342 }
 343 elsif ($^O ne 'dos') {
 344     if (!$Is_NetWare) {
 345         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 346         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 347         strip("$installbin/$perl_verbase$ver$exe_ext");
 348         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 349     }
 350     else {
 351         # If installing onto a NetWare server
 352         if ($nwinstall) {
 353             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 354             mkpath($Config{installnwsystem}, 1, 0777);
 355             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 356             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 357             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 358             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 359             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 360             mkpath($Config{installnwlcgi}, 1, 0777);
 361             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 362         }
 363     } #if (!$Is_NetWare)
 364 }
 365 else {
 366     safe_unlink("$installbin/$perl.exe");
 367     copy("perl.exe", "$installbin/$perl.exe");
 368 }
 369
 370 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 371 if ($d_dosuid) {
 372     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 373     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 374 }
 375
 376 # Install library files.
 377
 378 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 379
 380 mkpath($installprivlib, $verbose, 0777);
 381 mkpath($installarchlib, $verbose, 0777);
 382 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 383 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 384
 385 if (chdir "lib") {
 386     $do_installarchlib = ! samepath($installarchlib, '.');
 387     $do_installprivlib = ! samepath($installprivlib, '.');
 388     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 389
 390     if ($do_installarchlib || $do_installprivlib) {
 391         find(\&installlib, '.');
 392     }
 393     chdir ".." || die "Can't cd back to source directory: $!\n";
 394 }
 395 else {
 396     warn "Can't cd to lib to install lib files: $!\n";
 397 }
 398
 399 # Install header files and libraries.
 400 mkpath("$installarchlib/CORE", $verbose, 0777);
 401 my @corefiles;
 402 if ($Is_VMS) {  # We did core file selection during build
 403     my $coredir = "lib/$Config{archname}/$ver/CORE";
 404     $coredir =~ tr/./_/;
 405     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 406 }
 407 else {
 408     # [als] hard-coded 'libperl' name... not good!
 409     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 410
 411     # AIX needs perl.exp installed as well.
 412     push(@corefiles,'perl.exp') if $^O eq 'aix';
 413     if ($^O eq 'mpeix') {
 414         # MPE needs mpeixish.h installed as well.
 415         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 416         push(@corefiles,'mpeix/mpeixish.h');
 417     }
 418     # If they have built sperl.o...
 419     push(@corefiles,'sperl.o') if -f 'sperl.o';
 420 }
 421 foreach my $file (@corefiles) {
 422     # HP-UX (at least) needs to maintain execute permissions
 423     # on dynamically-loadable libraries. So we do it for all.
 424     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 425         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 426             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 427             chmod(0555, "$installarchlib/CORE/$file");
 428         } else {
 429             chmod(0444, "$installarchlib/CORE/$file");
 430         }
 431     }
 432 }
 433
 434 # Install main perl executables
 435 # Make links to ordinary names if installbin directory isn't current directory.
 436
 437 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 438     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 439     if ($^O eq 'mpeix') {
 440         # MPE doesn't support hard links, so use a symlink.
 441         # We don't want another cloned copy.
 442         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 443     } elsif ($^O eq 'vos') {
 444         # VOS doesn't support hard links, so use a symlink.
 445         symlink("$installbin/$perl_verbase$ver$exe_ext",
 446                 "$installbin/$perl$exe_ext");
 447     } else {
 448         link("$installbin/$perl_verbase$ver$exe_ext",
 449                 "$installbin/$perl$exe_ext");
 450     }
 451     link("$installbin/$perl_verbase$ver$exe_ext",
 452             "$installbin/suid$perl$exe_ext")
 453       if $d_dosuid;
 454 }
 455
 456 # For development purposes it can be very useful to have multiple perls
 457 # build for different "architectures" (eg threading or not) simultaneously.
 458 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 459     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 460     safe_unlink("$installbin/$archperl");
 461     if ($^O eq 'mpeix') {
 462         # MPE doesn't support hard links, so use a symlink.
 463         # We don't want another cloned copy.
 464         symlink($Config{perlpath}, "$installbin/$archperl");
 465     } elsif ($^O eq 'vos') {
 466         # VOS doesn't support hard links, so use a symlink.
 467         symlink("$installbin/$perl_verbase$ver$exe_ext",
 468                 "$installbin/$archperl");
 469     } else {
 470         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 471     }
 472 }
 473
 474 # Offer to install perl in a "standard" location
 475
 476 my $mainperl_is_instperl = 0;
 477
 478 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 479     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 480         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 481     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 482     my($instperl)       = "$installbin/$perl$exe_ext";
 483     my($expinstperl)    = "$binexp/$perl$exe_ext";
 484
 485     # First make sure $usrbinperl is not already the same as the perl we
 486     # just installed.
 487     if (-x $usrbinperl) {
 488         # Try to be clever about mainperl being a symbolic link
 489         # to binexp/perl if binexp and installbin are different.
 490         $mainperl_is_instperl =
 491             samepath($usrbinperl, $instperl) ||
 492             samepath($usrbinperl, $expinstperl) ||
 493              (($binexp ne $installbin) &&
 494               (-l $usrbinperl) &&
 495               ((readlink $usrbinperl) eq $expinstperl));
 496     }
 497     if (! $mainperl_is_instperl) {
 498         unlink($usrbinperl);
 499         ( $Config{'d_link'} eq 'define' &&
 500           eval { CORE::link $instperl, $usrbinperl } )  ||
 501         eval { symlink $expinstperl, $usrbinperl }      ||
 502         copy($instperl, $usrbinperl);
 503
 504         $mainperl_is_instperl = 1;
 505     }
 506 }
 507
 508 # Make links to ordinary names if installbin directory isn't current directory.
 509 if (!$Is_NetWare && $dbg eq '') {
 510     if (! samepath($installbin, 'x2p')) {
 511         my $base = 'a2p';
 512         $base .= $ver if $versiononly;
 513         safe_unlink("$installbin/$base$exe_ext");
 514         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 515         strip("$installbin/$base$exe_ext");
 516         chmod(0755, "$installbin/$base$exe_ext");
 517     }
 518 }
 519
 520 # cppstdin is just a script, but it is architecture-dependent, so
 521 # it can't safely be shared.  Place it in $installbin.
 522 # Note that Configure doesn't build cppstin if it isn't needed, so
 523 # we skip this if cppstdin doesn't exist.
 524 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 525     safe_unlink("$installbin/cppstdin");
 526     copy("cppstdin", "$installbin/cppstdin");
 527     chmod(0755, "$installbin/cppstdin");
 528 }
 529
 530 sub script_alias {
 531     my ($installscript, $orig, $alias, $scr_ext) = @_;
 532
 533     safe_unlink("$installscript/$alias$scr_ext");
 534     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 535         copy("$installscript/$orig$scr_ext",
 536              "$installscript/$alias$scr_ext");
 537     } elsif ($^O eq 'vos') {
 538         symlink("$installscript/$orig$scr_ext",
 539                 "$installscript/$alias$scr_ext");
 540     } else {
 541         link("$installscript/$orig$scr_ext",
 542              "$installscript/$alias$scr_ext");
 543     }
 544 }
 545
 546 # Install scripts.
 547 mkpath($installscript, $verbose, 0777);
 548 if ($versiononly) {
 549     for (@scripts) {
 550         (my $base = $_) =~ s#.*/##;
 551         $base .= $ver;
 552         copy($_,    "$installscript/$base");
 553         chmod(0755, "$installscript/$base");
 554     }
 555
 556     for (@tolink) {
 557         my ($from, $to) = map { "$_$ver" } @$_;
 558         (my $frbase = $from) =~ s#.*/##;
 559         (my $tobase = $to) =~ s#.*/##;
 560         script_alias($installscript, $frbase, $tobase, $scr_ext);
 561     }
 562 } else {
 563     for (@scripts) {
 564         (my $base = $_) =~ s#.*/##;
 565         copy($_, "$installscript/$base");
 566         chmod(0755, "$installscript/$base");
 567     }
 568
 569     for (@tolink) {
 570         my ($from, $to) = @$_;
 571         (my $frbase = $from) =~ s#.*/##;
 572         (my $tobase = $to) =~ s#.*/##;
 573         script_alias($installscript, $frbase, $tobase, $scr_ext);
 574     }
 575 }
 576
 577 # Install pod pages.  Where? I guess in $installprivlib/pod
 578 # ($installprivlib/pods for cygwin).
 579
 580 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 581 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 582     mkpath("${installprivlib}/$pod", $verbose, 0777);
 583
 584     # If Perl 5.003's perldiag.pod is there, rename it.
 585     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 586         read POD, $_, 4000;
 587         close POD;
 588         # Some of Perl 5.003's diagnostic messages ended with periods.
 589         if (/^=.*\.$/m) {
 590             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 591                                "${installprivlib}/$pod/perldiag-5.003.pod");
 592             print "  rename $from $to";
 593             rename($from, $to)
 594                 or warn "Couldn't rename $from to $to: $!\n"
 595                 unless $nonono;
 596         }
 597     }
 598
 599     for (@pods) {
 600         # $_ is a name like  pod/perl.pod
 601         (my $base = $_) =~ s#.*/##;
 602         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 603     }
 604
 605 }
 606
 607 # Check to make sure there aren't other perls around in installer's
 608 # path.  This is probably UNIX-specific.  Check all absolute directories
 609 # in the path except for where public executables are supposed to live.
 610 # Also skip $mainperl if the user opted to have it be a link to the
 611 # installed perl.
 612
 613 if (!$versiononly && $otherperls) {
 614     my ($path, @path);
 615     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 616     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 617     @path = split(/$dirsep/, $path);
 618     if ($Is_VMS) {
 619         my $i = 0;
 620         while (exists $ENV{'DCL$PATH' . $i}) {
 621             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 622             push(@path,$dir);
 623         }
 624     }
 625     my @otherperls;
 626     my %otherperls;
 627     for (@path) {
 628         next unless m,^/,;
 629         # Use &samepath here because some systems have other dirs linked
 630         # to $mainperldir (like SunOS)
 631         next if samepath($_, $binexp);
 632         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 633         my $otherperl = "$_/$perl$exe_ext";
 634         next if $otherperls{$otherperl}++;
 635         push(@otherperls, $otherperl)
 636             if (-x $otherperl && ! -d $otherperl);
 637     }
 638     if (@otherperls) {
 639         warn "\nWarning: $perl appears in your path in the following " .
 640             "locations beyond where\nwe just installed it:\n";
 641         for (@otherperls) {
 642             warn "    ", $_, "\n";
 643         }
 644         warn "\n";
 645     }
 646
 647 }
 648
 649 $packlist->write() unless $nonono;
 650 print "  Installation complete\n" if $verbose;
 651
 652 exit 0;
 653
 654 ###############################################################################
 655
 656 sub yn {
 657     my($prompt) = @_;
 658     my($answer);
 659     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 660     print STDERR $prompt;
 661     chop($answer = <STDIN>);
 662     $answer = $default if $answer =~ m/^\s*$/;
 663     ($answer =~ m/^[yY]/);
 664 }
 665
 666 sub unlink {
 667     my(@names) = @_;
 668     my($cnt) = 0;
 669
 670     return scalar(@names) if $Is_VMS;
 671
 672     foreach my $name (@names) {
 673         next unless -e $name;
 674         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 675         print "  unlink $name\n" if $verbose;
 676         ( CORE::unlink($name) and ++$cnt
 677           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 678     }
 679     return $cnt;
 680 }
 681
 682 sub safe_unlink {
 683     return if $nonono or $Is_VMS;
 684     my @names = @_;
 685     foreach my $name (@names) {
 686         next unless -e $name;
 687         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 688         print "  unlink $name\n" if $verbose;
 689         next if CORE::unlink($name);
 690         warn "Couldn't unlink $name: $!\n";
 691         if ($! =~ /busy/i) {
 692             print "  mv $name $name.old\n" if $verbose;
 693             safe_rename($name, "$name.old")
 694                 or warn "Couldn't rename $name: $!\n";
 695         }
 696     }
 697 }
 698
 699 sub safe_rename {
 700     my($from,$to) = @_;
 701     if (-f $to and not unlink($to)) {
 702         my($i);
 703         for ($i = 1; $i < 50; $i++) {
 704             last if rename($to, "$to.$i");
 705         }
 706         warn("Cannot rename to `$to.$i': $!"), return 0
 707            if $i >= 50; # Give up!
 708     }
 709     link($from,$to) || return 0;
 710     unlink($from);
 711 }
 712
 713 sub link {
 714     my($from,$to) = @_;
 715     my($success) = 0;
 716
 717     my $xfrom = $from;
 718     $xfrom =~ s/^\Q$destdir\E// if $destdir;
 719     my $xto = $to;
 720     $xto =~ s/^\Q$destdir\E// if $destdir;
 721     print $verbose ? "  ln $xfrom $xto\n" : "  $xto\n" unless $silent;
 722     eval {
 723         CORE::link($from, $to)
 724             ? $success++
 725             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 726               ? die "AFS"  # okay inside eval {}
 727               : die "Couldn't link $from to $to: $!\n"
 728           unless $nonono;
 729         $packlist->{$xto} = { from => $xfrom, type => 'link' };
 730     };
 731     if ($@) {
 732         warn "Replacing link() with File::Copy::copy(): $@";
 733         print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 734         print "  creating new version of $xto\n"
 735                  if $Is_VMS and -e $to and !$silent;
 736         unless ($nonono or File::Copy::copy($from, $to) and ++$success) {
 737             # Might have been that F::C::c can't overwrite the target
 738             warn "Couldn't copy $from to $to: $!\n"
 739                 unless -f $to and (chmod(0666, $to), unlink $to)
 740                         and File::Copy::copy($from, $to) and ++$success;
 741         }
 742         $packlist->{$xto} = { type => 'file' };
 743     }
 744     $success;
 745 }
 746
 747 sub chmod {
 748     my($mode,$name) = @_;
 749
 750     return if ($^O eq 'dos');
 751     printf "  chmod %o %s\n", $mode, $name if $verbose;
 752     CORE::chmod($mode,$name)
 753         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 754       unless $nonono;
 755 }
 756
 757 sub copy {
 758     my($from,$to) = @_;
 759
 760     my $xto = $to;
 761     $xto =~ s/^\Q$destdir\E// if $destdir;
 762     print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 763     print "  creating new version of $xto\n" if $Is_VMS and -e $to and !$silent;
 764     unless ($nonono or File::Copy::copy($from, $to)) {
 765         # Might have been that F::C::c can't overwrite the target
 766         warn "Couldn't copy $from to $to: $!\n"
 767             unless -f $to and (chmod(0666, $to), unlink $to)
 768                    and File::Copy::copy($from, $to);
 769     }
 770     $packlist->{$xto} = { type => 'file' };
 771 }
 772
 773 sub samepath {
 774     my($p1, $p2) = @_;
 775
 776     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 777
 778     if ($p1 ne $p2) {
 779         my($dev1, $ino1, $dev2, $ino2);
 780         ($dev1, $ino1) = stat($p1);
 781         ($dev2, $ino2) = stat($p2);
 782         ($dev1 == $dev2 && $ino1 == $ino2);
 783     }
 784     else {
 785         1;
 786     }
 787 }
 788
 789 sub installlib {
 790     my $dir = $File::Find::dir;
 791     $dir =~ s#^\.(?![^/])/?##;
 792     local($depth) = $dir ? "lib/$dir" : "lib";
 793
 794     my $name = $_;
 795
 796     # Ignore version control directories.
 797     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 798         $File::Find::prune = 1;
 799         return;
 800     }
 801
 802     # ignore patch backups, RCS files, emacs backup & temp files and the
 803     # .exists files, .PL files, and test files.
 804     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$} ||
 805               $dir  =~ m{/t(?:/|$)};
 806     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 807     # scripts in lib/ExtUtils, and the prove script in lib/Test/Harness
 808     # as well as the corelist script from lib/Module/CoreList/bin
 809     # (they're installed later with other utils)
 810     return if $name =~ /^(?:cpan|instmodsh|prove|corelist)\z/;
 811     # ignore the Makefiles
 812     return if $name =~ /^makefile$/i;
 813     # ignore the test extensions
 814     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 815     # ignore the demo files
 816     return if $dir =~ /\bdemos?\b/;
 817
 818     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
 819     # Changes.e2x and README.e2x are needed by enc2xs.
 820     return if $name =~ m{^(?:README|MANIFEST|META\.yml|INSTALL)$};
 821     return if $name =~ m{^(?:TODO|BUGS|CREDITS)$}i;
 822     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
 823
 824     $name = "$dir/$name" if $dir ne '';
 825
 826     my $installlib = $installprivlib;
 827     if ($dir =~ /^auto/ ||
 828           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 829           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
 830           $name eq 'Config_heavy.pl'
 831        ) {
 832         $installlib = $installarchlib;
 833         return unless $do_installarchlib;
 834     } else {
 835         return unless $do_installprivlib;
 836     }
 837
 838     if (-f $_) {
 839         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 840             $installlib = $installprivlib;
 841             #We're installing *.al and *.ix files into $installprivlib,
 842             #but we have to delete old *.al and *.ix files from the 5.000
 843             #distribution:
 844             #This might not work because $archname might have changed.
 845             unlink("$installarchlib/$name");
 846         }
 847         my $xname = "$installlib/$name";
 848         $xname =~ s/^\Q$destdir\E// if $destdir;
 849         $packlist->{$xname} = { type => 'file' };
 850         if ($force || compare($_, "$installlib/$name") || $nonono) {
 851             unlink("$installlib/$name");
 852             mkpath("$installlib/$dir", $verbose, 0777);
 853             # HP-UX (at least) needs to maintain execute permissions
 854             # on dynamically-loaded libraries.
 855             if ($Is_NetWare && !$nwinstall) {
 856                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 857                 # if copied will give problems when building new extensions.
 858                 # Has to be copied if we are installing on a NetWare server and hence
 859                 # the check !$nwinstall
 860                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 861                     copy_if_diff($_, "$installlib/$name")
 862                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 863                                   "$installlib/$name");
 864                 }
 865            } else {
 866                 if (copy_if_diff($_, "$installlib/$name")) {
 867                     if ($name =~ /\.(so|$dlext)$/o) {
 868                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 869                         chmod(0555, "$installlib/$name");
 870                     } else {
 871                         strip("-S", "$installlib/$name")
 872                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 873                         chmod(0444, "$installlib/$name");
 874                     }
 875                 }
 876             } #if ($Is_NetWare)
 877         }
 878     }
 879 }
 880
 881 # Copy $from to $to, only if $from is different than $to.
 882 # Also preserve modification times for .a libraries.
 883 # On some systems, if you do
 884 #   ranlib libperl.a
 885 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 886 # and then try to link against the installed libperl.a, you might
 887 # get an error message to the effect that the symbol table is older
 888 # than the library.
 889 # Return true if copying occurred.
 890
 891 sub copy_if_diff {
 892     my($from,$to)=@_;
 893     return 1 if (($^O eq 'VMS') && (-d $from));
 894     my $xto = $to;
 895     $xto =~ s/^\Q$destdir\E// if $destdir;
 896     my $perlpodbadsymlink;
 897     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 898         -l $from &&
 899         ! -e $from) {
 900         # Some Linux implementations have problems traversing over
 901         # multiple symlinks (when going over NFS?) and fail to read
 902         # the symlink target.  Combine this with the fact that some
 903         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 904         # and you end up with those pods not getting installed.
 905         $perlpodbadsymlink = 1;
 906     }
 907     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 908     $packlist->{$xto} = { type => 'file' };
 909     if ($force || compare($from, $to) || $nonono) {
 910         safe_unlink($to);   # In case we don't have write permissions.
 911         if ($nonono) {
 912             $from = $depth . "/" . $from if $depth;
 913         }
 914         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 915             $from = "README.$1";
 916         }
 917         copy($from, $to);
 918         # Restore timestamps if it's a .a library or for OS/2.
 919         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 920             my ($atime, $mtime) = (stat $from)[8,9];
 921             utime $atime, $mtime, $to;
 922         }
 923         1;
 924     }
 925 }
 926
 927 sub strip
 928 {
 929     my(@args) = @_;
 930
 931     return unless $dostrip;
 932
 933     my @opts;
 934     while (@args && $args[0] =~ /^(-\w+)$/) {
 935         push @opts, shift @args;
 936     }
 937
 938     foreach my $file (@args) {
 939         if (-f $file) {
 940             if ($verbose) {
 941                 print "  strip " . join(' ', @opts);
 942                 print " " if (@opts);
 943                 print "$file\n";
 944             }
 945             system("strip", @opts, $file);
 946         } else {
 947             print "# file '$file' skipped\n" if $verbose;
 948         }
 949     }
 950 }