installman

   1 #!./perl -w
   2 BEGIN { @INC = qw(lib) }
   3 use strict;
   4 use Config;
   5 use Getopt::Long;
   6 use File::Find;
   7 use File::Copy;
   8 use File::Path qw(mkpath);
   9 use ExtUtils::Packlist;
  10 use Pod::Man;
  11 use subs qw(unlink chmod rename link);
  12 use vars qw($packlist @modpods);
  13 require Cwd;
  14
  15 if ($Config{d_umask}) {
  16     umask(022); # umasks like 077 aren't that useful for installations
  17 }
  18
  19 $ENV{SHELL} = 'sh' if $^O eq 'os2';
  20
  21 my $ver = $Config{version};     # Not used presently.
  22 my $release = substr($],0,3);   # Not used presently.
  23 my $patchlevel = substr($],3,2);
  24 die "Patchlevel of perl ($patchlevel)",
  25     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
  26         if $patchlevel != $Config{'PERL_VERSION'};
  27
  28 my $usage =
  29 "Usage:  installman --man1dir=/usr/wherever --man1ext=1
  30                    --man3dir=/usr/wherever --man3ext=3
  31                    --batchlimit=40
  32                    --notify --verbose --silent --help
  33         Defaults are:
  34         man1dir = $Config{'installman1dir'};
  35         man1ext = $Config{'man1ext'};
  36         man3dir = $Config{'installman3dir'};
  37         man3ext = $Config{'man3ext'};
  38         --notify  (or -n) just lists commands that would be executed.
  39         --verbose (or -V) report all progress.
  40         --silent  (or -S) be silent. Only report errors.\n";
  41
  42 my %opts;
  43 GetOptions( \%opts,
  44             qw( man1dir=s man1ext=s man3dir=s man3ext=s batchlimit=i
  45                 notify n help silent S verbose V))
  46         || die $usage;
  47 die $usage if $opts{help};
  48
  49 $opts{man1dir} = $Config{'installman1dir'}
  50     unless defined($opts{man1dir});
  51 $opts{man1ext} = $Config{'man1ext'}
  52     unless defined($opts{man1ext});
  53 $opts{man3dir} = $Config{'installman3dir'}
  54     unless defined($opts{man3dir});
  55 $opts{man3ext} = $Config{'man3ext'}
  56     unless defined($opts{man3ext});
  57 $opts{silent} ||= $opts{S};
  58 $opts{notify} ||= $opts{n};
  59 $opts{verbose} ||= $opts{V} || $opts{notify};
  60
  61 #Sanity checks
  62
  63 -x  "./perl$Config{exe_ext}"
  64   or warn "./perl$Config{exe_ext} not found!  Have you run make?\n";
  65 -d  $Config{'installprivlib'}
  66         || warn "Perl library directory $Config{'installprivlib'} not found.
  67                 Have you run make install?.  (Installing anyway.)\n";
  68 -x "t/perl$Config{exe_ext}"             || warn "WARNING: You've never run 'make test'!!!",
  69         "  (Installing anyway.)\n";
  70
  71 $packlist = ExtUtils::Packlist->new("$Config{installarchlib}/.packlist");
  72
  73
  74 # Install the main pod pages.
  75 pod2man('pod', $opts{man1dir}, $opts{man1ext});
  76
  77 # Install the pods for library modules.
  78 pod2man('lib', $opts{man3dir}, $opts{man3ext});
  79
  80 # Install the pods embedded in the installed scripts
  81 open UTILS, "utils.lst" or die "Can't open 'utils.lst': $!";
  82 while (<UTILS>) {
  83     next if /^#/;
  84     chomp;
  85     $_ = $1 if /#.*pod\s*=\s*(\S+)/;
  86     my ($where, $what) = m|^(.*?)/(\S+)|;
  87     pod2man($where, $opts{man1dir}, $opts{man1ext}, $what);
  88     if (my ($where2, $what2) = m|#.*link\s*=\s*(\S+)/(\S+)|) {
  89         my $old = "$opts{man1dir}/$what.$opts{man1ext}";
  90         my $new = "$opts{man1dir}/$what2.$opts{man1ext}";
  91         unlink($new);
  92         link($old, $new);
  93     }
  94 }
  95
  96 sub pod2man {
  97     # @script is scripts names if we are installing manpages embedded
  98     # in scripts, () otherwise
  99     my($poddir, $mandir, $manext, @script) = @_;
 100
 101     my($downdir); # can't just use .. when installing xsubpp manpage
 102
 103     $downdir = $poddir;
 104     $downdir =~ s:[^/]+:..:g;
 105     my($builddir) = Cwd::getcwd();
 106
 107     if ($mandir eq ' ' or $mandir eq '') {
 108         if (@script) {
 109             warn "Skipping installation of $poddir/$_ man page.\n"
 110                 foreach @script;
 111         } else {
 112             warn "Skipping installation of $poddir man pages.\n";
 113         }
 114         return;
 115     }
 116
 117     print "chdir $poddir\n" if $opts{verbose};
 118     chdir $poddir || die "Unable to cd to $poddir directory!\n$!\n";
 119
 120     mkpath($mandir, $opts{verbose}, 0777) unless $opts{notify};  # In File::Path
 121     # Make a list of all the .pm and .pod files in the directory.  We will
 122     # always run from the lib directory and use the full pathname
 123     # of the pod.
 124     if (@script) {
 125         @modpods = @script;
 126     }
 127     else {
 128         @modpods = ();
 129         File::Find::find(\&lsmodpods, '.');
 130     }
 131     my @to_process;
 132     foreach my $mod (@modpods) {
 133         my $manpage = $mod;
 134         my $tmp;
 135         # Skip .pm files that have corresponding .pod files, and Functions.pm.
 136         next if (($tmp = $mod) =~ s/\.pm$/.pod/ && -f $tmp);
 137         next if ($mod eq 'Pod/Functions.pm');   #### Used only by pod itself
 138
 139         # Convert name from  File/Basename.pm to File::Basename.3 format,
 140         # if necessary.
 141         $manpage =~ s#\.p(m|od)$##;
 142         if ($^O eq 'os2' || $^O eq 'amigaos' || $^O eq 'uwin' || $^O eq 'cygwin') {
 143           $manpage =~ s#/#.#g;
 144         }
 145         else {
 146           $manpage =~ s#/#::#g;
 147         }
 148         $tmp = "${mandir}/${manpage}.tmp";
 149         $manpage = "${mandir}/${manpage}.${manext}";
 150         push @to_process, [$mod, $tmp, $manpage];
 151     }
 152
 153     my $parser = Pod::Man->new( section => $manext,
 154                                 official=> 1,
 155                                 center  => 'Perl Programmers Reference Guide'
 156                               );
 157     foreach my $page (@to_process) {
 158         my($pod, $tmp, $manpage) = @$page;
 159
 160         print "  $manpage\n";
 161         if (!$opts{notify} && $parser->parse_from_file($pod, $tmp)) {
 162             if (-s $tmp) {
 163                 if (rename($tmp, $manpage)) {
 164                     $packlist->{$manpage} = { type => 'file' };
 165                     next;
 166                 }
 167             }
 168             unlink($tmp);
 169         }
 170     }
 171     chdir "$builddir" || die "Unable to cd back to $builddir directory!\n$!\n";
 172     print "  chdir $builddir\n" if $opts{verbose};
 173 }
 174
 175 sub lsmodpods {
 176     my $dir  = $File::Find::dir;
 177     my $name = $File::Find::name;
 178     if (-f $_) {
 179         $name =~ s#^\./##;
 180         push(@modpods, $name) if ($name =~ /\.p(m|od)$/);
 181     }
 182 }
 183
 184 $packlist->write() unless $opts{notify};
 185 print "  Installation complete\n" if $opts{verbose};
 186
 187 exit 0;
 188
 189
 190 ###############################################################################
 191 # Utility subroutines from installperl
 192
 193 sub unlink {
 194     my(@names) = @_;
 195     my $cnt = 0;
 196
 197     foreach my $name (@names) {
 198         next unless -e $name;
 199         chmod 0777, $name if $^O eq 'os2';
 200         print "  unlink $name\n" if $opts{verbose};
 201         ( CORE::unlink($name) and ++$cnt
 202             or warn "Couldn't unlink $name: $!\n" ) unless $opts{notify};
 203     }
 204     return $cnt;
 205 }
 206
 207 sub link {
 208     my($from,$to) = @_;
 209     my($success) = 0;
 210
 211     print "  ln $from $to\n" if $opts{verbose};
 212     eval {
 213         CORE::link($from, $to)
 214             ? $success++
 215             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 216               ? die "AFS"  # okay inside eval {}
 217               : warn "Couldn't link $from to $to: $!\n"
 218           unless $opts{notify};
 219     };
 220     if ($@) {
 221         File::Copy::copy($from, $to)
 222             ? $success++
 223             : warn "Couldn't copy $from to $to: $!\n"
 224           unless $opts{notify};
 225     }
 226     $success;
 227 }
 228
 229 sub rename {
 230     my($from,$to) = @_;
 231     if (-f $to and not unlink($to)) {
 232         my($i);
 233         for ($i = 1; $i < 50; $i++) {
 234             last if CORE::rename($to, "$to.$i");
 235         }
 236         warn("Cannot rename to `$to.$i': $!"), return 0
 237             if $i >= 50;        # Give up!
 238     }
 239     link($from,$to) || return 0;
 240     unlink($from);
 241 }
 242
 243 sub chmod {
 244     my($mode,$name) = @_;
 245
 246     printf "  chmod %o %s\n", $mode, $name if $opts{verbose};
 247     CORE::chmod($mode,$name) || warn sprintf("Couldn't chmod %o %s: $!\n",$mode,$name)
 248         unless $opts{notify};
 249 }
 250
 251 sub samepath {
 252     my($p1, $p2) = @_;
 253     my($dev1, $ino1, $dev2, $ino2);
 254
 255     if ($p1 ne $p2) {
 256         ($dev1, $ino1) = stat($p1);
 257         ($dev2, $ino2) = stat($p2);
 258         ($dev1 == $dev2 && $ino1 == $ino2);
 259     }
 260     else {
 261         1;
 262     }
 263 }