ext/threads/threads.pm

   1 package threads;
   2
   3 use 5.008;
   4 use strict;
   5 use warnings;
   6 use Config;
   7
   8 BEGIN {
   9     unless ($Config{useithreads}) {
  10         my @caller = caller(2);
  11         die <<EOF;
  12 $caller[1] line $caller[2]:
  13
  14 This Perl hasn't been configured and built properly for the threads
  15 module to work.  (The 'useithreads' configuration option hasn't been used.)
  16
  17 Having threads support requires all of Perl and all of the XS modules in
  18 the Perl installation to be rebuilt, it is not just a question of adding
  19 the threads module.  (In other words, threaded and non-threaded Perls
  20 are binary incompatible.)
  21
  22 If you want to the use the threads module, please contact the people
  23 who built your Perl.
  24
  25 Cannot continue, aborting.
  26 EOF
  27     }
  28 }
  29
  30 use overload
  31     '==' => \&equal,
  32     'fallback' => 1;
  33
  34 #use threads::Shared;
  35
  36 BEGIN {
  37     warn "Warning, threads::shared has already been loaded. ".
  38        "To enable shared variables for these modules 'use threads' ".
  39        "must be called before any of those modules are loaded\n"
  40                if($threads::shared::threads_shared);
  41 }
  42
  43 require Exporter;
  44 require DynaLoader;
  45
  46 our @ISA = qw(Exporter DynaLoader);
  47
  48 our %EXPORT_TAGS = ( all => [qw(yield)]);
  49
  50 our @EXPORT_OK = ( @{ $EXPORT_TAGS{'all'} } );
  51
  52 our @EXPORT = qw(
  53 async
  54 );
  55 our $VERSION = '0.99';
  56
  57
  58 sub equal {
  59     return 1 if($_[0]->tid() == $_[1]->tid());
  60     return 0;
  61 }
  62
  63 sub async (&;@) {
  64     my $cref = shift;
  65     return threads->new($cref,@_);
  66 }
  67
  68 sub object {
  69     return undef unless @_ > 1;
  70     foreach (threads->list) {
  71         return $_ if $_->tid == $_[1];
  72     }
  73     return undef;
  74 }
  75
  76 $threads::threads = 1;
  77
  78 bootstrap threads $VERSION;
  79
  80 # why document 'new' then use 'create' in the tests!
  81 *create = \&new;
  82
  83 # Preloaded methods go here.
  84
  85 1;
  86 __END__
  87
  88 =head1 NAME
  89
  90 threads - Perl extension allowing use of interpreter based threads from perl
  91
  92 =head1 SYNOPSIS
  93
  94     use threads;
  95
  96     sub start_thread {
  97         print "Thread started\n";
  98     }
  99
 100     my $thread  = threads->create("start_thread","argument");
 101     my $thread2 = $thread->create(sub { print "I am a thread"},"argument");
 102     my $thread3 = async { foreach (@files) { ... } };
 103
 104     $thread->join();
 105     $thread->detach();
 106
 107     $thread = threads->self();
 108     $thread = threads->object( $tid );
 109
 110     $thread->tid();
 111     threads->tid();
 112     threads->self->tid();
 113
 114     threads->yield();
 115
 116     threads->list();
 117
 118 =head1 DESCRIPTION
 119
 120 Perl 5.6 introduced something called interpreter threads.  Interpreter
 121 threads are different from "5005threads" (the thread model of Perl
 122 5.005) by creating a new perl interpreter per thread and not sharing
 123 any data or state between threads by default.
 124
 125 Prior to perl 5.8 this has only been available to people embedding
 126 perl and for emulating fork() on windows.
 127
 128 The threads API is loosely based on the old Thread.pm API. It is very
 129 important to note that variables are not shared between threads, all
 130 variables are per default thread local.  To use shared variables one
 131 must use threads::shared.
 132
 133 It is also important to note that you must enable threads by doing
 134 C<use threads> as early as possible in the script itself and that it
 135 is not possible to enable threading inside an C<eval "">, C<do>,
 136 C<require>, or C<use>.  In particular, if you are intending to share
 137 variables with threads::shared, you must C<use threads> before you
 138 C<use threads::shared> and C<threads> will emit a warning if you do
 139 it the other way around.
 140
 141 =over
 142
 143 =item $thread = threads->create(function, LIST)
 144
 145 This will create a new thread with the entry point function and give
 146 it LIST as parameters.  It will return the corresponding threads
 147 object. The new() method is an alias for create().
 148
 149 =item $thread->join
 150
 151 This will wait for the corresponding thread to join. When the thread
 152 finishes, join() will return the return values of the entry point
 153 function. If the thread has been detached, an error will be thrown.
 154 If the program exits without all other threads having been either
 155 joined or detached, then a warning will be issued. (A program exits
 156 either because one of its threads explicitly calls exit(), or in the
 157 case of the main thread, reaches the end of the main program file.)
 158
 159 =item $thread->detach
 160
 161 Will make the thread unjoinable, and cause any eventual return value
 162 to be discarded.
 163
 164 =item threads->self
 165
 166 This will return the thread object for the current thread.
 167
 168 =item $thread->tid
 169
 170 This will return the id of the thread.  Thread IDs are integers, with
 171 the main thread in a program being 0.  Currently Perl assigns a unique
 172 tid to every thread ever created in your program, assigning the first
 173 thread to be created a tid of 1, and increasing the tid by 1 for each
 174 new thread that's created.
 175
 176 NB the class method C<< threads->tid() >> is a quick way to get the
 177 current thread id if you don't have your thread object handy.
 178
 179 =item threads->object( tid )
 180
 181 This will return the thread object for the thread associated with the
 182 specified tid.  Returns undef if there is no thread associated with the tid
 183 or no tid is specified or the specified tid is undef.
 184
 185 =item threads->yield();
 186
 187 This is a suggestion to the OS to let this thread yield CPU time to other
 188 threads.  What actually happens is highly dependent upon the underlying
 189 thread implementation.
 190
 191 You may do C<use threads qw(yield)> then use just a bare C<yield> in your
 192 code.
 193
 194 =item threads->list();
 195
 196 This will return a list of all non joined, non detached threads.
 197
 198 =item async BLOCK;
 199
 200 C<async> creates a thread to execute the block immediately following
 201 it.  This block is treated as an anonymous sub, and so must have a
 202 semi-colon after the closing brace. Like C<< threads->new >>, C<async>
 203 returns a thread object.
 204
 205 =back
 206
 207 =head1 WARNINGS
 208
 209 =over 4
 210
 211 =item A thread exited while %d other threads were still running
 212
 213 A thread (not necessarily the main thread) exited while there were
 214 still other threads running.  Usually it's a good idea to first collect
 215 the return values of the created threads by joining them, and only then
 216 exit from the main thread.
 217
 218 =back
 219
 220 =head1 BUGS / TODO
 221
 222 The current implementation of threads has been an attempt to get
 223 a correct threading system working that could be built on,
 224 and optimized, in newer versions of perl.
 225
 226 Currently the overhead of creating a thread is rather large,
 227 also the cost of returning values can be large. These are areas
 228 were there most likely will be work done to optimize what data
 229 that needs to be cloned.
 230
 231 =over
 232
 233 =item Parent-Child threads.
 234
 235 On some platforms it might not be possible to destroy "parent"
 236 threads while there are still existing child "threads".
 237
 238 This will be possibly be fixed in later versions of perl.
 239
 240 =item tid is I32
 241
 242 The thread id is a 32 bit integer, it can potentially overflow.
 243 This might be fixed in a later version of perl.
 244
 245 =item Returning objects
 246
 247 When you return an object the entire stash that the object is blessed
 248 as well.  This will lead to a large memory usage.  The ideal situation
 249 would be to detect the original stash if it existed.
 250
 251 =item PERL_OLD_SIGNALS are not threadsafe, will not be.
 252
 253 =back
 254
 255 =head1 AUTHOR and COPYRIGHT
 256
 257 Arthur Bergman E<lt>arthur at contiller.seE<gt>
 258
 259 threads is released under the same license as Perl.
 260
 261 Thanks to
 262
 263 Richard Soderberg E<lt>rs at crystalflame.netE<gt>
 264 Helping me out tons, trying to find reasons for races and other weird bugs!
 265
 266 Simon Cozens E<lt>simon at brecon.co.ukE<gt>
 267 Being there to answer zillions of annoying questions
 268
 269 Rocco Caputo E<lt>troc at netrus.netE<gt>
 270
 271 Vipul Ved Prakash E<lt>mail at vipul.netE<gt>
 272 Helping with debugging.
 273
 274 please join perl-ithreads@perl.org for more information
 275
 276 =head1 SEE ALSO
 277
 278 L<threads::shared>, L<perlthrtut>,
 279 L<http://www.perl.com/pub/a/2002/06/11/threads.html>,
 280 L<perlcall>, L<perlembed>, L<perlguts>
 281
 282 =cut