ext/threads/threads.pm

   1 package threads;
   2
   3 use 5.008;
   4 use strict;
   5 use warnings;
   6 use Config;
   7
   8 BEGIN {
   9     unless ($Config{useithreads}) {
  10         my @caller = caller(2);
  11         die <<EOF;
  12 $caller[1] line $caller[2]:
  13
  14 This Perl hasn't been configured and built properly for the threads
  15 module to work.  (The 'useithreads' configuration option hasn't been used.)
  16
  17 Having threads support requires all of Perl and all of the XS modules in
  18 the Perl installation to be rebuilt, it is not just a question of adding
  19 the threads module.  (In other words, threaded and non-threaded Perls
  20 are binary incompatible.)
  21
  22 If you want to the use the threads module, please contact the people
  23 who built your Perl.
  24
  25 Cannot continue, aborting.
  26 EOF
  27     }
  28 }
  29
  30 use overload
  31     '==' => \&equal,
  32     'fallback' => 1;
  33
  34 BEGIN {
  35     warn "Warning, threads::shared has already been loaded. ".
  36        "To enable shared variables for these modules 'use threads' ".
  37        "must be called before any of those modules are loaded\n"
  38                if($threads::shared::threads_shared);
  39 }
  40
  41 require Exporter;
  42 require DynaLoader;
  43
  44 our @ISA = qw(Exporter DynaLoader);
  45
  46 our %EXPORT_TAGS = ( all => [qw(yield)]);
  47
  48 our @EXPORT_OK = ( @{ $EXPORT_TAGS{'all'} } );
  49
  50 our @EXPORT = qw(
  51 async
  52 );
  53 our $VERSION = '1.04';
  54
  55
  56 # || 0 to ensure compatibility with previous versions
  57 sub equal { ($_[0]->tid == $_[1]->tid) || 0 }
  58
  59 # use "goto" trick to avoid pad problems from 5.8.1 (fixed in 5.8.2)
  60 # should also be faster
  61 sub async (&;@) { unshift @_,'threads'; goto &new }
  62
  63 sub object {
  64     return undef unless @_ > 1;
  65     foreach (threads->list) {
  66         return $_ if $_->tid == $_[1];
  67     }
  68     return undef;
  69 }
  70
  71 $threads::threads = 1;
  72
  73 bootstrap threads $VERSION;
  74
  75 # why document 'new' then use 'create' in the tests!
  76 *create = \&new;
  77
  78 # Preloaded methods go here.
  79
  80 1;
  81 __END__
  82
  83 =head1 NAME
  84
  85 threads - Perl extension allowing use of interpreter based threads from perl
  86
  87 =head1 SYNOPSIS
  88
  89     use threads;
  90
  91     sub start_thread {
  92         print "Thread started\n";
  93     }
  94
  95     my $thread  = threads->create("start_thread","argument");
  96     my $thread2 = $thread->create(sub { print "I am a thread"},"argument");
  97     my $thread3 = async { foreach (@files) { ... } };
  98
  99     $thread->join();
 100     $thread->detach();
 101
 102     $thread = threads->self();
 103     $thread = threads->object( $tid );
 104
 105     $thread->tid();
 106     threads->tid();
 107     threads->self->tid();
 108
 109     threads->yield();
 110
 111     threads->list();
 112
 113 =head1 DESCRIPTION
 114
 115 Perl 5.6 introduced something called interpreter threads.  Interpreter
 116 threads are different from "5005threads" (the thread model of Perl
 117 5.005) by creating a new perl interpreter per thread and not sharing
 118 any data or state between threads by default.
 119
 120 Prior to perl 5.8 this has only been available to people embedding
 121 perl and for emulating fork() on windows.
 122
 123 The threads API is loosely based on the old Thread.pm API. It is very
 124 important to note that variables are not shared between threads, all
 125 variables are per default thread local.  To use shared variables one
 126 must use threads::shared.
 127
 128 It is also important to note that you must enable threads by doing
 129 C<use threads> as early as possible in the script itself and that it
 130 is not possible to enable threading inside an C<eval "">, C<do>,
 131 C<require>, or C<use>.  In particular, if you are intending to share
 132 variables with threads::shared, you must C<use threads> before you
 133 C<use threads::shared> and C<threads> will emit a warning if you do
 134 it the other way around.
 135
 136 =over
 137
 138 =item $thread = threads->create(function, LIST)
 139
 140 This will create a new thread with the entry point function and give
 141 it LIST as parameters.  It will return the corresponding threads
 142 object. The new() method is an alias for create().
 143
 144 =item $thread->join
 145
 146 This will wait for the corresponding thread to join. When the thread
 147 finishes, join() will return the return values of the entry point
 148 function. If the thread has been detached, an error will be thrown.
 149
 150 The context (scalar or list) of the thread creation is also the
 151 context for join().  This means that if you intend to return an array
 152 from a thread, you must use C<my ($thread) = threads->new(...)>, and
 153 that if you intend to return a scalar, you must use C<my $thread = ...>.
 154
 155 If the program exits without all other threads having been either
 156 joined or detached, then a warning will be issued. (A program exits
 157 either because one of its threads explicitly calls exit(), or in the
 158 case of the main thread, reaches the end of the main program file.)
 159
 160
 161 =item $thread->detach
 162
 163 Will make the thread unjoinable, and cause any eventual return value
 164 to be discarded.
 165
 166 =item threads->self
 167
 168 This will return the thread object for the current thread.
 169
 170 =item $thread->tid
 171
 172 This will return the id of the thread.  Thread IDs are integers, with
 173 the main thread in a program being 0.  Currently Perl assigns a unique
 174 tid to every thread ever created in your program, assigning the first
 175 thread to be created a tid of 1, and increasing the tid by 1 for each
 176 new thread that's created.
 177
 178 NB the class method C<< threads->tid() >> is a quick way to get the
 179 current thread id if you don't have your thread object handy.
 180
 181 =item threads->object( tid )
 182
 183 This will return the thread object for the thread associated with the
 184 specified tid.  Returns undef if there is no thread associated with the tid
 185 or no tid is specified or the specified tid is undef.
 186
 187 =item threads->yield();
 188
 189 This is a suggestion to the OS to let this thread yield CPU time to other
 190 threads.  What actually happens is highly dependent upon the underlying
 191 thread implementation.
 192
 193 You may do C<use threads qw(yield)> then use just a bare C<yield> in your
 194 code.
 195
 196 =item threads->list();
 197
 198 This will return a list of all non joined, non detached threads.
 199
 200 =item async BLOCK;
 201
 202 C<async> creates a thread to execute the block immediately following
 203 it.  This block is treated as an anonymous sub, and so must have a
 204 semi-colon after the closing brace. Like C<< threads->new >>, C<async>
 205 returns a thread object.
 206
 207 =back
 208
 209 =head1 WARNINGS
 210
 211 =over 4
 212
 213 =item A thread exited while %d other threads were still running
 214
 215 A thread (not necessarily the main thread) exited while there were
 216 still other threads running.  Usually it's a good idea to first collect
 217 the return values of the created threads by joining them, and only then
 218 exit from the main thread.
 219
 220 =back
 221
 222 =head1 TODO
 223
 224 The current implementation of threads has been an attempt to get
 225 a correct threading system working that could be built on,
 226 and optimized, in newer versions of perl.
 227
 228 Currently the overhead of creating a thread is rather large,
 229 also the cost of returning values can be large. These are areas
 230 were there most likely will be work done to optimize what data
 231 that needs to be cloned.
 232
 233 =head1 BUGS
 234
 235 =over
 236
 237 =item Parent-Child threads.
 238
 239 On some platforms it might not be possible to destroy "parent"
 240 threads while there are still existing child "threads".
 241
 242 This will possibly be fixed in later versions of perl.
 243
 244 =item tid is I32
 245
 246 The thread id is a 32 bit integer, it can potentially overflow.
 247 This might be fixed in a later version of perl.
 248
 249 =item Returning objects
 250
 251 When you return an object the entire stash that the object is blessed
 252 as well.  This will lead to a large memory usage.  The ideal situation
 253 would be to detect the original stash if it existed.
 254
 255 =item Creating threads inside BEGIN blocks
 256
 257 Creating threads inside BEGIN blocks (or during the compilation phase
 258 in general) does not work.  (In Windows, trying to use fork() inside
 259 BEGIN blocks is an equally losing proposition, since it has been
 260 implemented in very much the same way as threads.)
 261
 262 =item PERL_OLD_SIGNALS are not threadsafe, will not be.
 263
 264 If your Perl has been built with PERL_OLD_SIGNALS (one has
 265 to explicitly add that symbol to ccflags, see C<perl -V>),
 266 signal handling is not threadsafe.
 267
 268 =back
 269
 270 =head1 AUTHOR and COPYRIGHT
 271
 272 Arthur Bergman E<lt>sky at nanisky.comE<gt>
 273
 274 threads is released under the same license as Perl.
 275
 276 Thanks to
 277
 278 Richard Soderberg E<lt>perl at crystalflame.netE<gt>
 279 Helping me out tons, trying to find reasons for races and other weird bugs!
 280
 281 Simon Cozens E<lt>simon at brecon.co.ukE<gt>
 282 Being there to answer zillions of annoying questions
 283
 284 Rocco Caputo E<lt>troc at netrus.netE<gt>
 285
 286 Vipul Ved Prakash E<lt>mail at vipul.netE<gt>
 287 Helping with debugging.
 288
 289 please join perl-ithreads@perl.org for more information
 290
 291 =head1 SEE ALSO
 292
 293 L<threads::shared>, L<perlthrtut>,
 294 L<http://www.perl.com/pub/a/2002/06/11/threads.html>,
 295 L<perlcall>, L<perlembed>, L<perlguts>
 296
 297 =cut