ext/threads/t/problems.t

   1
   2 BEGIN {
   3     chdir 't' if -d 't';
   4     push @INC, '../lib';
   5     require Config; import Config;
   6     unless ($Config{'useithreads'}) {
   7         print "1..0 # Skip: no useithreads\n";
   8         exit 0;
   9     }
  10 }
  11
  12 use warnings;
  13 use strict;
  14 use threads;
  15 use threads::shared;
  16
  17 # Note that we can't use  Test::More here, as we would need to
  18 # call is() from within the DESTROY() function at global destruction time,
  19 # and parts of Test::* may have already been freed by then
  20
  21 print "1..5\n";
  22
  23 my $test : shared = 1;
  24
  25 sub is($$$) {
  26     my ($got, $want, $desc) = @_;
  27     unless ($got eq $want) {
  28         print "# EXPECTED: $want\n";
  29         print "# GOT:      got\n";
  30         print "not ";
  31     }
  32     print "ok $test - $desc\n";
  33     $test++;
  34 }
  35
  36
  37 #
  38 # This tests for too much destruction
  39 # which was caused by cloning stashes
  40 # on join which led to double the dataspace
  41 #
  42 #########################
  43
  44 $|++;
  45
  46 {
  47     sub Foo::DESTROY {
  48         my $self = shift;
  49         my ($package, $file, $line) = caller;
  50         is(threads->tid(),$self->{tid},
  51                 "In destroy[$self->{tid}] it should be correct too" )
  52     }
  53     my $foo;
  54     $foo = bless {tid => 0}, 'Foo';
  55     my $bar = threads->create(sub {
  56         is(threads->tid(),1, "And tid be 1 here");
  57         $foo->{tid} = 1;
  58         return $foo;
  59     })->join();
  60     $bar->{tid} = 0;
  61 }
  62
  63 #
  64 # This tests whether we can call Config::myconfig after threads have been
  65 # started (interpreter cloned).  5.8.1 and 5.8.2 contained a bug that would
  66 # disallow that too be done, because an attempt was made to change a variable
  67 # with the : unique attribute.
  68 #
  69 #########################
  70
  71 threads->new( sub {1} )->join;
  72 my $not = eval { Config::myconfig() } ? '' : 'not ';
  73 print "${not}ok $test - Are we able to call Config::myconfig after clone\n";
  74 $test++;
  75
  76 1;