ext/threads/shared/shared.pm

   1 package threads::shared;
   2
   3 use 5.007_003;
   4 use strict;
   5 use warnings;
   6 use Config;
   7
   8 BEGIN {
   9     unless ($Config{useithreads}) {
  10         my @caller = caller(2);
  11         die <<EOF;
  12 $caller[1] line $caller[2]:
  13
  14 This Perl hasn't been configured and built properly for the threads
  15 module to work.  (The 'useithreads' configuration option hasn't been used.)
  16
  17 Having threads support requires all of Perl and all of the modules in
  18 the Perl installation to be rebuilt, it is not just a question of adding
  19 the threads module.  (In other words, threaded and non-threaded Perls
  20 are binary incompatible.)
  21
  22 If you want to the use the threads module, please contact the people
  23 who built your Perl.
  24
  25 Cannot continue, aborting.
  26 EOF
  27     }
  28 }
  29
  30 require Exporter;
  31 our @ISA = qw(Exporter);
  32 our @EXPORT = qw(share cond_wait cond_broadcast cond_signal _refcnt _id _thrcnt);
  33 our $VERSION = '0.90';
  34
  35 use Attribute::Handlers;
  36
  37
  38 if ($Config{'useithreads'}) {
  39         *cond_wait = \&cond_wait_enabled;
  40         *cond_signal = \&cond_signal_enabled;
  41         *cond_broadcast = \&cond_broadcast_enabled;
  42         require XSLoader;
  43         XSLoader::load('threads::shared',$VERSION);
  44 }
  45 else {
  46         *share = \&share_disabled;
  47         *cond_wait = \&cond_wait_disabled;
  48         *cond_signal = \&cond_signal_disabled;
  49         *cond_broadcast = \&cond_broadcast_disabled;
  50 }
  51
  52
  53 sub cond_wait_disabled { return @_ };
  54 sub cond_signal_disabled { return @_};
  55 sub cond_broadcast_disabled { return @_};
  56 sub share_disabled { return @_}
  57
  58 $threads::shared::threads_shared = 1;
  59
  60 sub _thrcnt { 42 }
  61
  62 sub threads::shared::tie::SPLICE
  63 {
  64  die "Splice not implemented for shared arrays";
  65 }
  66
  67 sub UNIVERSAL::shared : ATTR {
  68     my ($package, $symbol, $referent, $attr, $data, $phase) = @_;
  69     share($referent);
  70 }
  71
  72 __END__
  73
  74 =head1 NAME
  75
  76 threads::shared - Perl extension for sharing data structures between threads
  77
  78 =head1 SYNOPSIS
  79
  80   use threads;
  81   use threads::shared;
  82
  83   my($scalar, @array, %hash);
  84   share($scalar);
  85   share(@array);
  86   share(%hash);
  87   my $bar = share([]);
  88   $hash{bar} = share({});
  89
  90   lock(%hash);
  91   unlock(%hash);
  92   cond_wait($scalar);
  93   cond_broadcast(@array);
  94   cond_signal(%hash);
  95
  96 =head1 DESCRIPTION
  97
  98 This modules allows you to share() variables. These variables will
  99 then be shared across different threads (and pseudoforks on
 100 win32). They are used together with the threads module.
 101
 102 =head1 EXPORT
 103
 104 C<share>, C<lock>, C<unlock>, C<cond_wait>, C<cond_signal>, C<cond_broadcast>
 105
 106 =head1 FUNCTIONS
 107
 108 =over 4
 109
 110 =item share VARIABLE
 111
 112 C<share> takes a value and marks it as shared. You can share a scalar, array,
 113 hash, scalar ref, array ref or hash ref. C<share> will return the shared value.
 114
 115 C<share> will traverse up references exactly I<one> level.
 116 C<share(\$a)> is equivalent to C<share($a)>, while C<share(\\$a)> is not.
 117
 118 =item lock VARIABLE
 119
 120 C<lock> places a lock on a variable until the lock goes out of scope.  If
 121 the variable is locked by another thread, the C<lock> call will block until
 122 it's available. C<lock> is recursive, so multiple calls to C<lock> are
 123 safe -- the variable will remain locked until the outermost lock on the
 124 variable goes out of scope or C<unlock> is called enough times to match
 125 the number of calls to <lock>.
 126
 127 If a container object, such as a hash or array, is locked, all the elements
 128 of that container are not locked. For example, if a thread does a C<lock
 129 @a>, any other thread doing a C<lock($a[12])> won't block.
 130
 131 C<lock> will traverse up references exactly I<one> level.
 132 C<lock(\$a)> is equivalent to C<lock($a)>, while C<lock(\\$a)> is not.
 133
 134
 135 =item unlock VARIABLE
 136
 137 C<unlock> takes a B<locked> variable and decrements the lock count.
 138 If the lock count is zero the variable is unlocked. It is not necessary
 139 to call C<unlock> but it can be useful to reduce lock contention.
 140
 141 C<unlock> will traverse up references exactly I<one> level.
 142 C<unlock(\$a)> is equivalent to C<unlock($a)>, while C<unlock(\\$a)> is not.
 143
 144 =item cond_wait VARIABLE
 145
 146 The C<cond_wait> function takes a B<locked> variable as a parameter,
 147 unlocks the variable, and blocks until another thread does a C<cond_signal>
 148 or C<cond_broadcast> for that same locked variable. The variable that
 149 C<cond_wait> blocked on is relocked after the C<cond_wait> is satisfied.
 150 If there are multiple threads C<cond_wait>ing on the same variable, all but
 151 one will reblock waiting to reacquire the lock on the variable. (So if
 152 you're only using C<cond_wait> for synchronization, give up the lock as
 153 soon as possible)
 154
 155 It is important to note that the variable can be notified even if no
 156 thread C<cond_signal> or C<cond_broadcast> on the variable. It is therefore
 157 important to check the value of the variable and go back to waiting if the
 158 requirement is not fulfilled.
 159
 160 =item cond_signal VARIABLE
 161
 162 The C<cond_signal> function takes a B<locked> variable as a parameter and
 163 unblocks one thread that's C<cond_wait>ing on that variable. If more than
 164 one thread is blocked in a C<cond_wait> on that variable, only one (and
 165 which one is indeterminate) will be unblocked.
 166
 167 If there are no threads blocked in a C<cond_wait> on the variable, the
 168 signal is discarded.
 169
 170 =item cond_broadcast VARIABLE
 171
 172 The C<cond_broadcast> function works similarly to C<cond_signal>.
 173 C<cond_broadcast>, though, will unblock B<all> the threads that are blocked
 174 in a C<cond_wait> on the locked variable, rather than only one.
 175
 176 =back
 177
 178 =head1 NOTES
 179
 180 threads::shared is designed to disable itself silently if threads are
 181 not available. If you want access to threads, you must C<use threads>
 182 before you C<use threads::shared>.  threads will emit a warning if you
 183 use it after threads::shared.
 184
 185 =head1 BUGS
 186
 187 C<bless> is not supported on shared references. In the current version,
 188 C<bless> will only bless the thread local reference and the blessing
 189 will not propagate to the other threads. This is expected to be
 190 implemented in a future version of Perl.
 191
 192 Does not support splice on arrays!
 193
 194 =head1 AUTHOR
 195
 196 Arthur Bergman E<lt>arthur at contiller.seE<gt>
 197
 198 threads::shared is released under the same license as Perl
 199
 200 Documentation borrowed from Thread.pm
 201
 202 =head1 SEE ALSO
 203
 204 L<perl> L<threads>
 205
 206 =cut
 207
 208
 209
 210
 211