ext/re/re.pm

   1 package re;
   2
   3 # pragma for controlling the regex engine
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION     = "0.08";
   8 our @ISA         = qw(Exporter);
   9 our @EXPORT_OK   = qw(is_regexp regexp_pattern regmust
  10                       regname regnames
  11                       regnames_count regnames_iterinit regnames_iternext);
  12 our %EXPORT_OK = map { $_ => 1 } @EXPORT_OK;
  13
  14 # *** WARNING *** WARNING *** WARNING *** WARNING *** WARNING ***
  15 #
  16 # If you modify these values see comment below!
  17
  18 my %bitmask = (
  19     taint   => 0x00100000, # HINT_RE_TAINT
  20     eval    => 0x00200000, # HINT_RE_EVAL
  21 );
  22
  23 # - File::Basename contains a literal for 'taint' as a fallback.  If
  24 # taint is changed here, File::Basename must be updated as well.
  25 #
  26 # - ExtUtils::ParseXS uses a hardcoded
  27 # BEGIN { $^H |= 0x00200000 }
  28 # in it to allow re.xs to be built. So if 'eval' is changed here then
  29 # ExtUtils::ParseXS must be changed as well.
  30 #
  31 # *** WARNING *** WARNING *** WARNING *** WARNING *** WARNING ***
  32
  33 sub setcolor {
  34  eval {                         # Ignore errors
  35   require Term::Cap;
  36
  37   my $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
  38   my $props = $ENV{PERL_RE_TC} || 'md,me,so,se,us,ue';
  39   my @props = split /,/, $props;
  40   my $colors = join "\t", map {$terminal->Tputs($_,1)} @props;
  41
  42   $colors =~ s/\0//g;
  43   $ENV{PERL_RE_COLORS} = $colors;
  44  };
  45  if ($@) {
  46     $ENV{PERL_RE_COLORS} ||= qq'\t\t> <\t> <\t\t';
  47  }
  48
  49 }
  50
  51 my %flags = (
  52     COMPILE         => 0x0000FF,
  53     PARSE           => 0x000001,
  54     OPTIMISE        => 0x000002,
  55     TRIEC           => 0x000004,
  56     DUMP            => 0x000008,
  57
  58     EXECUTE         => 0x00FF00,
  59     INTUIT          => 0x000100,
  60     MATCH           => 0x000200,
  61     TRIEE           => 0x000400,
  62
  63     EXTRA           => 0xFF0000,
  64     TRIEM           => 0x010000,
  65     OFFSETS         => 0x020000,
  66     OFFSETSDBG      => 0x040000,
  67     STATE           => 0x080000,
  68     OPTIMISEM       => 0x100000,
  69     STACK           => 0x280000,
  70 );
  71 $flags{ALL} = -1;
  72 $flags{All} = $flags{all} = $flags{DUMP} | $flags{EXECUTE};
  73 $flags{Extra} = $flags{EXECUTE} | $flags{COMPILE};
  74 $flags{More} = $flags{MORE} = $flags{All} | $flags{TRIEC} | $flags{TRIEM} | $flags{STATE};
  75 $flags{State} = $flags{DUMP} | $flags{EXECUTE} | $flags{STATE};
  76 $flags{TRIE} = $flags{DUMP} | $flags{EXECUTE} | $flags{TRIEC};
  77
  78 my $installed;
  79 my $installed_error;
  80
  81 sub _do_install {
  82     if ( ! defined($installed) ) {
  83         require XSLoader;
  84         $installed = eval { XSLoader::load('re', $VERSION) } || 0;
  85         $installed_error = $@;
  86     }
  87 }
  88
  89 sub _load_unload {
  90     my ($on)= @_;
  91     if ($on) {
  92         _do_install();
  93         if ( ! $installed ) {
  94             die "'re' not installed!? ($installed_error)";
  95         } else {
  96             # We call install() every time, as if we didn't, we wouldn't
  97             # "see" any changes to the color environment var since
  98             # the last time it was called.
  99
 100             # install() returns an integer, which if casted properly
 101             # in C resolves to a structure containing the regex
 102             # hooks. Setting it to a random integer will guarantee
 103             # segfaults.
 104             $^H{regcomp} = install();
 105         }
 106     } else {
 107         delete $^H{regcomp};
 108     }
 109 }
 110
 111 sub bits {
 112     my $on = shift;
 113     my $bits = 0;
 114     unless (@_) {
 115         require Carp;
 116         Carp::carp("Useless use of \"re\" pragma");
 117     }
 118     foreach my $idx (0..$#_){
 119         my $s=$_[$idx];
 120         if ($s eq 'Debug' or $s eq 'Debugcolor') {
 121             setcolor() if $s =~/color/i;
 122             ${^RE_DEBUG_FLAGS} = 0 unless defined ${^RE_DEBUG_FLAGS};
 123             for my $idx ($idx+1..$#_) {
 124                 if ($flags{$_[$idx]}) {
 125                     if ($on) {
 126                         ${^RE_DEBUG_FLAGS} |= $flags{$_[$idx]};
 127                     } else {
 128                         ${^RE_DEBUG_FLAGS} &= ~ $flags{$_[$idx]};
 129                     }
 130                 } else {
 131                     require Carp;
 132                     Carp::carp("Unknown \"re\" Debug flag '$_[$idx]', possible flags: ",
 133                                join(", ",sort keys %flags ) );
 134                 }
 135             }
 136             _load_unload($on ? 1 : ${^RE_DEBUG_FLAGS});
 137             last;
 138         } elsif ($s eq 'debug' or $s eq 'debugcolor') {
 139             setcolor() if $s =~/color/i;
 140             _load_unload($on);
 141         } elsif (exists $bitmask{$s}) {
 142             $bits |= $bitmask{$s};
 143         } elsif ($EXPORT_OK{$s}) {
 144             _do_install();
 145             require Exporter;
 146             re->export_to_level(2, 're', $s);
 147         } else {
 148             require Carp;
 149             Carp::carp("Unknown \"re\" subpragma '$s' (known ones are: ",
 150                        join(', ', map {qq('$_')} 'debug', 'debugcolor', sort keys %bitmask),
 151                        ")");
 152         }
 153     }
 154     $bits;
 155 }
 156
 157 sub import {
 158     shift;
 159     $^H |= bits(1, @_);
 160 }
 161
 162 sub unimport {
 163     shift;
 164     $^H &= ~ bits(0, @_);
 165 }
 166
 167 1;
 168
 169 __END__
 170
 171 =head1 NAME
 172
 173 re - Perl pragma to alter regular expression behaviour
 174
 175 =head1 SYNOPSIS
 176
 177     use re 'taint';
 178     ($x) = ($^X =~ /^(.*)$/s);     # $x is tainted here
 179
 180     $pat = '(?{ $foo = 1 })';
 181     use re 'eval';
 182     /foo${pat}bar/;                # won't fail (when not under -T switch)
 183
 184     {
 185         no re 'taint';             # the default
 186         ($x) = ($^X =~ /^(.*)$/s); # $x is not tainted here
 187
 188         no re 'eval';              # the default
 189         /foo${pat}bar/;            # disallowed (with or without -T switch)
 190     }
 191
 192     use re 'debug';                # output debugging info during
 193     /^(.*)$/s;                     #     compile and run time
 194
 195
 196     use re 'debugcolor';           # same as 'debug', but with colored output
 197     ...
 198
 199     use re qw(Debug All);          # Finer tuned debugging options.
 200     use re qw(Debug More);
 201     no re qw(Debug ALL);           # Turn of all re debugging in this scope
 202
 203     use re qw(is_regexp regexp_pattern); # import utility functions
 204     my ($pat,$mods)=regexp_pattern(qr/foo/i);
 205     if (is_regexp($obj)) {
 206         print "Got regexp: ",
 207             scalar regexp_pattern($obj); # just as perl would stringify it
 208     }                                    # but no hassle with blessed re's.
 209
 210 (We use $^X in these examples because it's tainted by default.)
 211
 212 =head1 DESCRIPTION
 213
 214 =head2 'taint' mode
 215
 216 When C<use re 'taint'> is in effect, and a tainted string is the target
 217 of a regex, the regex memories (or values returned by the m// operator
 218 in list context) are tainted.  This feature is useful when regex operations
 219 on tainted data aren't meant to extract safe substrings, but to perform
 220 other transformations.
 221
 222 =head2 'eval' mode
 223
 224 When C<use re 'eval'> is in effect, a regex is allowed to contain
 225 C<(?{ ... })> zero-width assertions even if regular expression contains
 226 variable interpolation.  That is normally disallowed, since it is a
 227 potential security risk.  Note that this pragma is ignored when the regular
 228 expression is obtained from tainted data, i.e.  evaluation is always
 229 disallowed with tainted regular expressions.  See L<perlre/(?{ code })>.
 230
 231 For the purpose of this pragma, interpolation of precompiled regular
 232 expressions (i.e., the result of C<qr//>) is I<not> considered variable
 233 interpolation.  Thus:
 234
 235     /foo${pat}bar/
 236
 237 I<is> allowed if $pat is a precompiled regular expression, even
 238 if $pat contains C<(?{ ... })> assertions.
 239
 240 =head2 'debug' mode
 241
 242 When C<use re 'debug'> is in effect, perl emits debugging messages when
 243 compiling and using regular expressions.  The output is the same as that
 244 obtained by running a C<-DDEBUGGING>-enabled perl interpreter with the
 245 B<-Dr> switch. It may be quite voluminous depending on the complexity
 246 of the match.  Using C<debugcolor> instead of C<debug> enables a
 247 form of output that can be used to get a colorful display on terminals
 248 that understand termcap color sequences.  Set C<$ENV{PERL_RE_TC}> to a
 249 comma-separated list of C<termcap> properties to use for highlighting
 250 strings on/off, pre-point part on/off.
 251 See L<perldebug/"Debugging regular expressions"> for additional info.
 252
 253 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
 254 lexically scoped, as the other directives are.  However they have both
 255 compile-time and run-time effects.
 256
 257 See L<perlmodlib/Pragmatic Modules>.
 258
 259 =head2 'Debug' mode
 260
 261 Similarly C<use re 'Debug'> produces debugging output, the difference
 262 being that it allows the fine tuning of what debugging output will be
 263 emitted. Options are divided into three groups, those related to
 264 compilation, those related to execution and those related to special
 265 purposes. The options are as follows:
 266
 267 =over 4
 268
 269 =item Compile related options
 270
 271 =over 4
 272
 273 =item COMPILE
 274
 275 Turns on all compile related debug options.
 276
 277 =item PARSE
 278
 279 Turns on debug output related to the process of parsing the pattern.
 280
 281 =item OPTIMISE
 282
 283 Enables output related to the optimisation phase of compilation.
 284
 285 =item TRIEC
 286
 287 Detailed info about trie compilation.
 288
 289 =item DUMP
 290
 291 Dump the final program out after it is compiled and optimised.
 292
 293 =back
 294
 295 =item Execute related options
 296
 297 =over 4
 298
 299 =item EXECUTE
 300
 301 Turns on all execute related debug options.
 302
 303 =item MATCH
 304
 305 Turns on debugging of the main matching loop.
 306
 307 =item TRIEE
 308
 309 Extra debugging of how tries execute.
 310
 311 =item INTUIT
 312
 313 Enable debugging of start point optimisations.
 314
 315 =back
 316
 317 =item Extra debugging options
 318
 319 =over 4
 320
 321 =item EXTRA
 322
 323 Turns on all "extra" debugging options.
 324
 325 =item TRIEM
 326
 327 Enable enhanced TRIE debugging. Enhances both TRIEE
 328 and TRIEC.
 329
 330 =item STATE
 331
 332 Enable debugging of states in the engine.
 333
 334 =item STACK
 335
 336 Enable debugging of the recursion stack in the engine. Enabling
 337 or disabling this option automatically does the same for debugging
 338 states as well. This output from this can be quite large.
 339
 340 =item OPTIMISEM
 341
 342 Enable enhanced optimisation debugging and start point optimisations.
 343 Probably not useful except when debugging the regex engine itself.
 344
 345 =item OFFSETS
 346
 347 Dump offset information. This can be used to see how regops correlate
 348 to the pattern. Output format is
 349
 350    NODENUM:POSITION[LENGTH]
 351
 352 Where 1 is the position of the first char in the string. Note that position
 353 can be 0, or larger than the actual length of the pattern, likewise length
 354 can be zero.
 355
 356 =item OFFSETSDBG
 357
 358 Enable debugging of offsets information. This emits copious
 359 amounts of trace information and doesn't mesh well with other
 360 debug options.
 361
 362 Almost definitely only useful to people hacking
 363 on the offsets part of the debug engine.
 364
 365 =back
 366
 367 =item Other useful flags
 368
 369 These are useful shortcuts to save on the typing.
 370
 371 =over 4
 372
 373 =item ALL
 374
 375 Enable all compile and execute options at once.
 376
 377 =item All
 378
 379 Enable DUMP and all execute options. Equivalent to:
 380
 381   use re 'debug';
 382
 383 =item MORE
 384
 385 =item More
 386
 387 Enable TRIEM and all execute compile and execute options.
 388
 389 =back
 390
 391 =back
 392
 393 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
 394 lexically scoped, as the other directives are.  However they have both
 395 compile-time and run-time effects.
 396
 397 =head2 Exportable Functions
 398
 399 As of perl 5.9.5 're' debug contains a number of utility functions that
 400 may be optionally exported into the caller's namespace. They are listed
 401 below.
 402
 403 =over 4
 404
 405 =item is_regexp($ref)
 406
 407 Returns true if the argument is a compiled regular expression as returned
 408 by C<qr//>, false if it is not.
 409
 410 This function will not be confused by overloading or blessing. In
 411 internals terms, this extracts the regexp pointer out of the
 412 PERL_MAGIC_qr structure so it it cannot be fooled.
 413
 414 =item regexp_pattern($ref)
 415
 416 If the argument is a compiled regular expression as returned by C<qr//>,
 417 then this function returns the pattern.
 418
 419 In list context it returns a two element list, the first element
 420 containing the pattern and the second containing the modifiers used when
 421 the pattern was compiled.
 422
 423   my ($pat, $mods) = regexp_pattern($ref);
 424
 425 In scalar context it returns the same as perl would when strigifying a raw
 426 C<qr//> with the same pattern inside.  If the argument is not a compiled
 427 reference then this routine returns false but defined in scalar context,
 428 and the empty list in list context. Thus the following
 429
 430     if (regexp_pattern($ref) eq '(?i-xsm:foo)')
 431
 432 will be warning free regardless of what $ref actually is.
 433
 434 Like C<is_regexp> this function will not be confused by overloading
 435 or blessing of the object.
 436
 437 =item regmust($ref)
 438
 439 If the argument is a compiled regular expression as returned by C<qr//>,
 440 then this function returns what the optimiser consiers to be the longest
 441 anchored fixed string and longest floating fixed string in the pattern.
 442
 443 A I<fixed string> is defined as being a substring that must appear for the
 444 pattern to match. An I<anchored fixed string> is a fixed string that must
 445 appear at a particular offset from the beginning of the match. A I<floating
 446 fixed string> is defined as a fixed string that can appear at any point in
 447 a range of positions relative to the start of the match. For example,
 448
 449     my $qr = qr/here .* there/x;
 450     my ($anchored, $floating) = regmust($qr);
 451     print "anchored:'$anchored'\nfloating:'$floating'\n";
 452
 453 results in
 454
 455     anchored:'here'
 456     floating:'there'
 457
 458 Because the C<here> is before the C<.*> in the pattern, its position
 459 can be determined exactly. That's not true, however, for the C<there>;
 460 it could appear at any point after where the anchored string appeared.
 461 Perl uses both for its optimisations, prefering the longer, or, if they are
 462 equal, the floating.
 463
 464 B<NOTE:> This may not necessarily be the definitive longest anchored and
 465 floating string. This will be what the optimiser of the Perl that you
 466 are using thinks is the longest. If you believe that the result is wrong
 467 please report it via the L<perlbug> utility.
 468
 469 =item regname($name,$qr,$all)
 470
 471 Returns the contents of a named buffer. If $qr is missing, or is not the
 472 result of a qr// then returns the result of the last successful match. If
 473 $all is true then returns an array ref containing one entry per buffer,
 474 otherwise returns the first defined buffer.
 475
 476 =item regnames($qr,$all)
 477
 478 Returns a list of all of the named buffers defined in a pattern. If
 479 $all is true then it returns all names defined, if not returns only
 480 names which were involved in the last successful match. If $qr is omitted
 481 or is not the result of a qr// then returns the details for the last
 482 successful match.
 483
 484 =item regnames_iterinit($qr)
 485
 486 Initializes the internal hash iterator associated to a regexps named capture
 487 buffers. If $qr is omitted resets the iterator associated with the regexp used
 488 in the last successful match.
 489
 490 =item regnames_iternext($qr,$all)
 491
 492 Gets the next key from the hash associated with a regexp. If $qr
 493 is omitted resets the iterator associated with the regexp used in the
 494 last successful match. If $all is true returns the keys of all of the
 495 distinct named buffers in the pattern, if not returns only those names
 496 used in the last successful match.
 497
 498 =item regnames_count($qr)
 499
 500 Returns the number of distinct names defined in the regexp $qr. If
 501 $qr is omitted or not a regexp returns the count of names in the
 502 last successful match.
 503
 504 B<Note:> that this result is always the actual  number of distinct
 505 named buffers defined, it may not actually match that which is
 506 returned by C<regnames()> and related routines when those routines
 507 have not been called with the $all parameter set..
 508
 509 =back
 510
 511 =head1 SEE ALSO
 512
 513 L<perlmodlib/Pragmatic Modules>.
 514
 515 =cut