ext/Time/HiRes/HiRes.pm

   1 package Time::HiRes;
   2
   3 use strict;
   4 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK $AUTOLOAD);
   5
   6 require Exporter;
   7 use XSLoader;
   8
   9 @ISA = qw(Exporter);
  10
  11 @EXPORT = qw( );
  12 @EXPORT_OK = qw (usleep sleep ualarm alarm gettimeofday time tv_interval
  13                  getitimer setitimer ITIMER_REAL ITIMER_VIRTUAL ITIMER_PROF);
  14
  15 $VERSION = '1.20_00';
  16
  17 sub AUTOLOAD {
  18     my $constname;
  19     ($constname= $AUTOLOAD) =~ s/.*:://;
  20     my $val = constant($constname, @_ ? $_[0] : 0);
  21     if ($!) {
  22         my ($pack,$file,$line) = caller;
  23         die "Your vendor has not defined Time::HiRes macro $constname, used at $file line $line.\n";
  24     }
  25     {
  26         no strict 'refs';
  27         *$AUTOLOAD = sub { $val };
  28     }
  29     goto &$AUTOLOAD;
  30 }
  31
  32 XSLoader::load 'Time::HiRes', $VERSION;
  33
  34 # Preloaded methods go here.
  35
  36 sub tv_interval {
  37     # probably could have been done in C
  38     my ($a, $b) = @_;
  39     $b = [gettimeofday()] unless defined($b);
  40     (${$b}[0] - ${$a}[0]) + ((${$b}[1] - ${$a}[1]) / 1_000_000);
  41 }
  42
  43 # Autoload methods go after =cut, and are processed by the autosplit program.
  44
  45 1;
  46 __END__
  47
  48 =head1 NAME
  49
  50 Time::HiRes - High resolution ualarm, usleep, and gettimeofday
  51
  52 =head1 SYNOPSIS
  53
  54   use Time::HiRes qw( usleep ualarm gettimeofday tv_interval );
  55
  56   usleep ($microseconds);
  57
  58   ualarm ($microseconds);
  59   ualarm ($microseconds, $interval_microseconds);
  60
  61   $t0 = [gettimeofday];
  62   ($seconds, $microseconds) = gettimeofday;
  63
  64   $elapsed = tv_interval ( $t0, [$seconds, $microseconds]);
  65   $elapsed = tv_interval ( $t0, [gettimeofday]);
  66   $elapsed = tv_interval ( $t0 );
  67
  68   use Time::HiRes qw ( time alarm sleep );
  69
  70   $now_fractions = time;
  71   sleep ($floating_seconds);
  72   alarm ($floating_seconds);
  73   alarm ($floating_seconds, $floating_interval);
  74
  75   use Time::HiRes qw( setitimer getitimer
  76                       ITIMER_REAL ITIMER_VIRTUAL ITIMER_PROF );
  77
  78   setitimer ($which, $floating_seconds, $floating_interval );
  79   getitimer ($which);
  80
  81 =head1 DESCRIPTION
  82
  83 The C<Time::HiRes> module implements a Perl interface to the usleep, ualarm,
  84 and gettimeofday system calls. See the EXAMPLES section below and the test
  85 scripts for usage; see your system documentation for the description of
  86 the underlying gettimeofday, usleep, and ualarm calls.
  87
  88 If your system lacks gettimeofday(2) you don't get gettimeofday() or the
  89 one-arg form of tv_interval().  If you don't have usleep(3) or select(2)
  90 you don't get usleep() or sleep().  If your system don't have ualarm(3)
  91 or setitimer(2) you don't get ualarm() or alarm().
  92 If you try to import an unimplemented function in the C<use> statement
  93 it will fail at compile time.
  94
  95 The following functions can be imported from this module.
  96 No functions are exported by default.
  97
  98 =over 4
  99
 100 =item gettimeofday ()
 101
 102 In array context it returns a 2 element array with the seconds and
 103 microseconds since the epoch.  In scalar context it returns floating
 104 seconds like Time::HiRes::time() (see below).
 105
 106 =item usleep ( $useconds )
 107
 108 Issues a usleep for the number of microseconds specified.  Returns the
 109 number of microseconds actually slept.  See also Time::HiRes::sleep()
 110 below.
 111
 112 =item ualarm ( $useconds [, $interval_useconds ] )
 113
 114 Issues a ualarm call; interval_useconds is optional and will be 0 if
 115 unspecified, resulting in alarm-like behaviour.
 116
 117 =item tv_interval
 118
 119 S<tv_interval ( $ref_to_gettimeofday [, $ref_to_later_gettimeofday] )>
 120
 121 Returns the floating seconds between the two times, which should have been
 122 returned by gettimeofday(). If the second argument is omitted, then the
 123 current time is used.
 124
 125 =item time ()
 126
 127 Returns a floating seconds since the epoch. This function can be imported,
 128 resulting in a nice drop-in replacement for the C<time> provided with perl,
 129 see the EXAMPLES below.
 130
 131 B<NOTE>: Since Sunday, September 9th, 2001 at 01:46:40 AM GMT
 132 (when the time() seconds since epoch rolled over to 1_000_000_000),
 133 the default floating point format of Perl and the seconds since epoch
 134 have conspired to produce an apparent bug: if you print the value of
 135 Time::HiRes::time() you seem to be getting only five decimals, not six
 136 as promised (microseconds).  Not to worry, the microseconds are there
 137 (assuming your platform supports such granularity).  What is going on
 138 is that the default floating point format of Perl only outputs 15
 139 digits.  In this case that means ten digits before the decimal
 140 separator and five after.  To see the microseconds you can use either
 141 printf/sprintf with C<%.6f>, or the gettimeofday() function in list
 142 context, which will give you the seconds and microseconds as two
 143 separate values.
 144
 145 =item sleep ( $floating_seconds )
 146
 147 Converts $floating_seconds to microseconds and issues a usleep for the
 148 result.  Returns the number of seconds actually slept (a floating
 149 point value).  This function can be imported, resulting in a nice
 150 drop-in replacement for the C<sleep> provided with perl, see the
 151 EXAMPLES below.
 152
 153 =item alarm ( $floating_seconds [, $interval_floating_seconds ] )
 154
 155 Converts $floating_seconds and $interval_floating_seconds and issues
 156 a ualarm for the results.  The $interval_floating_seconds argument
 157 is optional and will be 0 if unspecified, resulting in alarm-like
 158 behaviour.  This function can be imported, resulting in a nice drop-in
 159 replacement for the C<alarm> provided with perl, see the EXAMPLES below.
 160
 161 =item setitimer
 162
 163 S<setitimer ( $which, $floating_seconds [, $interval_floating_seconds ] )>
 164
 165 Start up an interval timer: after a certain time, a signal is arrives,
 166 and more may keep arriving at certain intervals.  To disable a timer,
 167 use time of zero.  If interval is set to zero (or unspecified), the
 168 timer is disabled after the next delivered signal.
 169
 170 Use of interval timers may interfere with alarm(), sleep(), and usleep().
 171 In standard-speak the "interaction is unspecified", which means that
 172 I<anything> may happen: it may work, it may not.
 173
 174 In scalar context, the remaining time in the timer is returned.
 175
 176 In list context, both the remaining time and the interval are returned.
 177
 178 There are three interval timers: the $which can be ITIMER_REAL,
 179 ITIMER_VIRTUAL, or ITIMER_PROF.
 180
 181 ITIMER_REAL results in alarm()-like behavior.  Time is counted in
 182 I<real time>, that is, wallclock time.  SIGALRM is delivered when
 183 the timer expires.
 184
 185 ITIMER_VIRTUAL counts time in (process) I<virtual time>, that is, only
 186 when the process is running.  In multiprocessing/user/CPU systems this
 187 may be much less than real time.  (This time is also known as the
 188 I<user time>.)  SIGVTALRM is delivered when the timer expires.
 189
 190 ITIMER_PROF counts time when either the process virtual time or when
 191 the operating system is running on behalf of the process (such as
 192 I/O).  (This time is also known as the I<system time>.)  (Collectively
 193 these times are also known as the I<CPU time>.)  SIGPROF is delivered
 194 when the timer expires.  SIGPROF can interrupt system calls.
 195
 196 The semantics of interval timers for multithreaded programs are
 197 system-specific, and some systems may support additional interval
 198 timers.  See your setitimer() documentation.
 199
 200 =item getitimer ( $which )
 201
 202 Return the remaining time in the interval timer specified by $which.
 203
 204 In scalar context, the remaining time is returned.
 205
 206 In list context, both the remaining time and the interval are returned.
 207 The interval is always what you put in using setitimer().
 208
 209 =back
 210
 211 =head1 EXAMPLES
 212
 213   use Time::HiRes qw(usleep ualarm gettimeofday tv_interval);
 214
 215   $microseconds = 750_000;
 216   usleep $microseconds;
 217
 218   # signal alarm in 2.5s & every .1s thereafter
 219   ualarm 2_500_000, 100_000;
 220
 221   # get seconds and microseconds since the epoch
 222   ($s, $usec) = gettimeofday;
 223
 224   # measure elapsed time
 225   # (could also do by subtracting 2 gettimeofday return values)
 226   $t0 = [gettimeofday];
 227   # do bunch of stuff here
 228   $t1 = [gettimeofday];
 229   # do more stuff here
 230   $t0_t1 = tv_interval $t0, $t1;
 231
 232   $elapsed = tv_interval ($t0, [gettimeofday]);
 233   $elapsed = tv_interval ($t0); # equivalent code
 234
 235   #
 236   # replacements for time, alarm and sleep that know about
 237   # floating seconds
 238   #
 239   use Time::HiRes;
 240   $now_fractions = Time::HiRes::time;
 241   Time::HiRes::sleep (2.5);
 242   Time::HiRes::alarm (10.6666666);
 243
 244   use Time::HiRes qw ( time alarm sleep );
 245   $now_fractions = time;
 246   sleep (2.5);
 247   alarm (10.6666666);
 248
 249   # Arm an interval timer to go off first at 10 seconds and
 250   # after that every 2.5 seconds, in process virtual time
 251
 252   use Time::HiRes qw ( setitimer ITIMER_VIRTUAL time );
 253
 254   $SIG{VTLARM} = sub { print time, "\n" };
 255   setitimer(ITIMER_VIRTUAL, 10, 2.5);
 256
 257 =head1 C API
 258
 259 In addition to the perl API described above, a C API is available for
 260 extension writers.  The following C functions are available in the
 261 modglobal hash:
 262
 263   name             C prototype
 264   ---------------  ----------------------
 265   Time::NVtime     double (*)()
 266   Time::U2time     void (*)(UV ret[2])
 267
 268 Both functions return equivalent information (like C<gettimeofday>)
 269 but with different representations.  The names C<NVtime> and C<U2time>
 270 were selected mainly because they are operating system independent.
 271 (C<gettimeofday> is Un*x-centric.)
 272
 273 Here is an example of using NVtime from C:
 274
 275   double (*myNVtime)();
 276   SV **svp = hv_fetch(PL_modglobal, "Time::NVtime", 12, 0);
 277   if (!svp)         croak("Time::HiRes is required");
 278   if (!SvIOK(*svp)) croak("Time::NVtime isn't a function pointer");
 279   myNVtime = (double(*)()) SvIV(*svp);
 280   printf("The current time is: %f\n", (*myNVtime)());
 281
 282 =head1 CAVEATS
 283
 284 Notice that the core time() maybe rounding rather than truncating.
 285 What this means that the core time() may be giving time one second
 286 later than gettimeofday(), also known as Time::HiRes::time().
 287
 288 =head1 AUTHORS
 289
 290 D. Wegscheid <wegscd@whirlpool.com>
 291 R. Schertler <roderick@argon.org>
 292 J. Hietaniemi <jhi@iki.fi>
 293 G. Aas <gisle@aas.no>
 294
 295 =head1 REVISION
 296
 297 $Id: HiRes.pm,v 1.20 1999/03/16 02:26:13 wegscd Exp $
 298
 299 $Log: HiRes.pm,v $
 300 Revision 1.20  1999/03/16 02:26:13  wegscd
 301 Add documentation for NVTime and U2Time.
 302
 303 Revision 1.19  1998/09/30 02:34:42  wegscd
 304 No changes, bump version.
 305
 306 Revision 1.18  1998/07/07 02:41:35  wegscd
 307 No changes, bump version.
 308
 309 Revision 1.17  1998/07/02 01:45:13  wegscd
 310 Bump version to 1.17
 311
 312 Revision 1.16  1997/11/13 02:06:36  wegscd
 313 version bump to accomodate HiRes.xs fix.
 314
 315 Revision 1.15  1997/11/11 02:17:59  wegscd
 316 POD editing, courtesy of Gisle Aas.
 317
 318 Revision 1.14  1997/11/06 03:14:35  wegscd
 319 Update version # for Makefile.PL and HiRes.xs changes.
 320
 321 Revision 1.13  1997/11/05 05:36:25  wegscd
 322 change version # for Makefile.pl and HiRes.xs changes.
 323
 324 Revision 1.12  1997/10/13 20:55:33  wegscd
 325 Force a new version for Makefile.PL changes.
 326
 327 Revision 1.11  1997/09/05 19:59:33  wegscd
 328 New version to bump version for README and Makefile.PL fixes.
 329 Fix bad RCS log.
 330
 331 Revision 1.10  1997/05/23 01:11:38  wegscd
 332 Conditional compilation; EXPORT_FAIL fixes.
 333
 334 Revision 1.2  1996/12/30 13:28:40  wegscd
 335 Update documentation for what to do when missing ualarm() and friends.
 336
 337 Revision 1.1  1996/10/17 20:53:31  wegscd
 338 Fix =head1 being next to __END__ so pod2man works
 339
 340 Revision 1.0  1996/09/03 18:25:15  wegscd
 341 Initial revision
 342
 343 =head1 COPYRIGHT
 344
 345 Copyright (c) 1996-1997 Douglas E. Wegscheid.
 346 All rights reserved. This program is free software; you can
 347 redistribute it and/or modify it under the same terms as Perl itself.
 348
 349 =cut