ext/Time/HiRes/HiRes.pm

   1 package Time::HiRes;
   2
   3 use strict;
   4 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK $AUTOLOAD);
   5
   6 require Exporter;
   7 use XSLoader;
   8
   9 @ISA = qw(Exporter);
  10
  11 @EXPORT = qw( );
  12 @EXPORT_OK = qw (usleep sleep ualarm alarm gettimeofday time tv_interval
  13                  getitimer setitimer ITIMER_REAL ITIMER_VIRTUAL ITIMER_PROF);
  14
  15 $VERSION = '1.20_00';
  16
  17 sub AUTOLOAD {
  18     my $constname;
  19     ($constname= $AUTOLOAD) =~ s/.*:://;
  20     my $val = constant($constname, @_ ? $_[0] : 0);
  21     if ($!) {
  22         my ($pack,$file,$line) = caller;
  23         die "Your vendor has not defined Time::HiRes macro $constname, used at $file line $line.\n";
  24     }
  25     {
  26         no strict 'refs';
  27         *$AUTOLOAD = sub { $val };
  28     }
  29     goto &$AUTOLOAD;
  30 }
  31
  32 XSLoader::load 'Time::HiRes', $VERSION;
  33
  34 # Preloaded methods go here.
  35
  36 sub tv_interval {
  37     # probably could have been done in C
  38     my ($a, $b) = @_;
  39     $b = [gettimeofday()] unless defined($b);
  40     (${$b}[0] - ${$a}[0]) + ((${$b}[1] - ${$a}[1]) / 1_000_000);
  41 }
  42
  43 # Autoload methods go after =cut, and are processed by the autosplit program.
  44
  45 1;
  46 __END__
  47
  48 =head1 NAME
  49
  50 Time::HiRes - High resolution ualarm, usleep, and gettimeofday
  51
  52 =head1 SYNOPSIS
  53
  54   use Time::HiRes qw( usleep ualarm gettimeofday tv_interval );
  55
  56   usleep ($microseconds);
  57
  58   ualarm ($microseconds);
  59   ualarm ($microseconds, $interval_microseconds);
  60
  61   $t0 = [gettimeofday];
  62   ($seconds, $microseconds) = gettimeofday;
  63
  64   $elapsed = tv_interval ( $t0, [$seconds, $microseconds]);
  65   $elapsed = tv_interval ( $t0, [gettimeofday]);
  66   $elapsed = tv_interval ( $t0 );
  67
  68   use Time::HiRes qw ( time alarm sleep );
  69
  70   $now_fractions = time;
  71   sleep ($floating_seconds);
  72   alarm ($floating_seconds);
  73   alarm ($floating_seconds, $floating_interval);
  74
  75   use Time::HiRes qw( setitimer getitimer
  76                       ITIMER_REAL ITIMER_VIRTUAL ITIMER_PROF );
  77
  78   setitimer ($which, $floating_seconds, $floating_interval );
  79   getitimer ($which);
  80
  81 =head1 DESCRIPTION
  82
  83 The C<Time::HiRes> module implements a Perl interface to the usleep, ualarm,
  84 and gettimeofday system calls. See the EXAMPLES section below and the test
  85 scripts for usage; see your system documentation for the description of
  86 the underlying gettimeofday, usleep, and ualarm calls.
  87
  88 If your system lacks gettimeofday(2) you don't get gettimeofday() or the
  89 one-arg form of tv_interval().  If you don't have usleep(3) or select(2)
  90 you don't get usleep() or sleep().  If your system don't have ualarm(3)
  91 or setitimer(2) you don't get ualarm() or alarm().
  92 If you try to import an unimplemented function in the C<use> statement
  93 it will fail at compile time.
  94
  95 The following functions can be imported from this module.
  96 No functions are exported by default.
  97
  98 =over 4
  99
 100 =item gettimeofday ()
 101
 102 In array context it returns a 2 element array with the seconds and
 103 microseconds since the epoch.  In scalar context it returns floating
 104 seconds like Time::HiRes::time() (see below).
 105
 106 =item usleep ( $useconds )
 107
 108 Issues a usleep for the number of microseconds specified. See also
 109 Time::HiRes::sleep() below.
 110
 111 =item ualarm ( $useconds [, $interval_useconds ] )
 112
 113 Issues a ualarm call; interval_useconds is optional and will be 0 if
 114 unspecified, resulting in alarm-like behaviour.
 115
 116 =item tv_interval
 117
 118 S<tv_interval ( $ref_to_gettimeofday [, $ref_to_later_gettimeofday] )>
 119
 120 Returns the floating seconds between the two times, which should have been
 121 returned by gettimeofday(). If the second argument is omitted, then the
 122 current time is used.
 123
 124 =item time ()
 125
 126 Returns a floating seconds since the epoch. This function can be imported,
 127 resulting in a nice drop-in replacement for the C<time> provided with perl,
 128 see the EXAMPLES below.
 129
 130 B<NOTE>: Since Sunday, September 9th, 2001 at 01:46:40 AM GMT
 131 (when the time() seconds since epoch rolled over to 1_000_000_000),
 132 the default floating point format of Perl and the seconds since epoch
 133 have conspired to produce an apparent bug: if you print the value of
 134 Time::HiRes::time() you seem to be getting only five decimals, not six
 135 as promised (microseconds).  Not to worry, the microseconds are there
 136 (assuming your platform supports such granularity).  What is going on
 137 is that the default floating point format of Perl only outputs 15
 138 digits.  In this case that means ten digits before the decimal
 139 separator and five after.  To see the microseconds you can use either
 140 printf/sprintf with C<%.6f>, or the gettimeofday() function in list
 141 context, which will give you the seconds and microseconds as two
 142 separate values.
 143
 144 =item sleep ( $floating_seconds )
 145
 146 Converts $floating_seconds to microseconds and issues a usleep for the
 147 result.  This function can be imported, resulting in a nice drop-in
 148 replacement for the C<sleep> provided with perl, see the EXAMPLES below.
 149
 150 =item alarm ( $floating_seconds [, $interval_floating_seconds ] )
 151
 152 Converts $floating_seconds and $interval_floating_seconds and issues
 153 a ualarm for the results.  The $interval_floating_seconds argument
 154 is optional and will be 0 if unspecified, resulting in alarm-like
 155 behaviour.  This function can be imported, resulting in a nice drop-in
 156 replacement for the C<alarm> provided with perl, see the EXAMPLES below.
 157
 158 =item setitimer
 159
 160 S<setitimer ( $which, $floating_seconds [, $interval_floating_seconds ] )>
 161
 162 Start up an interval timer: after a certain time, a signal is arrives,
 163 and more may keep arriving at certain intervals.  To disable a timer,
 164 use time of zero.  If interval is set to zero (or unspecified), the
 165 timer is disabled after the next delivered signal.
 166
 167 Use of interval timers may interfere with alarm(), sleep(), and usleep().
 168 In standard-speak the "interaction is unspecified", which means that
 169 I<anything> may happen: it may work, it may not.
 170
 171 In scalar context, the remaining time in the timer is returned.
 172
 173 In list context, both the remaining time and the interval are returned.
 174
 175 There are three interval timers: the $which can be ITIMER_REAL,
 176 ITIMER_VIRTUAL, or ITIMER_PROF.
 177
 178 ITIMER_REAL results in alarm()-like behavior.  Time is counted in
 179 I<real time>, that is, wallclock time.  SIGALRM is delivered when
 180 the timer expires.
 181
 182 ITIMER_VIRTUAL counts time in (process) I<virtual time>, that is, only
 183 when the process is running.  In multiprocessing/user/CPU systems this
 184 may be much less than real time.  (This time is also known as the
 185 I<user time>.)  SIGVTALRM is delivered when the timer expires.
 186
 187 ITIMER_PROF counts time when either the process virtual time or when
 188 the operating system is running on behalf of the process (such as
 189 I/O).  (This time is also known as the I<system time>.)  (Collectively
 190 these times are also known as the I<CPU time>.)  SIGPROF is delivered
 191 when the timer expires.  SIGPROF can interrupt system calls.
 192
 193 The semantics of interval timers for multithreaded programs are
 194 system-specific, and some systems may support additional interval
 195 timers.  See your setitimer() documentation.
 196
 197 =item getitimer ( $which )
 198
 199 Return the remaining time in the interval timer specified by $which.
 200
 201 In scalar context, the remaining time is returned.
 202
 203 In list context, both the remaining time and the interval are returned.
 204 The interval is always what you put in using setitimer().
 205
 206 =back
 207
 208 =head1 EXAMPLES
 209
 210   use Time::HiRes qw(usleep ualarm gettimeofday tv_interval);
 211
 212   $microseconds = 750_000;
 213   usleep $microseconds;
 214
 215   # signal alarm in 2.5s & every .1s thereafter
 216   ualarm 2_500_000, 100_000;
 217
 218   # get seconds and microseconds since the epoch
 219   ($s, $usec) = gettimeofday;
 220
 221   # measure elapsed time
 222   # (could also do by subtracting 2 gettimeofday return values)
 223   $t0 = [gettimeofday];
 224   # do bunch of stuff here
 225   $t1 = [gettimeofday];
 226   # do more stuff here
 227   $t0_t1 = tv_interval $t0, $t1;
 228
 229   $elapsed = tv_interval ($t0, [gettimeofday]);
 230   $elapsed = tv_interval ($t0); # equivalent code
 231
 232   #
 233   # replacements for time, alarm and sleep that know about
 234   # floating seconds
 235   #
 236   use Time::HiRes;
 237   $now_fractions = Time::HiRes::time;
 238   Time::HiRes::sleep (2.5);
 239   Time::HiRes::alarm (10.6666666);
 240
 241   use Time::HiRes qw ( time alarm sleep );
 242   $now_fractions = time;
 243   sleep (2.5);
 244   alarm (10.6666666);
 245
 246   # Arm an interval timer to go off first at 10 seconds and
 247   # after that every 2.5 seconds, in process virtual time
 248
 249   use Time::HiRes qw ( setitimer ITIMER_VIRTUAL time );
 250
 251   $SIG{VTLARM} = sub { print time, "\n" };
 252   setitimer(ITIMER_VIRTUAL, 10, 2.5);
 253
 254 =head1 C API
 255
 256 In addition to the perl API described above, a C API is available for
 257 extension writers.  The following C functions are available in the
 258 modglobal hash:
 259
 260   name             C prototype
 261   ---------------  ----------------------
 262   Time::NVtime     double (*)()
 263   Time::U2time     void (*)(UV ret[2])
 264
 265 Both functions return equivalent information (like C<gettimeofday>)
 266 but with different representations.  The names C<NVtime> and C<U2time>
 267 were selected mainly because they are operating system independent.
 268 (C<gettimeofday> is Un*x-centric.)
 269
 270 Here is an example of using NVtime from C:
 271
 272   double (*myNVtime)();
 273   SV **svp = hv_fetch(PL_modglobal, "Time::NVtime", 12, 0);
 274   if (!svp)         croak("Time::HiRes is required");
 275   if (!SvIOK(*svp)) croak("Time::NVtime isn't a function pointer");
 276   myNVtime = (double(*)()) SvIV(*svp);
 277   printf("The current time is: %f\n", (*myNVtime)());
 278
 279 =head1 CAVEATS
 280
 281 Notice that the core time() maybe rounding rather than truncating.
 282 What this means that the core time() may be giving time one second
 283 later than gettimeofday(), also known as Time::HiRes::time().
 284
 285 =head1 AUTHORS
 286
 287 D. Wegscheid <wegscd@whirlpool.com>
 288 R. Schertler <roderick@argon.org>
 289 J. Hietaniemi <jhi@iki.fi>
 290 G. Aas <gisle@aas.no>
 291
 292 =head1 REVISION
 293
 294 $Id: HiRes.pm,v 1.20 1999/03/16 02:26:13 wegscd Exp $
 295
 296 $Log: HiRes.pm,v $
 297 Revision 1.20  1999/03/16 02:26:13  wegscd
 298 Add documentation for NVTime and U2Time.
 299
 300 Revision 1.19  1998/09/30 02:34:42  wegscd
 301 No changes, bump version.
 302
 303 Revision 1.18  1998/07/07 02:41:35  wegscd
 304 No changes, bump version.
 305
 306 Revision 1.17  1998/07/02 01:45:13  wegscd
 307 Bump version to 1.17
 308
 309 Revision 1.16  1997/11/13 02:06:36  wegscd
 310 version bump to accomodate HiRes.xs fix.
 311
 312 Revision 1.15  1997/11/11 02:17:59  wegscd
 313 POD editing, courtesy of Gisle Aas.
 314
 315 Revision 1.14  1997/11/06 03:14:35  wegscd
 316 Update version # for Makefile.PL and HiRes.xs changes.
 317
 318 Revision 1.13  1997/11/05 05:36:25  wegscd
 319 change version # for Makefile.pl and HiRes.xs changes.
 320
 321 Revision 1.12  1997/10/13 20:55:33  wegscd
 322 Force a new version for Makefile.PL changes.
 323
 324 Revision 1.11  1997/09/05 19:59:33  wegscd
 325 New version to bump version for README and Makefile.PL fixes.
 326 Fix bad RCS log.
 327
 328 Revision 1.10  1997/05/23 01:11:38  wegscd
 329 Conditional compilation; EXPORT_FAIL fixes.
 330
 331 Revision 1.2  1996/12/30 13:28:40  wegscd
 332 Update documentation for what to do when missing ualarm() and friends.
 333
 334 Revision 1.1  1996/10/17 20:53:31  wegscd
 335 Fix =head1 being next to __END__ so pod2man works
 336
 337 Revision 1.0  1996/09/03 18:25:15  wegscd
 338 Initial revision
 339
 340 =head1 COPYRIGHT
 341
 342 Copyright (c) 1996-1997 Douglas E. Wegscheid.
 343 All rights reserved. This program is free software; you can
 344 redistribute it and/or modify it under the same terms as Perl itself.
 345
 346 =cut