ext/Time/HiRes/HiRes.pm

   1 package Time::HiRes;
   2
   3 use strict;
   4 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK $AUTOLOAD);
   5
   6 require Exporter;
   7 use XSLoader;
   8
   9 @ISA = qw(Exporter);
  10
  11 @EXPORT = qw( );
  12 @EXPORT_OK = qw (usleep sleep ualarm alarm gettimeofday time tv_interval
  13                  getitimer setitimer ITIMER_REAL ITIMER_VIRTUAL ITIMER_PROF);
  14
  15 $VERSION = '1.21';
  16
  17 sub AUTOLOAD {
  18     my $constname;
  19     ($constname= $AUTOLOAD) =~ s/.*:://;
  20     my $val = constant($constname, @_ ? $_[0] : 0);
  21     if ($!) {
  22         my ($pack,$file,$line) = caller;
  23         die "Your vendor has not defined Time::HiRes macro $constname, used at $file line $line.\n";
  24     }
  25     {
  26         no strict 'refs';
  27         *$AUTOLOAD = sub { $val };
  28     }
  29     goto &$AUTOLOAD;
  30 }
  31
  32 XSLoader::load 'Time::HiRes', $VERSION;
  33
  34 # Preloaded methods go here.
  35
  36 sub tv_interval {
  37     # probably could have been done in C
  38     my ($a, $b) = @_;
  39     $b = [gettimeofday()] unless defined($b);
  40     (${$b}[0] - ${$a}[0]) + ((${$b}[1] - ${$a}[1]) / 1_000_000);
  41 }
  42
  43 # Autoload methods go after =cut, and are processed by the autosplit program.
  44
  45 1;
  46 __END__
  47
  48 =head1 NAME
  49
  50 Time::HiRes - High resolution ualarm, usleep, and gettimeofday
  51
  52 =head1 SYNOPSIS
  53
  54   use Time::HiRes qw( usleep ualarm gettimeofday tv_interval );
  55
  56   usleep ($microseconds);
  57
  58   ualarm ($microseconds);
  59   ualarm ($microseconds, $interval_microseconds);
  60
  61   $t0 = [gettimeofday];
  62   ($seconds, $microseconds) = gettimeofday;
  63
  64   $elapsed = tv_interval ( $t0, [$seconds, $microseconds]);
  65   $elapsed = tv_interval ( $t0, [gettimeofday]);
  66   $elapsed = tv_interval ( $t0 );
  67
  68   use Time::HiRes qw ( time alarm sleep );
  69
  70   $now_fractions = time;
  71   sleep ($floating_seconds);
  72   alarm ($floating_seconds);
  73   alarm ($floating_seconds, $floating_interval);
  74
  75   use Time::HiRes qw( setitimer getitimer
  76                       ITIMER_REAL ITIMER_VIRTUAL ITIMER_PROF );
  77
  78   setitimer ($which, $floating_seconds, $floating_interval );
  79   getitimer ($which);
  80
  81 =head1 DESCRIPTION
  82
  83 The C<Time::HiRes> module implements a Perl interface to the usleep, ualarm,
  84 and gettimeofday system calls. See the EXAMPLES section below and the test
  85 scripts for usage; see your system documentation for the description of
  86 the underlying gettimeofday, usleep, and ualarm calls.
  87
  88 If your system lacks gettimeofday(2) you don't get gettimeofday() or the
  89 one-arg form of tv_interval().  If you don't have usleep(3) or select(2)
  90 you don't get usleep() or sleep().  If your system don't have ualarm(3)
  91 or setitimer(2) you don't get ualarm() or alarm().
  92 If you try to import an unimplemented function in the C<use> statement
  93 it will fail at compile time.
  94
  95 The following functions can be imported from this module.
  96 No functions are exported by default.
  97
  98 =over 4
  99
 100 =item gettimeofday ()
 101
 102 In array context it returns a 2 element array with the seconds and
 103 microseconds since the epoch.  In scalar context it returns floating
 104 seconds like Time::HiRes::time() (see below).
 105
 106 =item usleep ( $useconds )
 107
 108 Issues a usleep for the number of microseconds specified. See also
 109 Time::HiRes::sleep() below.
 110
 111 =item ualarm ( $useconds [, $interval_useconds ] )
 112
 113 Issues a ualarm call; interval_useconds is optional and will be 0 if
 114 unspecified, resulting in alarm-like behaviour.
 115
 116 =item tv_interval ( $ref_to_gettimeofday [, $ref_to_later_gettimeofday] )
 117
 118 Returns the floating seconds between the two times, which should have been
 119 returned by gettimeofday(). If the second argument is omitted, then the
 120 current time is used.
 121
 122 =item time ()
 123
 124 Returns a floating seconds since the epoch. This function can be imported,
 125 resulting in a nice drop-in replacement for the C<time> provided with perl,
 126 see the EXAMPLES below.
 127
 128 =item sleep ( $floating_seconds )
 129
 130 Converts $floating_seconds to microseconds and issues a usleep for the
 131 result.  This function can be imported, resulting in a nice drop-in
 132 replacement for the C<sleep> provided with perl, see the EXAMPLES below.
 133
 134 =item alarm ( $floating_seconds [, $interval_floating_seconds ] )
 135
 136 Converts $floating_seconds and $interval_floating_seconds and issues
 137 a ualarm for the results.  The $interval_floating_seconds argument
 138 is optional and will be 0 if unspecified, resulting in alarm-like
 139 behaviour.  This function can be imported, resulting in a nice drop-in
 140 replacement for the C<alarm> provided with perl, see the EXAMPLES below.
 141
 142 =item setitimer ( $which, $floating_seconds [, $interval_floating_seconds ] )
 143
 144 Start up an interval timer: after a certain time, a signal is arrives,
 145 and more may keep arriving at certain intervals.  To disable a timer,
 146 use time of zero.  If interval is set to zero (or unspecified), the
 147 timer is disabled after the next delivered signal.
 148
 149 Use of interval timers may interfere with alarm(), sleep(), and usleep().
 150 In standard-speak the "interaction is unspecified", which means that
 151 I<anything> may happen: it may work, it may not.
 152
 153 In scalar context, the remaining time in the timer is returned.
 154
 155 In list context, both the remaining time and the interval are returned.
 156
 157 There are three interval timers: the $which can be ITIMER_REAL,
 158 ITIMER_VIRTUAL, or ITIMER_PROF.
 159
 160 ITIMER_REAL results in alarm()-like behavior.  Time is counted in
 161 I<real time>, that is, wallclock time.  SIGALRM is delivered when
 162 the timer expires.
 163
 164 ITIMER_VIRTUAL counts time in (process) I<virtual time>, that is, only
 165 when the process is running.  In multiprocessing/user/CPU systems this
 166 may be much less than real time.  (This time is also known as the
 167 I<user time>.)  SIGVTALRM is delivered when the timer expires.
 168
 169 ITIMER_PROF counts time when either the process virtual time or when
 170 the operating system is running on behalf of the process (such as
 171 I/O).  (This time is also known as the I<system time>.)  (Collectively
 172 these times are also known as the I<CPU time>.)  SIGPROF is delivered
 173 when the timer expires.  SIGPROF can interrupt system calls.
 174
 175 The semantics of interval timers for multithreaded programs are
 176 system-specific, and some systems may support additional interval
 177 timers.  See your setitimer() documentation.
 178
 179 =item getitimer ( $which )
 180
 181 Return the remaining time in the interval timer specified by $which.
 182
 183 In scalar context, the remaining time is returned.
 184
 185 In list context, both the remaining time and the interval are returned.
 186 The interval is always what you put in using setitimer().
 187
 188 =back
 189
 190 =head1 EXAMPLES
 191
 192   use Time::HiRes qw(usleep ualarm gettimeofday tv_interval);
 193
 194   $microseconds = 750_000;
 195   usleep $microseconds;
 196
 197   # signal alarm in 2.5s & every .1s thereafter
 198   ualarm 2_500_000, 100_000;
 199
 200   # get seconds and microseconds since the epoch
 201   ($s, $usec) = gettimeofday;
 202
 203   # measure elapsed time
 204   # (could also do by subtracting 2 gettimeofday return values)
 205   $t0 = [gettimeofday];
 206   # do bunch of stuff here
 207   $t1 = [gettimeofday];
 208   # do more stuff here
 209   $t0_t1 = tv_interval $t0, $t1;
 210
 211   $elapsed = tv_interval ($t0, [gettimeofday]);
 212   $elapsed = tv_interval ($t0); # equivalent code
 213
 214   #
 215   # replacements for time, alarm and sleep that know about
 216   # floating seconds
 217   #
 218   use Time::HiRes;
 219   $now_fractions = Time::HiRes::time;
 220   Time::HiRes::sleep (2.5);
 221   Time::HiRes::alarm (10.6666666);
 222
 223   use Time::HiRes qw ( time alarm sleep );
 224   $now_fractions = time;
 225   sleep (2.5);
 226   alarm (10.6666666);
 227
 228   # Arm an interval timer to go off first at 10 seconds and
 229   # after that every 2.5 seconds, in process virtual time
 230
 231   use Time::HiRes qw ( setitimer ITIMER_VIRTUAL time );
 232
 233   $SIG{VTLARM} = sub { print time, "\n" };
 234   setitimer(ITIMER_VIRTUAL, 10, 2.5);
 235
 236 =head1 C API
 237
 238 In addition to the perl API described above, a C API is available for
 239 extension writers.  The following C functions are available in the
 240 modglobal hash:
 241
 242   name             C prototype
 243   ---------------  ----------------------
 244   Time::NVtime     double (*)()
 245   Time::U2time     void (*)(UV ret[2])
 246
 247 Both functions return equivalent information (like C<gettimeofday>)
 248 but with different representations.  The names C<NVtime> and C<U2time>
 249 were selected mainly because they are operating system independent.
 250 (C<gettimeofday> is Un*x-centric.)
 251
 252 Here is an example of using NVtime from C:
 253
 254   double (*myNVtime)();
 255   SV **svp = hv_fetch(PL_modglobal, "Time::NVtime", 12, 0);
 256   if (!svp)         croak("Time::HiRes is required");
 257   if (!SvIOK(*svp)) croak("Time::NVtime isn't a function pointer");
 258   myNVtime = (double(*)()) SvIV(*svp);
 259   printf("The current time is: %f\n", (*myNVtime)());
 260
 261 =head1 AUTHORS
 262
 263 D. Wegscheid <wegscd@whirlpool.com>
 264 R. Schertler <roderick@argon.org>
 265 J. Hietaniemi <jhi@iki.fi>
 266 G. Aas <gisle@aas.no>
 267
 268 =head1 REVISION
 269
 270 $Id: HiRes.pm,v 1.20 1999/03/16 02:26:13 wegscd Exp $
 271
 272 $Log: HiRes.pm,v $
 273 Revision 1.20  1999/03/16 02:26:13  wegscd
 274 Add documentation for NVTime and U2Time.
 275
 276 Revision 1.19  1998/09/30 02:34:42  wegscd
 277 No changes, bump version.
 278
 279 Revision 1.18  1998/07/07 02:41:35  wegscd
 280 No changes, bump version.
 281
 282 Revision 1.17  1998/07/02 01:45:13  wegscd
 283 Bump version to 1.17
 284
 285 Revision 1.16  1997/11/13 02:06:36  wegscd
 286 version bump to accomodate HiRes.xs fix.
 287
 288 Revision 1.15  1997/11/11 02:17:59  wegscd
 289 POD editing, courtesy of Gisle Aas.
 290
 291 Revision 1.14  1997/11/06 03:14:35  wegscd
 292 Update version # for Makefile.PL and HiRes.xs changes.
 293
 294 Revision 1.13  1997/11/05 05:36:25  wegscd
 295 change version # for Makefile.pl and HiRes.xs changes.
 296
 297 Revision 1.12  1997/10/13 20:55:33  wegscd
 298 Force a new version for Makefile.PL changes.
 299
 300 Revision 1.11  1997/09/05 19:59:33  wegscd
 301 New version to bump version for README and Makefile.PL fixes.
 302 Fix bad RCS log.
 303
 304 Revision 1.10  1997/05/23 01:11:38  wegscd
 305 Conditional compilation; EXPORT_FAIL fixes.
 306
 307 Revision 1.2  1996/12/30 13:28:40  wegscd
 308 Update documentation for what to do when missing ualarm() and friends.
 309
 310 Revision 1.1  1996/10/17 20:53:31  wegscd
 311 Fix =head1 being next to __END__ so pod2man works
 312
 313 Revision 1.0  1996/09/03 18:25:15  wegscd
 314 Initial revision
 315
 316 =head1 COPYRIGHT
 317
 318 Copyright (c) 1996-1997 Douglas E. Wegscheid.
 319 All rights reserved. This program is free software; you can
 320 redistribute it and/or modify it under the same terms as Perl itself.
 321
 322 =cut