ext/Sys/Syslog/Makefile.PL

   1 use strict;
   2 use Config;
   3 use ExtUtils::MakeMaker;
   4 eval 'use ExtUtils::MakeMaker::Coverage';
   5 use File::Copy;
   6 use File::Path;
   7 use File::Spec;
   8 require 5.006;
   9
  10
  11 # create a typemap for Perl 5.6
  12 if ($] < 5.008) {
  13     open(TYPEMAP, ">typemap") or die "fatal: can't write typemap: $!";
  14     print TYPEMAP "const char *\t\tT_PV\n";
  15     close(TYPEMAP);
  16 }
  17
  18 # create a lib/ dir in order to avoid warnings in Test::Distribution
  19 mkdir "lib";
  20
  21 # virtual paths given to EU::MM
  22 my %virtual_path = ( 'Syslog.pm' => '$(INST_LIBDIR)/Syslog.pm' );
  23
  24 # detect when to use Win32::EvenLog
  25 my (@extra_params, @extra_prereqs);
  26 my $use_eventlog = eval "use Win32::EventLog; 1";
  27
  28 if ($use_eventlog) {
  29     print " * Win32::EventLog detected.\n";
  30     my $name = "PerlLog";
  31
  32     push @extra_prereqs, "Win32::TieRegistry" => 0, "Win32::EventLog" => 0;
  33
  34     $virtual_path{'win32/Win32.pm'   } = '$(INST_LIBDIR)/Syslog/Win32.pm';
  35     $virtual_path{'win32/PerlLog.dll'} = '$(INST_ARCHAUTODIR)/PerlLog.dll';
  36
  37     # recreate the DLL from its uuencoded form if it's not here
  38     if (! -f File::Spec->catfile("win32", "$name.dll")) {
  39         # read the uuencoded data
  40         open(UU, '<' . File::Spec->catfile("win32", "$name\_dll.uu"))
  41             or die "fatal: Can't read file '$name\_dll.uu': $!";
  42         my $uudata = do { local $/; <UU> };
  43         close(UU);
  44
  45         # write the DLL
  46         open(DLL, '>' . File::Spec->catfile("win32", "$name.dll"))
  47             or die "fatal: Can't write DLL '$name.dll': $!";
  48         binmode(DLL);
  49         print DLL unpack "u", $uudata;
  50         close(DLL);
  51     }
  52 }
  53 elsif ($^O =~ /Win32/) {
  54     print <<"NOTICE"
  55  *** You're running on a Win32 system,  but you lack the Win32::EventLog\a
  56  *** module, part of the libwin32 distribution. Although Sys::Syslog can
  57  *** be used without Win32::EventLog, it won't be very useful except for
  58  *** sending remote syslog messages.  If you want to log messages on the
  59  *** local host as well, please install libwin32 then Sys::Syslog again.
  60 NOTICE
  61 }
  62
  63 # detect when being built in Perl core
  64 if (grep { $_ eq 'PERL_CORE=1' } @ARGV) {
  65     push @extra_params,
  66         MAN3PODS    => {};      # Pods will be built by installman.
  67 }
  68 else {
  69     push @extra_params,
  70         DEFINE      => '-DUSE_PPPORT_H';
  71 }
  72
  73 WriteMakefile(
  74     NAME            => 'Sys::Syslog',
  75     LICENSE         => 'perl',
  76     VERSION_FROM    => 'Syslog.pm',
  77     ABSTRACT_FROM   => 'Syslog.pm',
  78     INSTALLDIRS     => 'perl',
  79     XSPROTOARG      => '-noprototypes',
  80     PM              => \%virtual_path,
  81     PREREQ_PM       => {
  82         'Test::More' => 0,
  83         'XSLoader'   => 0,
  84         @extra_prereqs,
  85     },
  86     dist            => { COMPRESS => 'gzip -9f', SUFFIX => 'gz', },
  87     clean           => { FILES => 'Sys-Syslog-*' },
  88     realclean       => { FILES => 'lib const-c.inc const-xs.inc macros.all PerlLog.h *.bak *.bin *.rc' },
  89     @extra_params
  90 );
  91
  92
  93 # find a default value for _PATH_LOG
  94 my $_PATH_LOG;
  95
  96 if (-c "/dev/conslog" and -w _) {
  97     # SunOS 5.8 has a worldwritable /dev/conslog STREAMS log driver.
  98     # The /dev/log STREAMS log driver on this platform has permissions
  99     # and ownership `crw-r----- root sys'.  /dev/conslog has more liberal
 100     # permissions.
 101     $_PATH_LOG = "/dev/conslog";
 102 }
 103 elsif (-S "/var/run/syslog" and -w _) {
 104     # Mac OS X puts it at a different path.
 105     $_PATH_LOG = "/var/run/syslog";
 106 }
 107 elsif (-S "/dev/log" and -w _) {
 108     # Most unixes have a unix domain socket /dev/log.
 109     $_PATH_LOG = "/dev/log";
 110 }
 111 else {
 112     $_PATH_LOG = "";
 113 }
 114
 115
 116 # if possible, generate the code that handles the constants with
 117 # ExtUtils::Constant, otherwise use cached copy in fallback/
 118 if(eval {require ExtUtils::Constant; 1}) {
 119     my @levels = qw(
 120         LOG_ALERT LOG_CRIT LOG_DEBUG LOG_EMERG LOG_ERR
 121         LOG_INFO LOG_NOTICE LOG_WARNING
 122     );
 123
 124     my @facilities = (
 125         # standard facilities
 126         qw(
 127             LOG_AUTH LOG_AUTHPRIV LOG_CRON LOG_DAEMON LOG_FTP LOG_KERN
 128             LOG_LOCAL0 LOG_LOCAL1 LOG_LOCAL2 LOG_LOCAL3 LOG_LOCAL4
 129             LOG_LOCAL5 LOG_LOCAL6 LOG_LOCAL7 LOG_LPR LOG_MAIL LOG_NEWS
 130             LOG_SYSLOG LOG_USER LOG_UUCP
 131         ),
 132         # Mac OS X specific facilities
 133         { name => "LOG_INSTALL",    type => "IV", default => [ "IV", "LOG_USER"  ] },
 134         { name => "LOG_LAUNCHD",    type => "IV", default => [ "IV", "LOG_DAEMON"] },
 135         { name => "LOG_NETINFO",    type => "IV", default => [ "IV", "LOG_DAEMON"] },
 136         { name => "LOG_RAS",        type => "IV", default => [ "IV", "LOG_AUTH"  ] },
 137         { name => "LOG_REMOTEAUTH", type => "IV", default => [ "IV", "LOG_AUTH"  ] },
 138         # modern BSD specific facilities
 139         { name => "LOG_CONSOLE",    type => "IV", default => [ "IV", "LOG_USER"  ] },
 140         { name => "LOG_NTP",        type => "IV", default => [ "IV", "LOG_DAEMON"] },
 141         { name => "LOG_SECURITY",   type => "IV", default => [ "IV", "LOG_AUTH"  ] },
 142         # IRIX specific facilities
 143         { name => "LOG_AUDIT",      type => "IV", default => [ "IV", "LOG_AUTH"  ] },
 144         { name => "LOG_LFMT",       type => "IV", default => [ "IV", "LOG_USER"  ] },
 145     );
 146
 147     my @options = qw(
 148         LOG_CONS LOG_PID LOG_NDELAY LOG_NOWAIT LOG_ODELAY LOG_PERROR
 149     );
 150
 151     my @others_macros = (
 152         qw(LOG_FACMASK),
 153         { name => "_PATH_LOG", type => "PV", default => [ "PV", qq("$_PATH_LOG") ] },
 154         { name => "LOG_PRIMASK",     type => "IV", default => [ "IV", 7] },
 155         { name => "LOG_NFACILITIES", type => "IV", default => [ "IV", scalar @facilities] },
 156     );
 157
 158     ExtUtils::Constant::WriteConstants(
 159         ($] > 5.009002 ? (PROXYSUBS => 1) : ()),
 160         NAME => 'Sys::Syslog',
 161         NAMES => [ @levels, @facilities, @options, @others_macros ],
 162     );
 163
 164     my @names = map { ref $_ ? $_->{name} : $_ } @levels, @facilities, @options;
 165     open(MACROS, '>macros.all') or warn "warning: Can't write 'macros.all': $!\n";
 166     print MACROS join $/, @names;
 167     close(MACROS);
 168 }
 169 else {
 170     foreach my $file ('const-c.inc', 'const-xs.inc') {
 171         my $fallback = File::Spec->catfile('fallback', $file);
 172         copy($fallback, $file) or die "fatal: Can't copy $fallback to $file: $!";
 173     }
 174 }