ext/Storable/t/compat06.t

   1 #!./perl
   2
   3 # $Id: compat-0.6.t,v 1.0.1.1 2001/02/17 12:26:21 ram Exp $
   4 #
   5 #  Copyright (c) 1995-2000, Raphael Manfredi
   6 #
   7 #  You may redistribute only under the same terms as Perl 5, as specified
   8 #  in the README file that comes with the distribution.
   9 #
  10
  11 BEGIN {
  12     if ($ENV{PERL_CORE}){
  13         chdir('t') if -d 't';
  14         @INC = ('.', '../lib', '../ext/Storable/t');
  15     } else {
  16         unshift @INC, 't';
  17     }
  18     require Config; import Config;
  19     if ($ENV{PERL_CORE} and $Config{'extensions'} !~ /\bStorable\b/) {
  20         print "1..0 # Skip: Storable was not built\n";
  21         exit 0;
  22     }
  23     require 'st-dump.pl';
  24 }
  25
  26 sub ok;
  27
  28 print "1..8\n";
  29
  30 use Storable qw(freeze nfreeze thaw);
  31
  32 package TIED_HASH;
  33
  34 sub TIEHASH {
  35         my $self = bless {}, shift;
  36         return $self;
  37 }
  38
  39 sub FETCH {
  40         my $self = shift;
  41         my ($key) = @_;
  42         $main::hash_fetch++;
  43         return $self->{$key};
  44 }
  45
  46 sub STORE {
  47         my $self = shift;
  48         my ($key, $val) = @_;
  49         $self->{$key} = $val;
  50 }
  51
  52 package SIMPLE;
  53
  54 sub make {
  55         my $self = bless [], shift;
  56         my ($x) = @_;
  57         $self->[0] = $x;
  58         return $self;
  59 }
  60
  61 package ROOT;
  62
  63 sub make {
  64         my $self = bless {}, shift;
  65         my $h = tie %hash, TIED_HASH;
  66         $self->{h} = $h;
  67         $self->{ref} = \%hash;
  68         my @pool;
  69         for (my $i = 0; $i < 5; $i++) {
  70                 push(@pool, SIMPLE->make($i));
  71         }
  72         $self->{obj} = \@pool;
  73         my @a = ('string', $h, $self);
  74         $self->{a} = \@a;
  75         $self->{num} = [1, 0, -3, -3.14159, 456, 4.5];
  76         $h->{key1} = 'val1';
  77         $h->{key2} = 'val2';
  78         return $self;
  79 };
  80
  81 sub num { $_[0]->{num} }
  82 sub h   { $_[0]->{h} }
  83 sub ref { $_[0]->{ref} }
  84 sub obj { $_[0]->{obj} }
  85
  86 package main;
  87
  88 my $is_EBCDIC = (ord('A') == 193) ? 1 : 0;
  89
  90 my $r = ROOT->make;
  91
  92 my $data = '';
  93 if (!$is_EBCDIC) {                      # ASCII machine
  94         while (<DATA>) {
  95                 next if /^#/;
  96             $data .= unpack("u", $_);
  97         }
  98 } else {
  99         while (<DATA>) {
 100                 next if /^#$/;          # skip comments
 101                 next if /^#\s+/;        # skip comments
 102                 next if /^[^#]/;        # skip uuencoding for ASCII machines
 103                 s/^#//;                         # prepare uuencoded data for EBCDIC machines
 104                 $data .= unpack("u", $_);
 105         }
 106 }
 107
 108 my $expected_length = $is_EBCDIC ? 217 : 278;
 109 ok 1, length $data == $expected_length;
 110
 111 my $y = thaw($data);
 112 ok 2, 1;
 113 ok 3, ref $y eq 'ROOT';
 114
 115 $Storable::canonical = 1;               # Prevent "used once" warning
 116 $Storable::canonical = 1;
 117 # Allow for long double string conversions.
 118 $y->{num}->[3] += 0;
 119 $r->{num}->[3] += 0;
 120 ok 4, nfreeze($y) eq nfreeze($r);
 121
 122 ok 5, $y->ref->{key1} eq 'val1';
 123 ok 6, $y->ref->{key2} eq 'val2';
 124 ok 7, $hash_fetch == 2;
 125
 126 my $num = $r->num;
 127 my $ok = 1;
 128 for (my $i = 0; $i < @$num; $i++) {
 129         do { $ok = 0; last } unless $num->[$i] == $y->num->[$i];
 130 }
 131 ok 8, $ok;
 132
 133 __END__
 134 #
 135 # using Storable-0.6@11, output of: print pack("u", nfreeze(ROOT->make));
 136 # original size: 278 bytes
 137 #
 138 M`P,````%!`(````&"(%8"(!8"'U8"@@M,RXQ-#$U.5@)```!R%@*`S0N-5A8
 139 M6`````-N=6T$`P````(*!'9A;#%8````!&ME>3$*!'9A;#)8````!&ME>3)B
 140 M"51)141?2$%32%A8`````6@$`@````,*!G-T<FEN9U@$``````I8!```````
 141 M6%A8`````6$$`@````4$`@````$(@%AB!E-)35!,15A8!`(````!"(%88@93
 142 M24U03$586`0"`````0B"6&(&4TE-4$Q%6%@$`@````$(@UAB!E-)35!,15A8
 143 M!`(````!"(188@9324U03$586%A8`````V]B:@0,!``````*6%A8`````W)E
 144 (9F($4D]/5%@`
 145 #
 146 # using Storable-0.6@11, output of: print '#' . pack("u", nfreeze(ROOT->make));
 147 # on OS/390 (cp 1047) original size: 217 bytes
 148 #
 149 #M!0,1!-G6UN,#````!00,!!$)X\G%Q&W(P>+(`P````(*!*6!D_$````$DH6H
 150 #M\0H$I8&3\@````22A:CR`````YF%A@0"````!@B!"(`(?0H(8/-+\?3Q]?D)
 151 #M```!R`H#]$OU`````Y6DE`0"````!001!N+)U-?3Q0(````!"(`$$@("````
 152 #M`0B!!!("`@````$(@@02`@(````!"(,$$@("`````0B$`````Y:"D00`````
 153 #E!`````&(!`(````#"@:BHYF)E8<$``````0$```````````!@0``