ext/Socket/socketpair.t

   1 #!./perl -w
   2
   3 my $child;
   4 my $can_fork;
   5
   6 BEGIN {
   7     chdir 't' if -d 't';
   8     @INC = '../lib';
   9     require Config; import Config;
  10     $can_fork = $Config{'d_fork'}
  11                 || ($^O eq 'MSWin32' && $Config{useithreads}
  12                     && $Config{ccflags} =~ /-DPERL_IMPLICIT_SYS\b/);
  13
  14
  15     if ($^O eq "hpux" or $Config{'extensions'} !~ /\bSocket\b/ &&
  16         !(($^O eq 'VMS') && $Config{d_socket})) {
  17         print "1..0\n";
  18         exit 0;
  19       }
  20
  21     # Too many things in this test will hang forever if something is wrong,
  22     # so we need a self destruct timer. And IO can hang despite an alarm.
  23
  24     # This is convoluted, but we must fork before Test::More, else child's
  25     # Test::More thinks that it ran no tests, and prints a message to that
  26     # effect
  27     if( $can_fork) {
  28       my $parent = $$;
  29       $child = fork;
  30       die "Fork failed" unless defined $child;
  31       if (!$child) {
  32         $SIG{INT} = sub {exit 0}; # You have 60 seconds. Your time starts now.
  33         my $must_finish_by = time + 60;
  34         my $remaining;
  35         while ($remaining = time - $must_finish_by) {
  36           sleep $remaining;
  37         }
  38         warn "Something unexpectedly hung during testing";
  39         kill "INT", $parent or die "Kill failed: $!";
  40         exit 1;
  41       }
  42     }
  43 }
  44
  45 use Socket;
  46 use Test::More;
  47 use strict;
  48 use warnings;
  49 use Errno;
  50
  51 my $skip_reason;
  52
  53 if( !$Config{d_alarm} ) {
  54   plan skip_all => "alarm() not implemented on this platform";
  55 } elsif( !$can_fork ) {
  56   plan skip_all => "fork() not implemented on this platform";
  57 } else {
  58   # This should fail but not die if there is real socketpair
  59   eval {socketpair LEFT, RIGHT, -1, -1, -1};
  60   if ($@ =~ /^Unsupported socket function "socketpair" called/) {
  61     plan skip_all => 'No socketpair (real or emulated)';
  62   } else {
  63     eval {AF_UNIX};
  64     if ($@ =~ /^Your vendor has not defined Socket macro AF_UNIX/) {
  65       plan skip_all => 'No AF_UNIX';
  66     } else {
  67       plan tests => 45;
  68     }
  69   }
  70 }
  71
  72 # But we'll install an alarm handler in case any of the races below fail.
  73 $SIG{ALRM} = sub {die "Unexpected alarm during testing"};
  74
  75 ok (socketpair (LEFT, RIGHT, AF_UNIX, SOCK_STREAM, PF_UNSPEC),
  76     "socketpair (LEFT, RIGHT, AF_UNIX, SOCK_STREAM, PF_UNSPEC)")
  77   or print "# \$\! = $!\n";
  78
  79 binmode(LEFT,  ":bytes");
  80 binmode(RIGHT, ":bytes");
  81
  82 my @left = ("hello ", "world\n");
  83 my @right = ("perl ", "rules!"); # Not like I'm trying to bias any survey here.
  84
  85 foreach (@left) {
  86   # is (syswrite (LEFT, $_), length $_, "write " . _qq ($_) . " to left");
  87   is (syswrite (LEFT, $_), length $_, "syswrite to left");
  88 }
  89 foreach (@right) {
  90   # is (syswrite (RIGHT, $_), length $_, "write " . _qq ($_) . " to right");
  91   is (syswrite (RIGHT, $_), length $_, "syswrite to right");
  92 }
  93
  94 # stream socket, so our writes will become joined:
  95 my ($buffer, $expect);
  96 $expect = join '', @right;
  97 undef $buffer;
  98 is (read (LEFT, $buffer, length $expect), length $expect, "read on left");
  99 is ($buffer, $expect, "content what we expected?");
 100 $expect = join '', @left;
 101 undef $buffer;
 102 is (read (RIGHT, $buffer, length $expect), length $expect, "read on right");
 103 is ($buffer, $expect, "content what we expected?");
 104
 105 ok (shutdown(LEFT, SHUT_WR), "shutdown left for writing");
 106 # This will hang forever if eof is buggy, and alarm doesn't interrupt system
 107 # Calls. Hence the child process minder.
 108 {
 109   local $SIG{ALRM} = sub { warn "EOF on right took over 3 seconds" };
 110   local $TODO = "Known problems with unix sockets on $^O"
 111       if $^O eq 'hpux' || $^O eq 'unicosmk';
 112   alarm 3;
 113   $! = 0;
 114   ok (eof RIGHT, "right is at EOF");
 115   is ($!, '', 'and $! should report no error');
 116   alarm 60;
 117 }
 118
 119 my $err = $!;
 120 $SIG{PIPE} = 'IGNORE';
 121 {
 122   local $SIG{ALRM}
 123     = sub { warn "syswrite to left didn't fail within 3 seconds" };
 124   alarm 3;
 125   # Split the system call from the is() - is() does IO so
 126   # (say) a flush may do a seek which on a pipe may disturb errno
 127   my $ans = syswrite (LEFT, "void");
 128   $err = $!;
 129   is ($ans, undef, "syswrite to shutdown left should fail");
 130   alarm 60;
 131 }
 132 {
 133   # This may need skipping on some OSes - restoring value saved above
 134   # should help
 135   $! = $err;
 136   ok (($!{EPIPE} or $!{ESHUTDOWN}), '$! should be EPIPE or ESHUTDOWN')
 137     or printf "\$\!=%d(%s)\n", $err, $err;
 138 }
 139
 140 my @gripping = (chr 255, chr 127);
 141 foreach (@gripping) {
 142   is (syswrite (RIGHT, $_), length $_, "syswrite to right");
 143 }
 144
 145 ok (!eof LEFT, "left is not at EOF");
 146
 147 $expect = join '', @gripping;
 148 undef $buffer;
 149 is (read (LEFT, $buffer, length $expect), length $expect, "read on left");
 150 is ($buffer, $expect, "content what we expected?");
 151
 152 ok (close LEFT, "close left");
 153 ok (close RIGHT, "close right");
 154
 155
 156 # And now datagrams
 157 # I suspect we also need a self destruct time-bomb for these, as I don't see any
 158 # guarantee that the stack won't drop a UDP packet, even if it is for localhost.
 159
 160 SKIP: {
 161   skip "No usable SOCK_DGRAM for socketpair", 24 if ($^O =~ /^(MSWin32|os2)\z/);
 162   local $TODO = "socketpair not supported on $^O" if $^O eq 'nto';
 163
 164 ok (socketpair (LEFT, RIGHT, AF_UNIX, SOCK_DGRAM, PF_UNSPEC),
 165     "socketpair (LEFT, RIGHT, AF_UNIX, SOCK_DGRAM, PF_UNSPEC)")
 166   or print "# \$\! = $!\n";
 167
 168 binmode(LEFT,  ":bytes");
 169 binmode(RIGHT, ":bytes");
 170
 171 foreach (@left) {
 172   # is (syswrite (LEFT, $_), length $_, "write " . _qq ($_) . " to left");
 173   is (syswrite (LEFT, $_), length $_, "syswrite to left");
 174 }
 175 foreach (@right) {
 176   # is (syswrite (RIGHT, $_), length $_, "write " . _qq ($_) . " to right");
 177   is (syswrite (RIGHT, $_), length $_, "syswrite to right");
 178 }
 179
 180 # stream socket, so our writes will become joined:
 181 my ($total);
 182 $total = join '', @right;
 183 foreach $expect (@right) {
 184   undef $buffer;
 185   is (sysread (LEFT, $buffer, length $total), length $expect, "read on left");
 186   is ($buffer, $expect, "content what we expected?");
 187 }
 188 $total = join '', @left;
 189 foreach $expect (@left) {
 190   undef $buffer;
 191   is (sysread (RIGHT, $buffer, length $total), length $expect, "read on right");
 192   is ($buffer, $expect, "content what we expected?");
 193 }
 194
 195 ok (shutdown(LEFT, 1), "shutdown left for writing");
 196
 197 # eof uses buffering. eof is indicated by a sysread of zero.
 198 # but for a datagram socket there's no way it can know nothing will ever be
 199 # sent
 200 SKIP: {
 201   skip "$^O does length 0 udp reads", 2 if ($^O eq 'os390');
 202
 203   my $alarmed = 0;
 204   local $SIG{ALRM} = sub { $alarmed = 1; };
 205   print "# Approximate forever as 3 seconds. Wait 'forever'...\n";
 206   alarm 3;
 207   undef $buffer;
 208   is (sysread (RIGHT, $buffer, 1), undef,
 209       "read on right should be interrupted");
 210   is ($alarmed, 1, "alarm should have fired");
 211 }
 212
 213 alarm 30;
 214
 215 #ok (eof RIGHT, "right is at EOF");
 216
 217 foreach (@gripping) {
 218   is (syswrite (RIGHT, $_), length $_, "syswrite to right");
 219 }
 220
 221 $total = join '', @gripping;
 222 foreach $expect (@gripping) {
 223   undef $buffer;
 224   is (sysread (LEFT, $buffer, length $total), length $expect, "read on left");
 225   is ($buffer, $expect, "content what we expected?");
 226 }
 227
 228 ok (close LEFT, "close left");
 229 ok (close RIGHT, "close right");
 230
 231 } # end of DGRAM SKIP
 232
 233 kill "INT", $child or warn "Failed to kill child process $child: $!";
 234 exit 0;