ext/POSIX/t/posix.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require Config; import Config;
   7     if ($^O ne 'VMS' and $Config{'extensions'} !~ /\bPOSIX\b/) {
   8         print "1..0\n";
   9         exit 0;
  10     }
  11 }
  12
  13 require "./test.pl";
  14 plan(tests => 38);
  15
  16
  17 use POSIX qw(fcntl_h signal_h limits_h _exit getcwd open read strftime write
  18              errno);
  19 use strict 'subs';
  20
  21 $| = 1;
  22
  23 $Is_W32     = $^O eq 'MSWin32';
  24 $Is_Dos     = $^O eq 'dos';
  25 $Is_MPE     = $^O eq 'mpeix';
  26 $Is_MacOS   = $^O eq 'MacOS';
  27 $Is_VMS     = $^O eq 'VMS';
  28 $Is_OS2     = $^O eq 'os2';
  29 $Is_UWin    = $^O eq 'uwin';
  30 $Is_OS390   = $^O eq 'os390';
  31
  32 ok( $testfd = open("TEST", O_RDONLY, 0),        'O_RDONLY with open' );
  33 read($testfd, $buffer, 9) if $testfd > 2;
  34 is( $buffer, "#!./perl\n",                      '    with read' );
  35
  36 write(1,"ok 3\nnot ok 3\n", 5);
  37 next_test();
  38
  39 SKIP: {
  40     skip("no pipe() support on DOS", 2) if $Is_Dos;
  41
  42     @fds = POSIX::pipe();
  43     ok( $fds[0] > $testfd,      'POSIX::pipe' );
  44
  45     CORE::open($reader = \*READER, "<&=".$fds[0]);
  46     CORE::open($writer = \*WRITER, ">&=".$fds[1]);
  47     print $writer "ok 5\n";
  48     close $writer;
  49     print <$reader>;
  50     close $reader;
  51     next_test();
  52 }
  53
  54 SKIP: {
  55     skip("no sigaction support on win32/dos", 6) if $Is_W32 || $Is_Dos;
  56
  57     my $sigset = new POSIX::SigSet 1, 3;
  58     $sigset->delset(1);
  59     ok(! $sigset->ismember(1),  'POSIX::SigSet->delset' );
  60     ok(  $sigset->ismember(3),  'POSIX::SigSet->ismember' );
  61
  62     SKIP: {
  63         skip("no kill() support on Mac OS", 4) if $Is_MacOS;
  64
  65         my $mask   = new POSIX::SigSet &SIGINT;
  66         my $action = new POSIX::SigAction 'main::SigHUP', $mask, 0;
  67         sigaction(&SIGHUP, $action);
  68         $SIG{'INT'} = 'SigINT';
  69         kill 'HUP', $$;
  70         sleep 1;
  71         print "ok 11 - signal masks successful\n";
  72
  73         sub SigHUP {
  74             print "ok 8 - sigaction SIGHUP\n";
  75             kill 'INT', $$;
  76             sleep 2;
  77             print "ok 9 - sig mask delayed SIGINT\n";
  78         }
  79
  80         sub SigINT {
  81             print "ok 10 -   masked SIGINT received\n";
  82         }
  83
  84         # The order of the above tests is very important, so
  85         # we use literal prints and hard coded numbers.
  86         next_test() for 1..4;
  87     }
  88 }
  89
  90 SKIP: {
  91     skip("_POSIX_OPEN_MAX is inaccurate on MPE", 1) if $Is_MPE;
  92     skip("_POSIX_OPEN_MAX undefined ($fds[1])",  1) unless &_POSIX_OPEN_MAX;
  93
  94     ok( &_POSIX_OPEN_MAX == 16 || &_POSIX_OPEN_MAX == 20, "The two allowed values according to susv2 and susv3" );
  95
  96 }
  97
  98 my $pat;
  99 if ($Is_MacOS) {
 100     $pat = qr/:t:$/;
 101 }
 102 elsif ( $Is_VMS ) {
 103     $pat = qr/\.T]/i;
 104 }
 105 else {
 106     $pat = qr#[\\/]t$#i;
 107 }
 108 like( getcwd(), qr/$pat/, 'getcwd' );
 109
 110 # Check string conversion functions.
 111
 112 SKIP: {
 113     skip("strtod() not present", 1) unless $Config{d_strtod};
 114
 115     $lc = &POSIX::setlocale(&POSIX::LC_NUMERIC, 'C') if $Config{d_setlocale};
 116
 117     # we're just checking that strtod works, not how accurate it is
 118     ($n, $x) = &POSIX::strtod('3.14159_OR_SO');
 119     ok((abs("3.14159" - $n) < 1e-6) && ($x == 6), 'strtod works');
 120
 121     &POSIX::setlocale(&POSIX::LC_NUMERIC, $lc) if $Config{d_setlocale};
 122 }
 123
 124 SKIP: {
 125     skip("strtol() not present", 2) unless $Config{d_strtol};
 126
 127     ($n, $x) = &POSIX::strtol('21_PENGUINS');
 128     is($n, 21, 'strtol() number');
 129     is($x, 9,  '         unparsed chars');
 130 }
 131
 132 SKIP: {
 133     skip("strtoul() not present", 2) unless $Config{d_strtoul};
 134
 135     ($n, $x) = &POSIX::strtoul('88_TEARS');
 136     is($n, 88, 'strtoul() number');
 137     is($x, 6,  '          unparsed chars');
 138 }
 139
 140 # Pick up whether we're really able to dynamically load everything.
 141 ok( &POSIX::acos(1.0) == 0.0,   'dynamic loading' );
 142
 143 # This can coredump if struct tm has a timezone field and we
 144 # didn't detect it.  If this fails, try adding
 145 # -DSTRUCT_TM_HASZONE to your cflags when compiling ext/POSIX/POSIX.c.
 146 # See ext/POSIX/hints/sunos_4.pl and ext/POSIX/hints/linux.pl
 147 print POSIX::strftime("ok 20 # %H:%M, on %D\n", localtime());
 148 next_test();
 149
 150 # If that worked, validate the mini_mktime() routine's normalisation of
 151 # input fields to strftime().
 152 sub try_strftime {
 153     my $expect = shift;
 154     my $got = POSIX::strftime("%a %b %d %H:%M:%S %Y %j", @_);
 155     is($got, $expect, "validating mini_mktime() and strftime(): $expect");
 156 }
 157
 158 $lc = &POSIX::setlocale(&POSIX::LC_TIME, 'C') if $Config{d_setlocale};
 159 try_strftime("Wed Feb 28 00:00:00 1996 059", 0,0,0, 28,1,96);
 160 try_strftime("Thu Feb 29 00:00:60 1996 060", 60,0,-24, 30,1,96);
 161 try_strftime("Fri Mar 01 00:00:00 1996 061", 0,0,-24, 31,1,96);
 162 try_strftime("Sun Feb 28 00:00:00 1999 059", 0,0,0, 28,1,99);
 163 try_strftime("Mon Mar 01 00:00:00 1999 060", 0,0,24, 28,1,99);
 164 try_strftime("Mon Feb 28 00:00:00 2000 059", 0,0,0, 28,1,100);
 165 try_strftime("Tue Feb 29 00:00:00 2000 060", 0,0,0, 0,2,100);
 166 try_strftime("Wed Mar 01 00:00:00 2000 061", 0,0,0, 1,2,100);
 167 try_strftime("Fri Mar 31 00:00:00 2000 091", 0,0,0, 31,2,100);
 168 &POSIX::setlocale(&POSIX::LC_TIME, $lc) if $Config{d_setlocale};
 169
 170 {
 171     for my $test (0, 1) {
 172         $! = 0;
 173         # POSIX::errno is autoloaded.
 174         # Autoloading requires many system calls.
 175         # errno() looks at $! to generate its result.
 176         # Autoloading should not munge the value.
 177         my $foo  = $!;
 178         my $errno = POSIX::errno();
 179
 180         local $TODO;
 181         $TODO = 'POSIX::errno() munged by autoloading on VMS'
 182             if $Is_VMS && $test == 0;
 183
 184         # Force numeric context.
 185         is( $errno + 0, $foo + 0,     'autoloading and errno() mix' );
 186     }
 187 }
 188
 189 SKIP: {
 190   skip("no kill() support on Mac OS", 1) if $Is_MacOS;
 191   is (eval "kill 0", 0, "check we have CORE::kill")
 192     or print "\$\@ is " . _qq($@) . "\n";
 193 }
 194
 195 # Check that we can import the POSIX kill routine
 196 POSIX->import ('kill');
 197 my $result = eval "kill 0";
 198 is ($result, undef, "we should now have POSIX::kill");
 199 # Check usage.
 200 like ($@, qr/^Usage: POSIX::kill\(pid, sig\)/, "check its usage message");
 201
 202 # Check unimplemented.
 203 $result = eval {POSIX::offsetof};
 204 is ($result, undef, "offsetof should fail");
 205 like ($@, qr/^Unimplemented: POSIX::offsetof\(\) is C-specific/,
 206       "check its unimplemented message");
 207
 208 # Check reimplemented.
 209 $result = eval {POSIX::fgets};
 210 is ($result, undef, "fgets should fail");
 211 like ($@, qr/^Use method IO::Handle::gets\(\) instead/,
 212       "check its redef message");
 213
 214 $| = 0;
 215 # The following line assumes buffered output, which may be not true:
 216 print '@#!*$@(!@#$' unless ($Is_MacOS || $Is_OS2 || $Is_UWin || $Is_OS390 ||
 217                             $Is_VMS ||
 218                             (defined $ENV{PERLIO} &&
 219                              $ENV{PERLIO} eq 'unix' &&
 220                              $Config::Config{useperlio}));
 221 _exit(0);